classes/cpan.bbclass

   1 #
   2 # This is for perl modules that use the old Makefile.PL build system
   3 #
   4 inherit cpan-base
   5
   6 EXTRA_CPANFLAGS ?= ""
   7
   8 # Env var which tells perl if it should use host (no) or target (yes) settings
   9 export PERLCONFIGTARGET = "${@is_target(d)}"
  10
  11 # Env var which tells perl where the perl include files are
  12 export PERL_INC = "${STAGING_LIBDIR}/perl/${@get_perl_version(d)}/CORE"
  13 export PERL_ARCHLIB = "${STAGING_LIBDIR_NATIVE}/perl/${@get_perl_version(d)}"
  14
  15 cpan_do_configure () {
  16         yes '' | perl Makefile.PL ${EXTRA_CPANFLAGS}
  17         if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
  18                 . ${STAGING_DIR_TARGET}/perl/config.sh
  19                 if [ "${IS_NEW_PERL}" = "yes" ]; then
  20                         sed -i -e "s:\(SITELIBEXP = \).*:\1${sitelibexp}:" \
  21                                 -e "s:\(SITEARCHEXP = \).*:\1${sitearchexp}:" \
  22                                 -e "s:\(INSTALLVENDORLIB = \).*:\1${D}${datadir}/perl5:" \
  23                                 -e "s:\(INSTALLVENDORARCH = \).*:\1${D}${libdir}/perl5:" \
  24                                 -e "s:\(LDDLFLAGS.*\)${STAGING_LIBDIR_NATIVE}:\1${STAGING_LIBDIR}:" \
  25                                 Makefile
  26                 else
  27                         sed -i -e "s:\(SITELIBEXP = \).*:\1${sitelibexp}:" \
  28                                 -e "s:\(SITEARCHEXP = \).*:\1${sitearchexp}:" \
  29                                 -e "s:\(INSTALLVENDORLIB = \).*:\1${D}${libdir}/perl5/site_perl/${version}:" \
  30                                 -e "s:\(INSTALLVENDORARCH = \).*:\1${D}${libdir}/perl5/site_perl/${version}:" \
  31                                 -e "s:\(LDDLFLAGS.*\)${STAGING_LIBDIR_NATIVE}:\1${STAGING_LIBDIR}:" \
  32                                 Makefile
  33                 fi
  34         fi
  35 }
  36
  37 cpan_do_compile () {
  38         if [ "${IS_NEW_PERL}" = "yes" ]; then
  39                 oe_runmake PASTHRU_INC="${CFLAGS}" CCFLAGS="${CFLAGS}" LD="${CCLD}"
  40         else
  41                 # You must use gcc to link on sh
  42                 OPTIONS=""
  43                 if test ${TARGET_ARCH} = "sh3" -o ${TARGET_ARCH} = "sh4"; then
  44                         OPTIONS="LD=${TARGET_ARCH}-${TARGET_OS}-gcc"
  45                 fi
  46                 if test ${TARGET_ARCH} = "powerpc" ; then
  47                         OPTIONS="LD=${TARGET_ARCH}-${TARGET_OS}-gcc"
  48                 fi
  49                 oe_runmake PASTHRU_INC="${CFLAGS}" CCFLAGS="${CFLAGS}" $OPTIONS
  50         fi
  51 }
  52
  53 cpan_do_install () {
  54         if [ ${@is_target(d)} = "yes" ]; then
  55                 oe_runmake install_vendor
  56         fi
  57 }
  58
  59 cpan_do_stage () {
  60         if [ ${@is_target(d)} = "no" ]; then
  61                 oe_runmake install_vendor
  62         fi
  63 }
  64
  65
  66 EXPORT_FUNCTIONS do_configure do_compile do_install do_stage