arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page_types.h>
  51 #include <asm/percpu.h>
  52 #include <asm/dwarf2.h>
  53 #include <asm/processor-flags.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/irq_vectors.h>
  56 #include <asm/cpufeature.h>
  57 #include <asm/alternative-asm.h>
  58
  59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  60 #include <linux/elf-em.h>
  61 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  62 #define __AUDIT_ARCH_LE    0x40000000
  63
  64 #ifndef CONFIG_AUDITSYSCALL
  65 #define sysenter_audit  syscall_trace_entry
  66 #define sysexit_audit   syscall_exit_work
  67 #endif
  68
  69         .section .entry.text, "ax"
  70
  71 /*
  72  * We use macros for low-level operations which need to be overridden
  73  * for paravirtualization.  The following will never clobber any registers:
  74  *   INTERRUPT_RETURN (aka. "iret")
  75  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  76  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  77  *
  78  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  79  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  80  * Allowing a register to be clobbered can shrink the paravirt replacement
  81  * enough to patch inline, increasing performance.
  82  */
  83
  84 #define nr_syscalls ((syscall_table_size)/4)
  85
  86 #ifdef CONFIG_PREEMPT
  87 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  88 #else
  89 #define preempt_stop(clobbers)
  90 #define resume_kernel           restore_all
  91 #endif
  92
  93 .macro TRACE_IRQS_IRET
  94 #ifdef CONFIG_TRACE_IRQFLAGS
  95         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  96         jz 1f
  97         TRACE_IRQS_ON
  98 1:
  99 #endif
 100 .endm
 101
 102 /*
 103  * User gs save/restore
 104  *
 105  * %gs is used for userland TLS and kernel only uses it for stack
 106  * canary which is required to be at %gs:20 by gcc.  Read the comment
 107  * at the top of stackprotector.h for more info.
 108  *
 109  * Local labels 98 and 99 are used.
 110  */
 111 #ifdef CONFIG_X86_32_LAZY_GS
 112
 113  /* unfortunately push/pop can't be no-op */
 114 .macro PUSH_GS
 115         pushl_cfi $0
 116 .endm
 117 .macro POP_GS pop=0
 118         addl $(4 + \pop), %esp
 119         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 120 .endm
 121 .macro POP_GS_EX
 122 .endm
 123
 124  /* all the rest are no-op */
 125 .macro PTGS_TO_GS
 126 .endm
 127 .macro PTGS_TO_GS_EX
 128 .endm
 129 .macro GS_TO_REG reg
 130 .endm
 131 .macro REG_TO_PTGS reg
 132 .endm
 133 .macro SET_KERNEL_GS reg
 134 .endm
 135
 136 #else   /* CONFIG_X86_32_LAZY_GS */
 137
 138 .macro PUSH_GS
 139         pushl_cfi %gs
 140         /*CFI_REL_OFFSET gs, 0*/
 141 .endm
 142
 143 .macro POP_GS pop=0
 144 98:     popl_cfi %gs
 145         /*CFI_RESTORE gs*/
 146   .if \pop <> 0
 147         add $\pop, %esp
 148         CFI_ADJUST_CFA_OFFSET -\pop
 149   .endif
 150 .endm
 151 .macro POP_GS_EX
 152 .pushsection .fixup, "ax"
 153 99:     movl $0, (%esp)
 154         jmp 98b
 155 .section __ex_table, "a"
 156         .align 4
 157         .long 98b, 99b
 158 .popsection
 159 .endm
 160
 161 .macro PTGS_TO_GS
 162 98:     mov PT_GS(%esp), %gs
 163 .endm
 164 .macro PTGS_TO_GS_EX
 165 .pushsection .fixup, "ax"
 166 99:     movl $0, PT_GS(%esp)
 167         jmp 98b
 168 .section __ex_table, "a"
 169         .align 4
 170         .long 98b, 99b
 171 .popsection
 172 .endm
 173
 174 .macro GS_TO_REG reg
 175         movl %gs, \reg
 176         /*CFI_REGISTER gs, \reg*/
 177 .endm
 178 .macro REG_TO_PTGS reg
 179         movl \reg, PT_GS(%esp)
 180         /*CFI_REL_OFFSET gs, PT_GS*/
 181 .endm
 182 .macro SET_KERNEL_GS reg
 183         movl $(__KERNEL_STACK_CANARY), \reg
 184         movl \reg, %gs
 185 .endm
 186
 187 #endif  /* CONFIG_X86_32_LAZY_GS */
 188
 189 .macro SAVE_ALL
 190         cld
 191         PUSH_GS
 192         pushl_cfi %fs
 193         /*CFI_REL_OFFSET fs, 0;*/
 194         pushl_cfi %es
 195         /*CFI_REL_OFFSET es, 0;*/
 196         pushl_cfi %ds
 197         /*CFI_REL_OFFSET ds, 0;*/
 198         pushl_cfi %eax
 199         CFI_REL_OFFSET eax, 0
 200         pushl_cfi %ebp
 201         CFI_REL_OFFSET ebp, 0
 202         pushl_cfi %edi
 203         CFI_REL_OFFSET edi, 0
 204         pushl_cfi %esi
 205         CFI_REL_OFFSET esi, 0
 206         pushl_cfi %edx
 207         CFI_REL_OFFSET edx, 0
 208         pushl_cfi %ecx
 209         CFI_REL_OFFSET ecx, 0
 210         pushl_cfi %ebx
 211         CFI_REL_OFFSET ebx, 0
 212         movl $(__USER_DS), %edx
 213         movl %edx, %ds
 214         movl %edx, %es
 215         movl $(__KERNEL_PERCPU), %edx
 216         movl %edx, %fs
 217         SET_KERNEL_GS %edx
 218 .endm
 219
 220 .macro RESTORE_INT_REGS
 221         popl_cfi %ebx
 222         CFI_RESTORE ebx
 223         popl_cfi %ecx
 224         CFI_RESTORE ecx
 225         popl_cfi %edx
 226         CFI_RESTORE edx
 227         popl_cfi %esi
 228         CFI_RESTORE esi
 229         popl_cfi %edi
 230         CFI_RESTORE edi
 231         popl_cfi %ebp
 232         CFI_RESTORE ebp
 233         popl_cfi %eax
 234         CFI_RESTORE eax
 235 .endm
 236
 237 .macro RESTORE_REGS pop=0
 238         RESTORE_INT_REGS
 239 1:      popl_cfi %ds
 240         /*CFI_RESTORE ds;*/
 241 2:      popl_cfi %es
 242         /*CFI_RESTORE es;*/
 243 3:      popl_cfi %fs
 244         /*CFI_RESTORE fs;*/
 245         POP_GS \pop
 246 .pushsection .fixup, "ax"
 247 4:      movl $0, (%esp)
 248         jmp 1b
 249 5:      movl $0, (%esp)
 250         jmp 2b
 251 6:      movl $0, (%esp)
 252         jmp 3b
 253 .section __ex_table, "a"
 254         .align 4
 255         .long 1b, 4b
 256         .long 2b, 5b
 257         .long 3b, 6b
 258 .popsection
 259         POP_GS_EX
 260 .endm
 261
 262 .macro RING0_INT_FRAME
 263         CFI_STARTPROC simple
 264         CFI_SIGNAL_FRAME
 265         CFI_DEF_CFA esp, 3*4
 266         /*CFI_OFFSET cs, -2*4;*/
 267         CFI_OFFSET eip, -3*4
 268 .endm
 269
 270 .macro RING0_EC_FRAME
 271         CFI_STARTPROC simple
 272         CFI_SIGNAL_FRAME
 273         CFI_DEF_CFA esp, 4*4
 274         /*CFI_OFFSET cs, -2*4;*/
 275         CFI_OFFSET eip, -3*4
 276 .endm
 277
 278 .macro RING0_PTREGS_FRAME
 279         CFI_STARTPROC simple
 280         CFI_SIGNAL_FRAME
 281         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 282         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 283         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 284         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 285         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 286         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 287         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 288         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 289         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 290         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 291         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 292         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 293 .endm
 294
 295 ENTRY(ret_from_fork)
 296         CFI_STARTPROC
 297         pushl_cfi %eax
 298         call schedule_tail
 299         GET_THREAD_INFO(%ebp)
 300         popl_cfi %eax
 301         pushl_cfi $0x0202               # Reset kernel eflags
 302         popfl_cfi
 303         jmp syscall_exit
 304         CFI_ENDPROC
 305 END(ret_from_fork)
 306
 307 /*
 308  * Interrupt exit functions should be protected against kprobes
 309  */
 310         .pushsection .kprobes.text, "ax"
 311 /*
 312  * Return to user mode is not as complex as all this looks,
 313  * but we want the default path for a system call return to
 314  * go as quickly as possible which is why some of this is
 315  * less clear than it otherwise should be.
 316  */
 317
 318         # userspace resumption stub bypassing syscall exit tracing
 319         ALIGN
 320         RING0_PTREGS_FRAME
 321 ret_from_exception:
 322         preempt_stop(CLBR_ANY)
 323 ret_from_intr:
 324         GET_THREAD_INFO(%ebp)
 325 resume_userspace_sig:
 326 #ifdef CONFIG_VM86
 327         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 328         movb PT_CS(%esp), %al
 329         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 330 #else
 331         /*
 332          * We can be coming here from a syscall done in the kernel space,
 333          * e.g. a failed kernel_execve().
 334          */
 335         movl PT_CS(%esp), %eax
 336         andl $SEGMENT_RPL_MASK, %eax
 337 #endif
 338         cmpl $USER_RPL, %eax
 339         jb resume_kernel                # not returning to v8086 or userspace
 340
 341 ENTRY(resume_userspace)
 342         LOCKDEP_SYS_EXIT
 343         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 344                                         # setting need_resched or sigpending
 345                                         # between sampling and the iret
 346         TRACE_IRQS_OFF
 347         movl TI_flags(%ebp), %ecx
 348         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 349                                         # int/exception return?
 350         jne work_pending
 351         jmp restore_all
 352 END(ret_from_exception)
 353
 354 #ifdef CONFIG_PREEMPT
 355 ENTRY(resume_kernel)
 356         DISABLE_INTERRUPTS(CLBR_ANY)
 357         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 358         jnz restore_all
 359 need_resched:
 360         movl TI_flags(%ebp), %ecx       # need_resched set ?
 361         testb $_TIF_NEED_RESCHED, %cl
 362         jz restore_all
 363         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 364         jz restore_all
 365         call preempt_schedule_irq
 366         jmp need_resched
 367 END(resume_kernel)
 368 #endif
 369         CFI_ENDPROC
 370 /*
 371  * End of kprobes section
 372  */
 373         .popsection
 374
 375 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 376    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 377
 378         # sysenter call handler stub
 379 ENTRY(ia32_sysenter_target)
 380         CFI_STARTPROC simple
 381         CFI_SIGNAL_FRAME
 382         CFI_DEF_CFA esp, 0
 383         CFI_REGISTER esp, ebp
 384         movl TSS_sysenter_sp0(%esp),%esp
 385 sysenter_past_esp:
 386         /*
 387          * Interrupts are disabled here, but we can't trace it until
 388          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 389          * we immediately enable interrupts at that point anyway.
 390          */
 391         pushl_cfi $__USER_DS
 392         /*CFI_REL_OFFSET ss, 0*/
 393         pushl_cfi %ebp
 394         CFI_REL_OFFSET esp, 0
 395         pushfl_cfi
 396         orl $X86_EFLAGS_IF, (%esp)
 397         pushl_cfi $__USER_CS
 398         /*CFI_REL_OFFSET cs, 0*/
 399         /*
 400          * Push current_thread_info()->sysenter_return to the stack.
 401          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 402          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 403          */
 404         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 405         CFI_REL_OFFSET eip, 0
 406
 407         pushl_cfi %eax
 408         SAVE_ALL
 409         ENABLE_INTERRUPTS(CLBR_NONE)
 410
 411 /*
 412  * Load the potential sixth argument from user stack.
 413  * Careful about security.
 414  */
 415         cmpl $__PAGE_OFFSET-3,%ebp
 416         jae syscall_fault
 417 1:      movl (%ebp),%ebp
 418         movl %ebp,PT_EBP(%esp)
 419 .section __ex_table,"a"
 420         .align 4
 421         .long 1b,syscall_fault
 422 .previous
 423
 424         GET_THREAD_INFO(%ebp)
 425
 426         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 427         jnz sysenter_audit
 428 sysenter_do_call:
 429         cmpl $(nr_syscalls), %eax
 430         jae sysenter_badsys
 431         call *sys_call_table(,%eax,4)
 432         movl %eax,PT_EAX(%esp)
 433 sysenter_after_call:
 434         LOCKDEP_SYS_EXIT
 435         DISABLE_INTERRUPTS(CLBR_ANY)
 436         TRACE_IRQS_OFF
 437         movl TI_flags(%ebp), %ecx
 438         testl $_TIF_ALLWORK_MASK, %ecx
 439         jne sysexit_audit
 440 sysenter_exit:
 441 /* if something modifies registers it must also disable sysexit */
 442         movl PT_EIP(%esp), %edx
 443         movl PT_OLDESP(%esp), %ecx
 444         xorl %ebp,%ebp
 445         TRACE_IRQS_ON
 446 1:      mov  PT_FS(%esp), %fs
 447         PTGS_TO_GS
 448         ENABLE_INTERRUPTS_SYSEXIT
 449
 450 #ifdef CONFIG_AUDITSYSCALL
 451 sysenter_audit:
 452         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 453         jnz syscall_trace_entry
 454         addl $4,%esp
 455         CFI_ADJUST_CFA_OFFSET -4
 456         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 457         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 458         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 459         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 460         movl %eax,%edx                  /* 2nd arg: syscall number */
 461         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 462         call audit_syscall_entry
 463         pushl_cfi %ebx
 464         movl PT_EAX(%esp),%eax          /* reload syscall number */
 465         jmp sysenter_do_call
 466
 467 sysexit_audit:
 468         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 469         jne syscall_exit_work
 470         TRACE_IRQS_ON
 471         ENABLE_INTERRUPTS(CLBR_ANY)
 472         movl %eax,%edx          /* second arg, syscall return value */
 473         cmpl $0,%eax            /* is it < 0? */
 474         setl %al                /* 1 if so, 0 if not */
 475         movzbl %al,%eax         /* zero-extend that */
 476         inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 477         call audit_syscall_exit
 478         DISABLE_INTERRUPTS(CLBR_ANY)
 479         TRACE_IRQS_OFF
 480         movl TI_flags(%ebp), %ecx
 481         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 482         jne syscall_exit_work
 483         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 484         jmp sysenter_exit
 485 #endif
 486
 487         CFI_ENDPROC
 488 .pushsection .fixup,"ax"
 489 2:      movl $0,PT_FS(%esp)
 490         jmp 1b
 491 .section __ex_table,"a"
 492         .align 4
 493         .long 1b,2b
 494 .popsection
 495         PTGS_TO_GS_EX
 496 ENDPROC(ia32_sysenter_target)
 497
 498 /*
 499  * syscall stub including irq exit should be protected against kprobes
 500  */
 501         .pushsection .kprobes.text, "ax"
 502         # system call handler stub
 503 ENTRY(system_call)
 504         RING0_INT_FRAME                 # can't unwind into user space anyway
 505         pushl_cfi %eax                  # save orig_eax
 506         SAVE_ALL
 507         GET_THREAD_INFO(%ebp)
 508                                         # system call tracing in operation / emulation
 509         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 510         jnz syscall_trace_entry
 511         cmpl $(nr_syscalls), %eax
 512         jae syscall_badsys
 513 syscall_call:
 514         call *sys_call_table(,%eax,4)
 515         movl %eax,PT_EAX(%esp)          # store the return value
 516 syscall_exit:
 517         LOCKDEP_SYS_EXIT
 518         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 519                                         # setting need_resched or sigpending
 520                                         # between sampling and the iret
 521         TRACE_IRQS_OFF
 522         movl TI_flags(%ebp), %ecx
 523         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 524         jne syscall_exit_work
 525
 526 restore_all:
 527         TRACE_IRQS_IRET
 528 restore_all_notrace:
 529         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 530         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 531         # are returning to the kernel.
 532         # See comments in process.c:copy_thread() for details.
 533         movb PT_OLDSS(%esp), %ah
 534         movb PT_CS(%esp), %al
 535         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 536         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 537         CFI_REMEMBER_STATE
 538         je ldt_ss                       # returning to user-space with LDT SS
 539 restore_nocheck:
 540         RESTORE_REGS 4                  # skip orig_eax/error_code
 541 irq_return:
 542         INTERRUPT_RETURN
 543 .section .fixup,"ax"
 544 ENTRY(iret_exc)
 545         pushl $0                        # no error code
 546         pushl $do_iret_error
 547         jmp error_code
 548 .previous
 549 .section __ex_table,"a"
 550         .align 4
 551         .long irq_return,iret_exc
 552 .previous
 553
 554         CFI_RESTORE_STATE
 555 ldt_ss:
 556 #ifdef CONFIG_PARAVIRT
 557         /*
 558          * The kernel can't run on a non-flat stack if paravirt mode
 559          * is active.  Rather than try to fixup the high bits of
 560          * ESP, bypass this code entirely.  This may break DOSemu
 561          * and/or Wine support in a paravirt VM, although the option
 562          * is still available to implement the setting of the high
 563          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 564          */
 565         cmpl $0, pv_info+PARAVIRT_enabled
 566         jne restore_nocheck
 567 #endif
 568
 569 /*
 570  * Setup and switch to ESPFIX stack
 571  *
 572  * We're returning to userspace with a 16 bit stack. The CPU will not
 573  * restore the high word of ESP for us on executing iret... This is an
 574  * "official" bug of all the x86-compatible CPUs, which we can work
 575  * around to make dosemu and wine happy. We do this by preloading the
 576  * high word of ESP with the high word of the userspace ESP while
 577  * compensating for the offset by changing to the ESPFIX segment with
 578  * a base address that matches for the difference.
 579  */
 580 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 581         mov %esp, %edx                  /* load kernel esp */
 582         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 583         mov %dx, %ax                    /* eax: new kernel esp */
 584         sub %eax, %edx                  /* offset (low word is 0) */
 585         shr $16, %edx
 586         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 587         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 588         pushl_cfi $__ESPFIX_SS
 589         pushl_cfi %eax                  /* new kernel esp */
 590         /* Disable interrupts, but do not irqtrace this section: we
 591          * will soon execute iret and the tracer was already set to
 592          * the irqstate after the iret */
 593         DISABLE_INTERRUPTS(CLBR_EAX)
 594         lss (%esp), %esp                /* switch to espfix segment */
 595         CFI_ADJUST_CFA_OFFSET -8
 596         jmp restore_nocheck
 597         CFI_ENDPROC
 598 ENDPROC(system_call)
 599
 600         # perform work that needs to be done immediately before resumption
 601         ALIGN
 602         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 603 work_pending:
 604         testb $_TIF_NEED_RESCHED, %cl
 605         jz work_notifysig
 606 work_resched:
 607         call schedule
 608         LOCKDEP_SYS_EXIT
 609         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 610                                         # setting need_resched or sigpending
 611                                         # between sampling and the iret
 612         TRACE_IRQS_OFF
 613         movl TI_flags(%ebp), %ecx
 614         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 615                                         # than syscall tracing?
 616         jz restore_all
 617         testb $_TIF_NEED_RESCHED, %cl
 618         jnz work_resched
 619
 620 work_notifysig:                         # deal with pending signals and
 621                                         # notify-resume requests
 622 #ifdef CONFIG_VM86
 623         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 624         movl %esp, %eax
 625         jne work_notifysig_v86          # returning to kernel-space or
 626                                         # vm86-space
 627         xorl %edx, %edx
 628         call do_notify_resume
 629         jmp resume_userspace_sig
 630
 631         ALIGN
 632 work_notifysig_v86:
 633         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 634         call save_v86_state             # %eax contains pt_regs pointer
 635         popl_cfi %ecx
 636         movl %eax, %esp
 637 #else
 638         movl %esp, %eax
 639 #endif
 640         xorl %edx, %edx
 641         call do_notify_resume
 642         jmp resume_userspace_sig
 643 END(work_pending)
 644
 645         # perform syscall exit tracing
 646         ALIGN
 647 syscall_trace_entry:
 648         movl $-ENOSYS,PT_EAX(%esp)
 649         movl %esp, %eax
 650         call syscall_trace_enter
 651         /* What it returned is what we'll actually use.  */
 652         cmpl $(nr_syscalls), %eax
 653         jnae syscall_call
 654         jmp syscall_exit
 655 END(syscall_trace_entry)
 656
 657         # perform syscall exit tracing
 658         ALIGN
 659 syscall_exit_work:
 660         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 661         jz work_pending
 662         TRACE_IRQS_ON
 663         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 664                                         # schedule() instead
 665         movl %esp, %eax
 666         call syscall_trace_leave
 667         jmp resume_userspace
 668 END(syscall_exit_work)
 669         CFI_ENDPROC
 670
 671         RING0_INT_FRAME                 # can't unwind into user space anyway
 672 syscall_fault:
 673         GET_THREAD_INFO(%ebp)
 674         movl $-EFAULT,PT_EAX(%esp)
 675         jmp resume_userspace
 676 END(syscall_fault)
 677
 678 syscall_badsys:
 679         movl $-ENOSYS,PT_EAX(%esp)
 680         jmp syscall_exit
 681 END(syscall_badsys)
 682
 683 sysenter_badsys:
 684         movl $-ENOSYS,PT_EAX(%esp)
 685         jmp sysenter_after_call
 686 END(syscall_badsys)
 687         CFI_ENDPROC
 688 /*
 689  * End of kprobes section
 690  */
 691         .popsection
 692
 693 /*
 694  * System calls that need a pt_regs pointer.
 695  */
 696 #define PTREGSCALL0(name) \
 697         ALIGN; \
 698 ptregs_##name: \
 699         leal 4(%esp),%eax; \
 700         jmp sys_##name;
 701
 702 #define PTREGSCALL1(name) \
 703         ALIGN; \
 704 ptregs_##name: \
 705         leal 4(%esp),%edx; \
 706         movl (PT_EBX+4)(%esp),%eax; \
 707         jmp sys_##name;
 708
 709 #define PTREGSCALL2(name) \
 710         ALIGN; \
 711 ptregs_##name: \
 712         leal 4(%esp),%ecx; \
 713         movl (PT_ECX+4)(%esp),%edx; \
 714         movl (PT_EBX+4)(%esp),%eax; \
 715         jmp sys_##name;
 716
 717 #define PTREGSCALL3(name) \
 718         ALIGN; \
 719 ptregs_##name: \
 720         CFI_STARTPROC; \
 721         leal 4(%esp),%eax; \
 722         pushl_cfi %eax; \
 723         movl PT_EDX(%eax),%ecx; \
 724         movl PT_ECX(%eax),%edx; \
 725         movl PT_EBX(%eax),%eax; \
 726         call sys_##name; \
 727         addl $4,%esp; \
 728         CFI_ADJUST_CFA_OFFSET -4; \
 729         ret; \
 730         CFI_ENDPROC; \
 731 ENDPROC(ptregs_##name)
 732
 733 PTREGSCALL1(iopl)
 734 PTREGSCALL0(fork)
 735 PTREGSCALL0(vfork)
 736 PTREGSCALL3(execve)
 737 PTREGSCALL2(sigaltstack)
 738 PTREGSCALL0(sigreturn)
 739 PTREGSCALL0(rt_sigreturn)
 740 PTREGSCALL2(vm86)
 741 PTREGSCALL1(vm86old)
 742
 743 /* Clone is an oddball.  The 4th arg is in %edi */
 744         ALIGN;
 745 ptregs_clone:
 746         CFI_STARTPROC
 747         leal 4(%esp),%eax
 748         pushl_cfi %eax
 749         pushl_cfi PT_EDI(%eax)
 750         movl PT_EDX(%eax),%ecx
 751         movl PT_ECX(%eax),%edx
 752         movl PT_EBX(%eax),%eax
 753         call sys_clone
 754         addl $8,%esp
 755         CFI_ADJUST_CFA_OFFSET -8
 756         ret
 757         CFI_ENDPROC
 758 ENDPROC(ptregs_clone)
 759
 760 .macro FIXUP_ESPFIX_STACK
 761 /*
 762  * Switch back for ESPFIX stack to the normal zerobased stack
 763  *
 764  * We can't call C functions using the ESPFIX stack. This code reads
 765  * the high word of the segment base from the GDT and swiches to the
 766  * normal stack and adjusts ESP with the matching offset.
 767  */
 768         /* fixup the stack */
 769         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 770         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 771         shl $16, %eax
 772         addl %esp, %eax                 /* the adjusted stack pointer */
 773         pushl_cfi $__KERNEL_DS
 774         pushl_cfi %eax
 775         lss (%esp), %esp                /* switch to the normal stack segment */
 776         CFI_ADJUST_CFA_OFFSET -8
 777 .endm
 778 .macro UNWIND_ESPFIX_STACK
 779         movl %ss, %eax
 780         /* see if on espfix stack */
 781         cmpw $__ESPFIX_SS, %ax
 782         jne 27f
 783         movl $__KERNEL_DS, %eax
 784         movl %eax, %ds
 785         movl %eax, %es
 786         /* switch to normal stack */
 787         FIXUP_ESPFIX_STACK
 788 27:
 789 .endm
 790
 791 /*
 792  * Build the entry stubs and pointer table with some assembler magic.
 793  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 794  * single cache line on all modern x86 implementations.
 795  */
 796 .section .init.rodata,"a"
 797 ENTRY(interrupt)
 798 .section .entry.text, "ax"
 799         .p2align 5
 800         .p2align CONFIG_X86_L1_CACHE_SHIFT
 801 ENTRY(irq_entries_start)
 802         RING0_INT_FRAME
 803 vector=FIRST_EXTERNAL_VECTOR
 804 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 805         .balign 32
 806   .rept 7
 807     .if vector < NR_VECTORS
 808       .if vector <> FIRST_EXTERNAL_VECTOR
 809         CFI_ADJUST_CFA_OFFSET -4
 810       .endif
 811 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 812       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 813         jmp 2f
 814       .endif
 815       .previous
 816         .long 1b
 817       .section .entry.text, "ax"
 818 vector=vector+1
 819     .endif
 820   .endr
 821 2:      jmp common_interrupt
 822 .endr
 823 END(irq_entries_start)
 824
 825 .previous
 826 END(interrupt)
 827 .previous
 828
 829 /*
 830  * the CPU automatically disables interrupts when executing an IRQ vector,
 831  * so IRQ-flags tracing has to follow that:
 832  */
 833         .p2align CONFIG_X86_L1_CACHE_SHIFT
 834 common_interrupt:
 835         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 836         SAVE_ALL
 837         TRACE_IRQS_OFF
 838         movl %esp,%eax
 839         call do_IRQ
 840         jmp ret_from_intr
 841 ENDPROC(common_interrupt)
 842         CFI_ENDPROC
 843
 844 /*
 845  *  Irq entries should be protected against kprobes
 846  */
 847         .pushsection .kprobes.text, "ax"
 848 #define BUILD_INTERRUPT3(name, nr, fn)  \
 849 ENTRY(name)                             \
 850         RING0_INT_FRAME;                \
 851         pushl_cfi $~(nr);               \
 852         SAVE_ALL;                       \
 853         TRACE_IRQS_OFF                  \
 854         movl %esp,%eax;                 \
 855         call fn;                        \
 856         jmp ret_from_intr;              \
 857         CFI_ENDPROC;                    \
 858 ENDPROC(name)
 859
 860 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 861
 862 /* The include is where all of the SMP etc. interrupts come from */
 863 #include <asm/entry_arch.h>
 864
 865 ENTRY(coprocessor_error)
 866         RING0_INT_FRAME
 867         pushl_cfi $0
 868         pushl_cfi $do_coprocessor_error
 869         jmp error_code
 870         CFI_ENDPROC
 871 END(coprocessor_error)
 872
 873 ENTRY(simd_coprocessor_error)
 874         RING0_INT_FRAME
 875         pushl_cfi $0
 876 #ifdef CONFIG_X86_INVD_BUG
 877         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 878 661:    pushl_cfi $do_general_protection
 879 662:
 880 .section .altinstructions,"a"
 881         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 882 .previous
 883 .section .altinstr_replacement,"ax"
 884 663:    pushl $do_simd_coprocessor_error
 885 664:
 886 .previous
 887 #else
 888         pushl_cfi $do_simd_coprocessor_error
 889 #endif
 890         jmp error_code
 891         CFI_ENDPROC
 892 END(simd_coprocessor_error)
 893
 894 ENTRY(device_not_available)
 895         RING0_INT_FRAME
 896         pushl_cfi $-1                   # mark this as an int
 897         pushl_cfi $do_device_not_available
 898         jmp error_code
 899         CFI_ENDPROC
 900 END(device_not_available)
 901
 902 #ifdef CONFIG_PARAVIRT
 903 ENTRY(native_iret)
 904         iret
 905 .section __ex_table,"a"
 906         .align 4
 907         .long native_iret, iret_exc
 908 .previous
 909 END(native_iret)
 910
 911 ENTRY(native_irq_enable_sysexit)
 912         sti
 913         sysexit
 914 END(native_irq_enable_sysexit)
 915 #endif
 916
 917 ENTRY(overflow)
 918         RING0_INT_FRAME
 919         pushl_cfi $0
 920         pushl_cfi $do_overflow
 921         jmp error_code
 922         CFI_ENDPROC
 923 END(overflow)
 924
 925 ENTRY(bounds)
 926         RING0_INT_FRAME
 927         pushl_cfi $0
 928         pushl_cfi $do_bounds
 929         jmp error_code
 930         CFI_ENDPROC
 931 END(bounds)
 932
 933 ENTRY(invalid_op)
 934         RING0_INT_FRAME
 935         pushl_cfi $0
 936         pushl_cfi $do_invalid_op
 937         jmp error_code
 938         CFI_ENDPROC
 939 END(invalid_op)
 940
 941 ENTRY(coprocessor_segment_overrun)
 942         RING0_INT_FRAME
 943         pushl_cfi $0
 944         pushl_cfi $do_coprocessor_segment_overrun
 945         jmp error_code
 946         CFI_ENDPROC
 947 END(coprocessor_segment_overrun)
 948
 949 ENTRY(invalid_TSS)
 950         RING0_EC_FRAME
 951         pushl_cfi $do_invalid_TSS
 952         jmp error_code
 953         CFI_ENDPROC
 954 END(invalid_TSS)
 955
 956 ENTRY(segment_not_present)
 957         RING0_EC_FRAME
 958         pushl_cfi $do_segment_not_present
 959         jmp error_code
 960         CFI_ENDPROC
 961 END(segment_not_present)
 962
 963 ENTRY(stack_segment)
 964         RING0_EC_FRAME
 965         pushl_cfi $do_stack_segment
 966         jmp error_code
 967         CFI_ENDPROC
 968 END(stack_segment)
 969
 970 ENTRY(alignment_check)
 971         RING0_EC_FRAME
 972         pushl_cfi $do_alignment_check
 973         jmp error_code
 974         CFI_ENDPROC
 975 END(alignment_check)
 976
 977 ENTRY(divide_error)
 978         RING0_INT_FRAME
 979         pushl_cfi $0                    # no error code
 980         pushl_cfi $do_divide_error
 981         jmp error_code
 982         CFI_ENDPROC
 983 END(divide_error)
 984
 985 #ifdef CONFIG_X86_MCE
 986 ENTRY(machine_check)
 987         RING0_INT_FRAME
 988         pushl_cfi $0
 989         pushl_cfi machine_check_vector
 990         jmp error_code
 991         CFI_ENDPROC
 992 END(machine_check)
 993 #endif
 994
 995 ENTRY(spurious_interrupt_bug)
 996         RING0_INT_FRAME
 997         pushl_cfi $0
 998         pushl_cfi $do_spurious_interrupt_bug
 999         jmp error_code
1000         CFI_ENDPROC
1001 END(spurious_interrupt_bug)
1002 /*
1003  * End of kprobes section
1004  */
1005         .popsection
1006
1007 ENTRY(kernel_thread_helper)
1008         pushl $0                # fake return address for unwinder
1009         CFI_STARTPROC
1010         movl %edi,%eax
1011         call *%esi
1012         call do_exit
1013         ud2                     # padding for call trace
1014         CFI_ENDPROC
1015 ENDPROC(kernel_thread_helper)
1016
1017 #ifdef CONFIG_XEN
1018 /* Xen doesn't set %esp to be precisely what the normal sysenter
1019    entrypoint expects, so fix it up before using the normal path. */
1020 ENTRY(xen_sysenter_target)
1021         RING0_INT_FRAME
1022         addl $5*4, %esp         /* remove xen-provided frame */
1023         CFI_ADJUST_CFA_OFFSET -5*4
1024         jmp sysenter_past_esp
1025         CFI_ENDPROC
1026
1027 ENTRY(xen_hypervisor_callback)
1028         CFI_STARTPROC
1029         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1030         SAVE_ALL
1031         TRACE_IRQS_OFF
1032
1033         /* Check to see if we got the event in the critical
1034            region in xen_iret_direct, after we've reenabled
1035            events and checked for pending events.  This simulates
1036            iret instruction's behaviour where it delivers a
1037            pending interrupt when enabling interrupts. */
1038         movl PT_EIP(%esp),%eax
1039         cmpl $xen_iret_start_crit,%eax
1040         jb   1f
1041         cmpl $xen_iret_end_crit,%eax
1042         jae  1f
1043
1044         jmp  xen_iret_crit_fixup
1045
1046 ENTRY(xen_do_upcall)
1047 1:      mov %esp, %eax
1048         call xen_evtchn_do_upcall
1049         jmp  ret_from_intr
1050         CFI_ENDPROC
1051 ENDPROC(xen_hypervisor_callback)
1052
1053 # Hypervisor uses this for application faults while it executes.
1054 # We get here for two reasons:
1055 #  1. Fault while reloading DS, ES, FS or GS
1056 #  2. Fault while executing IRET
1057 # Category 1 we fix up by reattempting the load, and zeroing the segment
1058 # register if the load fails.
1059 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1060 # normal Linux return path in this case because if we use the IRET hypercall
1061 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1062 # We distinguish between categories by maintaining a status value in EAX.
1063 ENTRY(xen_failsafe_callback)
1064         CFI_STARTPROC
1065         pushl_cfi %eax
1066         movl $1,%eax
1067 1:      mov 4(%esp),%ds
1068 2:      mov 8(%esp),%es
1069 3:      mov 12(%esp),%fs
1070 4:      mov 16(%esp),%gs
1071         /* EAX == 0 => Category 1 (Bad segment)
1072            EAX != 0 => Category 2 (Bad IRET) */
1073         testl %eax,%eax
1074         popl_cfi %eax
1075         lea 16(%esp),%esp
1076         CFI_ADJUST_CFA_OFFSET -16
1077         jz 5f
1078         jmp iret_exc
1079 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1080         SAVE_ALL
1081         jmp ret_from_exception
1082         CFI_ENDPROC
1083
1084 .section .fixup,"ax"
1085 6:      xorl %eax,%eax
1086         movl %eax,4(%esp)
1087         jmp 1b
1088 7:      xorl %eax,%eax
1089         movl %eax,8(%esp)
1090         jmp 2b
1091 8:      xorl %eax,%eax
1092         movl %eax,12(%esp)
1093         jmp 3b
1094 9:      xorl %eax,%eax
1095         movl %eax,16(%esp)
1096         jmp 4b
1097 .previous
1098 .section __ex_table,"a"
1099         .align 4
1100         .long 1b,6b
1101         .long 2b,7b
1102         .long 3b,8b
1103         .long 4b,9b
1104 .previous
1105 ENDPROC(xen_failsafe_callback)
1106
1107 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1108                 xen_evtchn_do_upcall)
1109
1110 #endif  /* CONFIG_XEN */
1111
1112 #ifdef CONFIG_FUNCTION_TRACER
1113 #ifdef CONFIG_DYNAMIC_FTRACE
1114
1115 ENTRY(mcount)
1116         ret
1117 END(mcount)
1118
1119 ENTRY(ftrace_caller)
1120         cmpl $0, function_trace_stop
1121         jne  ftrace_stub
1122
1123         pushl %eax
1124         pushl %ecx
1125         pushl %edx
1126         movl 0xc(%esp), %eax
1127         movl 0x4(%ebp), %edx
1128         subl $MCOUNT_INSN_SIZE, %eax
1129
1130 .globl ftrace_call
1131 ftrace_call:
1132         call ftrace_stub
1133
1134         popl %edx
1135         popl %ecx
1136         popl %eax
1137 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1138 .globl ftrace_graph_call
1139 ftrace_graph_call:
1140         jmp ftrace_stub
1141 #endif
1142
1143 .globl ftrace_stub
1144 ftrace_stub:
1145         ret
1146 END(ftrace_caller)
1147
1148 #else /* ! CONFIG_DYNAMIC_FTRACE */
1149
1150 ENTRY(mcount)
1151         cmpl $0, function_trace_stop
1152         jne  ftrace_stub
1153
1154         cmpl $ftrace_stub, ftrace_trace_function
1155         jnz trace
1156 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1157         cmpl $ftrace_stub, ftrace_graph_return
1158         jnz ftrace_graph_caller
1159
1160         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1161         jnz ftrace_graph_caller
1162 #endif
1163 .globl ftrace_stub
1164 ftrace_stub:
1165         ret
1166
1167         /* taken from glibc */
1168 trace:
1169         pushl %eax
1170         pushl %ecx
1171         pushl %edx
1172         movl 0xc(%esp), %eax
1173         movl 0x4(%ebp), %edx
1174         subl $MCOUNT_INSN_SIZE, %eax
1175
1176         call *ftrace_trace_function
1177
1178         popl %edx
1179         popl %ecx
1180         popl %eax
1181         jmp ftrace_stub
1182 END(mcount)
1183 #endif /* CONFIG_DYNAMIC_FTRACE */
1184 #endif /* CONFIG_FUNCTION_TRACER */
1185
1186 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1187 ENTRY(ftrace_graph_caller)
1188         cmpl $0, function_trace_stop
1189         jne ftrace_stub
1190
1191         pushl %eax
1192         pushl %ecx
1193         pushl %edx
1194         movl 0xc(%esp), %edx
1195         lea 0x4(%ebp), %eax
1196         movl (%ebp), %ecx
1197         subl $MCOUNT_INSN_SIZE, %edx
1198         call prepare_ftrace_return
1199         popl %edx
1200         popl %ecx
1201         popl %eax
1202         ret
1203 END(ftrace_graph_caller)
1204
1205 .globl return_to_handler
1206 return_to_handler:
1207         pushl %eax
1208         pushl %edx
1209         movl %ebp, %eax
1210         call ftrace_return_to_handler
1211         movl %eax, %ecx
1212         popl %edx
1213         popl %eax
1214         jmp *%ecx
1215 #endif
1216
1217 .section .rodata,"a"
1218 #include "syscall_table_32.S"
1219
1220 syscall_table_size=(.-sys_call_table)
1221
1222 /*
1223  * Some functions should be protected against kprobes
1224  */
1225         .pushsection .kprobes.text, "ax"
1226
1227 ENTRY(page_fault)
1228         RING0_EC_FRAME
1229         pushl_cfi $do_page_fault
1230         ALIGN
1231 error_code:
1232         /* the function address is in %gs's slot on the stack */
1233         pushl_cfi %fs
1234         /*CFI_REL_OFFSET fs, 0*/
1235         pushl_cfi %es
1236         /*CFI_REL_OFFSET es, 0*/
1237         pushl_cfi %ds
1238         /*CFI_REL_OFFSET ds, 0*/
1239         pushl_cfi %eax
1240         CFI_REL_OFFSET eax, 0
1241         pushl_cfi %ebp
1242         CFI_REL_OFFSET ebp, 0
1243         pushl_cfi %edi
1244         CFI_REL_OFFSET edi, 0
1245         pushl_cfi %esi
1246         CFI_REL_OFFSET esi, 0
1247         pushl_cfi %edx
1248         CFI_REL_OFFSET edx, 0
1249         pushl_cfi %ecx
1250         CFI_REL_OFFSET ecx, 0
1251         pushl_cfi %ebx
1252         CFI_REL_OFFSET ebx, 0
1253         cld
1254         movl $(__KERNEL_PERCPU), %ecx
1255         movl %ecx, %fs
1256         UNWIND_ESPFIX_STACK
1257         GS_TO_REG %ecx
1258         movl PT_GS(%esp), %edi          # get the function address
1259         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1260         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1261         REG_TO_PTGS %ecx
1262         SET_KERNEL_GS %ecx
1263         movl $(__USER_DS), %ecx
1264         movl %ecx, %ds
1265         movl %ecx, %es
1266         TRACE_IRQS_OFF
1267         movl %esp,%eax                  # pt_regs pointer
1268         call *%edi
1269         jmp ret_from_exception
1270         CFI_ENDPROC
1271 END(page_fault)
1272
1273 /*
1274  * Debug traps and NMI can happen at the one SYSENTER instruction
1275  * that sets up the real kernel stack. Check here, since we can't
1276  * allow the wrong stack to be used.
1277  *
1278  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1279  * already pushed 3 words if it hits on the sysenter instruction:
1280  * eflags, cs and eip.
1281  *
1282  * We just load the right stack, and push the three (known) values
1283  * by hand onto the new stack - while updating the return eip past
1284  * the instruction that would have done it for sysenter.
1285  */
1286 .macro FIX_STACK offset ok label
1287         cmpw $__KERNEL_CS, 4(%esp)
1288         jne \ok
1289 \label:
1290         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1291         CFI_DEF_CFA esp, 0
1292         CFI_UNDEFINED eip
1293         pushfl_cfi
1294         pushl_cfi $__KERNEL_CS
1295         pushl_cfi $sysenter_past_esp
1296         CFI_REL_OFFSET eip, 0
1297 .endm
1298
1299 ENTRY(debug)
1300         RING0_INT_FRAME
1301         cmpl $ia32_sysenter_target,(%esp)
1302         jne debug_stack_correct
1303         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1304 debug_stack_correct:
1305         pushl_cfi $-1                   # mark this as an int
1306         SAVE_ALL
1307         TRACE_IRQS_OFF
1308         xorl %edx,%edx                  # error code 0
1309         movl %esp,%eax                  # pt_regs pointer
1310         call do_debug
1311         jmp ret_from_exception
1312         CFI_ENDPROC
1313 END(debug)
1314
1315 /*
1316  * NMI is doubly nasty. It can happen _while_ we're handling
1317  * a debug fault, and the debug fault hasn't yet been able to
1318  * clear up the stack. So we first check whether we got  an
1319  * NMI on the sysenter entry path, but after that we need to
1320  * check whether we got an NMI on the debug path where the debug
1321  * fault happened on the sysenter path.
1322  */
1323 ENTRY(nmi)
1324         RING0_INT_FRAME
1325         pushl_cfi %eax
1326         movl %ss, %eax
1327         cmpw $__ESPFIX_SS, %ax
1328         popl_cfi %eax
1329         je nmi_espfix_stack
1330         cmpl $ia32_sysenter_target,(%esp)
1331         je nmi_stack_fixup
1332         pushl_cfi %eax
1333         movl %esp,%eax
1334         /* Do not access memory above the end of our stack page,
1335          * it might not exist.
1336          */
1337         andl $(THREAD_SIZE-1),%eax
1338         cmpl $(THREAD_SIZE-20),%eax
1339         popl_cfi %eax
1340         jae nmi_stack_correct
1341         cmpl $ia32_sysenter_target,12(%esp)
1342         je nmi_debug_stack_check
1343 nmi_stack_correct:
1344         /* We have a RING0_INT_FRAME here */
1345         pushl_cfi %eax
1346         SAVE_ALL
1347         xorl %edx,%edx          # zero error code
1348         movl %esp,%eax          # pt_regs pointer
1349         call do_nmi
1350         jmp restore_all_notrace
1351         CFI_ENDPROC
1352
1353 nmi_stack_fixup:
1354         RING0_INT_FRAME
1355         FIX_STACK 12, nmi_stack_correct, 1
1356         jmp nmi_stack_correct
1357
1358 nmi_debug_stack_check:
1359         /* We have a RING0_INT_FRAME here */
1360         cmpw $__KERNEL_CS,16(%esp)
1361         jne nmi_stack_correct
1362         cmpl $debug,(%esp)
1363         jb nmi_stack_correct
1364         cmpl $debug_esp_fix_insn,(%esp)
1365         ja nmi_stack_correct
1366         FIX_STACK 24, nmi_stack_correct, 1
1367         jmp nmi_stack_correct
1368
1369 nmi_espfix_stack:
1370         /* We have a RING0_INT_FRAME here.
1371          *
1372          * create the pointer to lss back
1373          */
1374         pushl_cfi %ss
1375         pushl_cfi %esp
1376         addl $4, (%esp)
1377         /* copy the iret frame of 12 bytes */
1378         .rept 3
1379         pushl_cfi 16(%esp)
1380         .endr
1381         pushl_cfi %eax
1382         SAVE_ALL
1383         FIXUP_ESPFIX_STACK              # %eax == %esp
1384         xorl %edx,%edx                  # zero error code
1385         call do_nmi
1386         RESTORE_REGS
1387         lss 12+4(%esp), %esp            # back to espfix stack
1388         CFI_ADJUST_CFA_OFFSET -24
1389         jmp irq_return
1390         CFI_ENDPROC
1391 END(nmi)
1392
1393 ENTRY(int3)
1394         RING0_INT_FRAME
1395         pushl_cfi $-1                   # mark this as an int
1396         SAVE_ALL
1397         TRACE_IRQS_OFF
1398         xorl %edx,%edx          # zero error code
1399         movl %esp,%eax          # pt_regs pointer
1400         call do_int3
1401         jmp ret_from_exception
1402         CFI_ENDPROC
1403 END(int3)
1404
1405 ENTRY(general_protection)
1406         RING0_EC_FRAME
1407         pushl_cfi $do_general_protection
1408         jmp error_code
1409         CFI_ENDPROC
1410 END(general_protection)
1411
1412 #ifdef CONFIG_KVM_GUEST
1413 ENTRY(async_page_fault)
1414         RING0_EC_FRAME
1415         pushl_cfi $do_async_page_fault
1416         jmp error_code
1417         CFI_ENDPROC
1418 END(async_page_fault)
1419 #endif
1420
1421 /*
1422  * End of kprobes section
1423  */
1424         .popsection