arch/powerpc/kvm/book3s_rmhandlers.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * You should have received a copy of the GNU General Public License
  12  * along with this program; if not, write to the Free Software
  13  * Foundation, 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/page.h>
  24 #include <asm/asm-offsets.h>
  25
  26 #ifdef CONFIG_PPC_BOOK3S_64
  27 #include <asm/exception-64s.h>
  28 #endif
  29
  30 /*****************************************************************************
  31  *                                                                           *
  32  *        Real Mode handlers that need to be in low physical memory          *
  33  *                                                                           *
  34  ****************************************************************************/
  35
  36 #if defined(CONFIG_PPC_BOOK3S_64)
  37
  38 #define LOAD_SHADOW_VCPU(reg)   GET_PACA(reg)
  39 #define SHADOW_VCPU_OFF         PACA_KVM_SVCPU
  40 #define MSR_NOIRQ               MSR_KERNEL & ~(MSR_IR | MSR_DR)
  41 #define FUNC(name)              GLUE(.,name)
  42
  43 #elif defined(CONFIG_PPC_BOOK3S_32)
  44
  45 #define LOAD_SHADOW_VCPU(reg)                                           \
  46         mfspr   reg, SPRN_SPRG_THREAD;                                  \
  47         lwz     reg, THREAD_KVM_SVCPU(reg);                             \
  48         /* PPC32 can have a NULL pointer - let's check for that */      \
  49         mtspr   SPRN_SPRG_SCRATCH1, r12;        /* Save r12 */          \
  50         mfcr    r12;                                                    \
  51         cmpwi   reg, 0;                                                 \
  52         bne     1f;                                                     \
  53         mfspr   reg, SPRN_SPRG_SCRATCH0;                                \
  54         mtcr    r12;                                                    \
  55         mfspr   r12, SPRN_SPRG_SCRATCH1;                                \
  56         b       kvmppc_resume_\intno;                                   \
  57 1:;                                                                     \
  58         mtcr    r12;                                                    \
  59         mfspr   r12, SPRN_SPRG_SCRATCH1;                                \
  60         tophys(reg, reg)
  61
  62 #define SHADOW_VCPU_OFF         0
  63 #define MSR_NOIRQ               MSR_KERNEL
  64 #define FUNC(name)              name
  65
  66 #endif
  67
  68 .macro INTERRUPT_TRAMPOLINE intno
  69
  70 .global kvmppc_trampoline_\intno
  71 kvmppc_trampoline_\intno:
  72
  73         SET_SCRATCH0(r13)               /* Save r13 */
  74
  75         /*
  76          * First thing to do is to find out if we're coming
  77          * from a KVM guest or a Linux process.
  78          *
  79          * To distinguish, we check a magic byte in the PACA/current
  80          */
  81         LOAD_SHADOW_VCPU(r13)
  82         PPC_STL r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH0)(r13)
  83         mfcr    r12
  84         stw     r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH1)(r13)
  85         lbz     r12, (SHADOW_VCPU_OFF + SVCPU_IN_GUEST)(r13)
  86         cmpwi   r12, KVM_GUEST_MODE_NONE
  87         bne     ..kvmppc_handler_hasmagic_\intno
  88         /* No KVM guest? Then jump back to the Linux handler! */
  89         lwz     r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH1)(r13)
  90         mtcr    r12
  91         PPC_LL  r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH0)(r13)
  92         GET_SCRATCH0(r13)                       /* r13 = original r13 */
  93         b       kvmppc_resume_\intno            /* Get back original handler */
  94
  95         /* Now we know we're handling a KVM guest */
  96 ..kvmppc_handler_hasmagic_\intno:
  97
  98         /* Should we just skip the faulting instruction? */
  99         cmpwi   r12, KVM_GUEST_MODE_SKIP
 100         beq     kvmppc_handler_skip_ins
 101
 102         /* Let's store which interrupt we're handling */
 103         li      r12, \intno
 104
 105         /* Jump into the SLB exit code that goes to the highmem handler */
 106         b       kvmppc_handler_trampoline_exit
 107
 108 .endm
 109
 110 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_SYSTEM_RESET
 111 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_MACHINE_CHECK
 112 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_DATA_STORAGE
 113 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_INST_STORAGE
 114 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_EXTERNAL
 115 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_EXTERNAL_HV
 116 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_ALIGNMENT
 117 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_PROGRAM
 118 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_FP_UNAVAIL
 119 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_DECREMENTER
 120 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_SYSCALL
 121 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_TRACE
 122 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_PERFMON
 123 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_ALTIVEC
 124
 125 /* Those are only available on 64 bit machines */
 126
 127 #ifdef CONFIG_PPC_BOOK3S_64
 128 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_DATA_SEGMENT
 129 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_INST_SEGMENT
 130 INTERRUPT_TRAMPOLINE    BOOK3S_INTERRUPT_VSX
 131 #endif
 132
 133 /*
 134  * Bring us back to the faulting code, but skip the
 135  * faulting instruction.
 136  *
 137  * This is a generic exit path from the interrupt
 138  * trampolines above.
 139  *
 140  * Input Registers:
 141  *
 142  * R12            = free
 143  * R13            = Shadow VCPU (PACA)
 144  * SVCPU.SCRATCH0 = guest R12
 145  * SVCPU.SCRATCH1 = guest CR
 146  * SPRG_SCRATCH0  = guest R13
 147  *
 148  */
 149 kvmppc_handler_skip_ins:
 150
 151         /* Patch the IP to the next instruction */
 152         mfsrr0  r12
 153         addi    r12, r12, 4
 154         mtsrr0  r12
 155
 156         /* Clean up all state */
 157         lwz     r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH1)(r13)
 158         mtcr    r12
 159         PPC_LL  r12, (SHADOW_VCPU_OFF + SVCPU_SCRATCH0)(r13)
 160         GET_SCRATCH0(r13)
 161
 162         /* And get back into the code */
 163         RFI
 164
 165 /*
 166  * This trampoline brings us back to a real mode handler
 167  *
 168  * Input Registers:
 169  *
 170  * R5 = SRR0
 171  * R6 = SRR1
 172  * LR = real-mode IP
 173  *
 174  */
 175 .global kvmppc_handler_lowmem_trampoline
 176 kvmppc_handler_lowmem_trampoline:
 177
 178         mtsrr0  r5
 179         mtsrr1  r6
 180         blr
 181 kvmppc_handler_lowmem_trampoline_end:
 182
 183 /*
 184  * Call a function in real mode
 185  *
 186  * Input Registers:
 187  *
 188  * R3 = function
 189  * R4 = MSR
 190  * R5 = scratch register
 191  *
 192  */
 193 _GLOBAL(kvmppc_rmcall)
 194         LOAD_REG_IMMEDIATE(r5, MSR_NOIRQ)
 195         mtmsr   r5              /* Disable relocation and interrupts, so mtsrr
 196                                    doesn't get interrupted */
 197         sync
 198         mtsrr0  r3
 199         mtsrr1  r4
 200         RFI
 201
 202 #if defined(CONFIG_PPC_BOOK3S_32)
 203 #define STACK_LR        INT_FRAME_SIZE+4
 204
 205 /* load_up_xxx have to run with MSR_DR=0 on Book3S_32 */
 206 #define MSR_EXT_START                                           \
 207         PPC_STL r20, _NIP(r1);                                  \
 208         mfmsr   r20;                                            \
 209         LOAD_REG_IMMEDIATE(r3, MSR_DR|MSR_EE);                  \
 210         andc    r3,r20,r3;              /* Disable DR,EE */     \
 211         mtmsr   r3;                                             \
 212         sync
 213
 214 #define MSR_EXT_END                                             \
 215         mtmsr   r20;                    /* Enable DR,EE */      \
 216         sync;                                                   \
 217         PPC_LL  r20, _NIP(r1)
 218
 219 #elif defined(CONFIG_PPC_BOOK3S_64)
 220 #define STACK_LR        _LINK
 221 #define MSR_EXT_START
 222 #define MSR_EXT_END
 223 #endif
 224
 225 /*
 226  * Activate current's external feature (FPU/Altivec/VSX)
 227  */
 228 #define define_load_up(what)                                    \
 229                                                                 \
 230 _GLOBAL(kvmppc_load_up_ ## what);                               \
 231         PPC_STLU r1, -INT_FRAME_SIZE(r1);                       \
 232         mflr    r3;                                             \
 233         PPC_STL r3, STACK_LR(r1);                               \
 234         MSR_EXT_START;                                          \
 235                                                                 \
 236         bl      FUNC(load_up_ ## what);                         \
 237                                                                 \
 238         MSR_EXT_END;                                            \
 239         PPC_LL  r3, STACK_LR(r1);                               \
 240         mtlr    r3;                                             \
 241         addi    r1, r1, INT_FRAME_SIZE;                         \
 242         blr
 243
 244 define_load_up(fpu)
 245 #ifdef CONFIG_ALTIVEC
 246 define_load_up(altivec)
 247 #endif
 248 #ifdef CONFIG_VSX
 249 define_load_up(vsx)
 250 #endif
 251
 252 .global kvmppc_trampoline_lowmem
 253 kvmppc_trampoline_lowmem:
 254         PPC_LONG kvmppc_handler_lowmem_trampoline - CONFIG_KERNEL_START
 255
 256 .global kvmppc_trampoline_enter
 257 kvmppc_trampoline_enter:
 258         PPC_LONG kvmppc_handler_trampoline_enter - CONFIG_KERNEL_START
 259
 260 #include "book3s_segment.S"