arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers up to R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64         .section .entry.text, "ax"
  65
  66 #ifdef CONFIG_FUNCTION_TRACER
  67 #ifdef CONFIG_DYNAMIC_FTRACE
  68 ENTRY(mcount)
  69         retq
  70 END(mcount)
  71
  72 ENTRY(ftrace_caller)
  73         cmpl $0, function_trace_stop
  74         jne  ftrace_stub
  75
  76         MCOUNT_SAVE_FRAME
  77
  78         movq 0x38(%rsp), %rdi
  79         movq 8(%rbp), %rsi
  80         subq $MCOUNT_INSN_SIZE, %rdi
  81
  82 GLOBAL(ftrace_call)
  83         call ftrace_stub
  84
  85         MCOUNT_RESTORE_FRAME
  86
  87 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  88 GLOBAL(ftrace_graph_call)
  89         jmp ftrace_stub
  90 #endif
  91
  92 GLOBAL(ftrace_stub)
  93         retq
  94 END(ftrace_caller)
  95
  96 #else /* ! CONFIG_DYNAMIC_FTRACE */
  97 ENTRY(mcount)
  98         cmpl $0, function_trace_stop
  99         jne  ftrace_stub
 100
 101         cmpq $ftrace_stub, ftrace_trace_function
 102         jnz trace
 103
 104 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 105         cmpq $ftrace_stub, ftrace_graph_return
 106         jnz ftrace_graph_caller
 107
 108         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 109         jnz ftrace_graph_caller
 110 #endif
 111
 112 GLOBAL(ftrace_stub)
 113         retq
 114
 115 trace:
 116         MCOUNT_SAVE_FRAME
 117
 118         movq 0x38(%rsp), %rdi
 119         movq 8(%rbp), %rsi
 120         subq $MCOUNT_INSN_SIZE, %rdi
 121
 122         call   *ftrace_trace_function
 123
 124         MCOUNT_RESTORE_FRAME
 125
 126         jmp ftrace_stub
 127 END(mcount)
 128 #endif /* CONFIG_DYNAMIC_FTRACE */
 129 #endif /* CONFIG_FUNCTION_TRACER */
 130
 131 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 132 ENTRY(ftrace_graph_caller)
 133         cmpl $0, function_trace_stop
 134         jne ftrace_stub
 135
 136         MCOUNT_SAVE_FRAME
 137
 138         leaq 8(%rbp), %rdi
 139         movq 0x38(%rsp), %rsi
 140         movq (%rbp), %rdx
 141         subq $MCOUNT_INSN_SIZE, %rsi
 142
 143         call    prepare_ftrace_return
 144
 145         MCOUNT_RESTORE_FRAME
 146
 147         retq
 148 END(ftrace_graph_caller)
 149
 150 GLOBAL(return_to_handler)
 151         subq  $24, %rsp
 152
 153         /* Save the return values */
 154         movq %rax, (%rsp)
 155         movq %rdx, 8(%rsp)
 156         movq %rbp, %rdi
 157
 158         call ftrace_return_to_handler
 159
 160         movq %rax, %rdi
 161         movq 8(%rsp), %rdx
 162         movq (%rsp), %rax
 163         addq $24, %rsp
 164         jmp *%rdi
 165 #endif
 166
 167
 168 #ifndef CONFIG_PREEMPT
 169 #define retint_kernel retint_restore_args
 170 #endif
 171
 172 #ifdef CONFIG_PARAVIRT
 173 ENTRY(native_usergs_sysret64)
 174         swapgs
 175         sysretq
 176 ENDPROC(native_usergs_sysret64)
 177 #endif /* CONFIG_PARAVIRT */
 178
 179
 180 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 181 #ifdef CONFIG_TRACE_IRQFLAGS
 182         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 183         jnc  1f
 184         TRACE_IRQS_ON
 185 1:
 186 #endif
 187 .endm
 188
 189 /*
 190  * C code is not supposed to know about undefined top of stack. Every time
 191  * a C function with an pt_regs argument is called from the SYSCALL based
 192  * fast path FIXUP_TOP_OF_STACK is needed.
 193  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 194  * manipulation.
 195  */
 196
 197         /* %rsp:at FRAMEEND */
 198         .macro FIXUP_TOP_OF_STACK tmp offset=0
 199         movq PER_CPU_VAR(old_rsp),\tmp
 200         movq \tmp,RSP+\offset(%rsp)
 201         movq $__USER_DS,SS+\offset(%rsp)
 202         movq $__USER_CS,CS+\offset(%rsp)
 203         movq $-1,RCX+\offset(%rsp)
 204         movq R11+\offset(%rsp),\tmp  /* get eflags */
 205         movq \tmp,EFLAGS+\offset(%rsp)
 206         .endm
 207
 208         .macro RESTORE_TOP_OF_STACK tmp offset=0
 209         movq RSP+\offset(%rsp),\tmp
 210         movq \tmp,PER_CPU_VAR(old_rsp)
 211         movq EFLAGS+\offset(%rsp),\tmp
 212         movq \tmp,R11+\offset(%rsp)
 213         .endm
 214
 215         .macro FAKE_STACK_FRAME child_rip
 216         /* push in order ss, rsp, eflags, cs, rip */
 217         xorl %eax, %eax
 218         pushq_cfi $__KERNEL_DS /* ss */
 219         /*CFI_REL_OFFSET        ss,0*/
 220         pushq_cfi %rax /* rsp */
 221         CFI_REL_OFFSET  rsp,0
 222         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 223         /*CFI_REL_OFFSET        rflags,0*/
 224         pushq_cfi $__KERNEL_CS /* cs */
 225         /*CFI_REL_OFFSET        cs,0*/
 226         pushq_cfi \child_rip /* rip */
 227         CFI_REL_OFFSET  rip,0
 228         pushq_cfi %rax /* orig rax */
 229         .endm
 230
 231         .macro UNFAKE_STACK_FRAME
 232         addq $8*6, %rsp
 233         CFI_ADJUST_CFA_OFFSET   -(6*8)
 234         .endm
 235
 236 /*
 237  * initial frame state for interrupts (and exceptions without error code)
 238  */
 239         .macro EMPTY_FRAME start=1 offset=0
 240         .if \start
 241         CFI_STARTPROC simple
 242         CFI_SIGNAL_FRAME
 243         CFI_DEF_CFA rsp,8+\offset
 244         .else
 245         CFI_DEF_CFA_OFFSET 8+\offset
 246         .endif
 247         .endm
 248
 249 /*
 250  * initial frame state for interrupts (and exceptions without error code)
 251  */
 252         .macro INTR_FRAME start=1 offset=0
 253         EMPTY_FRAME \start, SS+8+\offset-RIP
 254         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 255         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 256         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 257         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 258         CFI_REL_OFFSET rip, RIP+\offset-RIP
 259         .endm
 260
 261 /*
 262  * initial frame state for exceptions with error code (and interrupts
 263  * with vector already pushed)
 264  */
 265         .macro XCPT_FRAME start=1 offset=0
 266         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 267         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 268         .endm
 269
 270 /*
 271  * frame that enables calling into C.
 272  */
 273         .macro PARTIAL_FRAME start=1 offset=0
 274         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 275         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 276         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 281         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 284         .endm
 285
 286 /*
 287  * frame that enables passing a complete pt_regs to a C function.
 288  */
 289         .macro DEFAULT_FRAME start=1 offset=0
 290         PARTIAL_FRAME \start, R11+\offset-R15
 291         CFI_REL_OFFSET rbx, RBX+\offset
 292         CFI_REL_OFFSET rbp, RBP+\offset
 293         CFI_REL_OFFSET r12, R12+\offset
 294         CFI_REL_OFFSET r13, R13+\offset
 295         CFI_REL_OFFSET r14, R14+\offset
 296         CFI_REL_OFFSET r15, R15+\offset
 297         .endm
 298
 299 /* save partial stack frame */
 300         .macro SAVE_ARGS_IRQ
 301         cld
 302         /* start from rbp in pt_regs and jump over */
 303         movq_cfi rdi, RDI-RBP
 304         movq_cfi rsi, RSI-RBP
 305         movq_cfi rdx, RDX-RBP
 306         movq_cfi rcx, RCX-RBP
 307         movq_cfi rax, RAX-RBP
 308         movq_cfi  r8,  R8-RBP
 309         movq_cfi  r9,  R9-RBP
 310         movq_cfi r10, R10-RBP
 311         movq_cfi r11, R11-RBP
 312
 313         movq_cfi rbp, 0         /* push %rbp */
 314         movq %rsp, %rbp
 315
 316         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 317         testl $3, CS(%rdi)
 318         je 1f
 319         SWAPGS
 320         /*
 321          * irq_count is used to check if a CPU is already on an interrupt stack
 322          * or not. While this is essentially redundant with preempt_count it is
 323          * a little cheaper to use a separate counter in the PDA (short of
 324          * moving irq_enter into assembly, which would be too much work)
 325          */
 326 1:      incl PER_CPU_VAR(irq_count)
 327         jne 2f
 328         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 329         EMPTY_FRAME 0
 330         pushq_cfi %rbp                  /* backlink for unwinder */
 331         /*
 332          * We entered an interrupt context - irqs are off:
 333          */
 334 2:      TRACE_IRQS_OFF
 335         .endm
 336
 337 ENTRY(save_rest)
 338         PARTIAL_FRAME 1 REST_SKIP+8
 339         movq 5*8+16(%rsp), %r11 /* save return address */
 340         movq_cfi rbx, RBX+16
 341         movq_cfi rbp, RBP+16
 342         movq_cfi r12, R12+16
 343         movq_cfi r13, R13+16
 344         movq_cfi r14, R14+16
 345         movq_cfi r15, R15+16
 346         movq %r11, 8(%rsp)      /* return address */
 347         FIXUP_TOP_OF_STACK %r11, 16
 348         ret
 349         CFI_ENDPROC
 350 END(save_rest)
 351
 352 /* save complete stack frame */
 353         .pushsection .kprobes.text, "ax"
 354 ENTRY(save_paranoid)
 355         XCPT_FRAME 1 RDI+8
 356         cld
 357         movq_cfi rdi, RDI+8
 358         movq_cfi rsi, RSI+8
 359         movq_cfi rdx, RDX+8
 360         movq_cfi rcx, RCX+8
 361         movq_cfi rax, RAX+8
 362         movq_cfi r8, R8+8
 363         movq_cfi r9, R9+8
 364         movq_cfi r10, R10+8
 365         movq_cfi r11, R11+8
 366         movq_cfi rbx, RBX+8
 367         movq_cfi rbp, RBP+8
 368         movq_cfi r12, R12+8
 369         movq_cfi r13, R13+8
 370         movq_cfi r14, R14+8
 371         movq_cfi r15, R15+8
 372         movl $1,%ebx
 373         movl $MSR_GS_BASE,%ecx
 374         rdmsr
 375         testl %edx,%edx
 376         js 1f   /* negative -> in kernel */
 377         SWAPGS
 378         xorl %ebx,%ebx
 379 1:      ret
 380         CFI_ENDPROC
 381 END(save_paranoid)
 382         .popsection
 383
 384 /*
 385  * A newly forked process directly context switches into this address.
 386  *
 387  * rdi: prev task we switched from
 388  */
 389 ENTRY(ret_from_fork)
 390         DEFAULT_FRAME
 391
 392         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 393
 394         pushq_cfi kernel_eflags(%rip)
 395         popfq_cfi                               # reset kernel eflags
 396
 397         call schedule_tail                      # rdi: 'prev' task parameter
 398
 399         GET_THREAD_INFO(%rcx)
 400
 401         RESTORE_REST
 402
 403         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 404         je   int_ret_from_sys_call
 405
 406         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 407         jnz  int_ret_from_sys_call
 408
 409         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 410         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 411
 412         CFI_ENDPROC
 413 END(ret_from_fork)
 414
 415 /*
 416  * System call entry. Up to 6 arguments in registers are supported.
 417  *
 418  * SYSCALL does not save anything on the stack and does not change the
 419  * stack pointer.
 420  */
 421
 422 /*
 423  * Register setup:
 424  * rax  system call number
 425  * rdi  arg0
 426  * rcx  return address for syscall/sysret, C arg3
 427  * rsi  arg1
 428  * rdx  arg2
 429  * r10  arg3    (--> moved to rcx for C)
 430  * r8   arg4
 431  * r9   arg5
 432  * r11  eflags for syscall/sysret, temporary for C
 433  * r12-r15,rbp,rbx saved by C code, not touched.
 434  *
 435  * Interrupts are off on entry.
 436  * Only called from user space.
 437  *
 438  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 439  *      and report it properly in ps. Unfortunately we haven't.
 440  *
 441  * When user can change the frames always force IRET. That is because
 442  * it deals with uncanonical addresses better. SYSRET has trouble
 443  * with them due to bugs in both AMD and Intel CPUs.
 444  */
 445
 446 ENTRY(system_call)
 447         CFI_STARTPROC   simple
 448         CFI_SIGNAL_FRAME
 449         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 450         CFI_REGISTER    rip,rcx
 451         /*CFI_REGISTER  rflags,r11*/
 452         SWAPGS_UNSAFE_STACK
 453         /*
 454          * A hypervisor implementation might want to use a label
 455          * after the swapgs, so that it can do the swapgs
 456          * for the guest and jump here on syscall.
 457          */
 458 ENTRY(system_call_after_swapgs)
 459
 460         movq    %rsp,PER_CPU_VAR(old_rsp)
 461         movq    PER_CPU_VAR(kernel_stack),%rsp
 462         /*
 463          * No need to follow this irqs off/on section - it's straight
 464          * and short:
 465          */
 466         ENABLE_INTERRUPTS(CLBR_NONE)
 467         SAVE_ARGS 8,1
 468         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 469         movq  %rcx,RIP-ARGOFFSET(%rsp)
 470         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 471         GET_THREAD_INFO(%rcx)
 472         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 473         jnz tracesys
 474 system_call_fastpath:
 475         cmpq $__NR_syscall_max,%rax
 476         ja badsys
 477         movq %r10,%rcx
 478         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 479         movq %rax,RAX-ARGOFFSET(%rsp)
 480 /*
 481  * Syscall return path ending with SYSRET (fast path)
 482  * Has incomplete stack frame and undefined top of stack.
 483  */
 484 ret_from_sys_call:
 485         movl $_TIF_ALLWORK_MASK,%edi
 486         /* edi: flagmask */
 487 sysret_check:
 488         LOCKDEP_SYS_EXIT
 489         GET_THREAD_INFO(%rcx)
 490         DISABLE_INTERRUPTS(CLBR_NONE)
 491         TRACE_IRQS_OFF
 492         movl TI_flags(%rcx),%edx
 493         andl %edi,%edx
 494         jnz  sysret_careful
 495         CFI_REMEMBER_STATE
 496         /*
 497          * sysretq will re-enable interrupts:
 498          */
 499         TRACE_IRQS_ON
 500         movq RIP-ARGOFFSET(%rsp),%rcx
 501         CFI_REGISTER    rip,rcx
 502         RESTORE_ARGS 0,-ARG_SKIP,1
 503         /*CFI_REGISTER  rflags,r11*/
 504         movq    PER_CPU_VAR(old_rsp), %rsp
 505         USERGS_SYSRET64
 506
 507         CFI_RESTORE_STATE
 508         /* Handle reschedules */
 509         /* edx: work, edi: workmask */
 510 sysret_careful:
 511         bt $TIF_NEED_RESCHED,%edx
 512         jnc sysret_signal
 513         TRACE_IRQS_ON
 514         ENABLE_INTERRUPTS(CLBR_NONE)
 515         pushq_cfi %rdi
 516         call schedule
 517         popq_cfi %rdi
 518         jmp sysret_check
 519
 520         /* Handle a signal */
 521 sysret_signal:
 522         TRACE_IRQS_ON
 523         ENABLE_INTERRUPTS(CLBR_NONE)
 524 #ifdef CONFIG_AUDITSYSCALL
 525         bt $TIF_SYSCALL_AUDIT,%edx
 526         jc sysret_audit
 527 #endif
 528         /*
 529          * We have a signal, or exit tracing or single-step.
 530          * These all wind up with the iret return path anyway,
 531          * so just join that path right now.
 532          */
 533         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 534         jmp int_check_syscall_exit_work
 535
 536 badsys:
 537         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 538         jmp ret_from_sys_call
 539
 540 #ifdef CONFIG_AUDITSYSCALL
 541         /*
 542          * Fast path for syscall audit without full syscall trace.
 543          * We just call audit_syscall_entry() directly, and then
 544          * jump back to the normal fast path.
 545          */
 546 auditsys:
 547         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 548         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 549         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 550         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 551         movq %rax,%rsi                  /* 2nd arg: syscall number */
 552         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 553         call audit_syscall_entry
 554         LOAD_ARGS 0             /* reload call-clobbered registers */
 555         jmp system_call_fastpath
 556
 557         /*
 558          * Return fast path for syscall audit.  Call audit_syscall_exit()
 559          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 560          * masked off.
 561          */
 562 sysret_audit:
 563         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 564         cmpq $0,%rsi            /* is it < 0? */
 565         setl %al                /* 1 if so, 0 if not */
 566         movzbl %al,%edi         /* zero-extend that into %edi */
 567         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 568         call audit_syscall_exit
 569         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 570         jmp sysret_check
 571 #endif  /* CONFIG_AUDITSYSCALL */
 572
 573         /* Do syscall tracing */
 574 tracesys:
 575 #ifdef CONFIG_AUDITSYSCALL
 576         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 577         jz auditsys
 578 #endif
 579         SAVE_REST
 580         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 581         FIXUP_TOP_OF_STACK %rdi
 582         movq %rsp,%rdi
 583         call syscall_trace_enter
 584         /*
 585          * Reload arg registers from stack in case ptrace changed them.
 586          * We don't reload %rax because syscall_trace_enter() returned
 587          * the value it wants us to use in the table lookup.
 588          */
 589         LOAD_ARGS ARGOFFSET, 1
 590         RESTORE_REST
 591         cmpq $__NR_syscall_max,%rax
 592         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 593         movq %r10,%rcx  /* fixup for C */
 594         call *sys_call_table(,%rax,8)
 595         movq %rax,RAX-ARGOFFSET(%rsp)
 596         /* Use IRET because user could have changed frame */
 597
 598 /*
 599  * Syscall return path ending with IRET.
 600  * Has correct top of stack, but partial stack frame.
 601  */
 602 GLOBAL(int_ret_from_sys_call)
 603         DISABLE_INTERRUPTS(CLBR_NONE)
 604         TRACE_IRQS_OFF
 605         testl $3,CS-ARGOFFSET(%rsp)
 606         je retint_restore_args
 607         movl $_TIF_ALLWORK_MASK,%edi
 608         /* edi: mask to check */
 609 GLOBAL(int_with_check)
 610         LOCKDEP_SYS_EXIT_IRQ
 611         GET_THREAD_INFO(%rcx)
 612         movl TI_flags(%rcx),%edx
 613         andl %edi,%edx
 614         jnz   int_careful
 615         andl    $~TS_COMPAT,TI_status(%rcx)
 616         jmp   retint_swapgs
 617
 618         /* Either reschedule or signal or syscall exit tracking needed. */
 619         /* First do a reschedule test. */
 620         /* edx: work, edi: workmask */
 621 int_careful:
 622         bt $TIF_NEED_RESCHED,%edx
 623         jnc  int_very_careful
 624         TRACE_IRQS_ON
 625         ENABLE_INTERRUPTS(CLBR_NONE)
 626         pushq_cfi %rdi
 627         call schedule
 628         popq_cfi %rdi
 629         DISABLE_INTERRUPTS(CLBR_NONE)
 630         TRACE_IRQS_OFF
 631         jmp int_with_check
 632
 633         /* handle signals and tracing -- both require a full stack frame */
 634 int_very_careful:
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637 int_check_syscall_exit_work:
 638         SAVE_REST
 639         /* Check for syscall exit trace */
 640         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 641         jz int_signal
 642         pushq_cfi %rdi
 643         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 644         call syscall_trace_leave
 645         popq_cfi %rdi
 646         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 647         jmp int_restore_rest
 648
 649 int_signal:
 650         testl $_TIF_DO_NOTIFY_MASK,%edx
 651         jz 1f
 652         movq %rsp,%rdi          # &ptregs -> arg1
 653         xorl %esi,%esi          # oldset -> arg2
 654         call do_notify_resume
 655 1:      movl $_TIF_WORK_MASK,%edi
 656 int_restore_rest:
 657         RESTORE_REST
 658         DISABLE_INTERRUPTS(CLBR_NONE)
 659         TRACE_IRQS_OFF
 660         jmp int_with_check
 661         CFI_ENDPROC
 662 END(system_call)
 663
 664 /*
 665  * Certain special system calls that need to save a complete full stack frame.
 666  */
 667         .macro PTREGSCALL label,func,arg
 668 ENTRY(\label)
 669         PARTIAL_FRAME 1 8               /* offset 8: return address */
 670         subq $REST_SKIP, %rsp
 671         CFI_ADJUST_CFA_OFFSET REST_SKIP
 672         call save_rest
 673         DEFAULT_FRAME 0 8               /* offset 8: return address */
 674         leaq 8(%rsp), \arg      /* pt_regs pointer */
 675         call \func
 676         jmp ptregscall_common
 677         CFI_ENDPROC
 678 END(\label)
 679         .endm
 680
 681         PTREGSCALL stub_clone, sys_clone, %r8
 682         PTREGSCALL stub_fork, sys_fork, %rdi
 683         PTREGSCALL stub_vfork, sys_vfork, %rdi
 684         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 685         PTREGSCALL stub_iopl, sys_iopl, %rsi
 686
 687 ENTRY(ptregscall_common)
 688         DEFAULT_FRAME 1 8       /* offset 8: return address */
 689         RESTORE_TOP_OF_STACK %r11, 8
 690         movq_cfi_restore R15+8, r15
 691         movq_cfi_restore R14+8, r14
 692         movq_cfi_restore R13+8, r13
 693         movq_cfi_restore R12+8, r12
 694         movq_cfi_restore RBP+8, rbp
 695         movq_cfi_restore RBX+8, rbx
 696         ret $REST_SKIP          /* pop extended registers */
 697         CFI_ENDPROC
 698 END(ptregscall_common)
 699
 700 ENTRY(stub_execve)
 701         CFI_STARTPROC
 702         addq $8, %rsp
 703         PARTIAL_FRAME 0
 704         SAVE_REST
 705         FIXUP_TOP_OF_STACK %r11
 706         movq %rsp, %rcx
 707         call sys_execve
 708         RESTORE_TOP_OF_STACK %r11
 709         movq %rax,RAX(%rsp)
 710         RESTORE_REST
 711         jmp int_ret_from_sys_call
 712         CFI_ENDPROC
 713 END(stub_execve)
 714
 715 /*
 716  * sigreturn is special because it needs to restore all registers on return.
 717  * This cannot be done with SYSRET, so use the IRET return path instead.
 718  */
 719 ENTRY(stub_rt_sigreturn)
 720         CFI_STARTPROC
 721         addq $8, %rsp
 722         PARTIAL_FRAME 0
 723         SAVE_REST
 724         movq %rsp,%rdi
 725         FIXUP_TOP_OF_STACK %r11
 726         call sys_rt_sigreturn
 727         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 728         RESTORE_REST
 729         jmp int_ret_from_sys_call
 730         CFI_ENDPROC
 731 END(stub_rt_sigreturn)
 732
 733 /*
 734  * Build the entry stubs and pointer table with some assembler magic.
 735  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 736  * single cache line on all modern x86 implementations.
 737  */
 738         .section .init.rodata,"a"
 739 ENTRY(interrupt)
 740         .section .entry.text
 741         .p2align 5
 742         .p2align CONFIG_X86_L1_CACHE_SHIFT
 743 ENTRY(irq_entries_start)
 744         INTR_FRAME
 745 vector=FIRST_EXTERNAL_VECTOR
 746 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 747         .balign 32
 748   .rept 7
 749     .if vector < NR_VECTORS
 750       .if vector <> FIRST_EXTERNAL_VECTOR
 751         CFI_ADJUST_CFA_OFFSET -8
 752       .endif
 753 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 754       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 755         jmp 2f
 756       .endif
 757       .previous
 758         .quad 1b
 759       .section .entry.text
 760 vector=vector+1
 761     .endif
 762   .endr
 763 2:      jmp common_interrupt
 764 .endr
 765         CFI_ENDPROC
 766 END(irq_entries_start)
 767
 768 .previous
 769 END(interrupt)
 770 .previous
 771
 772 /*
 773  * Interrupt entry/exit.
 774  *
 775  * Interrupt entry points save only callee clobbered registers in fast path.
 776  *
 777  * Entry runs with interrupts off.
 778  */
 779
 780 /* 0(%rsp): ~(interrupt number) */
 781         .macro interrupt func
 782         /* reserve pt_regs for scratch regs and rbp */
 783         subq $ORIG_RAX-RBP, %rsp
 784         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 785         SAVE_ARGS_IRQ
 786         PARTIAL_FRAME 0
 787         call \func
 788         .endm
 789
 790 /*
 791  * Interrupt entry/exit should be protected against kprobes
 792  */
 793         .pushsection .kprobes.text, "ax"
 794         /*
 795          * The interrupt stubs push (~vector+0x80) onto the stack and
 796          * then jump to common_interrupt.
 797          */
 798         .p2align CONFIG_X86_L1_CACHE_SHIFT
 799 common_interrupt:
 800         XCPT_FRAME
 801         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 802         interrupt do_IRQ
 803         /* 0(%rsp): old_rsp-ARGOFFSET */
 804 ret_from_intr:
 805         DISABLE_INTERRUPTS(CLBR_NONE)
 806         TRACE_IRQS_OFF
 807         decl PER_CPU_VAR(irq_count)
 808         leaveq
 809
 810         CFI_RESTORE             rbp
 811         CFI_DEF_CFA_REGISTER    rsp
 812         CFI_ADJUST_CFA_OFFSET   -8
 813
 814         /* we did not save rbx, restore only from ARGOFFSET */
 815         addq $8, %rsp
 816         CFI_ADJUST_CFA_OFFSET   -8
 817 exit_intr:
 818         GET_THREAD_INFO(%rcx)
 819         testl $3,CS-ARGOFFSET(%rsp)
 820         je retint_kernel
 821
 822         /* Interrupt came from user space */
 823         /*
 824          * Has a correct top of stack, but a partial stack frame
 825          * %rcx: thread info. Interrupts off.
 826          */
 827 retint_with_reschedule:
 828         movl $_TIF_WORK_MASK,%edi
 829 retint_check:
 830         LOCKDEP_SYS_EXIT_IRQ
 831         movl TI_flags(%rcx),%edx
 832         andl %edi,%edx
 833         CFI_REMEMBER_STATE
 834         jnz  retint_careful
 835
 836 retint_swapgs:          /* return to user-space */
 837         /*
 838          * The iretq could re-enable interrupts:
 839          */
 840         DISABLE_INTERRUPTS(CLBR_ANY)
 841         TRACE_IRQS_IRETQ
 842         SWAPGS
 843         jmp restore_args
 844
 845 retint_restore_args:    /* return to kernel space */
 846         DISABLE_INTERRUPTS(CLBR_ANY)
 847         /*
 848          * The iretq could re-enable interrupts:
 849          */
 850         TRACE_IRQS_IRETQ
 851 restore_args:
 852         RESTORE_ARGS 0,8,0
 853
 854 irq_return:
 855         INTERRUPT_RETURN
 856
 857         .section __ex_table, "a"
 858         .quad irq_return, bad_iret
 859         .previous
 860
 861 #ifdef CONFIG_PARAVIRT
 862 ENTRY(native_iret)
 863         iretq
 864
 865         .section __ex_table,"a"
 866         .quad native_iret, bad_iret
 867         .previous
 868 #endif
 869
 870         .section .fixup,"ax"
 871 bad_iret:
 872         /*
 873          * The iret traps when the %cs or %ss being restored is bogus.
 874          * We've lost the original trap vector and error code.
 875          * #GPF is the most likely one to get for an invalid selector.
 876          * So pretend we completed the iret and took the #GPF in user mode.
 877          *
 878          * We are now running with the kernel GS after exception recovery.
 879          * But error_entry expects us to have user GS to match the user %cs,
 880          * so swap back.
 881          */
 882         pushq $0
 883
 884         SWAPGS
 885         jmp general_protection
 886
 887         .previous
 888
 889         /* edi: workmask, edx: work */
 890 retint_careful:
 891         CFI_RESTORE_STATE
 892         bt    $TIF_NEED_RESCHED,%edx
 893         jnc   retint_signal
 894         TRACE_IRQS_ON
 895         ENABLE_INTERRUPTS(CLBR_NONE)
 896         pushq_cfi %rdi
 897         call  schedule
 898         popq_cfi %rdi
 899         GET_THREAD_INFO(%rcx)
 900         DISABLE_INTERRUPTS(CLBR_NONE)
 901         TRACE_IRQS_OFF
 902         jmp retint_check
 903
 904 retint_signal:
 905         testl $_TIF_DO_NOTIFY_MASK,%edx
 906         jz    retint_swapgs
 907         TRACE_IRQS_ON
 908         ENABLE_INTERRUPTS(CLBR_NONE)
 909         SAVE_REST
 910         movq $-1,ORIG_RAX(%rsp)
 911         xorl %esi,%esi          # oldset
 912         movq %rsp,%rdi          # &pt_regs
 913         call do_notify_resume
 914         RESTORE_REST
 915         DISABLE_INTERRUPTS(CLBR_NONE)
 916         TRACE_IRQS_OFF
 917         GET_THREAD_INFO(%rcx)
 918         jmp retint_with_reschedule
 919
 920 #ifdef CONFIG_PREEMPT
 921         /* Returning to kernel space. Check if we need preemption */
 922         /* rcx:  threadinfo. interrupts off. */
 923 ENTRY(retint_kernel)
 924         cmpl $0,TI_preempt_count(%rcx)
 925         jnz  retint_restore_args
 926         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 927         jnc  retint_restore_args
 928         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 929         jnc  retint_restore_args
 930         call preempt_schedule_irq
 931         jmp exit_intr
 932 #endif
 933
 934         CFI_ENDPROC
 935 END(common_interrupt)
 936 /*
 937  * End of kprobes section
 938  */
 939        .popsection
 940
 941 /*
 942  * APIC interrupts.
 943  */
 944 .macro apicinterrupt num sym do_sym
 945 ENTRY(\sym)
 946         INTR_FRAME
 947         pushq_cfi $~(\num)
 948         interrupt \do_sym
 949         jmp ret_from_intr
 950         CFI_ENDPROC
 951 END(\sym)
 952 .endm
 953
 954 #ifdef CONFIG_SMP
 955 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 956         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 957 apicinterrupt REBOOT_VECTOR \
 958         reboot_interrupt smp_reboot_interrupt
 959 #endif
 960
 961 #ifdef CONFIG_X86_UV
 962 apicinterrupt UV_BAU_MESSAGE \
 963         uv_bau_message_intr1 uv_bau_message_interrupt
 964 #endif
 965 apicinterrupt LOCAL_TIMER_VECTOR \
 966         apic_timer_interrupt smp_apic_timer_interrupt
 967 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 968         x86_platform_ipi smp_x86_platform_ipi
 969
 970 #ifdef CONFIG_SMP
 971 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 972         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 973 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 974 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 975         invalidate_interrupt\idx smp_invalidate_interrupt
 976 .endif
 977 .endr
 978 #endif
 979
 980 apicinterrupt THRESHOLD_APIC_VECTOR \
 981         threshold_interrupt smp_threshold_interrupt
 982 apicinterrupt THERMAL_APIC_VECTOR \
 983         thermal_interrupt smp_thermal_interrupt
 984
 985 #ifdef CONFIG_X86_MCE
 986 apicinterrupt MCE_SELF_VECTOR \
 987         mce_self_interrupt smp_mce_self_interrupt
 988 #endif
 989
 990 #ifdef CONFIG_SMP
 991 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
 992         call_function_single_interrupt smp_call_function_single_interrupt
 993 apicinterrupt CALL_FUNCTION_VECTOR \
 994         call_function_interrupt smp_call_function_interrupt
 995 apicinterrupt RESCHEDULE_VECTOR \
 996         reschedule_interrupt smp_reschedule_interrupt
 997 #endif
 998
 999 apicinterrupt ERROR_APIC_VECTOR \
1000         error_interrupt smp_error_interrupt
1001 apicinterrupt SPURIOUS_APIC_VECTOR \
1002         spurious_interrupt smp_spurious_interrupt
1003
1004 #ifdef CONFIG_IRQ_WORK
1005 apicinterrupt IRQ_WORK_VECTOR \
1006         irq_work_interrupt smp_irq_work_interrupt
1007 #endif
1008
1009 /*
1010  * Exception entry points.
1011  */
1012 .macro zeroentry sym do_sym
1013 ENTRY(\sym)
1014         INTR_FRAME
1015         PARAVIRT_ADJUST_EXCEPTION_FRAME
1016         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1017         subq $ORIG_RAX-R15, %rsp
1018         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1019         call error_entry
1020         DEFAULT_FRAME 0
1021         movq %rsp,%rdi          /* pt_regs pointer */
1022         xorl %esi,%esi          /* no error code */
1023         call \do_sym
1024         jmp error_exit          /* %ebx: no swapgs flag */
1025         CFI_ENDPROC
1026 END(\sym)
1027 .endm
1028
1029 .macro paranoidzeroentry sym do_sym
1030 ENTRY(\sym)
1031         INTR_FRAME
1032         PARAVIRT_ADJUST_EXCEPTION_FRAME
1033         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1034         subq $ORIG_RAX-R15, %rsp
1035         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1036         call save_paranoid
1037         TRACE_IRQS_OFF
1038         movq %rsp,%rdi          /* pt_regs pointer */
1039         xorl %esi,%esi          /* no error code */
1040         call \do_sym
1041         jmp paranoid_exit       /* %ebx: no swapgs flag */
1042         CFI_ENDPROC
1043 END(\sym)
1044 .endm
1045
1046 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1047 .macro paranoidzeroentry_ist sym do_sym ist
1048 ENTRY(\sym)
1049         INTR_FRAME
1050         PARAVIRT_ADJUST_EXCEPTION_FRAME
1051         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1052         subq $ORIG_RAX-R15, %rsp
1053         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1054         call save_paranoid
1055         TRACE_IRQS_OFF
1056         movq %rsp,%rdi          /* pt_regs pointer */
1057         xorl %esi,%esi          /* no error code */
1058         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1059         call \do_sym
1060         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1061         jmp paranoid_exit       /* %ebx: no swapgs flag */
1062         CFI_ENDPROC
1063 END(\sym)
1064 .endm
1065
1066 .macro errorentry sym do_sym
1067 ENTRY(\sym)
1068         XCPT_FRAME
1069         PARAVIRT_ADJUST_EXCEPTION_FRAME
1070         subq $ORIG_RAX-R15, %rsp
1071         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1072         call error_entry
1073         DEFAULT_FRAME 0
1074         movq %rsp,%rdi                  /* pt_regs pointer */
1075         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1076         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1077         call \do_sym
1078         jmp error_exit                  /* %ebx: no swapgs flag */
1079         CFI_ENDPROC
1080 END(\sym)
1081 .endm
1082
1083         /* error code is on the stack already */
1084 .macro paranoiderrorentry sym do_sym
1085 ENTRY(\sym)
1086         XCPT_FRAME
1087         PARAVIRT_ADJUST_EXCEPTION_FRAME
1088         subq $ORIG_RAX-R15, %rsp
1089         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1090         call save_paranoid
1091         DEFAULT_FRAME 0
1092         TRACE_IRQS_OFF
1093         movq %rsp,%rdi                  /* pt_regs pointer */
1094         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1095         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1096         call \do_sym
1097         jmp paranoid_exit               /* %ebx: no swapgs flag */
1098         CFI_ENDPROC
1099 END(\sym)
1100 .endm
1101
1102 zeroentry divide_error do_divide_error
1103 zeroentry overflow do_overflow
1104 zeroentry bounds do_bounds
1105 zeroentry invalid_op do_invalid_op
1106 zeroentry device_not_available do_device_not_available
1107 paranoiderrorentry double_fault do_double_fault
1108 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1109 errorentry invalid_TSS do_invalid_TSS
1110 errorentry segment_not_present do_segment_not_present
1111 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1112 zeroentry coprocessor_error do_coprocessor_error
1113 errorentry alignment_check do_alignment_check
1114 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1115
1116         /* Reload gs selector with exception handling */
1117         /* edi:  new selector */
1118 ENTRY(native_load_gs_index)
1119         CFI_STARTPROC
1120         pushfq_cfi
1121         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1122         SWAPGS
1123 gs_change:
1124         movl %edi,%gs
1125 2:      mfence          /* workaround */
1126         SWAPGS
1127         popfq_cfi
1128         ret
1129         CFI_ENDPROC
1130 END(native_load_gs_index)
1131
1132         .section __ex_table,"a"
1133         .align 8
1134         .quad gs_change,bad_gs
1135         .previous
1136         .section .fixup,"ax"
1137         /* running with kernelgs */
1138 bad_gs:
1139         SWAPGS                  /* switch back to user gs */
1140         xorl %eax,%eax
1141         movl %eax,%gs
1142         jmp  2b
1143         .previous
1144
1145 ENTRY(kernel_thread_helper)
1146         pushq $0                # fake return address
1147         CFI_STARTPROC
1148         /*
1149          * Here we are in the child and the registers are set as they were
1150          * at kernel_thread() invocation in the parent.
1151          */
1152         call *%rsi
1153         # exit
1154         mov %eax, %edi
1155         call do_exit
1156         ud2                     # padding for call trace
1157         CFI_ENDPROC
1158 END(kernel_thread_helper)
1159
1160 /*
1161  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1162  *
1163  * C extern interface:
1164  *       extern long execve(const char *name, char **argv, char **envp)
1165  *
1166  * asm input arguments:
1167  *      rdi: name, rsi: argv, rdx: envp
1168  *
1169  * We want to fallback into:
1170  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1171  *
1172  * do_sys_execve asm fallback arguments:
1173  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1174  */
1175 ENTRY(kernel_execve)
1176         CFI_STARTPROC
1177         FAKE_STACK_FRAME $0
1178         SAVE_ALL
1179         movq %rsp,%rcx
1180         call sys_execve
1181         movq %rax, RAX(%rsp)
1182         RESTORE_REST
1183         testq %rax,%rax
1184         je int_ret_from_sys_call
1185         RESTORE_ARGS
1186         UNFAKE_STACK_FRAME
1187         ret
1188         CFI_ENDPROC
1189 END(kernel_execve)
1190
1191 /* Call softirq on interrupt stack. Interrupts are off. */
1192 ENTRY(call_softirq)
1193         CFI_STARTPROC
1194         pushq_cfi %rbp
1195         CFI_REL_OFFSET rbp,0
1196         mov  %rsp,%rbp
1197         CFI_DEF_CFA_REGISTER rbp
1198         incl PER_CPU_VAR(irq_count)
1199         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1200         push  %rbp                      # backlink for old unwinder
1201         call __do_softirq
1202         leaveq
1203         CFI_RESTORE             rbp
1204         CFI_DEF_CFA_REGISTER    rsp
1205         CFI_ADJUST_CFA_OFFSET   -8
1206         decl PER_CPU_VAR(irq_count)
1207         ret
1208         CFI_ENDPROC
1209 END(call_softirq)
1210
1211 #ifdef CONFIG_XEN
1212 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1213
1214 /*
1215  * A note on the "critical region" in our callback handler.
1216  * We want to avoid stacking callback handlers due to events occurring
1217  * during handling of the last event. To do this, we keep events disabled
1218  * until we've done all processing. HOWEVER, we must enable events before
1219  * popping the stack frame (can't be done atomically) and so it would still
1220  * be possible to get enough handler activations to overflow the stack.
1221  * Although unlikely, bugs of that kind are hard to track down, so we'd
1222  * like to avoid the possibility.
1223  * So, on entry to the handler we detect whether we interrupted an
1224  * existing activation in its critical region -- if so, we pop the current
1225  * activation and restart the handler using the previous one.
1226  */
1227 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1228         CFI_STARTPROC
1229 /*
1230  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1231  * see the correct pointer to the pt_regs
1232  */
1233         movq %rdi, %rsp            # we don't return, adjust the stack frame
1234         CFI_ENDPROC
1235         DEFAULT_FRAME
1236 11:     incl PER_CPU_VAR(irq_count)
1237         movq %rsp,%rbp
1238         CFI_DEF_CFA_REGISTER rbp
1239         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1240         pushq %rbp                      # backlink for old unwinder
1241         call xen_evtchn_do_upcall
1242         popq %rsp
1243         CFI_DEF_CFA_REGISTER rsp
1244         decl PER_CPU_VAR(irq_count)
1245         jmp  error_exit
1246         CFI_ENDPROC
1247 END(xen_do_hypervisor_callback)
1248
1249 /*
1250  * Hypervisor uses this for application faults while it executes.
1251  * We get here for two reasons:
1252  *  1. Fault while reloading DS, ES, FS or GS
1253  *  2. Fault while executing IRET
1254  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1255  * registers that could be reloaded and zeroed the others.
1256  * Category 2 we fix up by killing the current process. We cannot use the
1257  * normal Linux return path in this case because if we use the IRET hypercall
1258  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1259  * We distinguish between categories by comparing each saved segment register
1260  * with its current contents: any discrepancy means we in category 1.
1261  */
1262 ENTRY(xen_failsafe_callback)
1263         INTR_FRAME 1 (6*8)
1264         /*CFI_REL_OFFSET gs,GS*/
1265         /*CFI_REL_OFFSET fs,FS*/
1266         /*CFI_REL_OFFSET es,ES*/
1267         /*CFI_REL_OFFSET ds,DS*/
1268         CFI_REL_OFFSET r11,8
1269         CFI_REL_OFFSET rcx,0
1270         movw %ds,%cx
1271         cmpw %cx,0x10(%rsp)
1272         CFI_REMEMBER_STATE
1273         jne 1f
1274         movw %es,%cx
1275         cmpw %cx,0x18(%rsp)
1276         jne 1f
1277         movw %fs,%cx
1278         cmpw %cx,0x20(%rsp)
1279         jne 1f
1280         movw %gs,%cx
1281         cmpw %cx,0x28(%rsp)
1282         jne 1f
1283         /* All segments match their saved values => Category 2 (Bad IRET). */
1284         movq (%rsp),%rcx
1285         CFI_RESTORE rcx
1286         movq 8(%rsp),%r11
1287         CFI_RESTORE r11
1288         addq $0x30,%rsp
1289         CFI_ADJUST_CFA_OFFSET -0x30
1290         pushq_cfi $0    /* RIP */
1291         pushq_cfi %r11
1292         pushq_cfi %rcx
1293         jmp general_protection
1294         CFI_RESTORE_STATE
1295 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1296         movq (%rsp),%rcx
1297         CFI_RESTORE rcx
1298         movq 8(%rsp),%r11
1299         CFI_RESTORE r11
1300         addq $0x30,%rsp
1301         CFI_ADJUST_CFA_OFFSET -0x30
1302         pushq_cfi $0
1303         SAVE_ALL
1304         jmp error_exit
1305         CFI_ENDPROC
1306 END(xen_failsafe_callback)
1307
1308 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1309         xen_hvm_callback_vector xen_evtchn_do_upcall
1310
1311 #endif /* CONFIG_XEN */
1312
1313 /*
1314  * Some functions should be protected against kprobes
1315  */
1316         .pushsection .kprobes.text, "ax"
1317
1318 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1319 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1320 paranoiderrorentry stack_segment do_stack_segment
1321 #ifdef CONFIG_XEN
1322 zeroentry xen_debug do_debug
1323 zeroentry xen_int3 do_int3
1324 errorentry xen_stack_segment do_stack_segment
1325 #endif
1326 errorentry general_protection do_general_protection
1327 errorentry page_fault do_page_fault
1328 #ifdef CONFIG_KVM_GUEST
1329 errorentry async_page_fault do_async_page_fault
1330 #endif
1331 #ifdef CONFIG_X86_MCE
1332 paranoidzeroentry machine_check *machine_check_vector(%rip)
1333 #endif
1334
1335         /*
1336          * "Paranoid" exit path from exception stack.
1337          * Paranoid because this is used by NMIs and cannot take
1338          * any kernel state for granted.
1339          * We don't do kernel preemption checks here, because only
1340          * NMI should be common and it does not enable IRQs and
1341          * cannot get reschedule ticks.
1342          *
1343          * "trace" is 0 for the NMI handler only, because irq-tracing
1344          * is fundamentally NMI-unsafe. (we cannot change the soft and
1345          * hard flags at once, atomically)
1346          */
1347
1348         /* ebx: no swapgs flag */
1349 ENTRY(paranoid_exit)
1350         DEFAULT_FRAME
1351         DISABLE_INTERRUPTS(CLBR_NONE)
1352         TRACE_IRQS_OFF
1353         testl %ebx,%ebx                         /* swapgs needed? */
1354         jnz paranoid_restore
1355         testl $3,CS(%rsp)
1356         jnz   paranoid_userspace
1357 paranoid_swapgs:
1358         TRACE_IRQS_IRETQ 0
1359         SWAPGS_UNSAFE_STACK
1360         RESTORE_ALL 8
1361         jmp irq_return
1362 paranoid_restore:
1363         TRACE_IRQS_IRETQ 0
1364         RESTORE_ALL 8
1365         jmp irq_return
1366 paranoid_userspace:
1367         GET_THREAD_INFO(%rcx)
1368         movl TI_flags(%rcx),%ebx
1369         andl $_TIF_WORK_MASK,%ebx
1370         jz paranoid_swapgs
1371         movq %rsp,%rdi                  /* &pt_regs */
1372         call sync_regs
1373         movq %rax,%rsp                  /* switch stack for scheduling */
1374         testl $_TIF_NEED_RESCHED,%ebx
1375         jnz paranoid_schedule
1376         movl %ebx,%edx                  /* arg3: thread flags */
1377         TRACE_IRQS_ON
1378         ENABLE_INTERRUPTS(CLBR_NONE)
1379         xorl %esi,%esi                  /* arg2: oldset */
1380         movq %rsp,%rdi                  /* arg1: &pt_regs */
1381         call do_notify_resume
1382         DISABLE_INTERRUPTS(CLBR_NONE)
1383         TRACE_IRQS_OFF
1384         jmp paranoid_userspace
1385 paranoid_schedule:
1386         TRACE_IRQS_ON
1387         ENABLE_INTERRUPTS(CLBR_ANY)
1388         call schedule
1389         DISABLE_INTERRUPTS(CLBR_ANY)
1390         TRACE_IRQS_OFF
1391         jmp paranoid_userspace
1392         CFI_ENDPROC
1393 END(paranoid_exit)
1394
1395 /*
1396  * Exception entry point. This expects an error code/orig_rax on the stack.
1397  * returns in "no swapgs flag" in %ebx.
1398  */
1399 ENTRY(error_entry)
1400         XCPT_FRAME
1401         CFI_ADJUST_CFA_OFFSET 15*8
1402         /* oldrax contains error code */
1403         cld
1404         movq_cfi rdi, RDI+8
1405         movq_cfi rsi, RSI+8
1406         movq_cfi rdx, RDX+8
1407         movq_cfi rcx, RCX+8
1408         movq_cfi rax, RAX+8
1409         movq_cfi  r8,  R8+8
1410         movq_cfi  r9,  R9+8
1411         movq_cfi r10, R10+8
1412         movq_cfi r11, R11+8
1413         movq_cfi rbx, RBX+8
1414         movq_cfi rbp, RBP+8
1415         movq_cfi r12, R12+8
1416         movq_cfi r13, R13+8
1417         movq_cfi r14, R14+8
1418         movq_cfi r15, R15+8
1419         xorl %ebx,%ebx
1420         testl $3,CS+8(%rsp)
1421         je error_kernelspace
1422 error_swapgs:
1423         SWAPGS
1424 error_sti:
1425         TRACE_IRQS_OFF
1426         ret
1427
1428 /*
1429  * There are two places in the kernel that can potentially fault with
1430  * usergs. Handle them here. The exception handlers after iret run with
1431  * kernel gs again, so don't set the user space flag. B stepping K8s
1432  * sometimes report an truncated RIP for IRET exceptions returning to
1433  * compat mode. Check for these here too.
1434  */
1435 error_kernelspace:
1436         incl %ebx
1437         leaq irq_return(%rip),%rcx
1438         cmpq %rcx,RIP+8(%rsp)
1439         je error_swapgs
1440         movl %ecx,%eax  /* zero extend */
1441         cmpq %rax,RIP+8(%rsp)
1442         je bstep_iret
1443         cmpq $gs_change,RIP+8(%rsp)
1444         je error_swapgs
1445         jmp error_sti
1446
1447 bstep_iret:
1448         /* Fix truncated RIP */
1449         movq %rcx,RIP+8(%rsp)
1450         jmp error_swapgs
1451         CFI_ENDPROC
1452 END(error_entry)
1453
1454
1455 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1456 ENTRY(error_exit)
1457         DEFAULT_FRAME
1458         movl %ebx,%eax
1459         RESTORE_REST
1460         DISABLE_INTERRUPTS(CLBR_NONE)
1461         TRACE_IRQS_OFF
1462         GET_THREAD_INFO(%rcx)
1463         testl %eax,%eax
1464         jne retint_kernel
1465         LOCKDEP_SYS_EXIT_IRQ
1466         movl TI_flags(%rcx),%edx
1467         movl $_TIF_WORK_MASK,%edi
1468         andl %edi,%edx
1469         jnz retint_careful
1470         jmp retint_swapgs
1471         CFI_ENDPROC
1472 END(error_exit)
1473
1474
1475         /* runs on exception stack */
1476 ENTRY(nmi)
1477         INTR_FRAME
1478         PARAVIRT_ADJUST_EXCEPTION_FRAME
1479         pushq_cfi $-1
1480         subq $ORIG_RAX-R15, %rsp
1481         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1482         call save_paranoid
1483         DEFAULT_FRAME 0
1484         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1485         movq %rsp,%rdi
1486         movq $-1,%rsi
1487         call do_nmi
1488 #ifdef CONFIG_TRACE_IRQFLAGS
1489         /* paranoidexit; without TRACE_IRQS_OFF */
1490         /* ebx: no swapgs flag */
1491         DISABLE_INTERRUPTS(CLBR_NONE)
1492         testl %ebx,%ebx                         /* swapgs needed? */
1493         jnz nmi_restore
1494         testl $3,CS(%rsp)
1495         jnz nmi_userspace
1496 nmi_swapgs:
1497         SWAPGS_UNSAFE_STACK
1498 nmi_restore:
1499         RESTORE_ALL 8
1500         jmp irq_return
1501 nmi_userspace:
1502         GET_THREAD_INFO(%rcx)
1503         movl TI_flags(%rcx),%ebx
1504         andl $_TIF_WORK_MASK,%ebx
1505         jz nmi_swapgs
1506         movq %rsp,%rdi                  /* &pt_regs */
1507         call sync_regs
1508         movq %rax,%rsp                  /* switch stack for scheduling */
1509         testl $_TIF_NEED_RESCHED,%ebx
1510         jnz nmi_schedule
1511         movl %ebx,%edx                  /* arg3: thread flags */
1512         ENABLE_INTERRUPTS(CLBR_NONE)
1513         xorl %esi,%esi                  /* arg2: oldset */
1514         movq %rsp,%rdi                  /* arg1: &pt_regs */
1515         call do_notify_resume
1516         DISABLE_INTERRUPTS(CLBR_NONE)
1517         jmp nmi_userspace
1518 nmi_schedule:
1519         ENABLE_INTERRUPTS(CLBR_ANY)
1520         call schedule
1521         DISABLE_INTERRUPTS(CLBR_ANY)
1522         jmp nmi_userspace
1523         CFI_ENDPROC
1524 #else
1525         jmp paranoid_exit
1526         CFI_ENDPROC
1527 #endif
1528 END(nmi)
1529
1530 ENTRY(ignore_sysret)
1531         CFI_STARTPROC
1532         mov $-ENOSYS,%eax
1533         sysret
1534         CFI_ENDPROC
1535 END(ignore_sysret)
1536
1537 /*
1538  * End of kprobes section
1539  */
1540         .popsection