arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 PHDRS {
  17         text PT_LOAD FLAGS(5);  /* R_E */
  18         data PT_LOAD FLAGS(7);  /* RWE */
  19         user PT_LOAD FLAGS(7);  /* RWE */
  20         data.init PT_LOAD FLAGS(7);     /* RWE */
  21         note PT_NOTE FLAGS(4);  /* R__ */
  22 }
  23 SECTIONS
  24 {
  25   . = __START_KERNEL;
  26   phys_startup_64 = startup_64 - LOAD_OFFSET;
  27   _text = .;                    /* Text and read-only data */
  28   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  29         /* First the code that has to be first for bootstrapping */
  30         *(.bootstrap.text)
  31         /* Then all the functions that are "hot" in profiles, to group them
  32            onto the same hugetlb entry */
  33         #include "functionlist"
  34         /* Then the rest */
  35         *(.text)
  36         SCHED_TEXT
  37         LOCK_TEXT
  38         KPROBES_TEXT
  39         *(.fixup)
  40         *(.gnu.warning)
  41         } :text = 0x9090
  42                                 /* out-of-line lock text */
  43   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  44
  45   _etext = .;                   /* End of text section */
  46
  47   . = ALIGN(16);                /* Exception table */
  48   __start___ex_table = .;
  49   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  50   __stop___ex_table = .;
  51
  52   RODATA
  53
  54   BUG_TABLE
  55
  56   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  57                                 /* Data */
  58   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  59         *(.data)
  60         CONSTRUCTORS
  61         } :data
  62
  63   _edata = .;                   /* End of data section */
  64
  65   . = ALIGN(PAGE_SIZE);
  66   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  67   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  68         *(.data.cacheline_aligned)
  69   }
  70   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  71   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  72         *(.data.read_mostly)
  73   }
  74
  75 #define VSYSCALL_ADDR (-10*1024*1024)
  76 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  77 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  78
  79 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  80 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  81
  82 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  83 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  84
  85   . = VSYSCALL_ADDR;
  86   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  87   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  88
  89   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  90   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  91   xtime_lock = VVIRT(.xtime_lock);
  92
  93   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
  94   vxtime = VVIRT(.vxtime);
  95
  96   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
  97   vgetcpu_mode = VVIRT(.vgetcpu_mode);
  98
  99   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 100   sys_tz = VVIRT(.sys_tz);
 101
 102   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 103   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 104
 105   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 106   xtime = VVIRT(.xtime);
 107
 108   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 109   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 110   jiffies = VVIRT(.jiffies);
 111
 112   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 113   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 114   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 115
 116   . = VSYSCALL_VIRT_ADDR + 4096;
 117
 118 #undef VSYSCALL_ADDR
 119 #undef VSYSCALL_PHYS_ADDR
 120 #undef VSYSCALL_VIRT_ADDR
 121 #undef VLOAD_OFFSET
 122 #undef VLOAD
 123 #undef VVIRT_OFFSET
 124 #undef VVIRT
 125
 126   . = ALIGN(8192);              /* init_task */
 127   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 128         *(.data.init_task)
 129   }:data.init
 130
 131   . = ALIGN(4096);
 132   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 133         *(.data.page_aligned)
 134   }
 135
 136   /* might get freed after init */
 137   . = ALIGN(4096);
 138   __smp_alt_begin = .;
 139   __smp_alt_instructions = .;
 140   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 141         *(.smp_altinstructions)
 142   }
 143   __smp_alt_instructions_end = .;
 144   . = ALIGN(8);
 145   __smp_locks = .;
 146   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 147         *(.smp_locks)
 148   }
 149   __smp_locks_end = .;
 150   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 151         *(.smp_altinstr_replacement)
 152   }
 153   . = ALIGN(4096);
 154   __smp_alt_end = .;
 155
 156   . = ALIGN(4096);              /* Init code and data */
 157   __init_begin = .;
 158   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 159         _sinittext = .;
 160         *(.init.text)
 161         _einittext = .;
 162   }
 163   __initdata_begin = .;
 164   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 165   __initdata_end = .;
 166   . = ALIGN(16);
 167   __setup_start = .;
 168   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 169   __setup_end = .;
 170   __initcall_start = .;
 171   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 172         INITCALLS
 173   }
 174   __initcall_end = .;
 175   __con_initcall_start = .;
 176   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 177         *(.con_initcall.init)
 178   }
 179   __con_initcall_end = .;
 180   SECURITY_INIT
 181   . = ALIGN(8);
 182   __alt_instructions = .;
 183   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 184         *(.altinstructions)
 185   }
 186   __alt_instructions_end = .;
 187   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 188         *(.altinstr_replacement)
 189   }
 190   /* .exit.text is discard at runtime, not link time, to deal with references
 191      from .altinstructions and .eh_frame */
 192   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 193   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 194   . = ALIGN(4096);
 195   __initramfs_start = .;
 196   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 197   __initramfs_end = .;
 198     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 199   __per_cpu_start = .;
 200   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 201   __per_cpu_end = .;
 202   . = ALIGN(4096);
 203   __init_end = .;
 204
 205   . = ALIGN(4096);
 206   __nosave_begin = .;
 207   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 208   . = ALIGN(4096);
 209   __nosave_end = .;
 210
 211   __bss_start = .;              /* BSS */
 212   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 213         *(.bss.page_aligned)
 214         *(.bss)
 215         }
 216   __bss_stop = .;
 217
 218   _end = . ;
 219
 220   /* Sections to be discarded */
 221   /DISCARD/ : {
 222         *(.exitcall.exit)
 223 #ifndef CONFIG_UNWIND_INFO
 224         *(.eh_frame)
 225 #endif
 226         }
 227
 228   STABS_DEBUG
 229
 230   DWARF_DEBUG
 231 }