2 * linux/arch/x86_64/entry.S
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
10 * entry.S contains the system-call and fault low-level handling routines.
12 * Some of this is documented in Documentation/x86/entry_64.txt
14 * NOTE: This code handles signal-recognition, which happens every time
15 * after an interrupt and after each system call.
17 * Normal syscalls and interrupts don't save a full stack frame, this is
18 * only done for syscall tracing, signals or fork/exec et.al.
20 * A note on terminology:
21 * - top of stack: Architecture defined interrupt frame from SS to RIP
22 * at the top of the kernel process stack.
23 * - partial stack frame: partially saved registers up to R11.
24 * - full stack frame: Like partial stack frame, but all register saved.
27 * - CFI macros are used to generate dwarf2 unwind information for better
28 * backtraces. They don't change any code.
29 * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
30 * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
31 * There are unfortunately lots of special cases where some registers
32 * not touched. The macro is a big mess that should be cleaned up.
33 * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
34 * Gives a full stack frame.
35 * - ENTRY/END Define functions in the symbol table.
36 * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
37 * frame that is otherwise undefined after a SYSCALL
38 * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
39 * - idtentry - Define exception entry points.
42 #include <linux/linkage.h>
43 #include <asm/segment.h>
44 #include <asm/cache.h>
45 #include <asm/errno.h>
46 #include <asm/dwarf2.h>
47 #include <asm/calling.h>
48 #include <asm/asm-offsets.h>
50 #include <asm/unistd.h>
51 #include <asm/thread_info.h>
52 #include <asm/hw_irq.h>
53 #include <asm/page_types.h>
54 #include <asm/irqflags.h>
55 #include <asm/paravirt.h>
56 #include <asm/percpu.h>
58 #include <asm/context_tracking.h>
60 #include <asm/pgtable_types.h>
61 #include <linux/err.h>
63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
64 #include <linux/elf-em.h>
65 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
66 #define __AUDIT_ARCH_64BIT 0x80000000
67 #define __AUDIT_ARCH_LE 0x40000000
70 .section .entry.text, "ax"
73 #ifndef CONFIG_PREEMPT
74 #define retint_kernel retint_restore_args
77 #ifdef CONFIG_PARAVIRT
78 ENTRY(native_usergs_sysret64)
81 ENDPROC(native_usergs_sysret64)
82 #endif /* CONFIG_PARAVIRT */
85 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
86 #ifdef CONFIG_TRACE_IRQFLAGS
87 bt $9,EFLAGS-\offset(%rsp) /* interrupts off? */
95 * When dynamic function tracer is enabled it will add a breakpoint
96 * to all locations that it is about to modify, sync CPUs, update
97 * all the code, sync CPUs, then remove the breakpoints. In this time
98 * if lockdep is enabled, it might jump back into the debug handler
99 * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
101 * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
102 * make sure the stack pointer does not get reset back to the top
103 * of the debug stack, and instead just reuses the current stack.
105 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
107 .macro TRACE_IRQS_OFF_DEBUG
108 call debug_stack_set_zero
110 call debug_stack_reset
113 .macro TRACE_IRQS_ON_DEBUG
114 call debug_stack_set_zero
116 call debug_stack_reset
119 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
120 bt $9,EFLAGS-\offset(%rsp) /* interrupts off? */
127 # define TRACE_IRQS_OFF_DEBUG TRACE_IRQS_OFF
128 # define TRACE_IRQS_ON_DEBUG TRACE_IRQS_ON
129 # define TRACE_IRQS_IRETQ_DEBUG TRACE_IRQS_IRETQ
133 * C code is not supposed to know about undefined top of stack. Every time
134 * a C function with an pt_regs argument is called from the SYSCALL based
135 * fast path FIXUP_TOP_OF_STACK is needed.
136 * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
140 /* %rsp:at FRAMEEND */
141 .macro FIXUP_TOP_OF_STACK tmp offset=0
142 movq PER_CPU_VAR(old_rsp),\tmp
143 movq \tmp,RSP+\offset(%rsp)
144 movq $__USER_DS,SS+\offset(%rsp)
145 movq $__USER_CS,CS+\offset(%rsp)
146 movq $-1,RCX+\offset(%rsp)
147 movq R11+\offset(%rsp),\tmp /* get eflags */
148 movq \tmp,EFLAGS+\offset(%rsp)
151 .macro RESTORE_TOP_OF_STACK tmp offset=0
152 movq RSP+\offset(%rsp),\tmp
153 movq \tmp,PER_CPU_VAR(old_rsp)
154 movq EFLAGS+\offset(%rsp),\tmp
155 movq \tmp,R11+\offset(%rsp)
158 .macro FAKE_STACK_FRAME child_rip
159 /* push in order ss, rsp, eflags, cs, rip */
161 pushq_cfi $__KERNEL_DS /* ss */
162 /*CFI_REL_OFFSET ss,0*/
163 pushq_cfi %rax /* rsp */
165 pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
166 /*CFI_REL_OFFSET rflags,0*/
167 pushq_cfi $__KERNEL_CS /* cs */
168 /*CFI_REL_OFFSET cs,0*/
169 pushq_cfi \child_rip /* rip */
171 pushq_cfi %rax /* orig rax */
174 .macro UNFAKE_STACK_FRAME
176 CFI_ADJUST_CFA_OFFSET -(6*8)
180 * initial frame state for interrupts (and exceptions without error code)
182 .macro EMPTY_FRAME start=1 offset=0
186 CFI_DEF_CFA rsp,8+\offset
188 CFI_DEF_CFA_OFFSET 8+\offset
193 * initial frame state for interrupts (and exceptions without error code)
195 .macro INTR_FRAME start=1 offset=0
196 EMPTY_FRAME \start, SS+8+\offset-RIP
197 /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
198 CFI_REL_OFFSET rsp, RSP+\offset-RIP
199 /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
200 /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
201 CFI_REL_OFFSET rip, RIP+\offset-RIP
205 * initial frame state for exceptions with error code (and interrupts
206 * with vector already pushed)
208 .macro XCPT_FRAME start=1 offset=0
209 INTR_FRAME \start, RIP+\offset-ORIG_RAX
210 /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
214 * frame that enables calling into C.
216 .macro PARTIAL_FRAME start=1 offset=0
217 XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
218 CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
219 CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
220 CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
221 CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
222 CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
223 CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
224 CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
225 CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
226 CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
230 * frame that enables passing a complete pt_regs to a C function.
232 .macro DEFAULT_FRAME start=1 offset=0
233 PARTIAL_FRAME \start, R11+\offset-R15
234 CFI_REL_OFFSET rbx, RBX+\offset
235 CFI_REL_OFFSET rbp, RBP+\offset
236 CFI_REL_OFFSET r12, R12+\offset
237 CFI_REL_OFFSET r13, R13+\offset
238 CFI_REL_OFFSET r14, R14+\offset
239 CFI_REL_OFFSET r15, R15+\offset
242 /* save partial stack frame */
245 /* start from rbp in pt_regs and jump over */
246 movq_cfi rdi, (RDI-RBP)
247 movq_cfi rsi, (RSI-RBP)
248 movq_cfi rdx, (RDX-RBP)
249 movq_cfi rcx, (RCX-RBP)
250 movq_cfi rax, (RAX-RBP)
251 movq_cfi r8, (R8-RBP)
252 movq_cfi r9, (R9-RBP)
253 movq_cfi r10, (R10-RBP)
254 movq_cfi r11, (R11-RBP)
256 /* Save rbp so that we can unwind from get_irq_regs() */
259 /* Save previous stack value */
262 leaq -RBP(%rsp),%rdi /* arg1 for handler */
263 testl $3, CS-RBP(%rsi)
267 * irq_count is used to check if a CPU is already on an interrupt stack
268 * or not. While this is essentially redundant with preempt_count it is
269 * a little cheaper to use a separate counter in the PDA (short of
270 * moving irq_enter into assembly, which would be too much work)
272 1: incl PER_CPU_VAR(irq_count)
273 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
274 CFI_DEF_CFA_REGISTER rsi
276 /* Store previous stack value */
278 CFI_ESCAPE 0x0f /* DW_CFA_def_cfa_expression */, 6, \
279 0x77 /* DW_OP_breg7 */, 0, \
280 0x06 /* DW_OP_deref */, \
281 0x08 /* DW_OP_const1u */, SS+8-RBP, \
282 0x22 /* DW_OP_plus */
283 /* We entered an interrupt context - irqs are off: */
306 movl $MSR_GS_BASE,%ecx
309 js 1f /* negative -> in kernel */
317 * A newly forked process directly context switches into this address.
319 * rdi: prev task we switched from
324 LOCK ; btr $TIF_FORK,TI_flags(%r8)
327 popfq_cfi # reset kernel eflags
329 call schedule_tail # rdi: 'prev' task parameter
331 GET_THREAD_INFO(%rcx)
335 testl $3, CS-ARGOFFSET(%rsp) # from kernel_thread?
338 testl $_TIF_IA32, TI_flags(%rcx) # 32-bit compat task needs IRET
339 jnz int_ret_from_sys_call
341 RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
342 jmp ret_from_sys_call # go to the SYSRET fastpath
345 subq $REST_SKIP, %rsp # leave space for volatiles
346 CFI_ADJUST_CFA_OFFSET REST_SKIP
351 jmp int_ret_from_sys_call
356 * System call entry. Up to 6 arguments in registers are supported.
358 * SYSCALL does not save anything on the stack and does not change the
359 * stack pointer. However, it does mask the flags register for us, so
360 * CLD and CLAC are not needed.
365 * rax system call number
367 * rcx return address for syscall/sysret, C arg3
370 * r10 arg3 (--> moved to rcx for C)
373 * r11 eflags for syscall/sysret, temporary for C
374 * r12-r15,rbp,rbx saved by C code, not touched.
376 * Interrupts are off on entry.
377 * Only called from user space.
379 * XXX if we had a free scratch register we could save the RSP into the stack frame
380 * and report it properly in ps. Unfortunately we haven't.
382 * When user can change the frames always force IRET. That is because
383 * it deals with uncanonical addresses better. SYSRET has trouble
384 * with them due to bugs in both AMD and Intel CPUs.
390 CFI_DEF_CFA rsp,KERNEL_STACK_OFFSET
392 /*CFI_REGISTER rflags,r11*/
395 * A hypervisor implementation might want to use a label
396 * after the swapgs, so that it can do the swapgs
397 * for the guest and jump here on syscall.
399 GLOBAL(system_call_after_swapgs)
401 movq %rsp,PER_CPU_VAR(old_rsp)
402 movq PER_CPU_VAR(kernel_stack),%rsp
404 * No need to follow this irqs off/on section - it's straight
407 ENABLE_INTERRUPTS(CLBR_NONE)
409 movq %rax,ORIG_RAX-ARGOFFSET(%rsp)
410 movq %rcx,RIP-ARGOFFSET(%rsp)
411 CFI_REL_OFFSET rip,RIP-ARGOFFSET
412 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
414 system_call_fastpath:
415 #if __SYSCALL_MASK == ~0
416 cmpq $__NR_syscall_max,%rax
418 andl $__SYSCALL_MASK,%eax
419 cmpl $__NR_syscall_max,%eax
423 call *sys_call_table(,%rax,8) # XXX: rip relative
424 movq %rax,RAX-ARGOFFSET(%rsp)
426 * Syscall return path ending with SYSRET (fast path)
427 * Has incomplete stack frame and undefined top of stack.
430 movl $_TIF_ALLWORK_MASK,%edi
434 DISABLE_INTERRUPTS(CLBR_NONE)
436 movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
441 * sysretq will re-enable interrupts:
444 movq RIP-ARGOFFSET(%rsp),%rcx
446 RESTORE_ARGS 1,-ARG_SKIP,0
447 /*CFI_REGISTER rflags,r11*/
448 movq PER_CPU_VAR(old_rsp), %rsp
452 /* Handle reschedules */
453 /* edx: work, edi: workmask */
455 bt $TIF_NEED_RESCHED,%edx
458 ENABLE_INTERRUPTS(CLBR_NONE)
464 /* Handle a signal */
467 ENABLE_INTERRUPTS(CLBR_NONE)
468 #ifdef CONFIG_AUDITSYSCALL
469 bt $TIF_SYSCALL_AUDIT,%edx
473 * We have a signal, or exit tracing or single-step.
474 * These all wind up with the iret return path anyway,
475 * so just join that path right now.
477 FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
478 jmp int_check_syscall_exit_work
481 movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
482 jmp ret_from_sys_call
484 #ifdef CONFIG_AUDITSYSCALL
486 * Fast path for syscall audit without full syscall trace.
487 * We just call __audit_syscall_entry() directly, and then
488 * jump back to the normal fast path.
491 movq %r10,%r9 /* 6th arg: 4th syscall arg */
492 movq %rdx,%r8 /* 5th arg: 3rd syscall arg */
493 movq %rsi,%rcx /* 4th arg: 2nd syscall arg */
494 movq %rdi,%rdx /* 3rd arg: 1st syscall arg */
495 movq %rax,%rsi /* 2nd arg: syscall number */
496 movl $AUDIT_ARCH_X86_64,%edi /* 1st arg: audit arch */
497 call __audit_syscall_entry
498 LOAD_ARGS 0 /* reload call-clobbered registers */
499 jmp system_call_fastpath
502 * Return fast path for syscall audit. Call __audit_syscall_exit()
503 * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
507 movq RAX-ARGOFFSET(%rsp),%rsi /* second arg, syscall return value */
508 cmpq $-MAX_ERRNO,%rsi /* is it < -MAX_ERRNO? */
509 setbe %al /* 1 if so, 0 if not */
510 movzbl %al,%edi /* zero-extend that into %edi */
511 call __audit_syscall_exit
512 movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
514 #endif /* CONFIG_AUDITSYSCALL */
516 /* Do syscall tracing */
518 #ifdef CONFIG_AUDITSYSCALL
519 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
523 movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
524 FIXUP_TOP_OF_STACK %rdi
526 call syscall_trace_enter
528 * Reload arg registers from stack in case ptrace changed them.
529 * We don't reload %rax because syscall_trace_enter() returned
530 * the value it wants us to use in the table lookup.
532 LOAD_ARGS ARGOFFSET, 1
534 #if __SYSCALL_MASK == ~0
535 cmpq $__NR_syscall_max,%rax
537 andl $__SYSCALL_MASK,%eax
538 cmpl $__NR_syscall_max,%eax
540 ja int_ret_from_sys_call /* RAX(%rsp) set to -ENOSYS above */
541 movq %r10,%rcx /* fixup for C */
542 call *sys_call_table(,%rax,8)
543 movq %rax,RAX-ARGOFFSET(%rsp)
544 /* Use IRET because user could have changed frame */
547 * Syscall return path ending with IRET.
548 * Has correct top of stack, but partial stack frame.
550 GLOBAL(int_ret_from_sys_call)
551 DISABLE_INTERRUPTS(CLBR_NONE)
553 movl $_TIF_ALLWORK_MASK,%edi
554 /* edi: mask to check */
555 GLOBAL(int_with_check)
557 GET_THREAD_INFO(%rcx)
558 movl TI_flags(%rcx),%edx
561 andl $~TS_COMPAT,TI_status(%rcx)
564 /* Either reschedule or signal or syscall exit tracking needed. */
565 /* First do a reschedule test. */
566 /* edx: work, edi: workmask */
568 bt $TIF_NEED_RESCHED,%edx
571 ENABLE_INTERRUPTS(CLBR_NONE)
575 DISABLE_INTERRUPTS(CLBR_NONE)
579 /* handle signals and tracing -- both require a full stack frame */
582 ENABLE_INTERRUPTS(CLBR_NONE)
583 int_check_syscall_exit_work:
585 /* Check for syscall exit trace */
586 testl $_TIF_WORK_SYSCALL_EXIT,%edx
589 leaq 8(%rsp),%rdi # &ptregs -> arg1
590 call syscall_trace_leave
592 andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
596 testl $_TIF_DO_NOTIFY_MASK,%edx
598 movq %rsp,%rdi # &ptregs -> arg1
599 xorl %esi,%esi # oldset -> arg2
600 call do_notify_resume
601 1: movl $_TIF_WORK_MASK,%edi
604 DISABLE_INTERRUPTS(CLBR_NONE)
610 .macro FORK_LIKE func
613 popq %r11 /* save return address */
616 pushq %r11 /* put it back on stack */
617 FIXUP_TOP_OF_STACK %r11, 8
618 DEFAULT_FRAME 0 8 /* offset 8: return address */
620 RESTORE_TOP_OF_STACK %r11, 8
621 ret $REST_SKIP /* pop extended registers */
626 .macro FIXED_FRAME label,func
629 PARTIAL_FRAME 0 8 /* offset 8: return address */
630 FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
632 RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
641 FIXED_FRAME stub_iopl, sys_iopl
643 ENTRY(ptregscall_common)
644 DEFAULT_FRAME 1 8 /* offset 8: return address */
645 RESTORE_TOP_OF_STACK %r11, 8
646 movq_cfi_restore R15+8, r15
647 movq_cfi_restore R14+8, r14
648 movq_cfi_restore R13+8, r13
649 movq_cfi_restore R12+8, r12
650 movq_cfi_restore RBP+8, rbp
651 movq_cfi_restore RBX+8, rbx
652 ret $REST_SKIP /* pop extended registers */
654 END(ptregscall_common)
661 FIXUP_TOP_OF_STACK %r11
665 jmp int_ret_from_sys_call
670 * sigreturn is special because it needs to restore all registers on return.
671 * This cannot be done with SYSRET, so use the IRET return path instead.
673 ENTRY(stub_rt_sigreturn)
678 FIXUP_TOP_OF_STACK %r11
679 call sys_rt_sigreturn
680 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
682 jmp int_ret_from_sys_call
684 END(stub_rt_sigreturn)
686 #ifdef CONFIG_X86_X32_ABI
687 ENTRY(stub_x32_rt_sigreturn)
692 FIXUP_TOP_OF_STACK %r11
693 call sys32_x32_rt_sigreturn
694 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
696 jmp int_ret_from_sys_call
698 END(stub_x32_rt_sigreturn)
700 ENTRY(stub_x32_execve)
705 FIXUP_TOP_OF_STACK %r11
706 call compat_sys_execve
707 RESTORE_TOP_OF_STACK %r11
710 jmp int_ret_from_sys_call
717 * Build the entry stubs and pointer table with some assembler magic.
718 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
719 * single cache line on all modern x86 implementations.
721 .section .init.rodata,"a"
725 .p2align CONFIG_X86_L1_CACHE_SHIFT
726 ENTRY(irq_entries_start)
728 vector=FIRST_EXTERNAL_VECTOR
729 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
732 .if vector < NR_VECTORS
733 .if vector <> FIRST_EXTERNAL_VECTOR
734 CFI_ADJUST_CFA_OFFSET -8
736 1: pushq_cfi $(~vector+0x80) /* Note: always in signed byte range */
737 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
746 2: jmp common_interrupt
749 END(irq_entries_start)
756 * Interrupt entry/exit.
758 * Interrupt entry points save only callee clobbered registers in fast path.
760 * Entry runs with interrupts off.
763 /* 0(%rsp): ~(interrupt number) */
764 .macro interrupt func
765 /* reserve pt_regs for scratch regs and rbp */
766 subq $ORIG_RAX-RBP, %rsp
767 CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
773 * The interrupt stubs push (~vector+0x80) onto the stack and
774 * then jump to common_interrupt.
776 .p2align CONFIG_X86_L1_CACHE_SHIFT
780 addq $-0x80,(%rsp) /* Adjust vector to [-256,-1] range */
782 /* 0(%rsp): old_rsp-ARGOFFSET */
784 DISABLE_INTERRUPTS(CLBR_NONE)
786 decl PER_CPU_VAR(irq_count)
788 /* Restore saved previous stack */
790 CFI_DEF_CFA rsi,SS+8-RBP /* reg/off reset after def_cfa_expr */
791 leaq ARGOFFSET-RBP(%rsi), %rsp
792 CFI_DEF_CFA_REGISTER rsp
793 CFI_ADJUST_CFA_OFFSET RBP-ARGOFFSET
796 GET_THREAD_INFO(%rcx)
797 testl $3,CS-ARGOFFSET(%rsp)
800 /* Interrupt came from user space */
802 * Has a correct top of stack, but a partial stack frame
803 * %rcx: thread info. Interrupts off.
805 retint_with_reschedule:
806 movl $_TIF_WORK_MASK,%edi
809 movl TI_flags(%rcx),%edx
814 retint_swapgs: /* return to user-space */
816 * The iretq could re-enable interrupts:
818 DISABLE_INTERRUPTS(CLBR_ANY)
823 retint_restore_args: /* return to kernel space */
824 DISABLE_INTERRUPTS(CLBR_ANY)
826 * The iretq could re-enable interrupts:
837 * Are we returning to a stack segment from the LDT? Note: in
838 * 64-bit mode SS:RSP on the exception stack is always valid.
840 #ifdef CONFIG_X86_ESPFIX64
841 testb $4,(SS-RIP)(%rsp)
842 jnz native_irq_return_ldt
845 native_irq_return_iret:
847 _ASM_EXTABLE(native_irq_return_iret, bad_iret)
849 #ifdef CONFIG_X86_ESPFIX64
850 native_irq_return_ldt:
854 movq PER_CPU_VAR(espfix_waddr),%rdi
855 movq %rax,(0*8)(%rdi) /* RAX */
856 movq (2*8)(%rsp),%rax /* RIP */
857 movq %rax,(1*8)(%rdi)
858 movq (3*8)(%rsp),%rax /* CS */
859 movq %rax,(2*8)(%rdi)
860 movq (4*8)(%rsp),%rax /* RFLAGS */
861 movq %rax,(3*8)(%rdi)
862 movq (6*8)(%rsp),%rax /* SS */
863 movq %rax,(5*8)(%rdi)
864 movq (5*8)(%rsp),%rax /* RSP */
865 movq %rax,(4*8)(%rdi)
866 andl $0xffff0000,%eax
868 orq PER_CPU_VAR(espfix_stack),%rax
872 jmp native_irq_return_iret
878 * The iret traps when the %cs or %ss being restored is bogus.
879 * We've lost the original trap vector and error code.
880 * #GPF is the most likely one to get for an invalid selector.
881 * So pretend we completed the iret and took the #GPF in user mode.
883 * We are now running with the kernel GS after exception recovery.
884 * But error_entry expects us to have user GS to match the user %cs,
890 jmp general_protection
894 /* edi: workmask, edx: work */
897 bt $TIF_NEED_RESCHED,%edx
900 ENABLE_INTERRUPTS(CLBR_NONE)
904 GET_THREAD_INFO(%rcx)
905 DISABLE_INTERRUPTS(CLBR_NONE)
910 testl $_TIF_DO_NOTIFY_MASK,%edx
913 ENABLE_INTERRUPTS(CLBR_NONE)
915 movq $-1,ORIG_RAX(%rsp)
916 xorl %esi,%esi # oldset
917 movq %rsp,%rdi # &pt_regs
918 call do_notify_resume
920 DISABLE_INTERRUPTS(CLBR_NONE)
922 GET_THREAD_INFO(%rcx)
923 jmp retint_with_reschedule
925 #ifdef CONFIG_PREEMPT
926 /* Returning to kernel space. Check if we need preemption */
927 /* rcx: threadinfo. interrupts off. */
929 cmpl $0,PER_CPU_VAR(__preempt_count)
930 jnz retint_restore_args
931 bt $9,EFLAGS-ARGOFFSET(%rsp) /* interrupts off? */
932 jnc retint_restore_args
933 call preempt_schedule_irq
937 END(common_interrupt)
940 * If IRET takes a fault on the espfix stack, then we
941 * end up promoting it to a doublefault. In that case,
942 * modify the stack to make it look like we just entered
943 * the #GP handler from user space, similar to bad_iret.
945 #ifdef CONFIG_X86_ESPFIX64
949 movq RSP(%rdi),%rax /* Trap on the espfix stack? */
950 sarq $PGDIR_SHIFT,%rax
951 cmpl $ESPFIX_PGD_ENTRY,%eax
952 jne do_double_fault /* No, just deliver the fault */
953 cmpl $__KERNEL_CS,CS(%rdi)
956 cmpq $native_irq_return_iret,%rax
957 jne do_double_fault /* This shouldn't happen... */
958 movq PER_CPU_VAR(kernel_stack),%rax
959 subq $(6*8-KERNEL_STACK_OFFSET),%rax /* Reset to original stack */
961 movq $0,(%rax) /* Missing (lost) #GP error code */
962 movq $general_protection,RIP(%rdi)
965 END(__do_double_fault)
967 # define __do_double_fault do_double_fault
973 .macro apicinterrupt3 num sym do_sym
985 #ifdef CONFIG_TRACING
986 #define trace(sym) trace_##sym
987 #define smp_trace(sym) smp_trace_##sym
989 .macro trace_apicinterrupt num sym
990 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
993 .macro trace_apicinterrupt num sym do_sym
997 .macro apicinterrupt num sym do_sym
998 apicinterrupt3 \num \sym \do_sym
999 trace_apicinterrupt \num \sym
1003 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1004 irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1005 apicinterrupt3 REBOOT_VECTOR \
1006 reboot_interrupt smp_reboot_interrupt
1009 #ifdef CONFIG_X86_UV
1010 apicinterrupt3 UV_BAU_MESSAGE \
1011 uv_bau_message_intr1 uv_bau_message_interrupt
1013 apicinterrupt LOCAL_TIMER_VECTOR \
1014 apic_timer_interrupt smp_apic_timer_interrupt
1015 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1016 x86_platform_ipi smp_x86_platform_ipi
1018 #ifdef CONFIG_HAVE_KVM
1019 apicinterrupt3 POSTED_INTR_VECTOR \
1020 kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1023 #ifdef CONFIG_X86_MCE_THRESHOLD
1024 apicinterrupt THRESHOLD_APIC_VECTOR \
1025 threshold_interrupt smp_threshold_interrupt
1028 #ifdef CONFIG_X86_THERMAL_VECTOR
1029 apicinterrupt THERMAL_APIC_VECTOR \
1030 thermal_interrupt smp_thermal_interrupt
1034 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1035 call_function_single_interrupt smp_call_function_single_interrupt
1036 apicinterrupt CALL_FUNCTION_VECTOR \
1037 call_function_interrupt smp_call_function_interrupt
1038 apicinterrupt RESCHEDULE_VECTOR \
1039 reschedule_interrupt smp_reschedule_interrupt
1042 apicinterrupt ERROR_APIC_VECTOR \
1043 error_interrupt smp_error_interrupt
1044 apicinterrupt SPURIOUS_APIC_VECTOR \
1045 spurious_interrupt smp_spurious_interrupt
1047 #ifdef CONFIG_IRQ_WORK
1048 apicinterrupt IRQ_WORK_VECTOR \
1049 irq_work_interrupt smp_irq_work_interrupt
1053 * Exception entry points.
1055 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1057 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
1060 .if \shift_ist != -1 && \paranoid == 0
1061 .error "using shift_ist requires paranoid=1"
1071 PARAVIRT_ADJUST_EXCEPTION_FRAME
1073 .ifeq \has_error_code
1074 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1077 subq $ORIG_RAX-R15, %rsp
1078 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1089 .if \shift_ist != -1
1090 TRACE_IRQS_OFF_DEBUG /* reload IDT in case of recursion */
1096 movq %rsp,%rdi /* pt_regs pointer */
1099 movq ORIG_RAX(%rsp),%rsi /* get error code */
1100 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1102 xorl %esi,%esi /* no error code */
1105 .if \shift_ist != -1
1106 subq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1111 .if \shift_ist != -1
1112 addq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1116 jmp paranoid_exit /* %ebx: no swapgs flag */
1118 jmp error_exit /* %ebx: no swapgs flag */
1125 #ifdef CONFIG_TRACING
1126 .macro trace_idtentry sym do_sym has_error_code:req
1127 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
1128 idtentry \sym \do_sym has_error_code=\has_error_code
1131 .macro trace_idtentry sym do_sym has_error_code:req
1132 idtentry \sym \do_sym has_error_code=\has_error_code
1136 idtentry divide_error do_divide_error has_error_code=0
1137 idtentry overflow do_overflow has_error_code=0
1138 idtentry bounds do_bounds has_error_code=0
1139 idtentry invalid_op do_invalid_op has_error_code=0
1140 idtentry device_not_available do_device_not_available has_error_code=0
1141 idtentry double_fault __do_double_fault has_error_code=1 paranoid=1
1142 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1143 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1144 idtentry segment_not_present do_segment_not_present has_error_code=1
1145 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1146 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1147 idtentry alignment_check do_alignment_check has_error_code=1
1148 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1151 /* Reload gs selector with exception handling */
1152 /* edi: new selector */
1153 ENTRY(native_load_gs_index)
1156 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1160 2: mfence /* workaround */
1165 END(native_load_gs_index)
1167 _ASM_EXTABLE(gs_change,bad_gs)
1168 .section .fixup,"ax"
1169 /* running with kernelgs */
1171 SWAPGS /* switch back to user gs */
1177 /* Call softirq on interrupt stack. Interrupts are off. */
1178 ENTRY(do_softirq_own_stack)
1181 CFI_REL_OFFSET rbp,0
1183 CFI_DEF_CFA_REGISTER rbp
1184 incl PER_CPU_VAR(irq_count)
1185 cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1186 push %rbp # backlink for old unwinder
1190 CFI_DEF_CFA_REGISTER rsp
1191 CFI_ADJUST_CFA_OFFSET -8
1192 decl PER_CPU_VAR(irq_count)
1195 END(do_softirq_own_stack)
1198 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1201 * A note on the "critical region" in our callback handler.
1202 * We want to avoid stacking callback handlers due to events occurring
1203 * during handling of the last event. To do this, we keep events disabled
1204 * until we've done all processing. HOWEVER, we must enable events before
1205 * popping the stack frame (can't be done atomically) and so it would still
1206 * be possible to get enough handler activations to overflow the stack.
1207 * Although unlikely, bugs of that kind are hard to track down, so we'd
1208 * like to avoid the possibility.
1209 * So, on entry to the handler we detect whether we interrupted an
1210 * existing activation in its critical region -- if so, we pop the current
1211 * activation and restart the handler using the previous one.
1213 ENTRY(xen_do_hypervisor_callback) # do_hypervisor_callback(struct *pt_regs)
1216 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1217 * see the correct pointer to the pt_regs
1219 movq %rdi, %rsp # we don't return, adjust the stack frame
1222 11: incl PER_CPU_VAR(irq_count)
1224 CFI_DEF_CFA_REGISTER rbp
1225 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1226 pushq %rbp # backlink for old unwinder
1227 call xen_evtchn_do_upcall
1229 CFI_DEF_CFA_REGISTER rsp
1230 decl PER_CPU_VAR(irq_count)
1233 END(xen_do_hypervisor_callback)
1236 * Hypervisor uses this for application faults while it executes.
1237 * We get here for two reasons:
1238 * 1. Fault while reloading DS, ES, FS or GS
1239 * 2. Fault while executing IRET
1240 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1241 * registers that could be reloaded and zeroed the others.
1242 * Category 2 we fix up by killing the current process. We cannot use the
1243 * normal Linux return path in this case because if we use the IRET hypercall
1244 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1245 * We distinguish between categories by comparing each saved segment register
1246 * with its current contents: any discrepancy means we in category 1.
1248 ENTRY(xen_failsafe_callback)
1250 /*CFI_REL_OFFSET gs,GS*/
1251 /*CFI_REL_OFFSET fs,FS*/
1252 /*CFI_REL_OFFSET es,ES*/
1253 /*CFI_REL_OFFSET ds,DS*/
1254 CFI_REL_OFFSET r11,8
1255 CFI_REL_OFFSET rcx,0
1269 /* All segments match their saved values => Category 2 (Bad IRET). */
1275 CFI_ADJUST_CFA_OFFSET -0x30
1276 pushq_cfi $0 /* RIP */
1279 jmp general_protection
1281 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1287 CFI_ADJUST_CFA_OFFSET -0x30
1288 pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1292 END(xen_failsafe_callback)
1294 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1295 xen_hvm_callback_vector xen_evtchn_do_upcall
1297 #endif /* CONFIG_XEN */
1299 #if IS_ENABLED(CONFIG_HYPERV)
1300 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1301 hyperv_callback_vector hyperv_vector_handler
1302 #endif /* CONFIG_HYPERV */
1304 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1305 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1306 idtentry stack_segment do_stack_segment has_error_code=1 paranoid=1
1308 idtentry xen_debug do_debug has_error_code=0
1309 idtentry xen_int3 do_int3 has_error_code=0
1310 idtentry xen_stack_segment do_stack_segment has_error_code=1
1312 idtentry general_protection do_general_protection has_error_code=1
1313 trace_idtentry page_fault do_page_fault has_error_code=1
1314 #ifdef CONFIG_KVM_GUEST
1315 idtentry async_page_fault do_async_page_fault has_error_code=1
1317 #ifdef CONFIG_X86_MCE
1318 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1322 * "Paranoid" exit path from exception stack.
1323 * Paranoid because this is used by NMIs and cannot take
1324 * any kernel state for granted.
1325 * We don't do kernel preemption checks here, because only
1326 * NMI should be common and it does not enable IRQs and
1327 * cannot get reschedule ticks.
1329 * "trace" is 0 for the NMI handler only, because irq-tracing
1330 * is fundamentally NMI-unsafe. (we cannot change the soft and
1331 * hard flags at once, atomically)
1334 /* ebx: no swapgs flag */
1335 ENTRY(paranoid_exit)
1337 DISABLE_INTERRUPTS(CLBR_NONE)
1338 TRACE_IRQS_OFF_DEBUG
1339 testl %ebx,%ebx /* swapgs needed? */
1340 jnz paranoid_restore
1342 jnz paranoid_userspace
1349 TRACE_IRQS_IRETQ_DEBUG 0
1353 GET_THREAD_INFO(%rcx)
1354 movl TI_flags(%rcx),%ebx
1355 andl $_TIF_WORK_MASK,%ebx
1357 movq %rsp,%rdi /* &pt_regs */
1359 movq %rax,%rsp /* switch stack for scheduling */
1360 testl $_TIF_NEED_RESCHED,%ebx
1361 jnz paranoid_schedule
1362 movl %ebx,%edx /* arg3: thread flags */
1364 ENABLE_INTERRUPTS(CLBR_NONE)
1365 xorl %esi,%esi /* arg2: oldset */
1366 movq %rsp,%rdi /* arg1: &pt_regs */
1367 call do_notify_resume
1368 DISABLE_INTERRUPTS(CLBR_NONE)
1370 jmp paranoid_userspace
1373 ENABLE_INTERRUPTS(CLBR_ANY)
1375 DISABLE_INTERRUPTS(CLBR_ANY)
1377 jmp paranoid_userspace
1382 * Exception entry point. This expects an error code/orig_rax on the stack.
1383 * returns in "no swapgs flag" in %ebx.
1387 CFI_ADJUST_CFA_OFFSET 15*8
1388 /* oldrax contains error code */
1407 je error_kernelspace
1415 * There are two places in the kernel that can potentially fault with
1416 * usergs. Handle them here. The exception handlers after iret run with
1417 * kernel gs again, so don't set the user space flag. B stepping K8s
1418 * sometimes report an truncated RIP for IRET exceptions returning to
1419 * compat mode. Check for these here too.
1423 leaq native_irq_return_iret(%rip),%rcx
1424 cmpq %rcx,RIP+8(%rsp)
1426 movl %ecx,%eax /* zero extend */
1427 cmpq %rax,RIP+8(%rsp)
1429 cmpq $gs_change,RIP+8(%rsp)
1434 /* Fix truncated RIP */
1435 movq %rcx,RIP+8(%rsp)
1441 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1446 DISABLE_INTERRUPTS(CLBR_NONE)
1448 GET_THREAD_INFO(%rcx)
1451 LOCKDEP_SYS_EXIT_IRQ
1452 movl TI_flags(%rcx),%edx
1453 movl $_TIF_WORK_MASK,%edi
1461 * Test if a given stack is an NMI stack or not.
1463 .macro test_in_nmi reg stack nmi_ret normal_ret
1466 subq $EXCEPTION_STKSZ, %\reg
1472 /* runs on exception stack */
1475 PARAVIRT_ADJUST_EXCEPTION_FRAME
1477 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1478 * the iretq it performs will take us out of NMI context.
1479 * This means that we can have nested NMIs where the next
1480 * NMI is using the top of the stack of the previous NMI. We
1481 * can't let it execute because the nested NMI will corrupt the
1482 * stack of the previous NMI. NMI handlers are not re-entrant
1485 * To handle this case we do the following:
1486 * Check the a special location on the stack that contains
1487 * a variable that is set when NMIs are executing.
1488 * The interrupted task's stack is also checked to see if it
1490 * If the variable is not set and the stack is not the NMI
1492 * o Set the special variable on the stack
1493 * o Copy the interrupt frame into a "saved" location on the stack
1494 * o Copy the interrupt frame into a "copy" location on the stack
1495 * o Continue processing the NMI
1496 * If the variable is set or the previous stack is the NMI stack:
1497 * o Modify the "copy" location to jump to the repeate_nmi
1498 * o return back to the first NMI
1500 * Now on exit of the first NMI, we first clear the stack variable
1501 * The NMI stack will tell any nested NMIs at that point that it is
1502 * nested. Then we pop the stack normally with iret, and if there was
1503 * a nested NMI that updated the copy interrupt stack frame, a
1504 * jump will be made to the repeat_nmi code that will handle the second
1508 /* Use %rdx as out temp variable throughout */
1510 CFI_REL_OFFSET rdx, 0
1513 * If %cs was not the kernel segment, then the NMI triggered in user
1514 * space, which means it is definitely not nested.
1516 cmpl $__KERNEL_CS, 16(%rsp)
1520 * Check the special variable on the stack to see if NMIs are
1527 * Now test if the previous stack was an NMI stack.
1528 * We need the double check. We check the NMI stack to satisfy the
1529 * race when the first NMI clears the variable before returning.
1530 * We check the variable because the first NMI could be in a
1531 * breakpoint routine using a breakpoint stack.
1534 test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1539 * Do nothing if we interrupted the fixup in repeat_nmi.
1540 * It's about to repeat the NMI handler, so we are fine
1541 * with ignoring this one.
1543 movq $repeat_nmi, %rdx
1546 movq $end_repeat_nmi, %rdx
1551 /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1552 leaq -1*8(%rsp), %rdx
1554 CFI_ADJUST_CFA_OFFSET 1*8
1555 leaq -10*8(%rsp), %rdx
1556 pushq_cfi $__KERNEL_DS
1559 pushq_cfi $__KERNEL_CS
1560 pushq_cfi $repeat_nmi
1562 /* Put stack back */
1564 CFI_ADJUST_CFA_OFFSET -6*8
1570 /* No need to check faults here */
1576 * Because nested NMIs will use the pushed location that we
1577 * stored in rdx, we must keep that space available.
1578 * Here's what our stack frame will look like:
1579 * +-------------------------+
1581 * | original Return RSP |
1582 * | original RFLAGS |
1585 * +-------------------------+
1586 * | temp storage for rdx |
1587 * +-------------------------+
1588 * | NMI executing variable |
1589 * +-------------------------+
1591 * | copied Return RSP |
1595 * +-------------------------+
1597 * | Saved Return RSP |
1601 * +-------------------------+
1603 * +-------------------------+
1605 * The saved stack frame is used to fix up the copied stack frame
1606 * that a nested NMI may change to make the interrupted NMI iret jump
1607 * to the repeat_nmi. The original stack frame and the temp storage
1608 * is also used by nested NMIs and can not be trusted on exit.
1610 /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1614 /* Set the NMI executing variable on the stack. */
1618 * Leave room for the "copied" frame
1621 CFI_ADJUST_CFA_OFFSET 5*8
1623 /* Copy the stack frame to the Saved frame */
1625 pushq_cfi 11*8(%rsp)
1627 CFI_DEF_CFA_OFFSET SS+8-RIP
1629 /* Everything up to here is safe from nested NMIs */
1632 * If there was a nested NMI, the first NMI's iret will return
1633 * here. But NMIs are still enabled and we can take another
1634 * nested NMI. The nested NMI checks the interrupted RIP to see
1635 * if it is between repeat_nmi and end_repeat_nmi, and if so
1636 * it will just return, as we are about to repeat an NMI anyway.
1637 * This makes it safe to copy to the stack frame that a nested
1642 * Update the stack variable to say we are still in NMI (the update
1643 * is benign for the non-repeat case, where 1 was pushed just above
1644 * to this very stack slot).
1648 /* Make another copy, this one may be modified by nested NMIs */
1650 CFI_ADJUST_CFA_OFFSET -10*8
1652 pushq_cfi -6*8(%rsp)
1655 CFI_DEF_CFA_OFFSET SS+8-RIP
1659 * Everything below this point can be preempted by a nested
1660 * NMI if the first NMI took an exception and reset our iret stack
1661 * so that we repeat another NMI.
1663 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1664 subq $ORIG_RAX-R15, %rsp
1665 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1667 * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1668 * as we should not be calling schedule in NMI context.
1669 * Even with normal interrupts enabled. An NMI should not be
1670 * setting NEED_RESCHED or anything that normal interrupts and
1671 * exceptions might do.
1677 * Save off the CR2 register. If we take a page fault in the NMI then
1678 * it could corrupt the CR2 value. If the NMI preempts a page fault
1679 * handler before it was able to read the CR2 register, and then the
1680 * NMI itself takes a page fault, the page fault that was preempted
1681 * will read the information from the NMI page fault and not the
1682 * origin fault. Save it off and restore it if it changes.
1683 * Use the r12 callee-saved register.
1687 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1692 /* Did the NMI take a page fault? Restore cr2 if it did */
1699 testl %ebx,%ebx /* swapgs needed? */
1704 /* Pop the extra iret frame at once */
1707 /* Clear the NMI executing stack variable */
1713 ENTRY(ignore_sysret)