arch/x86/boot/compressed/head_32.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .text
  25
  26 #include <linux/linkage.h>
  27 #include <asm/segment.h>
  28 #include <asm/page_types.h>
  29 #include <asm/boot.h>
  30 #include <asm/asm-offsets.h>
  31
  32         .section ".text.head","ax",@progbits
  33 ENTRY(startup_32)
  34         cld
  35         /*
  36          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  37          * us to not reload segments
  38          */
  39         testb   $(1<<6), BP_loadflags(%esi)
  40         jnz     1f
  41
  42         cli
  43         movl    $__BOOT_DS, %eax
  44         movl    %eax, %ds
  45         movl    %eax, %es
  46         movl    %eax, %fs
  47         movl    %eax, %gs
  48         movl    %eax, %ss
  49 1:
  50
  51 /*
  52  * Calculate the delta between where we were compiled to run
  53  * at and where we were actually loaded at.  This can only be done
  54  * with a short local call on x86.  Nothing  else will tell us what
  55  * address we are running at.  The reserved chunk of the real-mode
  56  * data at 0x1e4 (defined as a scratch field) are used as the stack
  57  * for this calculation. Only 4 bytes are needed.
  58  */
  59         leal    (BP_scratch+4)(%esi), %esp
  60         call    1f
  61 1:      popl    %ebp
  62         subl    $1b, %ebp
  63
  64 /*
  65  * %ebp contains the address we are loaded at by the boot loader and %ebx
  66  * contains the address where we should move the kernel image temporarily
  67  * for safe in-place decompression.
  68  */
  69
  70 #ifdef CONFIG_RELOCATABLE
  71         movl    %ebp, %ebx
  72         addl    $(CONFIG_PHYSICAL_ALIGN - 1), %ebx
  73         andl    $(~(CONFIG_PHYSICAL_ALIGN - 1)), %ebx
  74 #else
  75         movl    $LOAD_PHYSICAL_ADDR, %ebx
  76 #endif
  77
  78         /* Target address to relocate to for decompression */
  79         addl    $z_extract_offset, %ebx
  80
  81         /* Set up the stack */
  82         leal    boot_stack_end(%ebx), %esp
  83
  84         /* Zero EFLAGS */
  85         pushl   $0
  86         popfl
  87
  88 /*
  89  * Copy the compressed kernel to the end of our buffer
  90  * where decompression in place becomes safe.
  91  */
  92         pushl   %esi
  93         leal    (_bss-4)(%ebp), %esi
  94         leal    (_bss-4)(%ebx), %edi
  95         movl    $(_bss - startup_32), %ecx
  96         shrl    $2, %ecx
  97         std
  98         rep     movsl
  99         cld
 100         popl    %esi
 101
 102 /*
 103  * Jump to the relocated address.
 104  */
 105         leal    relocated(%ebx), %eax
 106         jmp     *%eax
 107 ENDPROC(startup_32)
 108
 109         .text
 110 relocated:
 111
 112 /*
 113  * Clear BSS (stack is currently empty)
 114  */
 115         xorl    %eax, %eax
 116         leal    _bss(%ebx), %edi
 117         leal    _ebss(%ebx), %ecx
 118         subl    %edi, %ecx
 119         shrl    $2, %ecx
 120         rep     stosl
 121
 122 /*
 123  * Do the decompression, and jump to the new kernel..
 124  */
 125         leal    z_extract_offset_negative(%ebx), %ebp
 126                                 /* push arguments for decompress_kernel: */
 127         pushl   %ebp            /* output address */
 128         pushl   $z_input_len    /* input_len */
 129         leal    input_data(%ebx), %eax
 130         pushl   %eax            /* input_data */
 131         leal    boot_heap(%ebx), %eax
 132         pushl   %eax            /* heap area */
 133         pushl   %esi            /* real mode pointer */
 134         call    decompress_kernel
 135         addl    $20, %esp
 136
 137 #if CONFIG_RELOCATABLE
 138 /*
 139  * Find the address of the relocations.
 140  */
 141         leal    z_output_len(%ebp), %edi
 142
 143 /*
 144  * Calculate the delta between where vmlinux was compiled to run
 145  * and where it was actually loaded.
 146  */
 147         movl    %ebp, %ebx
 148         subl    $LOAD_PHYSICAL_ADDR, %ebx
 149         jz      2f      /* Nothing to be done if loaded at compiled addr. */
 150 /*
 151  * Process relocations.
 152  */
 153
 154 1:      subl    $4, %edi
 155         movl    (%edi), %ecx
 156         testl   %ecx, %ecx
 157         jz      2f
 158         addl    %ebx, -__PAGE_OFFSET(%ebx, %ecx)
 159         jmp     1b
 160 2:
 161 #endif
 162
 163 /*
 164  * Jump to the decompressed kernel.
 165  */
 166         xorl    %ebx, %ebx
 167         jmp     *%ebp
 168
 169 /*
 170  * Stack and heap for uncompression
 171  */
 172         .bss
 173         .balign 4
 174 boot_heap:
 175         .fill BOOT_HEAP_SIZE, 1, 0
 176 boot_stack:
 177         .fill BOOT_STACK_SIZE, 1, 0
 178 boot_stack_end: