scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with is a section in vmlinux called
  10 # __mcount_loc that contains a list of pointers to all the
  11 # call sites in the kernel that call mcount. Later on boot up, the kernel
  12 # will read this list, save the locations and turn them into nops.
  13 # When tracing or profiling is later enabled, these locations will then
  14 # be converted back to pointers to some function.
  15 #
  16 # This is no easy feat. This script is called just after the original
  17 # object is compiled and before it is linked.
  18 #
  19 # The references to the call sites are offsets from the section of text
  20 # that the call site is in. Hence, all functions in a section that
  21 # has a call site to mcount, will have the offset from the beginning of
  22 # the section and not the beginning of the function.
  23 #
  24 # The trick is to find a way to record the beginning of the section.
  25 # The way we do this is to look at the first function in the section
  26 # which will also be the location of that section after final link.
  27 # e.g.
  28 #
  29 #  .section ".text.sched"
  30 #  .globl my_func
  31 #  my_func:
  32 #        [...]
  33 #        call mcount  (offset: 0x5)
  34 #        [...]
  35 #        ret
  36 #  other_func:
  37 #        [...]
  38 #        call mcount (offset: 0x1b)
  39 #        [...]
  40 #
  41 # Both relocation offsets for the mcounts in the above example will be
  42 # offset from .text.sched. If we make another file called tmp.s with:
  43 #
  44 #  .section __mcount_loc
  45 #  .quad  my_func + 0x5
  46 #  .quad  my_func + 0x1b
  47 #
  48 # We can then compile this tmp.s into tmp.o, and link it to the original
  49 # object.
  50 #
  51 # But this gets hard if my_func is not globl (a static function).
  52 # In such a case we have:
  53 #
  54 #  .section ".text.sched"
  55 #  my_func:
  56 #        [...]
  57 #        call mcount  (offset: 0x5)
  58 #        [...]
  59 #        ret
  60 #  .globl my_func
  61 #  other_func:
  62 #        [...]
  63 #        call mcount (offset: 0x1b)
  64 #        [...]
  65 #
  66 # If we make the tmp.s the same as above, when we link together with
  67 # the original object, we will end up with two symbols for my_func:
  68 # one local, one global.  After final compile, we will end up with
  69 # an undefined reference to my_func.
  70 #
  71 # Since local objects can reference local variables, we need to find
  72 # a way to make tmp.o reference the local objects of the original object
  73 # file after it is linked together. To do this, we convert the my_func
  74 # into a global symbol before linking tmp.o. Then after we link tmp.o
  75 # we will only have a single symbol for my_func that is global.
  76 # We can convert my_func back into a local symbol and we are done.
  77 #
  78 # Here are the steps we take:
  79 #
  80 # 1) Record all the local symbols by using 'nm'
  81 # 2) Use objdump to find all the call site offsets and sections for
  82 #    mcount.
  83 # 3) Compile the list into its own object.
  84 # 4) Do we have to deal with local functions? If not, go to step 8.
  85 # 5) Make an object that converts these local functions to global symbols
  86 #    with objcopy.
  87 # 6) Link together this new object with the list object.
  88 # 7) Convert the local functions back to local symbols and rename
  89 #    the result as the original object.
  90 #    End.
  91 # 8) Link the object with the list object.
  92 # 9) Move the result back to the original object.
  93 #    End.
  94 #
  95
  96 use strict;
  97
  98 my $P = $0;
  99 $P =~ s@.*/@@g;
 100
 101 my $V = '0.1';
 102
 103 if ($#ARGV < 7) {
 104         print "usage: $P arch objdump objcopy cc ld nm rm mv is_module inputfile\n";
 105         print "version: $V\n";
 106         exit(1);
 107 }
 108
 109 my ($arch, $bits, $objdump, $objcopy, $cc,
 110     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 111
 112 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 113 if ($inputfile eq "kernel/trace/ftrace.o") {
 114     exit(0);
 115 }
 116
 117 # Acceptable sections to record.
 118 my %text_sections = (
 119      ".text" => 1,
 120      ".sched.text" => 1,
 121      ".spinlock.text" => 1,
 122      ".irqentry.text" => 1,
 123 );
 124
 125 $objdump = "objdump" if ((length $objdump) == 0);
 126 $objcopy = "objcopy" if ((length $objcopy) == 0);
 127 $cc = "gcc" if ((length $cc) == 0);
 128 $ld = "ld" if ((length $ld) == 0);
 129 $nm = "nm" if ((length $nm) == 0);
 130 $rm = "rm" if ((length $rm) == 0);
 131 $mv = "mv" if ((length $mv) == 0);
 132
 133 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 134 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 135
 136 my %locals;             # List of local (static) functions
 137 my %weak;               # List of weak functions
 138 my %convert;            # List of local functions used that needs conversion
 139
 140 my $type;
 141 my $nm_regex;           # Find the local functions (return function)
 142 my $section_regex;      # Find the start of a section
 143 my $function_regex;     # Find the name of a function
 144                         #    (return offset and func name)
 145 my $mcount_regex;       # Find the call site to mcount (return offset)
 146 my $alignment;          # The .align value to use for $mcount_section
 147 my $section_type;       # Section header plus possible alignment command
 148
 149 if ($arch eq "x86") {
 150     if ($bits == 64) {
 151         $arch = "x86_64";
 152     } else {
 153         $arch = "i386";
 154     }
 155 }
 156
 157 #
 158 # We base the defaults off of i386, the other archs may
 159 # feel free to change them in the below if statements.
 160 #
 161 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 162 $section_regex = "Disassembly of section\\s+(\\S+):";
 163 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 164 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 165 $section_type = '@progbits';
 166 $type = ".long";
 167
 168 if ($arch eq "x86_64") {
 169     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 170     $type = ".quad";
 171     $alignment = 8;
 172
 173     # force flags for this arch
 174     $ld .= " -m elf_x86_64";
 175     $objdump .= " -M x86-64";
 176     $objcopy .= " -O elf64-x86-64";
 177     $cc .= " -m64";
 178
 179 } elsif ($arch eq "i386") {
 180     $alignment = 4;
 181
 182     # force flags for this arch
 183     $ld .= " -m elf_i386";
 184     $objdump .= " -M i386";
 185     $objcopy .= " -O elf32-i386";
 186     $cc .= " -m32";
 187
 188 } elsif ($arch eq "sh") {
 189     $alignment = 2;
 190
 191     # force flags for this arch
 192     $ld .= " -m shlelf_linux";
 193     $objcopy .= " -O elf32-sh-linux";
 194     $cc .= " -m32";
 195
 196 } elsif ($arch eq "powerpc") {
 197     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 198     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 199     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 200
 201     if ($bits == 64) {
 202         $type = ".quad";
 203     }
 204
 205 } elsif ($arch eq "arm") {
 206     $alignment = 2;
 207     $section_type = '%progbits';
 208
 209 } else {
 210     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 211 }
 212
 213 my $text_found = 0;
 214 my $read_function = 0;
 215 my $opened = 0;
 216 my $mcount_section = "__mcount_loc";
 217
 218 my $dirname;
 219 my $filename;
 220 my $prefix;
 221 my $ext;
 222
 223 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 224     $dirname = $1;
 225     $filename = $2;
 226 } else {
 227     $dirname = ".";
 228     $filename = $inputfile;
 229 }
 230
 231 if ($filename =~ m,^(.*)(\.\S),) {
 232     $prefix = $1;
 233     $ext = $2;
 234 } else {
 235     $prefix = $filename;
 236     $ext = "";
 237 }
 238
 239 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 240 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 241
 242 #
 243 # --globalize-symbols came out in 2.17, we must test the version
 244 # of objcopy, and if it is less than 2.17, then we can not
 245 # record local functions.
 246 my $use_locals = 01;
 247 my $local_warn_once = 0;
 248 my $found_version = 0;
 249
 250 open (IN, "$objcopy --version |") || die "error running $objcopy";
 251 while (<IN>) {
 252     if (/objcopy.*\s(\d+)\.(\d+)/) {
 253         my $major = $1;
 254         my $minor = $2;
 255
 256         $found_version = 1;
 257         if ($major < 2 ||
 258             ($major == 2 && $minor < 17)) {
 259             $use_locals = 0;
 260         }
 261         last;
 262     }
 263 }
 264 close (IN);
 265
 266 if (!$found_version) {
 267     print STDERR "WARNING: could not find objcopy version.\n" .
 268         "\tDisabling local function references.\n";
 269 }
 270
 271
 272 #
 273 # Step 1: find all the local (static functions) and weak symbols.
 274 #        't' is local, 'w/W' is weak (we never use a weak function)
 275 #
 276 open (IN, "$nm $inputfile|") || die "error running $nm";
 277 while (<IN>) {
 278     if (/$nm_regex/) {
 279         $locals{$1} = 1;
 280     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
 281         $weak{$2} = $1;
 282     }
 283 }
 284 close(IN);
 285
 286 my @offsets;            # Array of offsets of mcount callers
 287 my $ref_func;           # reference function to use for offsets
 288 my $offset = 0;         # offset of ref_func to section beginning
 289
 290 ##
 291 # update_funcs - print out the current mcount callers
 292 #
 293 #  Go through the list of offsets to callers and write them to
 294 #  the output file in a format that can be read by an assembler.
 295 #
 296 sub update_funcs
 297 {
 298     return if ($#offsets < 0);
 299
 300     defined($ref_func) || die "No function to reference";
 301
 302     # A section only had a weak function, to represent it.
 303     # Unfortunately, a weak function may be overwritten by another
 304     # function of the same name, making all these offsets incorrect.
 305     # To be safe, we simply print a warning and bail.
 306     if (defined $weak{$ref_func}) {
 307         print STDERR
 308             "$inputfile: WARNING: referencing weak function" .
 309             " $ref_func for mcount\n";
 310         return;
 311     }
 312
 313     # is this function static? If so, note this fact.
 314     if (defined $locals{$ref_func}) {
 315
 316         # only use locals if objcopy supports globalize-symbols
 317         if (!$use_locals) {
 318             return;
 319         }
 320         $convert{$ref_func} = 1;
 321     }
 322
 323     # Loop through all the mcount caller offsets and print a reference
 324     # to the caller based from the ref_func.
 325     for (my $i=0; $i <= $#offsets; $i++) {
 326         if (!$opened) {
 327             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 328             $opened = 1;
 329             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 330             print FILE "\t.align $alignment\n" if (defined($alignment));
 331         }
 332         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
 333     }
 334 }
 335
 336 #
 337 # Step 2: find the sections and mcount call sites
 338 #
 339 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
 340
 341 my $text;
 342
 343 while (<IN>) {
 344     # is it a section?
 345     if (/$section_regex/) {
 346
 347         # Only record text sections that we know are safe
 348         if (defined($text_sections{$1})) {
 349             $read_function = 1;
 350         } else {
 351             $read_function = 0;
 352         }
 353         # print out any recorded offsets
 354         update_funcs() if ($text_found);
 355
 356         # reset all markers and arrays
 357         $text_found = 0;
 358         undef($ref_func);
 359         undef(@offsets);
 360
 361     # section found, now is this a start of a function?
 362     } elsif ($read_function && /$function_regex/) {
 363         $text_found = 1;
 364         $offset = hex $1;
 365         $text = $2;
 366
 367         # if this is either a local function or a weak function
 368         # keep looking for functions that are global that
 369         # we can use safely.
 370         if (!defined($locals{$text}) && !defined($weak{$text})) {
 371             $ref_func = $text;
 372             $read_function = 0;
 373         } else {
 374             # if we already have a function, and this is weak, skip it
 375             if (!defined($ref_func) || !defined($weak{$text})) {
 376                 $ref_func = $text;
 377             }
 378         }
 379     }
 380
 381     # is this a call site to mcount? If so, record it to print later
 382     if ($text_found && /$mcount_regex/) {
 383         $offsets[$#offsets + 1] = hex $1;
 384     }
 385 }
 386
 387 # dump out anymore offsets that may have been found
 388 update_funcs() if ($text_found);
 389
 390 # If we did not find any mcount callers, we are done (do nothing).
 391 if (!$opened) {
 392     exit(0);
 393 }
 394
 395 close(FILE);
 396
 397 #
 398 # Step 3: Compile the file that holds the list of call sites to mcount.
 399 #
 400 `$cc -o $mcount_o -c $mcount_s`;
 401
 402 my @converts = keys %convert;
 403
 404 #
 405 # Step 4: Do we have sections that started with local functions?
 406 #
 407 if ($#converts >= 0) {
 408     my $globallist = "";
 409     my $locallist = "";
 410
 411     foreach my $con (@converts) {
 412         $globallist .= " --globalize-symbol $con";
 413         $locallist .= " --localize-symbol $con";
 414     }
 415
 416     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 417     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 418
 419     #
 420     # Step 5: set up each local function as a global
 421     #
 422     `$objcopy $globallist $inputfile $globalobj`;
 423
 424     #
 425     # Step 6: Link the global version to our list.
 426     #
 427     `$ld -r $globalobj $mcount_o -o $globalmix`;
 428
 429     #
 430     # Step 7: Convert the local functions back into local symbols
 431     #
 432     `$objcopy $locallist $globalmix $inputfile`;
 433
 434     # Remove the temp files
 435     `$rm $globalobj $globalmix`;
 436
 437 } else {
 438
 439     my $mix = $dirname . "/.tmp_mx_" . $filename;
 440
 441     #
 442     # Step 8: Link the object with our list of call sites object.
 443     #
 444     `$ld -r $inputfile $mcount_o -o $mix`;
 445
 446     #
 447     # Step 9: Move the result back to the original object.
 448     #
 449     `$mv $mix $inputfile`;
 450 }
 451
 452 # Clean up the temp files
 453 `$rm $mcount_o $mcount_s`;
 454
 455 exit(0);