arch/x86/boot/compressed/head_64.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .code32
  25         .text
  26
  27 #include <linux/linkage.h>
  28 #include <asm/segment.h>
  29 #include <asm/pgtable_types.h>
  30 #include <asm/page_types.h>
  31 #include <asm/boot.h>
  32 #include <asm/msr.h>
  33 #include <asm/processor-flags.h>
  34 #include <asm/asm-offsets.h>
  35
  36         .section ".text.head"
  37         .code32
  38 ENTRY(startup_32)
  39         cld
  40         /*
  41          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  42          * us to not reload segments
  43          */
  44         testb $(1<<6), BP_loadflags(%esi)
  45         jnz 1f
  46
  47         cli
  48         movl    $(__KERNEL_DS), %eax
  49         movl    %eax, %ds
  50         movl    %eax, %es
  51         movl    %eax, %ss
  52 1:
  53
  54 /*
  55  * Calculate the delta between where we were compiled to run
  56  * at and where we were actually loaded at.  This can only be done
  57  * with a short local call on x86.  Nothing  else will tell us what
  58  * address we are running at.  The reserved chunk of the real-mode
  59  * data at 0x1e4 (defined as a scratch field) are used as the stack
  60  * for this calculation. Only 4 bytes are needed.
  61  */
  62         leal    (BP_scratch+4)(%esi), %esp
  63         call    1f
  64 1:      popl    %ebp
  65         subl    $1b, %ebp
  66
  67 /* setup a stack and make sure cpu supports long mode. */
  68         movl    $boot_stack_end, %eax
  69         addl    %ebp, %eax
  70         movl    %eax, %esp
  71
  72         call    verify_cpu
  73         testl   %eax, %eax
  74         jnz     no_longmode
  75
  76 /*
  77  * Compute the delta between where we were compiled to run at
  78  * and where the code will actually run at.
  79  *
  80  * %ebp contains the address we are loaded at by the boot loader and %ebx
  81  * contains the address where we should move the kernel image temporarily
  82  * for safe in-place decompression.
  83  */
  84
  85 #ifdef CONFIG_RELOCATABLE
  86         movl    %ebp, %ebx
  87         addl    $(PMD_PAGE_SIZE -1), %ebx
  88         andl    $PMD_PAGE_MASK, %ebx
  89 #else
  90         movl    $CONFIG_PHYSICAL_START, %ebx
  91 #endif
  92
  93         /* Replace the compressed data size with the uncompressed size */
  94         subl    input_len(%ebp), %ebx
  95         movl    output_len(%ebp), %eax
  96         addl    %eax, %ebx
  97         /* Add 8 bytes for every 32K input block */
  98         shrl    $12, %eax
  99         addl    %eax, %ebx
 100         /* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
 101         addl    $(32768 + 18 + 4095), %ebx
 102         andl    $~4095, %ebx
 103
 104 /*
 105  * Prepare for entering 64 bit mode
 106  */
 107
 108         /* Load new GDT with the 64bit segments using 32bit descriptor */
 109         leal    gdt(%ebp), %eax
 110         movl    %eax, gdt+2(%ebp)
 111         lgdt    gdt(%ebp)
 112
 113         /* Enable PAE mode */
 114         xorl    %eax, %eax
 115         orl     $(X86_CR4_PAE), %eax
 116         movl    %eax, %cr4
 117
 118  /*
 119   * Build early 4G boot pagetable
 120   */
 121         /* Initialize Page tables to 0 */
 122         leal    pgtable(%ebx), %edi
 123         xorl    %eax, %eax
 124         movl    $((4096*6)/4), %ecx
 125         rep     stosl
 126
 127         /* Build Level 4 */
 128         leal    pgtable + 0(%ebx), %edi
 129         leal    0x1007 (%edi), %eax
 130         movl    %eax, 0(%edi)
 131
 132         /* Build Level 3 */
 133         leal    pgtable + 0x1000(%ebx), %edi
 134         leal    0x1007(%edi), %eax
 135         movl    $4, %ecx
 136 1:      movl    %eax, 0x00(%edi)
 137         addl    $0x00001000, %eax
 138         addl    $8, %edi
 139         decl    %ecx
 140         jnz     1b
 141
 142         /* Build Level 2 */
 143         leal    pgtable + 0x2000(%ebx), %edi
 144         movl    $0x00000183, %eax
 145         movl    $2048, %ecx
 146 1:      movl    %eax, 0(%edi)
 147         addl    $0x00200000, %eax
 148         addl    $8, %edi
 149         decl    %ecx
 150         jnz     1b
 151
 152         /* Enable the boot page tables */
 153         leal    pgtable(%ebx), %eax
 154         movl    %eax, %cr3
 155
 156         /* Enable Long mode in EFER (Extended Feature Enable Register) */
 157         movl    $MSR_EFER, %ecx
 158         rdmsr
 159         btsl    $_EFER_LME, %eax
 160         wrmsr
 161
 162         /*
 163          * Setup for the jump to 64bit mode
 164          *
 165          * When the jump is performend we will be in long mode but
 166          * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
 167          * (and in turn EFER.LMA = 1).  To jump into 64bit mode we use
 168          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 169          * We place all of the values on our mini stack so lret can
 170          * used to perform that far jump.
 171          */
 172         pushl   $__KERNEL_CS
 173         leal    startup_64(%ebp), %eax
 174         pushl   %eax
 175
 176         /* Enter paged protected Mode, activating Long Mode */
 177         movl    $(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
 178         movl    %eax, %cr0
 179
 180         /* Jump from 32bit compatibility mode into 64bit mode. */
 181         lret
 182 ENDPROC(startup_32)
 183
 184 no_longmode:
 185         /* This isn't an x86-64 CPU so hang */
 186 1:
 187         hlt
 188         jmp     1b
 189
 190 #include "../../kernel/verify_cpu_64.S"
 191
 192         /*
 193          * Be careful here startup_64 needs to be at a predictable
 194          * address so I can export it in an ELF header.  Bootloaders
 195          * should look at the ELF header to find this address, as
 196          * it may change in the future.
 197          */
 198         .code64
 199         .org 0x200
 200 ENTRY(startup_64)
 201         /*
 202          * We come here either from startup_32 or directly from a
 203          * 64bit bootloader.  If we come here from a bootloader we depend on
 204          * an identity mapped page table being provied that maps our
 205          * entire text+data+bss and hopefully all of memory.
 206          */
 207
 208         /* Setup data segments. */
 209         xorl    %eax, %eax
 210         movl    %eax, %ds
 211         movl    %eax, %es
 212         movl    %eax, %ss
 213         movl    %eax, %fs
 214         movl    %eax, %gs
 215         lldt    %ax
 216         movl    $0x20, %eax
 217         ltr     %ax
 218
 219         /*
 220          * Compute the decompressed kernel start address.  It is where
 221          * we were loaded at aligned to a 2M boundary. %rbp contains the
 222          * decompressed kernel start address.
 223          *
 224          * If it is a relocatable kernel then decompress and run the kernel
 225          * from load address aligned to 2MB addr, otherwise decompress and
 226          * run the kernel from CONFIG_PHYSICAL_START
 227          */
 228
 229         /* Start with the delta to where the kernel will run at. */
 230 #ifdef CONFIG_RELOCATABLE
 231         leaq    startup_32(%rip) /* - $startup_32 */, %rbp
 232         addq    $(PMD_PAGE_SIZE - 1), %rbp
 233         andq    $PMD_PAGE_MASK, %rbp
 234         movq    %rbp, %rbx
 235 #else
 236         movq    $CONFIG_PHYSICAL_START, %rbp
 237         movq    %rbp, %rbx
 238 #endif
 239
 240         /* Replace the compressed data size with the uncompressed size */
 241         movl    input_len(%rip), %eax
 242         subq    %rax, %rbx
 243         movl    output_len(%rip), %eax
 244         addq    %rax, %rbx
 245         /* Add 8 bytes for every 32K input block */
 246         shrq    $12, %rax
 247         addq    %rax, %rbx
 248         /* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
 249         addq    $(32768 + 18 + 4095), %rbx
 250         andq    $~4095, %rbx
 251
 252 /*
 253  * Copy the compressed kernel to the end of our buffer
 254  * where decompression in place becomes safe.
 255  */
 256         leaq    _bss(%rip), %r8
 257         leaq    _bss(%rbx), %r9
 258         movq    $_bss /* - $startup_32 */, %rcx
 259 1:      subq    $8, %r8
 260         subq    $8, %r9
 261         movq    0(%r8), %rax
 262         movq    %rax, 0(%r9)
 263         subq    $8, %rcx
 264         jnz     1b
 265
 266 /*
 267  * Jump to the relocated address.
 268  */
 269         leaq    relocated(%rbx), %rax
 270         jmp     *%rax
 271
 272         .text
 273 relocated:
 274
 275 /*
 276  * Clear BSS
 277  */
 278         xorq    %rax, %rax
 279         leaq    _bss(%rbx), %rdi
 280         leaq    _ebss(%rbx), %rcx
 281         subq    %rdi, %rcx
 282         cld
 283         rep     stosb
 284
 285         /* Setup the stack */
 286         leaq    boot_stack_end(%rip), %rsp
 287
 288         /* zero EFLAGS after setting rsp */
 289         pushq   $0
 290         popfq
 291
 292 /*
 293  * Do the decompression, and jump to the new kernel..
 294  */
 295         pushq   %rsi                    # Save the real mode argument
 296         movq    %rsi, %rdi              # real mode address
 297         leaq    boot_heap(%rip), %rsi   # malloc area for uncompression
 298         leaq    input_data(%rip), %rdx  # input_data
 299         movl    input_len(%rip), %eax
 300         movq    %rax, %rcx              # input_len
 301         movq    %rbp, %r8               # output
 302         call    decompress_kernel
 303         popq    %rsi
 304
 305 /*
 306  * Jump to the decompressed kernel.
 307  */
 308         jmp     *%rbp
 309
 310         .data
 311 gdt:
 312         .word   gdt_end - gdt
 313         .long   gdt
 314         .word   0
 315         .quad   0x0000000000000000      /* NULL descriptor */
 316         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 317         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 318         .quad   0x0080890000000000      /* TS descriptor */
 319         .quad   0x0000000000000000      /* TS continued */
 320 gdt_end:
 321
 322 /*
 323  * Stack and heap for uncompression
 324  */
 325         .bss
 326         .balign 4
 327 boot_heap:
 328         .fill BOOT_HEAP_SIZE, 1, 0
 329 boot_stack:
 330         .fill BOOT_STACK_SIZE, 1, 0
 331 boot_stack_end:
 332
 333 /*
 334  * Space for page tables (not in .bss so not zeroed)
 335  */
 336         .section ".pgtable","a",@nobits
 337         .balign 4096
 338 pgtable:
 339         .fill 6*4096, 1, 0