arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   5  * Licensed under the GNU GPL.
   6  * thanks to Philipp Rumpf, Mike Shaver and various others
   7  * sorry about the wall, puffin..
   8  */
   9
  10 #include <asm/asm-offsets.h>
  11 #include <asm/unistd.h>
  12 #include <asm/errno.h>
  13 #include <asm/page.h>
  14 #include <asm/psw.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/assembly.h>
  17 #include <asm/processor.h>
  18
  19 #include <linux/linkage.h>
  20
  21         /* We fill the empty parts of the gateway page with
  22          * something that will kill the kernel or a
  23          * userspace application.
  24          */
  25 #define KILL_INSN       break   0,0
  26
  27         .level          LEVEL
  28
  29         .text
  30
  31         .import syscall_exit,code
  32         .import syscall_exit_rfi,code
  33
  34         /* Linux gateway page is aliased to virtual page 0 in the kernel
  35          * address space. Since it is a gateway page it cannot be
  36          * dereferenced, so null pointers will still fault. We start
  37          * the actual entry point at 0x100. We put break instructions
  38          * at the beginning of the page to trap null indirect function
  39          * pointers.
  40          */
  41
  42         .align PAGE_SIZE
  43 ENTRY(linux_gateway_page)
  44
  45         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  46         .rept 44
  47         KILL_INSN
  48         .endr
  49
  50         /* ADDRESS 0xb0 to 0xb8, lws uses two insns for entry */
  51         /* Light-weight-syscall entry must always be located at 0xb0 */
  52         /* WARNING: Keep this number updated with table size changes */
  53 #define __NR_lws_entries (2)
  54
  55 lws_entry:
  56         gate    lws_start, %r0          /* increase privilege */
  57         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  58
  59         /* Fill from 0xb8 to 0xe0 */
  60         .rept 10
  61         KILL_INSN
  62         .endr
  63
  64         /* This function MUST be located at 0xe0 for glibc's threading
  65         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  66 set_thread_pointer:
  67         gate    .+8, %r0                /* increase privilege */
  68         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  69         be      0(%sr7,%r31)            /* return to user space */
  70         mtctl   %r26, %cr27             /* move arg0 to the control register */
  71
  72         /* Increase the chance of trapping if random jumps occur to this
  73         address, fill from 0xf0 to 0x100 */
  74         .rept 4
  75         KILL_INSN
  76         .endr
  77
  78 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
  79         .align 256
  80 linux_gateway_entry:
  81         gate    .+8, %r0                        /* become privileged */
  82         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
  83         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
  84         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
  85
  86 #ifdef CONFIG_64BIT
  87         /* for now we can *always* set the W bit on entry to the syscall
  88          * since we don't support wide userland processes.  We could
  89          * also save the current SM other than in r0 and restore it on
  90          * exit from the syscall, and also use that value to know
  91          * whether to do narrow or wide syscalls. -PB
  92          */
  93         ssm     PSW_SM_W, %r1
  94         extrd,u %r1,PSW_W_BIT,1,%r1
  95         /* sp must be aligned on 4, so deposit the W bit setting into
  96          * the bottom of sp temporarily */
  97         or,ev   %r1,%r30,%r30
  98         b,n     1f
  99         /* The top halves of argument registers must be cleared on syscall
 100          * entry from narrow executable.
 101          */
 102         depdi   0, 31, 32, %r26
 103         depdi   0, 31, 32, %r25
 104         depdi   0, 31, 32, %r24
 105         depdi   0, 31, 32, %r23
 106         depdi   0, 31, 32, %r22
 107         depdi   0, 31, 32, %r21
 108 1:
 109 #endif
 110
 111         /* We use a rsm/ssm pair to prevent sr3 from being clobbered
 112          * by external interrupts.
 113          */
 114         mfsp    %sr7,%r1                        /* save user sr7 */
 115         rsm     PSW_SM_I, %r0                   /* disable interrupts */
 116         mtsp    %r1,%sr3                        /* and store it in sr3 */
 117
 118         mfctl   %cr30,%r1
 119         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 120         xor     %r1,%r30,%r1
 121         xor     %r1,%r30,%r30
 122
 123         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 124
 125         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 126          *       contains a valid kernel stack pointer. It is also
 127          *       critical that we don't start using the kernel stack
 128          *       until after sr7 has been set to 0.
 129          */
 130
 131         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 132         ssm     PSW_SM_I, %r0                   /* enable interrupts */
 133         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 134         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 135         LDREG   TI_TASK(%r1),%r1
 136
 137         /* Save some registers for sigcontext and potential task
 138            switch (see entry.S for the details of which ones are
 139            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 140            a process is on a syscall or not.  For an interrupt the real
 141            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 142         STREG   %r0,  TASK_PT_PSW(%r1)
 143         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 144         STREG   %r19, TASK_PT_GR19(%r1)
 145
 146         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 147 #ifdef CONFIG_64BIT
 148         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 149 #if 0
 150         xor     %r19,%r2,%r2                    /* clear bottom bit */
 151         depd,z  %r19,1,1,%r19
 152         std     %r19,TASK_PT_PSW(%r1)
 153 #endif
 154 #endif
 155         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 156
 157         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 158         STREG   %r21, TASK_PT_GR21(%r1)
 159         STREG   %r22, TASK_PT_GR22(%r1)
 160         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 161         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 162         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 163         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 164         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 165         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 166         STREG   %r28, TASK_PT_ORIG_R28(%r1)     /* return value 0 (saved for signals) */
 167         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 168         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 169
 170         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 171         save_fp %r27                            /* or potential task switch  */
 172
 173         mfctl   %cr11, %r27                     /* i.e. SAR */
 174         STREG   %r27, TASK_PT_SAR(%r1)
 175
 176         loadgp
 177
 178 #ifdef CONFIG_64BIT
 179         ldo     -16(%r30),%r29                  /* Reference param save area */
 180         copy    %r19,%r2                        /* W bit back to r2 */
 181 #else
 182         /* no need to save these on stack in wide mode because the first 8
 183          * args are passed in registers */
 184         stw     %r22, -52(%r30)                 /* 5th argument */
 185         stw     %r21, -56(%r30)                 /* 6th argument */
 186 #endif
 187
 188         /* Are we being ptraced? */
 189         mfctl   %cr30, %r1
 190         LDREG   TI_TASK(%r1),%r1
 191         ldw     TASK_PTRACE(%r1), %r1
 192         bb,<,n  %r1,31,.Ltracesys
 193
 194         /* Note!  We cannot use the syscall table that is mapped
 195         nearby since the gateway page is mapped execute-only. */
 196
 197 #ifdef CONFIG_64BIT
 198         ldil    L%sys_call_table, %r1
 199         or,=    %r2,%r2,%r2
 200         addil   L%(sys_call_table64-sys_call_table), %r1
 201         ldo     R%sys_call_table(%r1), %r19
 202         or,=    %r2,%r2,%r2
 203         ldo     R%sys_call_table64(%r1), %r19
 204 #else
 205         ldil    L%sys_call_table, %r1
 206         ldo     R%sys_call_table(%r1), %r19
 207 #endif
 208         comiclr,>>      __NR_Linux_syscalls, %r20, %r0
 209         b,n     .Lsyscall_nosys
 210
 211         LDREGX  %r20(%r19), %r19
 212
 213         /* If this is a sys_rt_sigreturn call, and the signal was received
 214          * when not in_syscall, then we want to return via syscall_exit_rfi,
 215          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 216          * trampoline code in signal.c).
 217          */
 218         ldi     __NR_rt_sigreturn,%r2
 219         comb,=  %r2,%r20,.Lrt_sigreturn
 220 .Lin_syscall:
 221         ldil    L%syscall_exit,%r2
 222         be      0(%sr7,%r19)
 223         ldo     R%syscall_exit(%r2),%r2
 224 .Lrt_sigreturn:
 225         comib,<> 0,%r25,.Lin_syscall
 226         ldil    L%syscall_exit_rfi,%r2
 227         be      0(%sr7,%r19)
 228         ldo     R%syscall_exit_rfi(%r2),%r2
 229
 230         /* Note!  Because we are not running where we were linked, any
 231         calls to functions external to this file must be indirect.  To
 232         be safe, we apply the opposite rule to functions within this
 233         file, with local labels given to them to ensure correctness. */
 234
 235 .Lsyscall_nosys:
 236 syscall_nosys:
 237         ldil    L%syscall_exit,%r1
 238         be      R%syscall_exit(%sr7,%r1)
 239         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 240
 241
 242 /* Warning! This trace code is a virtual duplicate of the code above so be
 243  * sure to maintain both! */
 244 .Ltracesys:
 245 tracesys:
 246         /* Need to save more registers so the debugger can see where we
 247          * are.  This saves only the lower 8 bits of PSW, so that the C
 248          * bit is still clear on syscalls, and the D bit is set if this
 249          * full register save path has been executed.  We check the D
 250          * bit on syscall_return_rfi to determine which registers to
 251          * restore.  An interrupt results in a full PSW saved with the
 252          * C bit set, a non-straced syscall entry results in C and D clear
 253          * in the saved PSW.
 254          */
 255         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 256         LDREG   TI_TASK(%r1), %r1
 257         ssm     0,%r2
 258         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 259         mfsp    %sr0,%r2
 260         STREG   %r2,TASK_PT_SR0(%r1)
 261         mfsp    %sr1,%r2
 262         STREG   %r2,TASK_PT_SR1(%r1)
 263         mfsp    %sr2,%r2
 264         STREG   %r2,TASK_PT_SR2(%r1)
 265         mfsp    %sr3,%r2
 266         STREG   %r2,TASK_PT_SR3(%r1)
 267         STREG   %r2,TASK_PT_SR4(%r1)
 268         STREG   %r2,TASK_PT_SR5(%r1)
 269         STREG   %r2,TASK_PT_SR6(%r1)
 270         STREG   %r2,TASK_PT_SR7(%r1)
 271         STREG   %r2,TASK_PT_IASQ0(%r1)
 272         STREG   %r2,TASK_PT_IASQ1(%r1)
 273         LDREG   TASK_PT_GR31(%r1),%r2
 274         STREG   %r2,TASK_PT_IAOQ0(%r1)
 275         ldo     4(%r2),%r2
 276         STREG   %r2,TASK_PT_IAOQ1(%r1)
 277         ldo     TASK_REGS(%r1),%r2
 278         /* reg_save %r2 */
 279         STREG   %r3,PT_GR3(%r2)
 280         STREG   %r4,PT_GR4(%r2)
 281         STREG   %r5,PT_GR5(%r2)
 282         STREG   %r6,PT_GR6(%r2)
 283         STREG   %r7,PT_GR7(%r2)
 284         STREG   %r8,PT_GR8(%r2)
 285         STREG   %r9,PT_GR9(%r2)
 286         STREG   %r10,PT_GR10(%r2)
 287         STREG   %r11,PT_GR11(%r2)
 288         STREG   %r12,PT_GR12(%r2)
 289         STREG   %r13,PT_GR13(%r2)
 290         STREG   %r14,PT_GR14(%r2)
 291         STREG   %r15,PT_GR15(%r2)
 292         STREG   %r16,PT_GR16(%r2)
 293         STREG   %r17,PT_GR17(%r2)
 294         STREG   %r18,PT_GR18(%r2)
 295         /* Finished saving things for the debugger */
 296
 297         copy    %r2,%r26
 298         ldil    L%do_syscall_trace_enter,%r1
 299         ldil    L%tracesys_next,%r2
 300         be      R%do_syscall_trace_enter(%sr7,%r1)
 301         ldo     R%tracesys_next(%r2),%r2
 302
 303 tracesys_next:
 304         /* do_syscall_trace_enter either returned the syscallno, or -1L,
 305          *  so we skip restoring the PT_GR20 below, since we pulled it from
 306          *  task->thread.regs.gr[20] above.
 307          */
 308         copy    %ret0,%r20
 309         ldil    L%sys_call_table,%r1
 310         ldo     R%sys_call_table(%r1), %r19
 311
 312         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 313         LDREG   TI_TASK(%r1), %r1
 314         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 315         LDREG   TASK_PT_GR25(%r1), %r25
 316         LDREG   TASK_PT_GR24(%r1), %r24
 317         LDREG   TASK_PT_GR23(%r1), %r23
 318 #ifdef CONFIG_64BIT
 319         LDREG   TASK_PT_GR22(%r1), %r22
 320         LDREG   TASK_PT_GR21(%r1), %r21
 321         ldo     -16(%r30),%r29                  /* Reference param save area */
 322 #endif
 323
 324         comiclr,>>      __NR_Linux_syscalls, %r20, %r0
 325         b,n     .Lsyscall_nosys
 326
 327         LDREGX  %r20(%r19), %r19
 328
 329         /* If this is a sys_rt_sigreturn call, and the signal was received
 330          * when not in_syscall, then we want to return via syscall_exit_rfi,
 331          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 332          * trampoline code in signal.c).
 333          */
 334         ldi     __NR_rt_sigreturn,%r2
 335         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 336 .Ltrace_in_syscall:
 337         ldil    L%tracesys_exit,%r2
 338         be      0(%sr7,%r19)
 339         ldo     R%tracesys_exit(%r2),%r2
 340
 341         /* Do *not* call this function on the gateway page, because it
 342         makes a direct call to syscall_trace. */
 343
 344 tracesys_exit:
 345         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 346         LDREG   TI_TASK(%r1), %r1
 347 #ifdef CONFIG_64BIT
 348         ldo     -16(%r30),%r29                  /* Reference param save area */
 349 #endif
 350         ldo     TASK_REGS(%r1),%r26
 351         bl      do_syscall_trace_exit,%r2
 352         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 353         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 354         LDREG   TI_TASK(%r1), %r1
 355         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 356
 357         ldil    L%syscall_exit,%r1
 358         be,n    R%syscall_exit(%sr7,%r1)
 359
 360 .Ltrace_rt_sigreturn:
 361         comib,<> 0,%r25,.Ltrace_in_syscall
 362         ldil    L%tracesys_sigexit,%r2
 363         be      0(%sr7,%r19)
 364         ldo     R%tracesys_sigexit(%r2),%r2
 365
 366 tracesys_sigexit:
 367         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 368         LDREG   TI_TASK(%r1), %r1
 369 #ifdef CONFIG_64BIT
 370         ldo     -16(%r30),%r29                  /* Reference param save area */
 371 #endif
 372         bl      do_syscall_trace_exit,%r2
 373         ldo     TASK_REGS(%r1),%r26
 374
 375         ldil    L%syscall_exit_rfi,%r1
 376         be,n    R%syscall_exit_rfi(%sr7,%r1)
 377
 378
 379         /*********************************************************
 380                 32/64-bit Light-Weight-Syscall ABI
 381
 382                 * - Indicates a hint for userspace inline asm
 383                 implementations.
 384
 385                 Syscall number (caller-saves)
 386                 - %r20
 387                 * In asm clobber.
 388
 389                 Argument registers (caller-saves)
 390                 - %r26, %r25, %r24, %r23, %r22
 391                 * In asm input.
 392
 393                 Return registers (caller-saves)
 394                 - %r28 (return), %r21 (errno)
 395                 * In asm output.
 396
 397                 Caller-saves registers
 398                 - %r1, %r27, %r29
 399                 - %r2 (return pointer)
 400                 - %r31 (ble link register)
 401                 * In asm clobber.
 402
 403                 Callee-saves registers
 404                 - %r3-%r18
 405                 - %r30 (stack pointer)
 406                 * Not in asm clobber.
 407
 408                 If userspace is 32-bit:
 409                 Callee-saves registers
 410                 - %r19 (32-bit PIC register)
 411
 412                 Differences from 32-bit calling convention:
 413                 - Syscall number in %r20
 414                 - Additional argument register %r22 (arg4)
 415                 - Callee-saves %r19.
 416
 417                 If userspace is 64-bit:
 418                 Callee-saves registers
 419                 - %r27 (64-bit PIC register)
 420
 421                 Differences from 64-bit calling convention:
 422                 - Syscall number in %r20
 423                 - Additional argument register %r22 (arg4)
 424                 - Callee-saves %r27.
 425
 426                 Error codes returned by entry path:
 427
 428                 ENOSYS - r20 was an invalid LWS number.
 429
 430         *********************************************************/
 431 lws_start:
 432
 433 #ifdef CONFIG_64BIT
 434         /* FIXME: If we are a 64-bit kernel just
 435          *        turn this on unconditionally.
 436          */
 437         ssm     PSW_SM_W, %r1
 438         extrd,u %r1,PSW_W_BIT,1,%r1
 439         /* sp must be aligned on 4, so deposit the W bit setting into
 440          * the bottom of sp temporarily */
 441         or,ev   %r1,%r30,%r30
 442
 443         /* Clip LWS number to a 32-bit value always */
 444         depdi   0, 31, 32, %r20
 445 #endif
 446
 447         /* Is the lws entry number valid? */
 448         comiclr,>>      __NR_lws_entries, %r20, %r0
 449         b,n     lws_exit_nosys
 450
 451         /* WARNING: Trashing sr2 and sr3 */
 452         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 453         mtsp    %r1,%sr3
 454         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 455
 456         /* Load table start */
 457         ldil    L%lws_table, %r1
 458         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 459         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 460
 461         /* Jump to lws, lws table pointers already relocated */
 462         be,n    0(%sr2,%r21)
 463
 464 lws_exit_nosys:
 465         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 466         /* Fall through: Return to userspace */
 467
 468 lws_exit:
 469 #ifdef CONFIG_64BIT
 470         /* decide whether to reset the wide mode bit
 471          *
 472          * For a syscall, the W bit is stored in the lowest bit
 473          * of sp.  Extract it and reset W if it is zero */
 474         extrd,u,*<>     %r30,63,1,%r1
 475         rsm     PSW_SM_W, %r0
 476         /* now reset the lowest bit of sp if it was set */
 477         xor     %r30,%r1,%r30
 478 #endif
 479         be,n    0(%sr7, %r31)
 480
 481
 482
 483         /***************************************************
 484                 Implementing CAS as an atomic operation:
 485
 486                 %r26 - Address to examine
 487                 %r25 - Old value to check (old)
 488                 %r24 - New value to set (new)
 489                 %r28 - Return prev through this register.
 490                 %r21 - Kernel error code
 491
 492                 If debugging is DISabled:
 493
 494                 %r21 has the following meanings:
 495
 496                 EAGAIN - CAS is busy, ldcw failed, try again.
 497                 EFAULT - Read or write failed.
 498
 499                 If debugging is enabled:
 500
 501                 EDEADLOCK - CAS called recursively.
 502                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 503                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 504                 EFAULT - Read or write failed.
 505
 506                 Scratch: r20, r28, r1
 507
 508         ****************************************************/
 509
 510         /* Do not enable LWS debugging */
 511 #define ENABLE_LWS_DEBUG 0
 512
 513         /* ELF64 Process entry path */
 514 lws_compare_and_swap64:
 515 #ifdef CONFIG_64BIT
 516         b,n     lws_compare_and_swap
 517 #else
 518         /* If we are not a 64-bit kernel, then we don't
 519          * have 64-bit input registers, and calling
 520          * the 64-bit LWS CAS returns ENOSYS.
 521          */
 522         b,n     lws_exit_nosys
 523 #endif
 524
 525         /* ELF32 Process entry path */
 526 lws_compare_and_swap32:
 527 #ifdef CONFIG_64BIT
 528         /* Clip all the input registers */
 529         depdi   0, 31, 32, %r26
 530         depdi   0, 31, 32, %r25
 531         depdi   0, 31, 32, %r24
 532 #endif
 533
 534 lws_compare_and_swap:
 535         /* Load start of lock table */
 536         ldil    L%lws_lock_start, %r20
 537         ldo     R%lws_lock_start(%r20), %r28
 538
 539         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 540         extru  %r26, 27, 4, %r20
 541
 542         /* Find lock to use, the hash is either one of 0 to
 543            15, multiplied by 16 (keep it 16-byte aligned)
 544            and add to the lock table offset. */
 545         shlw    %r20, 4, %r20
 546         add     %r20, %r28, %r20
 547
 548 # if ENABLE_LWS_DEBUG
 549         /*
 550                 DEBUG, check for deadlock!
 551                 If the thread register values are the same
 552                 then we were the one that locked it last and
 553                 this is a recurisve call that will deadlock.
 554                 We *must* giveup this call and fail.
 555         */
 556         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 557         /* WARNING: If cr27 cycles to the same value we have problems */
 558         mfctl   %cr27, %r21                             /* Get current thread register */
 559         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 560         b       lws_exit                                /* Return error! */
 561         ldo     -EDEADLOCK(%r0), %r21
 562 cas_lock:
 563         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 564         ldo     1(%r0), %r28                            /* 1st case */
 565         b       lws_exit                                /* Contended... */
 566         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 567 cas_nocontend:
 568 # endif
 569 /* ENABLE_LWS_DEBUG */
 570
 571         LDCW    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 572         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 573 cas_wouldblock:
 574         ldo     2(%r0), %r28                            /* 2nd case */
 575         b       lws_exit                                /* Contended... */
 576         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 577
 578         /*
 579                 prev = *addr;
 580                 if ( prev == old )
 581                   *addr = new;
 582                 return prev;
 583         */
 584
 585         /* NOTES:
 586                 This all works becuse intr_do_signal
 587                 and schedule both check the return iasq
 588                 and see that we are on the kernel page
 589                 so this process is never scheduled off
 590                 or is ever sent any signal of any sort,
 591                 thus it is wholly atomic from usrspaces
 592                 perspective
 593         */
 594 cas_action:
 595 #if defined CONFIG_SMP && ENABLE_LWS_DEBUG
 596         /* DEBUG */
 597         mfctl   %cr27, %r1
 598         stw     %r1, 4(%sr2,%r20)
 599 #endif
 600         /* The load and store could fail */
 601 1:      ldw     0(%sr3,%r26), %r28
 602         sub,<>  %r28, %r25, %r0
 603 2:      stw     %r24, 0(%sr3,%r26)
 604         /* Free lock */
 605         stw     %r20, 0(%sr2,%r20)
 606 #if ENABLE_LWS_DEBUG
 607         /* Clear thread register indicator */
 608         stw     %r0, 4(%sr2,%r20)
 609 #endif
 610         /* Return to userspace, set no error */
 611         b       lws_exit
 612         copy    %r0, %r21
 613
 614 3:
 615         /* Error occurred on load or store */
 616         /* Free lock */
 617         stw     %r20, 0(%sr2,%r20)
 618 #if ENABLE_LWS_DEBUG
 619         stw     %r0, 4(%sr2,%r20)
 620 #endif
 621         b       lws_exit
 622         ldo     -EFAULT(%r0),%r21       /* set errno */
 623         nop
 624         nop
 625         nop
 626         nop
 627
 628         /* Two exception table entries, one for the load,
 629            the other for the store. Either return -EFAULT.
 630            Each of the entries must be relocated. */
 631         .section __ex_table,"aw"
 632         ASM_ULONG_INSN (1b - linux_gateway_page), (3b - linux_gateway_page)
 633         ASM_ULONG_INSN (2b - linux_gateway_page), (3b - linux_gateway_page)
 634         .previous
 635
 636
 637         /* Make sure nothing else is placed on this page */
 638         .align PAGE_SIZE
 639 END(linux_gateway_page)
 640 ENTRY(end_linux_gateway_page)
 641
 642         /* Relocate symbols assuming linux_gateway_page is mapped
 643            to virtual address 0x0 */
 644
 645 #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page)
 646
 647         .section .rodata,"a"
 648
 649         .align PAGE_SIZE
 650         /* Light-weight-syscall table */
 651         /* Start of lws table. */
 652 ENTRY(lws_table)
 653         LWS_ENTRY(compare_and_swap32)   /* 0 - ELF32 Atomic compare and swap */
 654         LWS_ENTRY(compare_and_swap64)   /* 1 - ELF64 Atomic compare and swap */
 655 END(lws_table)
 656         /* End of lws table */
 657
 658         .align PAGE_SIZE
 659 ENTRY(sys_call_table)
 660 #include "syscall_table.S"
 661 END(sys_call_table)
 662
 663 #ifdef CONFIG_64BIT
 664         .align PAGE_SIZE
 665 ENTRY(sys_call_table64)
 666 #define SYSCALL_TABLE_64BIT
 667 #include "syscall_table.S"
 668 END(sys_call_table64)
 669 #endif
 670
 671         /*
 672                 All light-weight-syscall atomic operations
 673                 will use this set of locks
 674
 675                 NOTE: The lws_lock_start symbol must be
 676                 at least 16-byte aligned for safe use
 677                 with ldcw.
 678         */
 679         .section .data
 680         .align  PAGE_SIZE
 681 ENTRY(lws_lock_start)
 682         /* lws locks */
 683         .rept 16
 684         /* Keep locks aligned at 16-bytes */
 685         .word 1
 686         .word 0
 687         .word 0
 688         .word 0
 689         .endr
 690 END(lws_lock_start)
 691         .previous
 692
 693 .end
 694
 695