arch/ia64/kernel/gate.S

   1 /*
   2  * This file contains the code that gets mapped at the upper end of each task's text
   3  * region.  For now, it contains the signal trampoline code only.
   4  *
   5  * Copyright (C) 1999-2003 Hewlett-Packard Co
   6  *      David Mosberger-Tang <davidm@hpl.hp.com>
   7  */
   8
   9 #include <linux/config.h>
  10
  11 #include <asm/asmmacro.h>
  12 #include <asm/errno.h>
  13 #include <asm/offsets.h>
  14 #include <asm/sigcontext.h>
  15 #include <asm/system.h>
  16 #include <asm/unistd.h>
  17
  18 /*
  19  * We can't easily refer to symbols inside the kernel.  To avoid full runtime relocation,
  20  * complications with the linker (which likes to create PLT stubs for branches
  21  * to targets outside the shared object) and to avoid multi-phase kernel builds, we
  22  * simply create minimalistic "patch lists" in special ELF sections.
  23  */
  24         .section ".data.patch.fsyscall_table", "a"
  25         .previous
  26 #define LOAD_FSYSCALL_TABLE(reg)                        \
  27 [1:]    movl reg=0;                                     \
  28         .xdata4 ".data.patch.fsyscall_table", 1b-.
  29
  30         .section ".data.patch.brl_fsys_bubble_down", "a"
  31         .previous
  32 #define BRL_COND_FSYS_BUBBLE_DOWN(pr)                   \
  33 [1:](pr)brl.cond.sptk 0;                                \
  34         .xdata4 ".data.patch.brl_fsys_bubble_down", 1b-.
  35
  36 GLOBAL_ENTRY(__kernel_syscall_via_break)
  37         .prologue
  38         .altrp b6
  39         .body
  40         /*
  41          * Note: for (fast) syscall restart to work, the break instruction must be
  42          *       the first one in the bundle addressed by syscall_via_break.
  43          */
  44 { .mib
  45         break 0x100000
  46         nop.i 0
  47         br.ret.sptk.many b6
  48 }
  49 END(__kernel_syscall_via_break)
  50
  51 /*
  52  * On entry:
  53  *      r11 = saved ar.pfs
  54  *      r15 = system call #
  55  *      b0  = saved return address
  56  *      b6  = return address
  57  * On exit:
  58  *      r11 = saved ar.pfs
  59  *      r15 = system call #
  60  *      b0  = saved return address
  61  *      all other "scratch" registers:  undefined
  62  *      all "preserved" registers:      same as on entry
  63  */
  64
  65 GLOBAL_ENTRY(__kernel_syscall_via_epc)
  66         .prologue
  67         .altrp b6
  68         .body
  69 {
  70         /*
  71          * Note: the kernel cannot assume that the first two instructions in this
  72          * bundle get executed.  The remaining code must be safe even if
  73          * they do not get executed.
  74          */
  75         adds r17=-1024,r15                      // A
  76         mov r10=0                               // A    default to successful syscall execution
  77         epc                                     // B    causes split-issue
  78 }
  79         ;;
  80         rsm psr.be                              // M2 (5 cyc to srlz.d)
  81         LOAD_FSYSCALL_TABLE(r14)                // X
  82         ;;
  83         mov r16=IA64_KR(CURRENT)                // M2 (12 cyc)
  84         shladd r18=r17,3,r14                    // A
  85         mov r19=NR_syscalls-1                   // A
  86         ;;
  87         lfetch [r18]                            // M0|1
  88         mov r29=psr                             // M2 (12 cyc)
  89         // If r17 is a NaT, p6 will be zero
  90         cmp.geu p6,p7=r19,r17                   // A    (sysnr > 0 && sysnr < 1024+NR_syscalls)?
  91         ;;
  92         mov r21=ar.fpsr                         // M2 (12 cyc)
  93         tnat.nz p10,p9=r15                      // I0
  94         mov.i r26=ar.pfs                        // I0 (would stall anyhow due to srlz.d...)
  95         ;;
  96         srlz.d                                  // M0 (forces split-issue) ensure PSR.BE==0
  97 (p6)    ld8 r18=[r18]                           // M0|1
  98         nop.i 0
  99         ;;
 100         nop.m 0
 101 (p6)    mov b7=r18                              // I0
 102 (p6)    tbit.z.unc p8,p0=r18,0                  // I0 (dual-issues with "mov b7=r18"!)
 103
 104         nop.m 0
 105         nop.i 0
 106 (p8)    br.dptk.many b7                         // B
 107
 108         mov r27=ar.rsc                          // M2 (12 cyc)
 109 (p6)    rsm psr.i                               // M2
 110 /*
 111  * brl.cond doesn't work as intended because the linker would convert this branch
 112  * into a branch to a PLT.  Perhaps there will be a way to avoid this with some
 113  * future version of the linker.  In the meantime, we just use an indirect branch
 114  * instead.
 115  */
 116 #ifdef CONFIG_ITANIUM
 117 (p6)    add r14=-8,r14                          // r14 <- addr of fsys_bubble_down entry
 118         ;;
 119 (p6)    ld8 r14=[r14]                           // r14 <- fsys_bubble_down
 120         ;;
 121 (p6)    mov b7=r14
 122 (p6)    br.sptk.many b7
 123 #else
 124         BRL_COND_FSYS_BUBBLE_DOWN(p6)
 125 #endif
 126
 127         mov r10=-1
 128 (p10)   mov r8=EINVAL
 129 (p9)    mov r8=ENOSYS
 130         FSYS_RETURN
 131 END(__kernel_syscall_via_epc)
 132
 133 #       define ARG0_OFF         (16 + IA64_SIGFRAME_ARG0_OFFSET)
 134 #       define ARG1_OFF         (16 + IA64_SIGFRAME_ARG1_OFFSET)
 135 #       define ARG2_OFF         (16 + IA64_SIGFRAME_ARG2_OFFSET)
 136 #       define SIGHANDLER_OFF   (16 + IA64_SIGFRAME_HANDLER_OFFSET)
 137 #       define SIGCONTEXT_OFF   (16 + IA64_SIGFRAME_SIGCONTEXT_OFFSET)
 138
 139 #       define FLAGS_OFF        IA64_SIGCONTEXT_FLAGS_OFFSET
 140 #       define CFM_OFF          IA64_SIGCONTEXT_CFM_OFFSET
 141 #       define FR6_OFF          IA64_SIGCONTEXT_FR6_OFFSET
 142 #       define BSP_OFF          IA64_SIGCONTEXT_AR_BSP_OFFSET
 143 #       define RNAT_OFF         IA64_SIGCONTEXT_AR_RNAT_OFFSET
 144 #       define UNAT_OFF         IA64_SIGCONTEXT_AR_UNAT_OFFSET
 145 #       define FPSR_OFF         IA64_SIGCONTEXT_AR_FPSR_OFFSET
 146 #       define PR_OFF           IA64_SIGCONTEXT_PR_OFFSET
 147 #       define RP_OFF           IA64_SIGCONTEXT_IP_OFFSET
 148 #       define SP_OFF           IA64_SIGCONTEXT_R12_OFFSET
 149 #       define RBS_BASE_OFF     IA64_SIGCONTEXT_RBS_BASE_OFFSET
 150 #       define LOADRS_OFF       IA64_SIGCONTEXT_LOADRS_OFFSET
 151 #       define base0            r2
 152 #       define base1            r3
 153         /*
 154          * When we get here, the memory stack looks like this:
 155          *
 156          *   +===============================+
 157          *   |                               |
 158          *   //     struct sigframe          //
 159          *   |                               |
 160          *   +-------------------------------+ <-- sp+16
 161          *   |      16 byte of scratch       |
 162          *   |            space              |
 163          *   +-------------------------------+ <-- sp
 164          *
 165          * The register stack looks _exactly_ the way it looked at the time the signal
 166          * occurred.  In other words, we're treading on a potential mine-field: each
 167          * incoming general register may be a NaT value (including sp, in which case the
 168          * process ends up dying with a SIGSEGV).
 169          *
 170          * The first thing need to do is a cover to get the registers onto the backing
 171          * store.  Once that is done, we invoke the signal handler which may modify some
 172          * of the machine state.  After returning from the signal handler, we return
 173          * control to the previous context by executing a sigreturn system call.  A signal
 174          * handler may call the rt_sigreturn() function to directly return to a given
 175          * sigcontext.  However, the user-level sigreturn() needs to do much more than
 176          * calling the rt_sigreturn() system call as it needs to unwind the stack to
 177          * restore preserved registers that may have been saved on the signal handler's
 178          * call stack.
 179          */
 180
 181 #define SIGTRAMP_SAVES                                                                          \
 182         .unwabi 3, 's';         /* mark this as a sigtramp handler (saves scratch regs) */      \
 183         .unwabi @svr4, 's'; /* backwards compatibility with old unwinders (remove in v2.7) */   \
 184         .savesp ar.unat, UNAT_OFF+SIGCONTEXT_OFF;                                               \
 185         .savesp ar.fpsr, FPSR_OFF+SIGCONTEXT_OFF;                                               \
 186         .savesp pr, PR_OFF+SIGCONTEXT_OFF;                                                      \
 187         .savesp rp, RP_OFF+SIGCONTEXT_OFF;                                                      \
 188         .savesp ar.pfs, CFM_OFF+SIGCONTEXT_OFF;                                                 \
 189         .vframesp SP_OFF+SIGCONTEXT_OFF
 190
 191 GLOBAL_ENTRY(__kernel_sigtramp)
 192         // describe the state that is active when we get here:
 193         .prologue
 194         SIGTRAMP_SAVES
 195         .body
 196
 197         .label_state 1
 198
 199         adds base0=SIGHANDLER_OFF,sp
 200         adds base1=RBS_BASE_OFF+SIGCONTEXT_OFF,sp
 201         br.call.sptk.many rp=1f
 202 1:
 203         ld8 r17=[base0],(ARG0_OFF-SIGHANDLER_OFF)       // get pointer to signal handler's plabel
 204         ld8 r15=[base1]                                 // get address of new RBS base (or NULL)
 205         cover                           // push args in interrupted frame onto backing store
 206         ;;
 207         cmp.ne p1,p0=r15,r0             // do we need to switch rbs? (note: pr is saved by kernel)
 208         mov.m r9=ar.bsp                 // fetch ar.bsp
 209         .spillsp.p p1, ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
 210 (p1)    br.cond.spnt setup_rbs          // yup -> (clobbers p8, r14-r16, and r18-r20)
 211 back_from_setup_rbs:
 212         alloc r8=ar.pfs,0,0,3,0
 213         ld8 out0=[base0],16             // load arg0 (signum)
 214         adds base1=(ARG1_OFF-(RBS_BASE_OFF+SIGCONTEXT_OFF)),base1
 215         ;;
 216         ld8 out1=[base1]                // load arg1 (siginfop)
 217         ld8 r10=[r17],8                 // get signal handler entry point
 218         ;;
 219         ld8 out2=[base0]                // load arg2 (sigcontextp)
 220         ld8 gp=[r17]                    // get signal handler's global pointer
 221         adds base0=(BSP_OFF+SIGCONTEXT_OFF),sp
 222         ;;
 223         .spillsp ar.bsp, BSP_OFF+SIGCONTEXT_OFF
 224         st8 [base0]=r9                  // save sc_ar_bsp
 225         adds base0=(FR6_OFF+SIGCONTEXT_OFF),sp
 226         adds base1=(FR6_OFF+16+SIGCONTEXT_OFF),sp
 227         ;;
 228         stf.spill [base0]=f6,32
 229         stf.spill [base1]=f7,32
 230         ;;
 231         stf.spill [base0]=f8,32
 232         stf.spill [base1]=f9,32
 233         mov b6=r10
 234         ;;
 235         stf.spill [base0]=f10,32
 236         stf.spill [base1]=f11,32
 237         ;;
 238         stf.spill [base0]=f12,32
 239         stf.spill [base1]=f13,32
 240         ;;
 241         stf.spill [base0]=f14,32
 242         stf.spill [base1]=f15,32
 243         br.call.sptk.many rp=b6                 // call the signal handler
 244 .ret0:  adds base0=(BSP_OFF+SIGCONTEXT_OFF),sp
 245         ;;
 246         ld8 r15=[base0]                         // fetch sc_ar_bsp
 247         mov r14=ar.bsp
 248         ;;
 249         cmp.ne p1,p0=r14,r15                    // do we need to restore the rbs?
 250 (p1)    br.cond.spnt restore_rbs                // yup -> (clobbers r14-r18, f6 & f7)
 251         ;;
 252 back_from_restore_rbs:
 253         adds base0=(FR6_OFF+SIGCONTEXT_OFF),sp
 254         adds base1=(FR6_OFF+16+SIGCONTEXT_OFF),sp
 255         ;;
 256         ldf.fill f6=[base0],32
 257         ldf.fill f7=[base1],32
 258         ;;
 259         ldf.fill f8=[base0],32
 260         ldf.fill f9=[base1],32
 261         ;;
 262         ldf.fill f10=[base0],32
 263         ldf.fill f11=[base1],32
 264         ;;
 265         ldf.fill f12=[base0],32
 266         ldf.fill f13=[base1],32
 267         ;;
 268         ldf.fill f14=[base0],32
 269         ldf.fill f15=[base1],32
 270         mov r15=__NR_rt_sigreturn
 271         .restore sp                             // pop .prologue
 272         break __BREAK_SYSCALL
 273
 274         .prologue
 275         SIGTRAMP_SAVES
 276 setup_rbs:
 277         mov ar.rsc=0                            // put RSE into enforced lazy mode
 278         ;;
 279         .save ar.rnat, r19
 280         mov r19=ar.rnat                         // save RNaT before switching backing store area
 281         adds r14=(RNAT_OFF+SIGCONTEXT_OFF),sp
 282
 283         mov r18=ar.bspstore
 284         mov ar.bspstore=r15                     // switch over to new register backing store area
 285         ;;
 286
 287         .spillsp ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
 288         st8 [r14]=r19                           // save sc_ar_rnat
 289         .body
 290         mov.m r16=ar.bsp                        // sc_loadrs <- (new bsp - new bspstore) << 16
 291         adds r14=(LOADRS_OFF+SIGCONTEXT_OFF),sp
 292         ;;
 293         invala
 294         sub r15=r16,r15
 295         extr.u r20=r18,3,6
 296         ;;
 297         mov ar.rsc=0xf                          // set RSE into eager mode, pl 3
 298         cmp.eq p8,p0=63,r20
 299         shl r15=r15,16
 300         ;;
 301         st8 [r14]=r15                           // save sc_loadrs
 302 (p8)    st8 [r18]=r19           // if bspstore points at RNaT slot, store RNaT there now
 303         .restore sp                             // pop .prologue
 304         br.cond.sptk back_from_setup_rbs
 305
 306         .prologue
 307         SIGTRAMP_SAVES
 308         .spillsp ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
 309         .body
 310 restore_rbs:
 311         // On input:
 312         //      r14 = bsp1 (bsp at the time of return from signal handler)
 313         //      r15 = bsp0 (bsp at the time the signal occurred)
 314         //
 315         // Here, we need to calculate bspstore0, the value that ar.bspstore needs
 316         // to be set to, based on bsp0 and the size of the dirty partition on
 317         // the alternate stack (sc_loadrs >> 16).  This can be done with the
 318         // following algorithm:
 319         //
 320         //  bspstore0 = rse_skip_regs(bsp0, -rse_num_regs(bsp1 - (loadrs >> 19), bsp1));
 321         //
 322         // This is what the code below does.
 323         //
 324         alloc r2=ar.pfs,0,0,0,0                 // alloc null frame
 325         adds r16=(LOADRS_OFF+SIGCONTEXT_OFF),sp
 326         adds r18=(RNAT_OFF+SIGCONTEXT_OFF),sp
 327         ;;
 328         ld8 r17=[r16]
 329         ld8 r16=[r18]                   // get new rnat
 330         extr.u r18=r15,3,6      // r18 <- rse_slot_num(bsp0)
 331         ;;
 332         mov ar.rsc=r17                  // put RSE into enforced lazy mode
 333         shr.u r17=r17,16
 334         ;;
 335         sub r14=r14,r17         // r14 (bspstore1) <- bsp1 - (sc_loadrs >> 16)
 336         shr.u r17=r17,3         // r17 <- (sc_loadrs >> 19)
 337         ;;
 338         loadrs                  // restore dirty partition
 339         extr.u r14=r14,3,6      // r14 <- rse_slot_num(bspstore1)
 340         ;;
 341         add r14=r14,r17         // r14 <- rse_slot_num(bspstore1) + (sc_loadrs >> 19)
 342         ;;
 343         shr.u r14=r14,6         // r14 <- (rse_slot_num(bspstore1) + (sc_loadrs >> 19))/0x40
 344         ;;
 345         sub r14=r14,r17         // r14 <- -rse_num_regs(bspstore1, bsp1)
 346         movl r17=0x8208208208208209
 347         ;;
 348         add r18=r18,r14         // r18 (delta) <- rse_slot_num(bsp0) - rse_num_regs(bspstore1,bsp1)
 349         setf.sig f7=r17
 350         cmp.lt p7,p0=r14,r0     // p7 <- (r14 < 0)?
 351         ;;
 352 (p7)    adds r18=-62,r18        // delta -= 62
 353         ;;
 354         setf.sig f6=r18
 355         ;;
 356         xmpy.h f6=f6,f7
 357         ;;
 358         getf.sig r17=f6
 359         ;;
 360         add r17=r17,r18
 361         shr r18=r18,63
 362         ;;
 363         shr r17=r17,5
 364         ;;
 365         sub r17=r17,r18         // r17 = delta/63
 366         ;;
 367         add r17=r14,r17         // r17 <- delta/63 - rse_num_regs(bspstore1, bsp1)
 368         ;;
 369         shladd r15=r17,3,r15    // r15 <- bsp0 + 8*(delta/63 - rse_num_regs(bspstore1, bsp1))
 370         ;;
 371         mov ar.bspstore=r15                     // switch back to old register backing store area
 372         ;;
 373         mov ar.rnat=r16                         // restore RNaT
 374         mov ar.rsc=0xf                          // (will be restored later on from sc_ar_rsc)
 375         // invala not necessary as that will happen when returning to user-mode
 376         br.cond.sptk back_from_restore_rbs
 377 END(__kernel_sigtramp)