arch/x86/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/pgtable_types.h>
  16 #include <asm/alternative-asm.h>
  17 #include <asm/cpufeature.h>
  18 #include <asm/kaiser.h>
  19 #include <asm/irqflags.h>
  20 #include <linux/linkage.h>
  21
  22 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  23 #include <linux/elf-em.h>
  24 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  25 #define __AUDIT_ARCH_LE    0x40000000
  26
  27 #ifndef CONFIG_AUDITSYSCALL
  28 #define sysexit_audit ia32_ret_from_sys_call
  29 #define sysretl_audit ia32_ret_from_sys_call
  30 #endif
  31
  32         .section .entry.text, "ax"
  33
  34 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  35
  36         .macro IA32_ARG_FIXUP noebp=0
  37         movl    %edi,%r8d
  38         .if \noebp
  39         .else
  40         movl    %ebp,%r9d
  41         .endif
  42         xchg    %ecx,%esi
  43         movl    %ebx,%edi
  44         movl    %edx,%edx       /* zero extension */
  45         .endm
  46
  47         /* clobbers %eax */
  48         .macro  CLEAR_RREGS offset=0, _r9=rax
  49         xorl    %eax,%eax
  50         movq    %rax,\offset+R11(%rsp)
  51         movq    %rax,\offset+R10(%rsp)
  52         movq    %\_r9,\offset+R9(%rsp)
  53         movq    %rax,\offset+R8(%rsp)
  54         .endm
  55
  56         /*
  57          * Reload arg registers from stack in case ptrace changed them.
  58          * We don't reload %eax because syscall_trace_enter() returned
  59          * the %rax value we should see.  Instead, we just truncate that
  60          * value to 32 bits again as we did on entry from user mode.
  61          * If it's a new value set by user_regset during entry tracing,
  62          * this matches the normal truncation of the user-mode value.
  63          * If it's -1 to make us punt the syscall, then (u32)-1 is still
  64          * an appropriately invalid value.
  65          */
  66         .macro LOAD_ARGS32 offset, _r9=0
  67         .if \_r9
  68         movl \offset+16(%rsp),%r9d
  69         .endif
  70         movl \offset+40(%rsp),%ecx
  71         movl \offset+48(%rsp),%edx
  72         movl \offset+56(%rsp),%esi
  73         movl \offset+64(%rsp),%edi
  74         movl %eax,%eax                  /* zero extension */
  75         .endm
  76
  77         .macro CFI_STARTPROC32 simple
  78         CFI_STARTPROC   \simple
  79         CFI_UNDEFINED   r8
  80         CFI_UNDEFINED   r9
  81         CFI_UNDEFINED   r10
  82         CFI_UNDEFINED   r11
  83         CFI_UNDEFINED   r12
  84         CFI_UNDEFINED   r13
  85         CFI_UNDEFINED   r14
  86         CFI_UNDEFINED   r15
  87         .endm
  88
  89 #ifdef CONFIG_PARAVIRT
  90 ENTRY(native_usergs_sysret32)
  91         swapgs
  92         sysretl
  93 ENDPROC(native_usergs_sysret32)
  94
  95 ENTRY(native_irq_enable_sysexit)
  96         swapgs
  97         sti
  98         sysexit
  99 ENDPROC(native_irq_enable_sysexit)
 100 #endif
 101
 102 /*
 103  * 32bit SYSENTER instruction entry.
 104  *
 105  * Arguments:
 106  * %eax System call number.
 107  * %ebx Arg1
 108  * %ecx Arg2
 109  * %edx Arg3
 110  * %esi Arg4
 111  * %edi Arg5
 112  * %ebp user stack
 113  * 0(%ebp) Arg6
 114  *
 115  * Interrupts off.
 116  *
 117  * This is purely a fast path. For anything complicated we use the int 0x80
 118  * path below.  Set up a complete hardware stack frame to share code
 119  * with the int 0x80 path.
 120  */
 121 ENTRY(ia32_sysenter_target)
 122         CFI_STARTPROC32 simple
 123         CFI_SIGNAL_FRAME
 124         CFI_DEF_CFA     rsp,0
 125         CFI_REGISTER    rsp,rbp
 126         SWAPGS_UNSAFE_STACK
 127         SWITCH_KERNEL_CR3_NO_STACK
 128         movq    PER_CPU_VAR(kernel_stack), %rsp
 129         addq    $(KERNEL_STACK_OFFSET),%rsp
 130         /*
 131          * No need to follow this irqs on/off section: the syscall
 132          * disabled irqs, here we enable it straight after entry:
 133          */
 134         ENABLE_INTERRUPTS(CLBR_NONE)
 135         movl    %ebp,%ebp               /* zero extension */
 136         pushq_cfi $__USER32_DS
 137         /*CFI_REL_OFFSET ss,0*/
 138         pushq_cfi %rbp
 139         CFI_REL_OFFSET rsp,0
 140         pushfq_cfi
 141         /*CFI_REL_OFFSET rflags,0*/
 142         movl    8*3-THREAD_SIZE+TI_sysenter_return(%rsp), %r10d
 143         CFI_REGISTER rip,r10
 144         pushq_cfi $__USER32_CS
 145         /*CFI_REL_OFFSET cs,0*/
 146         movl    %eax, %eax
 147         pushq_cfi %r10
 148         CFI_REL_OFFSET rip,0
 149         pushq_cfi %rax
 150         cld
 151         SAVE_ARGS 0,1,0
 152         /* no need to do an access_ok check here because rbp has been
 153            32bit zero extended */
 154 1:      movl    (%rbp),%ebp
 155         .section __ex_table,"a"
 156         .quad 1b,ia32_badarg
 157         .previous
 158         GET_THREAD_INFO(%r10)
 159         orl    $TS_COMPAT,TI_status(%r10)
 160         testl  $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%r10)
 161         CFI_REMEMBER_STATE
 162         jnz  sysenter_tracesys
 163         cmpq    $(IA32_NR_syscalls-1),%rax
 164         ja      ia32_badsys
 165 sysenter_do_call:
 166         IA32_ARG_FIXUP
 167 sysenter_dispatch:
 168         call    *ia32_sys_call_table(,%rax,8)
 169         movq    %rax,RAX-ARGOFFSET(%rsp)
 170         GET_THREAD_INFO(%r10)
 171         DISABLE_INTERRUPTS(CLBR_NONE)
 172         TRACE_IRQS_OFF
 173         testl   $_TIF_ALLWORK_MASK,TI_flags(%r10)
 174         jnz     sysexit_audit
 175 sysexit_from_sys_call:
 176         andl    $~TS_COMPAT,TI_status(%r10)
 177         /* clear IF, that popfq doesn't enable interrupts early */
 178         andl  $~0x200,EFLAGS-R11(%rsp)
 179         movl    RIP-R11(%rsp),%edx              /* User %eip */
 180         CFI_REGISTER rip,rdx
 181         RESTORE_ARGS 0,24,0,0,0,0
 182         xorq    %r8,%r8
 183         xorq    %r9,%r9
 184         xorq    %r10,%r10
 185         xorq    %r11,%r11
 186         popfq_cfi
 187         /*CFI_RESTORE rflags*/
 188         popq_cfi %rcx                           /* User %esp */
 189         CFI_REGISTER rsp,rcx
 190         TRACE_IRQS_ON
 191         SWITCH_USER_CR3
 192         ENABLE_INTERRUPTS_SYSEXIT32
 193
 194 #ifdef CONFIG_AUDITSYSCALL
 195         .macro auditsys_entry_common
 196         movl %esi,%r9d                  /* 6th arg: 4th syscall arg */
 197         movl %edx,%r8d                  /* 5th arg: 3rd syscall arg */
 198         /* (already in %ecx)               4th arg: 2nd syscall arg */
 199         movl %ebx,%edx                  /* 3rd arg: 1st syscall arg */
 200         movl %eax,%esi                  /* 2nd arg: syscall number */
 201         movl $AUDIT_ARCH_I386,%edi      /* 1st arg: audit arch */
 202         call audit_syscall_entry
 203         movl RAX-ARGOFFSET(%rsp),%eax   /* reload syscall number */
 204         cmpq $(IA32_NR_syscalls-1),%rax
 205         ja ia32_badsys
 206         movl %ebx,%edi                  /* reload 1st syscall arg */
 207         movl RCX-ARGOFFSET(%rsp),%esi   /* reload 2nd syscall arg */
 208         movl RDX-ARGOFFSET(%rsp),%edx   /* reload 3rd syscall arg */
 209         movl RSI-ARGOFFSET(%rsp),%ecx   /* reload 4th syscall arg */
 210         movl RDI-ARGOFFSET(%rsp),%r8d   /* reload 5th syscall arg */
 211         .endm
 212
 213         .macro auditsys_exit exit
 214         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),TI_flags(%r10)
 215         jnz ia32_ret_from_sys_call
 216         TRACE_IRQS_ON
 217         ENABLE_INTERRUPTS(CLBR_NONE)
 218         movl %eax,%esi          /* second arg, syscall return value */
 219         cmpl $0,%eax            /* is it < 0? */
 220         setl %al                /* 1 if so, 0 if not */
 221         movzbl %al,%edi         /* zero-extend that into %edi */
 222         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 223         call audit_syscall_exit
 224         GET_THREAD_INFO(%r10)
 225         movl RAX-ARGOFFSET(%rsp),%eax   /* reload syscall return value */
 226         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 227         DISABLE_INTERRUPTS(CLBR_NONE)
 228         TRACE_IRQS_OFF
 229         testl %edi,TI_flags(%r10)
 230         jz \exit
 231         CLEAR_RREGS -ARGOFFSET
 232         jmp int_with_check
 233         .endm
 234
 235 sysenter_auditsys:
 236         CFI_RESTORE_STATE
 237         auditsys_entry_common
 238         movl %ebp,%r9d                  /* reload 6th syscall arg */
 239         jmp sysenter_dispatch
 240
 241 sysexit_audit:
 242         auditsys_exit sysexit_from_sys_call
 243 #endif
 244
 245 sysenter_tracesys:
 246 #ifdef CONFIG_AUDITSYSCALL
 247         testl   $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%r10)
 248         jz      sysenter_auditsys
 249 #endif
 250         SAVE_REST
 251         CLEAR_RREGS
 252         movq    $-ENOSYS,RAX(%rsp)/* ptrace can change this for a bad syscall */
 253         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 254         call    syscall_trace_enter
 255         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 256         RESTORE_REST
 257         cmpq    $(IA32_NR_syscalls-1),%rax
 258         ja      int_ret_from_sys_call /* sysenter_tracesys has set RAX(%rsp) */
 259         jmp     sysenter_do_call
 260         CFI_ENDPROC
 261 ENDPROC(ia32_sysenter_target)
 262
 263 /*
 264  * 32bit SYSCALL instruction entry.
 265  *
 266  * Arguments:
 267  * %eax System call number.
 268  * %ebx Arg1
 269  * %ecx return EIP
 270  * %edx Arg3
 271  * %esi Arg4
 272  * %edi Arg5
 273  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 274  * %esp user stack
 275  * 0(%esp) Arg6
 276  *
 277  * Interrupts off.
 278  *
 279  * This is purely a fast path. For anything complicated we use the int 0x80
 280  * path below.  Set up a complete hardware stack frame to share code
 281  * with the int 0x80 path.
 282  */
 283 ENTRY(ia32_cstar_target)
 284         CFI_STARTPROC32 simple
 285         CFI_SIGNAL_FRAME
 286         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 287         CFI_REGISTER    rip,rcx
 288         /*CFI_REGISTER  rflags,r11*/
 289         SWAPGS_UNSAFE_STACK
 290         SWITCH_KERNEL_CR3_NO_STACK
 291         movl    %esp,%r8d
 292         CFI_REGISTER    rsp,r8
 293         movq    PER_CPU_VAR(kernel_stack),%rsp
 294         /*
 295          * No need to follow this irqs on/off section: the syscall
 296          * disabled irqs and here we enable it straight after entry:
 297          */
 298         ENABLE_INTERRUPTS(CLBR_NONE)
 299         SAVE_ARGS 8,0,0
 300         movl    %eax,%eax       /* zero extension */
 301         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 302         movq    %rcx,RIP-ARGOFFSET(%rsp)
 303         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 304         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 305         movl    %ebp,%ecx
 306         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 307         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 308         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 309         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 310         movq    %r8,RSP-ARGOFFSET(%rsp)
 311         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 312         /* no need to do an access_ok check here because r8 has been
 313            32bit zero extended */
 314         /* hardware stack frame is complete now */
 315 1:      movl    (%r8),%r9d
 316         .section __ex_table,"a"
 317         .quad 1b,ia32_badarg
 318         .previous
 319         GET_THREAD_INFO(%r10)
 320         orl   $TS_COMPAT,TI_status(%r10)
 321         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%r10)
 322         CFI_REMEMBER_STATE
 323         jnz   cstar_tracesys
 324         cmpq $IA32_NR_syscalls-1,%rax
 325         ja  ia32_badsys
 326 cstar_do_call:
 327         IA32_ARG_FIXUP 1
 328 cstar_dispatch:
 329         call *ia32_sys_call_table(,%rax,8)
 330         movq %rax,RAX-ARGOFFSET(%rsp)
 331         GET_THREAD_INFO(%r10)
 332         DISABLE_INTERRUPTS(CLBR_NONE)
 333         TRACE_IRQS_OFF
 334         testl $_TIF_ALLWORK_MASK,TI_flags(%r10)
 335         jnz sysretl_audit
 336 sysretl_from_sys_call:
 337         andl $~TS_COMPAT,TI_status(%r10)
 338         RESTORE_ARGS 0,-ARG_SKIP,0,0,0
 339         movl RIP-ARGOFFSET(%rsp),%ecx
 340         CFI_REGISTER rip,rcx
 341         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 342         /*CFI_REGISTER rflags,r11*/
 343         xorq    %r10,%r10
 344         xorq    %r9,%r9
 345         xorq    %r8,%r8
 346         TRACE_IRQS_ON
 347         SWITCH_USER_CR3
 348         movl RSP-ARGOFFSET(%rsp),%esp
 349         CFI_RESTORE rsp
 350         USERGS_SYSRET32
 351
 352 #ifdef CONFIG_AUDITSYSCALL
 353 cstar_auditsys:
 354         CFI_RESTORE_STATE
 355         movl %r9d,R9-ARGOFFSET(%rsp)    /* register to be clobbered by call */
 356         auditsys_entry_common
 357         movl R9-ARGOFFSET(%rsp),%r9d    /* reload 6th syscall arg */
 358         jmp cstar_dispatch
 359
 360 sysretl_audit:
 361         auditsys_exit sysretl_from_sys_call
 362 #endif
 363
 364 cstar_tracesys:
 365 #ifdef CONFIG_AUDITSYSCALL
 366         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%r10)
 367         jz cstar_auditsys
 368 #endif
 369         xchgl %r9d,%ebp
 370         SAVE_REST
 371         CLEAR_RREGS 0, r9
 372         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 373         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 374         call syscall_trace_enter
 375         LOAD_ARGS32 ARGOFFSET, 1  /* reload args from stack in case ptrace changed it */
 376         RESTORE_REST
 377         xchgl %ebp,%r9d
 378         cmpq $(IA32_NR_syscalls-1),%rax
 379         ja int_ret_from_sys_call /* cstar_tracesys has set RAX(%rsp) */
 380         jmp cstar_do_call
 381 END(ia32_cstar_target)
 382
 383 ia32_badarg:
 384         movq $-EFAULT,%rax
 385         jmp ia32_sysret
 386         CFI_ENDPROC
 387
 388 /*
 389  * Emulated IA32 system calls via int 0x80.
 390  *
 391  * Arguments:
 392  * %eax System call number.
 393  * %ebx Arg1
 394  * %ecx Arg2
 395  * %edx Arg3
 396  * %esi Arg4
 397  * %edi Arg5
 398  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 399  *
 400  * Notes:
 401  * Uses the same stack frame as the x86-64 version.
 402  * All registers except %eax must be saved (but ptrace may violate that)
 403  * Arguments are zero extended. For system calls that want sign extension and
 404  * take long arguments a wrapper is needed. Most calls can just be called
 405  * directly.
 406  * Assumes it is only called from user space and entered with interrupts off.
 407  */
 408
 409 ENTRY(ia32_syscall)
 410         CFI_STARTPROC32 simple
 411         CFI_SIGNAL_FRAME
 412         CFI_DEF_CFA     rsp,SS+8-RIP
 413         /*CFI_REL_OFFSET        ss,SS-RIP*/
 414         CFI_REL_OFFSET  rsp,RSP-RIP
 415         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 416         /*CFI_REL_OFFSET        cs,CS-RIP*/
 417         CFI_REL_OFFSET  rip,RIP-RIP
 418         PARAVIRT_ADJUST_EXCEPTION_FRAME
 419         SWAPGS
 420         SWITCH_KERNEL_CR3_NO_STACK
 421         /*
 422          * No need to follow this irqs on/off section: the syscall
 423          * disabled irqs and here we enable it straight after entry:
 424          */
 425         ENABLE_INTERRUPTS(CLBR_NONE)
 426         movl %eax,%eax
 427         pushq_cfi %rax
 428         cld
 429         /* note the registers are not zero extended to the sf.
 430            this could be a problem. */
 431         SAVE_ARGS 0,1,0
 432         GET_THREAD_INFO(%r10)
 433         orl   $TS_COMPAT,TI_status(%r10)
 434         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%r10)
 435         jnz ia32_tracesys
 436         cmpq $(IA32_NR_syscalls-1),%rax
 437         ja ia32_badsys
 438 ia32_do_call:
 439         IA32_ARG_FIXUP
 440         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 441 ia32_sysret:
 442         movq %rax,RAX-ARGOFFSET(%rsp)
 443 ia32_ret_from_sys_call:
 444         CLEAR_RREGS -ARGOFFSET
 445         jmp int_ret_from_sys_call
 446
 447 ia32_tracesys:
 448         SAVE_REST
 449         CLEAR_RREGS
 450         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 451         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 452         call syscall_trace_enter
 453         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 454         RESTORE_REST
 455         cmpq $(IA32_NR_syscalls-1),%rax
 456         ja  int_ret_from_sys_call       /* ia32_tracesys has set RAX(%rsp) */
 457         jmp ia32_do_call
 458 END(ia32_syscall)
 459
 460 ia32_badsys:
 461         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 462         movq $-ENOSYS,%rax
 463         jmp ia32_sysret
 464
 465 quiet_ni_syscall:
 466         movq $-ENOSYS,%rax
 467         ret
 468         CFI_ENDPROC
 469
 470         .macro PTREGSCALL label, func, arg
 471         .globl \label
 472 \label:
 473         leaq \func(%rip),%rax
 474         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 475         jmp  ia32_ptregs_common
 476         .endm
 477
 478         CFI_STARTPROC32
 479
 480         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 481         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 482         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 483         PTREGSCALL stub32_execve, sys32_execve, %rcx
 484         PTREGSCALL stub32_fork, sys_fork, %rdi
 485         PTREGSCALL stub32_clone, sys32_clone, %rdx
 486         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 487         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 488
 489 ENTRY(ia32_ptregs_common)
 490         popq %r11
 491         CFI_ENDPROC
 492         CFI_STARTPROC32 simple
 493         CFI_SIGNAL_FRAME
 494         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 495         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 496         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 497         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 498         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 499         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 500         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 501 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 502 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 503         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 504 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 505         SAVE_REST
 506         call *%rax
 507         RESTORE_REST
 508         jmp  ia32_sysret        /* misbalances the return cache */
 509         CFI_ENDPROC
 510 END(ia32_ptregs_common)
 511
 512         .section .rodata,"a"
 513         .align 8
 514 ia32_sys_call_table:
 515         .quad sys_restart_syscall
 516         .quad sys_exit
 517         .quad stub32_fork
 518         .quad sys_read
 519         .quad sys_write
 520         .quad compat_sys_open           /* 5 */
 521         .quad sys_close
 522         .quad sys32_waitpid
 523         .quad sys_creat
 524         .quad sys_link
 525         .quad sys_unlink                /* 10 */
 526         .quad stub32_execve
 527         .quad sys_chdir
 528         .quad compat_sys_time
 529         .quad sys_mknod
 530         .quad sys_chmod         /* 15 */
 531         .quad sys_lchown16
 532         .quad quiet_ni_syscall                  /* old break syscall holder */
 533         .quad sys_stat
 534         .quad sys32_lseek
 535         .quad sys_getpid                /* 20 */
 536         .quad compat_sys_mount  /* mount  */
 537         .quad sys_oldumount     /* old_umount  */
 538         .quad sys_setuid16
 539         .quad sys_getuid16
 540         .quad compat_sys_stime  /* stime */             /* 25 */
 541         .quad compat_sys_ptrace /* ptrace */
 542         .quad sys_alarm
 543         .quad sys_fstat /* (old)fstat */
 544         .quad sys_pause
 545         .quad compat_sys_utime  /* 30 */
 546         .quad quiet_ni_syscall  /* old stty syscall holder */
 547         .quad quiet_ni_syscall  /* old gtty syscall holder */
 548         .quad sys_access
 549         .quad sys_nice
 550         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 551         .quad sys_sync
 552         .quad sys32_kill
 553         .quad sys_rename
 554         .quad sys_mkdir
 555         .quad sys_rmdir         /* 40 */
 556         .quad sys_dup
 557         .quad sys_pipe
 558         .quad compat_sys_times
 559         .quad quiet_ni_syscall                  /* old prof syscall holder */
 560         .quad sys_brk           /* 45 */
 561         .quad sys_setgid16
 562         .quad sys_getgid16
 563         .quad sys_signal
 564         .quad sys_geteuid16
 565         .quad sys_getegid16     /* 50 */
 566         .quad sys_acct
 567         .quad sys_umount                        /* new_umount */
 568         .quad quiet_ni_syscall                  /* old lock syscall holder */
 569         .quad compat_sys_ioctl
 570         .quad compat_sys_fcntl64                /* 55 */
 571         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 572         .quad sys_setpgid
 573         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 574         .quad sys_olduname
 575         .quad sys_umask         /* 60 */
 576         .quad sys_chroot
 577         .quad compat_sys_ustat
 578         .quad sys_dup2
 579         .quad sys_getppid
 580         .quad sys_getpgrp               /* 65 */
 581         .quad sys_setsid
 582         .quad sys32_sigaction
 583         .quad sys_sgetmask
 584         .quad sys_ssetmask
 585         .quad sys_setreuid16    /* 70 */
 586         .quad sys_setregid16
 587         .quad sys32_sigsuspend
 588         .quad compat_sys_sigpending
 589         .quad sys_sethostname
 590         .quad compat_sys_setrlimit      /* 75 */
 591         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 592         .quad compat_sys_getrusage
 593         .quad compat_sys_gettimeofday
 594         .quad compat_sys_settimeofday
 595         .quad sys_getgroups16   /* 80 */
 596         .quad sys_setgroups16
 597         .quad compat_sys_old_select
 598         .quad sys_symlink
 599         .quad sys_lstat
 600         .quad sys_readlink              /* 85 */
 601         .quad sys_uselib
 602         .quad sys_swapon
 603         .quad sys_reboot
 604         .quad compat_sys_old_readdir
 605         .quad sys32_mmap                /* 90 */
 606         .quad sys_munmap
 607         .quad sys_truncate
 608         .quad sys_ftruncate
 609         .quad sys_fchmod
 610         .quad sys_fchown16              /* 95 */
 611         .quad sys_getpriority
 612         .quad sys_setpriority
 613         .quad quiet_ni_syscall                  /* old profil syscall holder */
 614         .quad compat_sys_statfs
 615         .quad compat_sys_fstatfs                /* 100 */
 616         .quad sys_ioperm
 617         .quad compat_sys_socketcall
 618         .quad sys_syslog
 619         .quad compat_sys_setitimer
 620         .quad compat_sys_getitimer      /* 105 */
 621         .quad compat_sys_newstat
 622         .quad compat_sys_newlstat
 623         .quad compat_sys_newfstat
 624         .quad sys_uname
 625         .quad stub32_iopl               /* 110 */
 626         .quad sys_vhangup
 627         .quad quiet_ni_syscall  /* old "idle" system call */
 628         .quad sys32_vm86_warning        /* vm86old */
 629         .quad compat_sys_wait4
 630         .quad sys_swapoff               /* 115 */
 631         .quad compat_sys_sysinfo
 632         .quad sys32_ipc
 633         .quad sys_fsync
 634         .quad stub32_sigreturn
 635         .quad stub32_clone              /* 120 */
 636         .quad sys_setdomainname
 637         .quad sys_newuname
 638         .quad sys_modify_ldt
 639         .quad compat_sys_adjtimex
 640         .quad sys32_mprotect            /* 125 */
 641         .quad compat_sys_sigprocmask
 642         .quad quiet_ni_syscall          /* create_module */
 643         .quad sys_init_module
 644         .quad sys_delete_module
 645         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 646         .quad sys32_quotactl
 647         .quad sys_getpgid
 648         .quad sys_fchdir
 649         .quad quiet_ni_syscall  /* bdflush */
 650         .quad sys_sysfs         /* 135 */
 651         .quad sys_personality
 652         .quad quiet_ni_syscall  /* for afs_syscall */
 653         .quad sys_setfsuid16
 654         .quad sys_setfsgid16
 655         .quad sys_llseek                /* 140 */
 656         .quad compat_sys_getdents
 657         .quad compat_sys_select
 658         .quad sys_flock
 659         .quad sys_msync
 660         .quad compat_sys_readv          /* 145 */
 661         .quad compat_sys_writev
 662         .quad sys_getsid
 663         .quad sys_fdatasync
 664         .quad compat_sys_sysctl /* sysctl */
 665         .quad sys_mlock         /* 150 */
 666         .quad sys_munlock
 667         .quad sys_mlockall
 668         .quad sys_munlockall
 669         .quad sys_sched_setparam
 670         .quad sys_sched_getparam   /* 155 */
 671         .quad sys_sched_setscheduler
 672         .quad sys_sched_getscheduler
 673         .quad sys_sched_yield
 674         .quad sys_sched_get_priority_max
 675         .quad sys_sched_get_priority_min  /* 160 */
 676         .quad sys32_sched_rr_get_interval
 677         .quad compat_sys_nanosleep
 678         .quad sys_mremap
 679         .quad sys_setresuid16
 680         .quad sys_getresuid16   /* 165 */
 681         .quad sys32_vm86_warning        /* vm86 */
 682         .quad quiet_ni_syscall  /* query_module */
 683         .quad sys_poll
 684         .quad quiet_ni_syscall /* old nfsservctl */
 685         .quad sys_setresgid16   /* 170 */
 686         .quad sys_getresgid16
 687         .quad sys_prctl
 688         .quad stub32_rt_sigreturn
 689         .quad sys32_rt_sigaction
 690         .quad sys32_rt_sigprocmask      /* 175 */
 691         .quad sys32_rt_sigpending
 692         .quad compat_sys_rt_sigtimedwait
 693         .quad sys32_rt_sigqueueinfo
 694         .quad sys_rt_sigsuspend
 695         .quad sys32_pread               /* 180 */
 696         .quad sys32_pwrite
 697         .quad sys_chown16
 698         .quad sys_getcwd
 699         .quad sys_capget
 700         .quad sys_capset
 701         .quad stub32_sigaltstack
 702         .quad sys32_sendfile
 703         .quad quiet_ni_syscall          /* streams1 */
 704         .quad quiet_ni_syscall          /* streams2 */
 705         .quad stub32_vfork            /* 190 */
 706         .quad compat_sys_getrlimit
 707         .quad sys_mmap_pgoff
 708         .quad sys32_truncate64
 709         .quad sys32_ftruncate64
 710         .quad sys32_stat64              /* 195 */
 711         .quad sys32_lstat64
 712         .quad sys32_fstat64
 713         .quad sys_lchown
 714         .quad sys_getuid
 715         .quad sys_getgid                /* 200 */
 716         .quad sys_geteuid
 717         .quad sys_getegid
 718         .quad sys_setreuid
 719         .quad sys_setregid
 720         .quad sys_getgroups     /* 205 */
 721         .quad sys_setgroups
 722         .quad sys_fchown
 723         .quad sys_setresuid
 724         .quad sys_getresuid
 725         .quad sys_setresgid     /* 210 */
 726         .quad sys_getresgid
 727         .quad sys_chown
 728         .quad sys_setuid
 729         .quad sys_setgid
 730         .quad sys_setfsuid              /* 215 */
 731         .quad sys_setfsgid
 732         .quad sys_pivot_root
 733         .quad sys_mincore
 734         .quad sys_madvise
 735         .quad compat_sys_getdents64     /* 220 getdents64 */
 736         .quad compat_sys_fcntl64
 737         .quad quiet_ni_syscall          /* tux */
 738         .quad quiet_ni_syscall          /* security */
 739         .quad sys_gettid
 740         .quad sys32_readahead   /* 225 */
 741         .quad sys_setxattr
 742         .quad sys_lsetxattr
 743         .quad sys_fsetxattr
 744         .quad sys_getxattr
 745         .quad sys_lgetxattr     /* 230 */
 746         .quad sys_fgetxattr
 747         .quad sys_listxattr
 748         .quad sys_llistxattr
 749         .quad sys_flistxattr
 750         .quad sys_removexattr   /* 235 */
 751         .quad sys_lremovexattr
 752         .quad sys_fremovexattr
 753         .quad sys_tkill
 754         .quad sys_sendfile64
 755         .quad compat_sys_futex          /* 240 */
 756         .quad compat_sys_sched_setaffinity
 757         .quad compat_sys_sched_getaffinity
 758         .quad sys_set_thread_area
 759         .quad sys_get_thread_area
 760         .quad compat_sys_io_setup       /* 245 */
 761         .quad sys_io_destroy
 762         .quad compat_sys_io_getevents
 763         .quad compat_sys_io_submit
 764         .quad sys_io_cancel
 765         .quad sys32_fadvise64           /* 250 */
 766         .quad quiet_ni_syscall  /* free_huge_pages */
 767         .quad sys_exit_group
 768         .quad sys32_lookup_dcookie
 769         .quad sys_epoll_create
 770         .quad sys_epoll_ctl             /* 255 */
 771         .quad sys_epoll_wait
 772         .quad sys_remap_file_pages
 773         .quad sys_set_tid_address
 774         .quad compat_sys_timer_create
 775         .quad compat_sys_timer_settime  /* 260 */
 776         .quad compat_sys_timer_gettime
 777         .quad sys_timer_getoverrun
 778         .quad sys_timer_delete
 779         .quad compat_sys_clock_settime
 780         .quad compat_sys_clock_gettime  /* 265 */
 781         .quad compat_sys_clock_getres
 782         .quad compat_sys_clock_nanosleep
 783         .quad compat_sys_statfs64
 784         .quad compat_sys_fstatfs64
 785         .quad sys_tgkill                /* 270 */
 786         .quad compat_sys_utimes
 787         .quad sys32_fadvise64_64
 788         .quad quiet_ni_syscall  /* sys_vserver */
 789         .quad sys_mbind
 790         .quad compat_sys_get_mempolicy  /* 275 */
 791         .quad sys_set_mempolicy
 792         .quad compat_sys_mq_open
 793         .quad sys_mq_unlink
 794         .quad compat_sys_mq_timedsend
 795         .quad compat_sys_mq_timedreceive        /* 280 */
 796         .quad compat_sys_mq_notify
 797         .quad compat_sys_mq_getsetattr
 798         .quad compat_sys_kexec_load     /* reserved for kexec */
 799         .quad compat_sys_waitid
 800         .quad quiet_ni_syscall          /* 285: sys_altroot */
 801         .quad sys_add_key
 802         .quad sys_request_key
 803         .quad compat_sys_keyctl
 804         .quad sys_ioprio_set
 805         .quad sys_ioprio_get            /* 290 */
 806         .quad sys_inotify_init
 807         .quad sys_inotify_add_watch
 808         .quad sys_inotify_rm_watch
 809         .quad sys_migrate_pages
 810         .quad compat_sys_openat         /* 295 */
 811         .quad sys_mkdirat
 812         .quad sys_mknodat
 813         .quad sys_fchownat
 814         .quad compat_sys_futimesat
 815         .quad sys32_fstatat             /* 300 */
 816         .quad sys_unlinkat
 817         .quad sys_renameat
 818         .quad sys_linkat
 819         .quad sys_symlinkat
 820         .quad sys_readlinkat            /* 305 */
 821         .quad sys_fchmodat
 822         .quad sys_faccessat
 823         .quad compat_sys_pselect6
 824         .quad compat_sys_ppoll
 825         .quad sys_unshare               /* 310 */
 826         .quad compat_sys_set_robust_list
 827         .quad compat_sys_get_robust_list
 828         .quad sys_splice
 829         .quad sys32_sync_file_range
 830         .quad sys_tee                   /* 315 */
 831         .quad compat_sys_vmsplice
 832         .quad compat_sys_move_pages
 833         .quad sys_getcpu
 834         .quad sys_epoll_pwait
 835         .quad compat_sys_utimensat      /* 320 */
 836         .quad compat_sys_signalfd
 837         .quad sys_timerfd_create
 838         .quad sys_eventfd
 839         .quad sys32_fallocate
 840         .quad compat_sys_timerfd_settime        /* 325 */
 841         .quad compat_sys_timerfd_gettime
 842         .quad compat_sys_signalfd4
 843         .quad sys_eventfd2
 844         .quad sys_epoll_create1
 845         .quad sys_dup3                          /* 330 */
 846         .quad sys_pipe2
 847         .quad sys_inotify_init1
 848         .quad compat_sys_preadv
 849         .quad compat_sys_pwritev
 850         .quad compat_sys_rt_tgsigqueueinfo      /* 335 */
 851         .quad sys_perf_event_open
 852         .quad compat_sys_recvmmsg
 853         .quad sys_fanotify_init
 854         .quad sys32_fanotify_mark
 855         .quad sys_prlimit64             /* 340 */
 856         .quad sys_name_to_handle_at
 857         .quad compat_sys_open_by_handle_at
 858         .quad compat_sys_clock_adjtime
 859         .quad sys_syncfs
 860         .quad compat_sys_sendmmsg       /* 345 */
 861         .quad sys_setns
 862         .quad compat_sys_process_vm_readv
 863         .quad compat_sys_process_vm_writev
 864 ia32_syscall_end: