arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35
  36 /*
  37  * System calls.
  38  */
  39         .section        ".toc","aw"
  40 .SYS_CALL_TABLE:
  41         .tc .sys_call_table[TC],.sys_call_table
  42
  43 /* This value is used to mark exception frames on the stack. */
  44 exception_marker:
  45         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  46
  47         .section        ".text"
  48         .align 7
  49
  50 #undef SHOW_SYSCALLS
  51
  52         .globl system_call_common
  53 system_call_common:
  54         andi.   r10,r12,MSR_PR
  55         mr      r10,r1
  56         addi    r1,r1,-INT_FRAME_SIZE
  57         beq-    1f
  58         ld      r1,PACAKSAVE(r13)
  59 1:      std     r10,0(r1)
  60         std     r11,_NIP(r1)
  61         std     r12,_MSR(r1)
  62         std     r0,GPR0(r1)
  63         std     r10,GPR1(r1)
  64         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  65         /*
  66          * This "crclr so" clears CR0.SO, which is the error indication on
  67          * return from this system call.  There must be no cmp instruction
  68          * between it and the "mfcr r9" below, otherwise if XER.SO is set,
  69          * CR0.SO will get set, causing all system calls to appear to fail.
  70          */
  71         crclr   so
  72         std     r2,GPR2(r1)
  73         std     r3,GPR3(r1)
  74         std     r4,GPR4(r1)
  75         std     r5,GPR5(r1)
  76         std     r6,GPR6(r1)
  77         std     r7,GPR7(r1)
  78         std     r8,GPR8(r1)
  79         li      r11,0
  80         std     r11,GPR9(r1)
  81         std     r11,GPR10(r1)
  82         std     r11,GPR11(r1)
  83         std     r11,GPR12(r1)
  84         std     r9,GPR13(r1)
  85         mfcr    r9
  86         mflr    r10
  87         li      r11,0xc01
  88         std     r9,_CCR(r1)
  89         std     r10,_LINK(r1)
  90         std     r11,_TRAP(r1)
  91         mfxer   r9
  92         mfctr   r10
  93         std     r9,_XER(r1)
  94         std     r10,_CTR(r1)
  95         std     r3,ORIG_GPR3(r1)
  96         ld      r2,PACATOC(r13)
  97         addi    r9,r1,STACK_FRAME_OVERHEAD
  98         ld      r11,exception_marker@toc(r2)
  99         std     r11,-16(r9)             /* "regshere" marker */
 100 #if defined(CONFIG_VIRT_CPU_ACCOUNTING) && defined(CONFIG_PPC_SPLPAR)
 101 BEGIN_FW_FTR_SECTION
 102         beq     33f
 103         /* if from user, see if there are any DTL entries to process */
 104         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 105         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 106         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 107         cmpd    cr1,r11,r10
 108         beq+    cr1,33f
 109         bl      .accumulate_stolen_time
 110         REST_GPR(0,r1)
 111         REST_4GPRS(3,r1)
 112         REST_2GPRS(7,r1)
 113         addi    r9,r1,STACK_FRAME_OVERHEAD
 114 33:
 115 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 116 #endif /* CONFIG_VIRT_CPU_ACCOUNTING && CONFIG_PPC_SPLPAR */
 117
 118 #ifdef CONFIG_TRACE_IRQFLAGS
 119         bl      .trace_hardirqs_on
 120         REST_GPR(0,r1)
 121         REST_4GPRS(3,r1)
 122         REST_2GPRS(7,r1)
 123         addi    r9,r1,STACK_FRAME_OVERHEAD
 124         ld      r12,_MSR(r1)
 125 #endif /* CONFIG_TRACE_IRQFLAGS */
 126         li      r10,1
 127         stb     r10,PACASOFTIRQEN(r13)
 128         stb     r10,PACAHARDIRQEN(r13)
 129         std     r10,SOFTE(r1)
 130
 131         /* Hard enable interrupts */
 132 #ifdef CONFIG_PPC_BOOK3E
 133         wrteei  1
 134 #else
 135         mfmsr   r11
 136         ori     r11,r11,MSR_EE
 137         mtmsrd  r11,1
 138 #endif /* CONFIG_PPC_BOOK3E */
 139
 140 #ifdef SHOW_SYSCALLS
 141         bl      .do_show_syscall
 142         REST_GPR(0,r1)
 143         REST_4GPRS(3,r1)
 144         REST_2GPRS(7,r1)
 145         addi    r9,r1,STACK_FRAME_OVERHEAD
 146 #endif
 147         clrrdi  r11,r1,THREAD_SHIFT
 148         ld      r10,TI_FLAGS(r11)
 149         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 150         bne-    syscall_dotrace
 151 syscall_dotrace_cont:
 152         cmpldi  0,r0,NR_syscalls
 153         bge-    syscall_enosys
 154
 155 system_call:                    /* label this so stack traces look sane */
 156 /*
 157  * Need to vector to 32 Bit or default sys_call_table here,
 158  * based on caller's run-mode / personality.
 159  */
 160         ld      r11,.SYS_CALL_TABLE@toc(2)
 161         andi.   r10,r10,_TIF_32BIT
 162         beq     15f
 163         addi    r11,r11,8       /* use 32-bit syscall entries */
 164         clrldi  r3,r3,32
 165         clrldi  r4,r4,32
 166         clrldi  r5,r5,32
 167         clrldi  r6,r6,32
 168         clrldi  r7,r7,32
 169         clrldi  r8,r8,32
 170 15:
 171         slwi    r0,r0,4
 172         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 173         mtctr   r10
 174         bctrl                   /* Call handler */
 175
 176 syscall_exit:
 177         std     r3,RESULT(r1)
 178 #ifdef SHOW_SYSCALLS
 179         bl      .do_show_syscall_exit
 180         ld      r3,RESULT(r1)
 181 #endif
 182         clrrdi  r12,r1,THREAD_SHIFT
 183
 184         ld      r8,_MSR(r1)
 185 #ifdef CONFIG_PPC_BOOK3S
 186         /* No MSR:RI on BookE */
 187         andi.   r10,r8,MSR_RI
 188         beq-    unrecov_restore
 189 #endif
 190
 191         /* Disable interrupts so current_thread_info()->flags can't change,
 192          * and so that we don't get interrupted after loading SRR0/1.
 193          */
 194 #ifdef CONFIG_PPC_BOOK3E
 195         wrteei  0
 196 #else
 197         mfmsr   r10
 198         rldicl  r10,r10,48,1
 199         rotldi  r10,r10,16
 200         mtmsrd  r10,1
 201 #endif /* CONFIG_PPC_BOOK3E */
 202
 203         ld      r9,TI_FLAGS(r12)
 204         li      r11,-_LAST_ERRNO
 205         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 206         bne-    syscall_exit_work
 207         cmpld   r3,r11
 208         ld      r5,_CCR(r1)
 209         bge-    syscall_error
 210 syscall_error_cont:
 211         ld      r7,_NIP(r1)
 212 BEGIN_FTR_SECTION
 213         stdcx.  r0,0,r1                 /* to clear the reservation */
 214 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 215         andi.   r6,r8,MSR_PR
 216         ld      r4,_LINK(r1)
 217         /*
 218          * Clear RI before restoring r13.  If we are returning to
 219          * userspace and we take an exception after restoring r13,
 220          * we end up corrupting the userspace r13 value.
 221          */
 222 #ifdef CONFIG_PPC_BOOK3S
 223         /* No MSR:RI on BookE */
 224         li      r12,MSR_RI
 225         andc    r11,r10,r12
 226         mtmsrd  r11,1                   /* clear MSR.RI */
 227 #endif /* CONFIG_PPC_BOOK3S */
 228
 229         beq-    1f
 230         ACCOUNT_CPU_USER_EXIT(r11, r12)
 231         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 232 1:      ld      r2,GPR2(r1)
 233         ld      r1,GPR1(r1)
 234         mtlr    r4
 235         mtcr    r5
 236         mtspr   SPRN_SRR0,r7
 237         mtspr   SPRN_SRR1,r8
 238         RFI
 239         b       .       /* prevent speculative execution */
 240
 241 syscall_error:
 242         oris    r5,r5,0x1000    /* Set SO bit in CR */
 243         neg     r3,r3
 244         std     r5,_CCR(r1)
 245         b       syscall_error_cont
 246
 247 /* Traced system call support */
 248 syscall_dotrace:
 249         bl      .save_nvgprs
 250         addi    r3,r1,STACK_FRAME_OVERHEAD
 251         bl      .do_syscall_trace_enter
 252         /*
 253          * Restore argument registers possibly just changed.
 254          * We use the return value of do_syscall_trace_enter
 255          * for the call number to look up in the table (r0).
 256          */
 257         mr      r0,r3
 258         ld      r3,GPR3(r1)
 259         ld      r4,GPR4(r1)
 260         ld      r5,GPR5(r1)
 261         ld      r6,GPR6(r1)
 262         ld      r7,GPR7(r1)
 263         ld      r8,GPR8(r1)
 264         addi    r9,r1,STACK_FRAME_OVERHEAD
 265         clrrdi  r10,r1,THREAD_SHIFT
 266         ld      r10,TI_FLAGS(r10)
 267         b       syscall_dotrace_cont
 268
 269 syscall_enosys:
 270         li      r3,-ENOSYS
 271         b       syscall_exit
 272
 273 syscall_exit_work:
 274         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 275          If TIF_NOERROR is set, just save r3 as it is. */
 276
 277         andi.   r0,r9,_TIF_RESTOREALL
 278         beq+    0f
 279         REST_NVGPRS(r1)
 280         b       2f
 281 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 282         blt+    1f
 283         andi.   r0,r9,_TIF_NOERROR
 284         bne-    1f
 285         ld      r5,_CCR(r1)
 286         neg     r3,r3
 287         oris    r5,r5,0x1000    /* Set SO bit in CR */
 288         std     r5,_CCR(r1)
 289 1:      std     r3,GPR3(r1)
 290 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 291         beq     4f
 292
 293         /* Clear per-syscall TIF flags if any are set.  */
 294
 295         li      r11,_TIF_PERSYSCALL_MASK
 296         addi    r12,r12,TI_FLAGS
 297 3:      ldarx   r10,0,r12
 298         andc    r10,r10,r11
 299         stdcx.  r10,0,r12
 300         bne-    3b
 301         subi    r12,r12,TI_FLAGS
 302
 303 4:      /* Anything else left to do? */
 304         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 305         beq     .ret_from_except_lite
 306
 307         /* Re-enable interrupts */
 308 #ifdef CONFIG_PPC_BOOK3E
 309         wrteei  1
 310 #else
 311         mfmsr   r10
 312         ori     r10,r10,MSR_EE
 313         mtmsrd  r10,1
 314 #endif /* CONFIG_PPC_BOOK3E */
 315
 316         bl      .save_nvgprs
 317         addi    r3,r1,STACK_FRAME_OVERHEAD
 318         bl      .do_syscall_trace_leave
 319         b       .ret_from_except
 320
 321 /* Save non-volatile GPRs, if not already saved. */
 322 _GLOBAL(save_nvgprs)
 323         ld      r11,_TRAP(r1)
 324         andi.   r0,r11,1
 325         beqlr-
 326         SAVE_NVGPRS(r1)
 327         clrrdi  r0,r11,1
 328         std     r0,_TRAP(r1)
 329         blr
 330
 331
 332 /*
 333  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 334  * and thus put the process into the stopped state where we might
 335  * want to examine its user state with ptrace.  Therefore we need
 336  * to save all the nonvolatile registers (r14 - r31) before calling
 337  * the C code.  Similarly, fork, vfork and clone need the full
 338  * register state on the stack so that it can be copied to the child.
 339  */
 340
 341 _GLOBAL(ppc_fork)
 342         bl      .save_nvgprs
 343         bl      .sys_fork
 344         b       syscall_exit
 345
 346 _GLOBAL(ppc_vfork)
 347         bl      .save_nvgprs
 348         bl      .sys_vfork
 349         b       syscall_exit
 350
 351 _GLOBAL(ppc_clone)
 352         bl      .save_nvgprs
 353         bl      .sys_clone
 354         b       syscall_exit
 355
 356 _GLOBAL(ppc32_swapcontext)
 357         bl      .save_nvgprs
 358         bl      .compat_sys_swapcontext
 359         b       syscall_exit
 360
 361 _GLOBAL(ppc64_swapcontext)
 362         bl      .save_nvgprs
 363         bl      .sys_swapcontext
 364         b       syscall_exit
 365
 366 _GLOBAL(ret_from_fork)
 367         bl      .schedule_tail
 368         REST_NVGPRS(r1)
 369         li      r3,0
 370         b       syscall_exit
 371
 372 /*
 373  * This routine switches between two different tasks.  The process
 374  * state of one is saved on its kernel stack.  Then the state
 375  * of the other is restored from its kernel stack.  The memory
 376  * management hardware is updated to the second process's state.
 377  * Finally, we can return to the second process, via ret_from_except.
 378  * On entry, r3 points to the THREAD for the current task, r4
 379  * points to the THREAD for the new task.
 380  *
 381  * Note: there are two ways to get to the "going out" portion
 382  * of this code; either by coming in via the entry (_switch)
 383  * or via "fork" which must set up an environment equivalent
 384  * to the "_switch" path.  If you change this you'll have to change
 385  * the fork code also.
 386  *
 387  * The code which creates the new task context is in 'copy_thread'
 388  * in arch/powerpc/kernel/process.c
 389  */
 390         .align  7
 391 _GLOBAL(_switch)
 392         mflr    r0
 393         std     r0,16(r1)
 394         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 395         /* r3-r13 are caller saved -- Cort */
 396         SAVE_8GPRS(14, r1)
 397         SAVE_10GPRS(22, r1)
 398         mflr    r20             /* Return to switch caller */
 399         mfmsr   r22
 400         li      r0, MSR_FP
 401 #ifdef CONFIG_VSX
 402 BEGIN_FTR_SECTION
 403         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 404 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 405 #endif /* CONFIG_VSX */
 406 #ifdef CONFIG_ALTIVEC
 407 BEGIN_FTR_SECTION
 408         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 409         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 410         std     r24,THREAD_VRSAVE(r3)
 411 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 412 #endif /* CONFIG_ALTIVEC */
 413 #ifdef CONFIG_PPC64
 414 BEGIN_FTR_SECTION
 415         mfspr   r25,SPRN_DSCR
 416         std     r25,THREAD_DSCR(r3)
 417 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 418 #endif
 419         and.    r0,r0,r22
 420         beq+    1f
 421         andc    r22,r22,r0
 422         MTMSRD(r22)
 423         isync
 424 1:      std     r20,_NIP(r1)
 425         mfcr    r23
 426         std     r23,_CCR(r1)
 427         std     r1,KSP(r3)      /* Set old stack pointer */
 428
 429 #ifdef CONFIG_SMP
 430         /* We need a sync somewhere here to make sure that if the
 431          * previous task gets rescheduled on another CPU, it sees all
 432          * stores it has performed on this one.
 433          */
 434         sync
 435 #endif /* CONFIG_SMP */
 436
 437         /*
 438          * If we optimise away the clear of the reservation in system
 439          * calls because we know the CPU tracks the address of the
 440          * reservation, then we need to clear it here to cover the
 441          * case that the kernel context switch path has no larx
 442          * instructions.
 443          */
 444 BEGIN_FTR_SECTION
 445         ldarx   r6,0,r1
 446 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 447
 448         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 449         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 450
 451         ld      r8,KSP(r4)      /* new stack pointer */
 452 #ifdef CONFIG_PPC_BOOK3S
 453 BEGIN_FTR_SECTION
 454   BEGIN_FTR_SECTION_NESTED(95)
 455         clrrdi  r6,r8,28        /* get its ESID */
 456         clrrdi  r9,r1,28        /* get current sp ESID */
 457   FTR_SECTION_ELSE_NESTED(95)
 458         clrrdi  r6,r8,40        /* get its 1T ESID */
 459         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 460   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 461 FTR_SECTION_ELSE
 462         b       2f
 463 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 464         clrldi. r0,r6,2         /* is new ESID c00000000? */
 465         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 466         cror    eq,4*cr1+eq,eq
 467         beq     2f              /* if yes, don't slbie it */
 468
 469         /* Bolt in the new stack SLB entry */
 470         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 471         oris    r0,r6,(SLB_ESID_V)@h
 472         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 473 BEGIN_FTR_SECTION
 474         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 475         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 476         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 477 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 478
 479         /* Update the last bolted SLB.  No write barriers are needed
 480          * here, provided we only update the current CPU's SLB shadow
 481          * buffer.
 482          */
 483         ld      r9,PACA_SLBSHADOWPTR(r13)
 484         li      r12,0
 485         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 486         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 487         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 488
 489         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 490          * we have 1TB segments, the only CPUs known to have the errata
 491          * only support less than 1TB of system memory and we'll never
 492          * actually hit this code path.
 493          */
 494
 495         slbie   r6
 496         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 497         slbmte  r7,r0
 498         isync
 499 2:
 500 #endif /* !CONFIG_PPC_BOOK3S */
 501
 502         clrrdi  r7,r8,THREAD_SHIFT      /* base of new stack */
 503         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 504            because we don't need to leave the 288-byte ABI gap at the
 505            top of the kernel stack. */
 506         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 507
 508         mr      r1,r8           /* start using new stack pointer */
 509         std     r7,PACAKSAVE(r13)
 510
 511         ld      r6,_CCR(r1)
 512         mtcrf   0xFF,r6
 513
 514 #ifdef CONFIG_ALTIVEC
 515 BEGIN_FTR_SECTION
 516         ld      r0,THREAD_VRSAVE(r4)
 517         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 518 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 519 #endif /* CONFIG_ALTIVEC */
 520 #ifdef CONFIG_PPC64
 521 BEGIN_FTR_SECTION
 522         ld      r0,THREAD_DSCR(r4)
 523         cmpd    r0,r25
 524         beq     1f
 525         mtspr   SPRN_DSCR,r0
 526 1:
 527 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 528 #endif
 529
 530         /* r3-r13 are destroyed -- Cort */
 531         REST_8GPRS(14, r1)
 532         REST_10GPRS(22, r1)
 533
 534         /* convert old thread to its task_struct for return value */
 535         addi    r3,r3,-THREAD
 536         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 537         mtlr    r7
 538         addi    r1,r1,SWITCH_FRAME_SIZE
 539         blr
 540
 541         .align  7
 542 _GLOBAL(ret_from_except)
 543         ld      r11,_TRAP(r1)
 544         andi.   r0,r11,1
 545         bne     .ret_from_except_lite
 546         REST_NVGPRS(r1)
 547
 548 _GLOBAL(ret_from_except_lite)
 549         /*
 550          * Disable interrupts so that current_thread_info()->flags
 551          * can't change between when we test it and when we return
 552          * from the interrupt.
 553          */
 554 #ifdef CONFIG_PPC_BOOK3E
 555         wrteei  0
 556 #else
 557         mfmsr   r10             /* Get current interrupt state */
 558         rldicl  r9,r10,48,1     /* clear MSR_EE */
 559         rotldi  r9,r9,16
 560         mtmsrd  r9,1            /* Update machine state */
 561 #endif /* CONFIG_PPC_BOOK3E */
 562
 563 #ifdef CONFIG_PREEMPT
 564         clrrdi  r9,r1,THREAD_SHIFT      /* current_thread_info() */
 565         li      r0,_TIF_NEED_RESCHED    /* bits to check */
 566         ld      r3,_MSR(r1)
 567         ld      r4,TI_FLAGS(r9)
 568         /* Move MSR_PR bit in r3 to _TIF_SIGPENDING position in r0 */
 569         rlwimi  r0,r3,32+TIF_SIGPENDING-MSR_PR_LG,_TIF_SIGPENDING
 570         and.    r0,r4,r0        /* check NEED_RESCHED and maybe SIGPENDING */
 571         bne     do_work
 572
 573 #else /* !CONFIG_PREEMPT */
 574         ld      r3,_MSR(r1)     /* Returning to user mode? */
 575         andi.   r3,r3,MSR_PR
 576         beq     restore         /* if not, just restore regs and return */
 577
 578         /* Check current_thread_info()->flags */
 579         clrrdi  r9,r1,THREAD_SHIFT
 580         ld      r4,TI_FLAGS(r9)
 581         andi.   r0,r4,_TIF_USER_WORK_MASK
 582         bne     do_work
 583 #endif /* !CONFIG_PREEMPT */
 584
 585 restore:
 586         ld      r5,SOFTE(r1)
 587         TRACE_AND_RESTORE_IRQ(r5);
 588
 589         /* extract EE bit and use it to restore paca->hard_enabled */
 590         ld      r3,_MSR(r1)
 591         rldicl  r4,r3,49,63             /* r0 = (r3 >> 15) & 1 */
 592         stb     r4,PACAHARDIRQEN(r13)
 593
 594 #ifdef CONFIG_PPC_BOOK3E
 595         b       .exception_return_book3e
 596 #else
 597         ld      r4,_CTR(r1)
 598         ld      r0,_LINK(r1)
 599         mtctr   r4
 600         mtlr    r0
 601         ld      r4,_XER(r1)
 602         mtspr   SPRN_XER,r4
 603
 604         REST_8GPRS(5, r1)
 605
 606         andi.   r0,r3,MSR_RI
 607         beq-    unrecov_restore
 608
 609         /*
 610          * Clear the reservation. If we know the CPU tracks the address of
 611          * the reservation then we can potentially save some cycles and use
 612          * a larx. On POWER6 and POWER7 this is significantly faster.
 613          */
 614 BEGIN_FTR_SECTION
 615         stdcx.  r0,0,r1         /* to clear the reservation */
 616 FTR_SECTION_ELSE
 617         ldarx   r4,0,r1
 618 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 619
 620         /*
 621          * Clear RI before restoring r13.  If we are returning to
 622          * userspace and we take an exception after restoring r13,
 623          * we end up corrupting the userspace r13 value.
 624          */
 625         mfmsr   r4
 626         andc    r4,r4,r0        /* r0 contains MSR_RI here */
 627         mtmsrd  r4,1
 628
 629         /*
 630          * r13 is our per cpu area, only restore it if we are returning to
 631          * userspace
 632          */
 633         andi.   r0,r3,MSR_PR
 634         beq     1f
 635         ACCOUNT_CPU_USER_EXIT(r2, r4)
 636         REST_GPR(13, r1)
 637 1:
 638         mtspr   SPRN_SRR1,r3
 639
 640         ld      r2,_CCR(r1)
 641         mtcrf   0xFF,r2
 642         ld      r2,_NIP(r1)
 643         mtspr   SPRN_SRR0,r2
 644
 645         ld      r0,GPR0(r1)
 646         ld      r2,GPR2(r1)
 647         ld      r3,GPR3(r1)
 648         ld      r4,GPR4(r1)
 649         ld      r1,GPR1(r1)
 650
 651         rfid
 652         b       .       /* prevent speculative execution */
 653
 654 #endif /* CONFIG_PPC_BOOK3E */
 655
 656 do_work:
 657 #ifdef CONFIG_PREEMPT
 658         andi.   r0,r3,MSR_PR    /* Returning to user mode? */
 659         bne     user_work
 660         /* Check that preempt_count() == 0 and interrupts are enabled */
 661         lwz     r8,TI_PREEMPT(r9)
 662         cmpwi   cr1,r8,0
 663         ld      r0,SOFTE(r1)
 664         cmpdi   r0,0
 665         crandc  eq,cr1*4+eq,eq
 666         bne     restore
 667
 668         /* Here we are preempting the current task.
 669          *
 670          * Ensure interrupts are soft-disabled. We also properly mark
 671          * the PACA to reflect the fact that they are hard-disabled
 672          * and trace the change
 673          */
 674         li      r0,0
 675         stb     r0,PACASOFTIRQEN(r13)
 676         stb     r0,PACAHARDIRQEN(r13)
 677         TRACE_DISABLE_INTS
 678
 679         /* Call the scheduler with soft IRQs off */
 680 1:      bl      .preempt_schedule_irq
 681
 682         /* Hard-disable interrupts again (and update PACA) */
 683 #ifdef CONFIG_PPC_BOOK3E
 684         wrteei  0
 685 #else
 686         mfmsr   r10
 687         rldicl  r10,r10,48,1
 688         rotldi  r10,r10,16
 689         mtmsrd  r10,1
 690 #endif /* CONFIG_PPC_BOOK3E */
 691         li      r0,0
 692         stb     r0,PACAHARDIRQEN(r13)
 693
 694         /* Re-test flags and eventually loop */
 695         clrrdi  r9,r1,THREAD_SHIFT
 696         ld      r4,TI_FLAGS(r9)
 697         andi.   r0,r4,_TIF_NEED_RESCHED
 698         bne     1b
 699         b       restore
 700
 701 user_work:
 702 #endif /* CONFIG_PREEMPT */
 703
 704         /* Enable interrupts */
 705 #ifdef CONFIG_PPC_BOOK3E
 706         wrteei  1
 707 #else
 708         ori     r10,r10,MSR_EE
 709         mtmsrd  r10,1
 710 #endif /* CONFIG_PPC_BOOK3E */
 711
 712         andi.   r0,r4,_TIF_NEED_RESCHED
 713         beq     1f
 714         li      r5,1
 715         TRACE_AND_RESTORE_IRQ(r5);
 716         bl      .schedule
 717         b       .ret_from_except_lite
 718
 719 1:      bl      .save_nvgprs
 720         li      r5,1
 721         TRACE_AND_RESTORE_IRQ(r5);
 722         addi    r3,r1,STACK_FRAME_OVERHEAD
 723         bl      .do_notify_resume
 724         b       .ret_from_except
 725
 726 unrecov_restore:
 727         addi    r3,r1,STACK_FRAME_OVERHEAD
 728         bl      .unrecoverable_exception
 729         b       unrecov_restore
 730
 731 #ifdef CONFIG_PPC_RTAS
 732 /*
 733  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 734  * called with the MMU off.
 735  *
 736  * In addition, we need to be in 32b mode, at least for now.
 737  *
 738  * Note: r3 is an input parameter to rtas, so don't trash it...
 739  */
 740 _GLOBAL(enter_rtas)
 741         mflr    r0
 742         std     r0,16(r1)
 743         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 744
 745         /* Because RTAS is running in 32b mode, it clobbers the high order half
 746          * of all registers that it saves.  We therefore save those registers
 747          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 748          */
 749         SAVE_GPR(2, r1)                 /* Save the TOC */
 750         SAVE_GPR(13, r1)                /* Save paca */
 751         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 752         SAVE_10GPRS(22, r1)             /* ditto */
 753
 754         mfcr    r4
 755         std     r4,_CCR(r1)
 756         mfctr   r5
 757         std     r5,_CTR(r1)
 758         mfspr   r6,SPRN_XER
 759         std     r6,_XER(r1)
 760         mfdar   r7
 761         std     r7,_DAR(r1)
 762         mfdsisr r8
 763         std     r8,_DSISR(r1)
 764
 765         /* Temporary workaround to clear CR until RTAS can be modified to
 766          * ignore all bits.
 767          */
 768         li      r0,0
 769         mtcr    r0
 770
 771 #ifdef CONFIG_BUG
 772         /* There is no way it is acceptable to get here with interrupts enabled,
 773          * check it with the asm equivalent of WARN_ON
 774          */
 775         lbz     r0,PACASOFTIRQEN(r13)
 776 1:      tdnei   r0,0
 777         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 778 #endif
 779
 780         /* Hard-disable interrupts */
 781         mfmsr   r6
 782         rldicl  r7,r6,48,1
 783         rotldi  r7,r7,16
 784         mtmsrd  r7,1
 785
 786         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 787          * so they are saved in the PACA which allows us to restore
 788          * our original state after RTAS returns.
 789          */
 790         std     r1,PACAR1(r13)
 791         std     r6,PACASAVEDMSR(r13)
 792
 793         /* Setup our real return addr */
 794         LOAD_REG_ADDR(r4,.rtas_return_loc)
 795         clrldi  r4,r4,2                 /* convert to realmode address */
 796         mtlr    r4
 797
 798         li      r0,0
 799         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 800         andc    r0,r6,r0
 801
 802         li      r9,1
 803         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 804         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 805         andc    r6,r0,r9
 806         sync                            /* disable interrupts so SRR0/1 */
 807         mtmsrd  r0                      /* don't get trashed */
 808
 809         LOAD_REG_ADDR(r4, rtas)
 810         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 811         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 812
 813         mtspr   SPRN_SRR0,r5
 814         mtspr   SPRN_SRR1,r6
 815         rfid
 816         b       .       /* prevent speculative execution */
 817
 818 _STATIC(rtas_return_loc)
 819         /* relocation is off at this point */
 820         GET_PACA(r4)
 821         clrldi  r4,r4,2                 /* convert to realmode address */
 822
 823         bcl     20,31,$+4
 824 0:      mflr    r3
 825         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
 826
 827         mfmsr   r6
 828         li      r0,MSR_RI
 829         andc    r6,r6,r0
 830         sync
 831         mtmsrd  r6
 832
 833         ld      r1,PACAR1(r4)           /* Restore our SP */
 834         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 835
 836         mtspr   SPRN_SRR0,r3
 837         mtspr   SPRN_SRR1,r4
 838         rfid
 839         b       .       /* prevent speculative execution */
 840
 841         .align  3
 842 1:      .llong  .rtas_restore_regs
 843
 844 _STATIC(rtas_restore_regs)
 845         /* relocation is on at this point */
 846         REST_GPR(2, r1)                 /* Restore the TOC */
 847         REST_GPR(13, r1)                /* Restore paca */
 848         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 849         REST_10GPRS(22, r1)             /* ditto */
 850
 851         GET_PACA(r13)
 852
 853         ld      r4,_CCR(r1)
 854         mtcr    r4
 855         ld      r5,_CTR(r1)
 856         mtctr   r5
 857         ld      r6,_XER(r1)
 858         mtspr   SPRN_XER,r6
 859         ld      r7,_DAR(r1)
 860         mtdar   r7
 861         ld      r8,_DSISR(r1)
 862         mtdsisr r8
 863
 864         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 865         ld      r0,16(r1)               /* get return address */
 866
 867         mtlr    r0
 868         blr                             /* return to caller */
 869
 870 #endif /* CONFIG_PPC_RTAS */
 871
 872 _GLOBAL(enter_prom)
 873         mflr    r0
 874         std     r0,16(r1)
 875         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
 876
 877         /* Because PROM is running in 32b mode, it clobbers the high order half
 878          * of all registers that it saves.  We therefore save those registers
 879          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
 880          */
 881         SAVE_GPR(2, r1)
 882         SAVE_GPR(13, r1)
 883         SAVE_8GPRS(14, r1)
 884         SAVE_10GPRS(22, r1)
 885         mfcr    r10
 886         mfmsr   r11
 887         std     r10,_CCR(r1)
 888         std     r11,_MSR(r1)
 889
 890         /* Get the PROM entrypoint */
 891         mtlr    r4
 892
 893         /* Switch MSR to 32 bits mode
 894          */
 895 #ifdef CONFIG_PPC_BOOK3E
 896         rlwinm  r11,r11,0,1,31
 897         mtmsr   r11
 898 #else /* CONFIG_PPC_BOOK3E */
 899         mfmsr   r11
 900         li      r12,1
 901         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
 902         andc    r11,r11,r12
 903         li      r12,1
 904         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
 905         andc    r11,r11,r12
 906         mtmsrd  r11
 907 #endif /* CONFIG_PPC_BOOK3E */
 908         isync
 909
 910         /* Enter PROM here... */
 911         blrl
 912
 913         /* Just make sure that r1 top 32 bits didn't get
 914          * corrupt by OF
 915          */
 916         rldicl  r1,r1,0,32
 917
 918         /* Restore the MSR (back to 64 bits) */
 919         ld      r0,_MSR(r1)
 920         MTMSRD(r0)
 921         isync
 922
 923         /* Restore other registers */
 924         REST_GPR(2, r1)
 925         REST_GPR(13, r1)
 926         REST_8GPRS(14, r1)
 927         REST_10GPRS(22, r1)
 928         ld      r4,_CCR(r1)
 929         mtcr    r4
 930
 931         addi    r1,r1,PROM_FRAME_SIZE
 932         ld      r0,16(r1)
 933         mtlr    r0
 934         blr
 935
 936 #ifdef CONFIG_FUNCTION_TRACER
 937 #ifdef CONFIG_DYNAMIC_FTRACE
 938 _GLOBAL(mcount)
 939 _GLOBAL(_mcount)
 940         blr
 941
 942 _GLOBAL(ftrace_caller)
 943         /* Taken from output of objdump from lib64/glibc */
 944         mflr    r3
 945         ld      r11, 0(r1)
 946         stdu    r1, -112(r1)
 947         std     r3, 128(r1)
 948         ld      r4, 16(r11)
 949         subi    r3, r3, MCOUNT_INSN_SIZE
 950 .globl ftrace_call
 951 ftrace_call:
 952         bl      ftrace_stub
 953         nop
 954 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 955 .globl ftrace_graph_call
 956 ftrace_graph_call:
 957         b       ftrace_graph_stub
 958 _GLOBAL(ftrace_graph_stub)
 959 #endif
 960         ld      r0, 128(r1)
 961         mtlr    r0
 962         addi    r1, r1, 112
 963 _GLOBAL(ftrace_stub)
 964         blr
 965 #else
 966 _GLOBAL(mcount)
 967         blr
 968
 969 _GLOBAL(_mcount)
 970         /* Taken from output of objdump from lib64/glibc */
 971         mflr    r3
 972         ld      r11, 0(r1)
 973         stdu    r1, -112(r1)
 974         std     r3, 128(r1)
 975         ld      r4, 16(r11)
 976
 977         subi    r3, r3, MCOUNT_INSN_SIZE
 978         LOAD_REG_ADDR(r5,ftrace_trace_function)
 979         ld      r5,0(r5)
 980         ld      r5,0(r5)
 981         mtctr   r5
 982         bctrl
 983         nop
 984
 985
 986 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 987         b       ftrace_graph_caller
 988 #endif
 989         ld      r0, 128(r1)
 990         mtlr    r0
 991         addi    r1, r1, 112
 992 _GLOBAL(ftrace_stub)
 993         blr
 994
 995 #endif /* CONFIG_DYNAMIC_FTRACE */
 996
 997 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 998 _GLOBAL(ftrace_graph_caller)
 999         /* load r4 with local address */
1000         ld      r4, 128(r1)
1001         subi    r4, r4, MCOUNT_INSN_SIZE
1002
1003         /* get the parent address */
1004         ld      r11, 112(r1)
1005         addi    r3, r11, 16
1006
1007         bl      .prepare_ftrace_return
1008         nop
1009
1010         ld      r0, 128(r1)
1011         mtlr    r0
1012         addi    r1, r1, 112
1013         blr
1014
1015 _GLOBAL(return_to_handler)
1016         /* need to save return values */
1017         std     r4,  -24(r1)
1018         std     r3,  -16(r1)
1019         std     r31, -8(r1)
1020         mr      r31, r1
1021         stdu    r1, -112(r1)
1022
1023         bl      .ftrace_return_to_handler
1024         nop
1025
1026         /* return value has real return address */
1027         mtlr    r3
1028
1029         ld      r1, 0(r1)
1030         ld      r4,  -24(r1)
1031         ld      r3,  -16(r1)
1032         ld      r31, -8(r1)
1033
1034         /* Jump back to real return address */
1035         blr
1036
1037 _GLOBAL(mod_return_to_handler)
1038         /* need to save return values */
1039         std     r4,  -32(r1)
1040         std     r3,  -24(r1)
1041         /* save TOC */
1042         std     r2,  -16(r1)
1043         std     r31, -8(r1)
1044         mr      r31, r1
1045         stdu    r1, -112(r1)
1046
1047         /*
1048          * We are in a module using the module's TOC.
1049          * Switch to our TOC to run inside the core kernel.
1050          */
1051         ld      r2, PACATOC(r13)
1052
1053         bl      .ftrace_return_to_handler
1054         nop
1055
1056         /* return value has real return address */
1057         mtlr    r3
1058
1059         ld      r1, 0(r1)
1060         ld      r4,  -32(r1)
1061         ld      r3,  -24(r1)
1062         ld      r2,  -16(r1)
1063         ld      r31, -8(r1)
1064
1065         /* Jump back to real return address */
1066         blr
1067 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1068 #endif /* CONFIG_FUNCTION_TRACER */