arch/powerpc/xmon/setjmp.S

   1 /*
   2  * Copyright (C) 1996 Paul Mackerras.
   3  *
   4  *      This program is free software; you can redistribute it and/or
   5  *      modify it under the terms of the GNU General Public License
   6  *      as published by the Free Software Foundation; either version
   7  *      2 of the License, or (at your option) any later version.
   8  *
   9  * NOTE: assert(sizeof(buf) > 23 * sizeof(long))
  10  */
  11 #include <asm/processor.h>
  12 #include <asm/ppc_asm.h>
  13 #include <asm/asm-offsets.h>
  14
  15 _GLOBAL(xmon_setjmp)
  16         mflr    r0
  17         STL     r0,0(r3)
  18         STL     r1,SZL(r3)
  19         STL     r2,2*SZL(r3)
  20         mfcr    r0
  21         STL     r0,3*SZL(r3)
  22         STL     r13,4*SZL(r3)
  23         STL     r14,5*SZL(r3)
  24         STL     r15,6*SZL(r3)
  25         STL     r16,7*SZL(r3)
  26         STL     r17,8*SZL(r3)
  27         STL     r18,9*SZL(r3)
  28         STL     r19,10*SZL(r3)
  29         STL     r20,11*SZL(r3)
  30         STL     r21,12*SZL(r3)
  31         STL     r22,13*SZL(r3)
  32         STL     r23,14*SZL(r3)
  33         STL     r24,15*SZL(r3)
  34         STL     r25,16*SZL(r3)
  35         STL     r26,17*SZL(r3)
  36         STL     r27,18*SZL(r3)
  37         STL     r28,19*SZL(r3)
  38         STL     r29,20*SZL(r3)
  39         STL     r30,21*SZL(r3)
  40         STL     r31,22*SZL(r3)
  41         li      r3,0
  42         blr
  43
  44 _GLOBAL(xmon_longjmp)
  45         CMPI    r4,0
  46         bne     1f
  47         li      r4,1
  48 1:      LDL     r13,4*SZL(r3)
  49         LDL     r14,5*SZL(r3)
  50         LDL     r15,6*SZL(r3)
  51         LDL     r16,7*SZL(r3)
  52         LDL     r17,8*SZL(r3)
  53         LDL     r18,9*SZL(r3)
  54         LDL     r19,10*SZL(r3)
  55         LDL     r20,11*SZL(r3)
  56         LDL     r21,12*SZL(r3)
  57         LDL     r22,13*SZL(r3)
  58         LDL     r23,14*SZL(r3)
  59         LDL     r24,15*SZL(r3)
  60         LDL     r25,16*SZL(r3)
  61         LDL     r26,17*SZL(r3)
  62         LDL     r27,18*SZL(r3)
  63         LDL     r28,19*SZL(r3)
  64         LDL     r29,20*SZL(r3)
  65         LDL     r30,21*SZL(r3)
  66         LDL     r31,22*SZL(r3)
  67         LDL     r0,3*SZL(r3)
  68         mtcrf   0x38,r0
  69         LDL     r0,0(r3)
  70         LDL     r1,SZL(r3)
  71         LDL     r2,2*SZL(r3)
  72         mtlr    r0
  73         mr      r3,r4
  74         blr
  75
  76 /*
  77  * Grab the register values as they are now.
  78  * This won't do a particularily good job because we really
  79  * want our caller's caller's registers, and our caller has
  80  * already executed its prologue.
  81  * ToDo: We could reach back into the caller's save area to do
  82  * a better job of representing the caller's state (note that
  83  * that will be different for 32-bit and 64-bit, because of the
  84  * different ABIs, though).
  85  */
  86 _GLOBAL(xmon_save_regs)
  87         STL     r0,0*SZL(r3)
  88         STL     r2,2*SZL(r3)
  89         STL     r3,3*SZL(r3)
  90         STL     r4,4*SZL(r3)
  91         STL     r5,5*SZL(r3)
  92         STL     r6,6*SZL(r3)
  93         STL     r7,7*SZL(r3)
  94         STL     r8,8*SZL(r3)
  95         STL     r9,9*SZL(r3)
  96         STL     r10,10*SZL(r3)
  97         STL     r11,11*SZL(r3)
  98         STL     r12,12*SZL(r3)
  99         STL     r13,13*SZL(r3)
 100         STL     r14,14*SZL(r3)
 101         STL     r15,15*SZL(r3)
 102         STL     r16,16*SZL(r3)
 103         STL     r17,17*SZL(r3)
 104         STL     r18,18*SZL(r3)
 105         STL     r19,19*SZL(r3)
 106         STL     r20,20*SZL(r3)
 107         STL     r21,21*SZL(r3)
 108         STL     r22,22*SZL(r3)
 109         STL     r23,23*SZL(r3)
 110         STL     r24,24*SZL(r3)
 111         STL     r25,25*SZL(r3)
 112         STL     r26,26*SZL(r3)
 113         STL     r27,27*SZL(r3)
 114         STL     r28,28*SZL(r3)
 115         STL     r29,29*SZL(r3)
 116         STL     r30,30*SZL(r3)
 117         STL     r31,31*SZL(r3)
 118         /* go up one stack frame for SP */
 119         LDL     r4,0(r1)
 120         STL     r4,1*SZL(r3)
 121         /* get caller's LR */
 122         LDL     r0,LRSAVE(r4)
 123         STL     r0,_NIP-STACK_FRAME_OVERHEAD(r3)
 124         STL     r0,_LINK-STACK_FRAME_OVERHEAD(r3)
 125         mfmsr   r0
 126         STL     r0,_MSR-STACK_FRAME_OVERHEAD(r3)
 127         mfctr   r0
 128         STL     r0,_CTR-STACK_FRAME_OVERHEAD(r3)
 129         mfxer   r0
 130         STL     r0,_XER-STACK_FRAME_OVERHEAD(r3)
 131         mfcr    r0
 132         STL     r0,_CCR-STACK_FRAME_OVERHEAD(r3)
 133         li      r0,0
 134         STL     r0,_TRAP-STACK_FRAME_OVERHEAD(r3)
 135         blr