arch/x86/include/asm/calling.h

   1 /*
   2
   3  x86 function call convention, 64-bit:
   4  -------------------------------------
   5   arguments           |  callee-saved      | extra caller-saved | return
   6  [callee-clobbered]   |                    | [callee-clobbered] |
   7  ---------------------------------------------------------------------------
   8  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
   9
  10  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  11    functions when it sees tail-call optimization possibilities) rflags is
  12    clobbered. Leftover arguments are passed over the stack frame.)
  13
  14  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  15
  16  [**] for struct return values wider than 64 bits the return convention is a
  17       bit more complex: up to 128 bits width we return small structures
  18       straight in rax, rdx. For structures larger than that (3 words or
  19       larger) the caller puts a pointer to an on-stack return struct
  20       [allocated in the caller's stack frame] into the first argument - i.e.
  21       into rdi. All other arguments shift up by one in this case.
  22       Fortunately this case is rare in the kernel.
  23
  24 For 32-bit we have the following conventions - kernel is built with
  25 -mregparm=3 and -freg-struct-return:
  26
  27  x86 function calling convention, 32-bit:
  28  ----------------------------------------
  29   arguments         | callee-saved        | extra caller-saved | return
  30  [callee-clobbered] |                     | [callee-clobbered] |
  31  -------------------------------------------------------------------------
  32  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  33
  34  ( here too esp is obviously invariant across normal function calls. eflags
  35    is clobbered. Leftover arguments are passed over the stack frame. )
  36
  37  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  38
  39  [**] We build with -freg-struct-return, which on 32-bit means similar
  40       semantics as on 64-bit: edx can be used for a second return value
  41       (i.e. covering integer and structure sizes up to 64 bits) - after that
  42       it gets more complex and more expensive: 3-word or larger struct returns
  43       get done in the caller's frame and the pointer to the return struct goes
  44       into regparm0, i.e. eax - the other arguments shift up and the
  45       function's register parameters degenerate to regparm=2 in essence.
  46
  47 */
  48
  49 #include <asm/dwarf2.h>
  50
  51 #ifdef CONFIG_X86_64
  52
  53 /*
  54  * 64-bit system call stack frame layout defines and helpers,
  55  * for assembly code:
  56  */
  57
  58 /* The layout forms the "struct pt_regs" on the stack: */
  59 /*
  60  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  61  * unless syscall needs a complete, fully filled "struct pt_regs".
  62  */
  63 #define R15             0*8
  64 #define R14             1*8
  65 #define R13             2*8
  66 #define R12             3*8
  67 #define RBP             4*8
  68 #define RBX             5*8
  69 /* These regs are callee-clobbered. Always saved on kernel entry. */
  70 #define R11             6*8
  71 #define R10             7*8
  72 #define R9              8*8
  73 #define R8              9*8
  74 #define RAX             10*8
  75 #define RCX             11*8
  76 #define RDX             12*8
  77 #define RSI             13*8
  78 #define RDI             14*8
  79 /*
  80  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  81  * On hw interrupt, it's IRQ number:
  82  */
  83 #define ORIG_RAX        15*8
  84 /* Return frame for iretq */
  85 #define RIP             16*8
  86 #define CS              17*8
  87 #define EFLAGS          18*8
  88 #define RSP             19*8
  89 #define SS              20*8
  90
  91 #define ARGOFFSET       0
  92
  93         .macro ALLOC_PT_GPREGS_ON_STACK addskip=0
  94         subq    $15*8+\addskip, %rsp
  95         CFI_ADJUST_CFA_OFFSET 15*8+\addskip
  96         .endm
  97
  98         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8plus=1
  99         .if \r8plus
 100         movq_cfi r11, 6*8+\offset
 101         movq_cfi r10, 7*8+\offset
 102         movq_cfi r9,  8*8+\offset
 103         movq_cfi r8,  9*8+\offset
 104         .endif
 105         .if \rax
 106         movq_cfi rax, 10*8+\offset
 107         .endif
 108         .if \rcx
 109         movq_cfi rcx, 11*8+\offset
 110         .endif
 111         movq_cfi rdx, 12*8+\offset
 112         movq_cfi rsi, 13*8+\offset
 113         movq_cfi rdi, 14*8+\offset
 114         .endm
 115         .macro SAVE_C_REGS offset=0
 116         SAVE_C_REGS_HELPER \offset, 1, 1, 1
 117         .endm
 118         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 119         SAVE_C_REGS_HELPER \offset, 0, 0, 1
 120         .endm
 121         .macro SAVE_C_REGS_EXCEPT_R891011
 122         SAVE_C_REGS_HELPER 0, 1, 1, 0
 123         .endm
 124         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 125         SAVE_C_REGS_HELPER 0, 1, 0, 0
 126         .endm
 127
 128         .macro SAVE_EXTRA_REGS offset=0
 129         movq_cfi r15, 0*8+\offset
 130         movq_cfi r14, 1*8+\offset
 131         movq_cfi r13, 2*8+\offset
 132         movq_cfi r12, 3*8+\offset
 133         movq_cfi rbp, 4*8+\offset
 134         movq_cfi rbx, 5*8+\offset
 135         .endm
 136         .macro SAVE_EXTRA_REGS_RBP offset=0
 137         movq_cfi rbp, 4*8+\offset
 138         .endm
 139
 140         .macro RESTORE_EXTRA_REGS offset=0
 141         movq_cfi_restore 0*8+\offset, r15
 142         movq_cfi_restore 1*8+\offset, r14
 143         movq_cfi_restore 2*8+\offset, r13
 144         movq_cfi_restore 3*8+\offset, r12
 145         movq_cfi_restore 4*8+\offset, rbp
 146         movq_cfi_restore 5*8+\offset, rbx
 147         .endm
 148
 149         .macro RESTORE_C_REGS_HELPER rstor_rax=1, rstor_rcx=1, rstor_r11=1, rstor_r8910=1, rstor_rdx=1
 150         .if \rstor_r11
 151         movq_cfi_restore 6*8, r11
 152         .endif
 153         .if \rstor_r8910
 154         movq_cfi_restore 7*8, r10
 155         movq_cfi_restore 8*8, r9
 156         movq_cfi_restore 9*8, r8
 157         .endif
 158         .if \rstor_rax
 159         movq_cfi_restore 10*8, rax
 160         .endif
 161         .if \rstor_rcx
 162         movq_cfi_restore 11*8, rcx
 163         .endif
 164         .if \rstor_rdx
 165         movq_cfi_restore 12*8, rdx
 166         .endif
 167         movq_cfi_restore 13*8, rsi
 168         movq_cfi_restore 14*8, rdi
 169         .endm
 170         .macro RESTORE_C_REGS
 171         RESTORE_C_REGS_HELPER 1,1,1,1,1
 172         .endm
 173         .macro RESTORE_C_REGS_EXCEPT_RAX
 174         RESTORE_C_REGS_HELPER 0,1,1,1,1
 175         .endm
 176         .macro RESTORE_C_REGS_EXCEPT_RCX
 177         RESTORE_C_REGS_HELPER 1,0,1,1,1
 178         .endm
 179         .macro RESTORE_RSI_RDI
 180         RESTORE_C_REGS_HELPER 0,0,0,0,0
 181         .endm
 182         .macro RESTORE_RSI_RDI_RDX
 183         RESTORE_C_REGS_HELPER 0,0,0,0,1
 184         .endm
 185
 186         .macro REMOVE_PT_GPREGS_FROM_STACK addskip=0
 187         addq $15*8+\addskip, %rsp
 188         CFI_ADJUST_CFA_OFFSET -(15*8+\addskip)
 189         .endm
 190
 191         .macro icebp
 192         .byte 0xf1
 193         .endm
 194
 195 #else /* CONFIG_X86_64 */
 196
 197 /*
 198  * For 32bit only simplified versions of SAVE_ALL/RESTORE_ALL. These
 199  * are different from the entry_32.S versions in not changing the segment
 200  * registers. So only suitable for in kernel use, not when transitioning
 201  * from or to user space. The resulting stack frame is not a standard
 202  * pt_regs frame. The main use case is calling C code from assembler
 203  * when all the registers need to be preserved.
 204  */
 205
 206         .macro SAVE_ALL
 207         pushl_cfi_reg eax
 208         pushl_cfi_reg ebp
 209         pushl_cfi_reg edi
 210         pushl_cfi_reg esi
 211         pushl_cfi_reg edx
 212         pushl_cfi_reg ecx
 213         pushl_cfi_reg ebx
 214         .endm
 215
 216         .macro RESTORE_ALL
 217         popl_cfi_reg ebx
 218         popl_cfi_reg ecx
 219         popl_cfi_reg edx
 220         popl_cfi_reg esi
 221         popl_cfi_reg edi
 222         popl_cfi_reg ebp
 223         popl_cfi_reg eax
 224         .endm
 225
 226 #endif /* CONFIG_X86_64 */
 227