arch/s390/kernel/head64.S

   1 /*
   2  * arch/s390/kernel/head64.S
   3  *
   4  * Copyright (C) IBM Corp. 1999,2010
   5  *
   6  *   Author(s): Hartmut Penner <hp@de.ibm.com>
   7  *              Martin Schwidefsky <schwidefsky@de.ibm.com>
   8  *              Rob van der Heij <rvdhei@iae.nl>
   9  *              Heiko Carstens <heiko.carstens@de.ibm.com>
  10  *
  11  */
  12
  13 #include <linux/init.h>
  14 #include <asm/asm-offsets.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/page.h>
  17
  18 __HEAD
  19         .globl  startup_continue
  20 startup_continue:
  21         larl    %r1,sched_clock_base_cc
  22         mvc     0(8,%r1),__LC_LAST_UPDATE_CLOCK
  23         larl    %r13,.LPG1              # get base
  24         lmh     %r0,%r15,.Lzero64-.LPG1(%r13)   # clear high-order half
  25         lctlg   %c0,%c15,.Lctl-.LPG1(%r13)      # load control registers
  26         lg      %r12,.Lparmaddr-.LPG1(%r13)     # pointer to parameter area
  27                                         # move IPL device to lowcore
  28         lghi    %r0,__LC_PASTE
  29         stg     %r0,__LC_VDSO_PER_CPU
  30 #
  31 # Setup stack
  32 #
  33         larl    %r15,init_thread_union
  34         stg     %r15,__LC_THREAD_INFO   # cache thread info in lowcore
  35         lg      %r14,__TI_task(%r15)    # cache current in lowcore
  36         stg     %r14,__LC_CURRENT
  37         aghi    %r15,1<<(PAGE_SHIFT+THREAD_ORDER) # init_task_union + THREAD_SIZE
  38         stg     %r15,__LC_KERNEL_STACK  # set end of kernel stack
  39         aghi    %r15,-160
  40 #
  41 # Save ipl parameters, clear bss memory, initialize storage key for kernel pages,
  42 # and create a kernel NSS if the SAVESYS= parm is defined
  43 #
  44         brasl   %r14,startup_init
  45         lpswe   .Lentry-.LPG1(13)       # jump to _stext in primary-space,
  46                                         # virtual and never return ...
  47         .align  16
  48 .LPG1:
  49 .Lentry:.quad   0x0000000180000000,_stext
  50 .Lctl:  .quad   0x04350002              # cr0: various things
  51         .quad   0                       # cr1: primary space segment table
  52         .quad   .Lduct                  # cr2: dispatchable unit control table
  53         .quad   0                       # cr3: instruction authorization
  54         .quad   0                       # cr4: instruction authorization
  55         .quad   .Lduct                  # cr5: primary-aste origin
  56         .quad   0                       # cr6:  I/O interrupts
  57         .quad   0                       # cr7:  secondary space segment table
  58         .quad   0                       # cr8:  access registers translation
  59         .quad   0                       # cr9:  tracing off
  60         .quad   0                       # cr10: tracing off
  61         .quad   0                       # cr11: tracing off
  62         .quad   0                       # cr12: tracing off
  63         .quad   0                       # cr13: home space segment table
  64         .quad   0xc0000000              # cr14: machine check handling off
  65         .quad   0                       # cr15: linkage stack operations
  66 .Lpcmsk:.quad   0x0000000180000000
  67 .L4malign:.quad 0xffffffffffc00000
  68 .Lscan2g:.quad  0x80000000 + 0x20000 - 8        # 2GB + 128K - 8
  69 .Lnop:  .long   0x07000700
  70 .Lzero64:.fill  16,4,0x0
  71 .Lparmaddr:
  72         .quad   PARMAREA
  73         .align  64
  74 .Lduct: .long   0,0,0,0,.Lduald,0,0,0
  75         .long   0,0,0,0,0,0,0,0
  76         .align  128
  77 .Lduald:.rept   8
  78         .long   0x80000000,0,0,0        # invalid access-list entries
  79         .endr
  80
  81         .globl  _ehead
  82 _ehead:
  83
  84 #ifdef CONFIG_SHARED_KERNEL
  85         .org    0x100000
  86 #endif
  87
  88 #
  89 # startup-code, running in absolute addressing mode
  90 #
  91         .globl  _stext
  92 _stext: basr    %r13,0                  # get base
  93 .LPG3:
  94 # check control registers
  95         stctg   %c0,%c15,0(%r15)
  96         oi      6(%r15),0x40            # enable sigp emergency signal
  97         oi      4(%r15),0x10            # switch on low address proctection
  98         lctlg   %c0,%c15,0(%r15)
  99
 100         lam     0,15,.Laregs-.LPG3(%r13)        # load acrs needed by uaccess
 101         brasl   %r14,start_kernel       # go to C code
 102 #
 103 # We returned from start_kernel ?!? PANIK
 104 #
 105         basr    %r13,0
 106         lpswe   .Ldw-.(%r13)            # load disabled wait psw
 107
 108         .align  8
 109 .Ldw:   .quad   0x0002000180000000,0x0000000000000000
 110 .Laregs:.long   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0