arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .text.head : {
  27                 _stext = .;
  28                 _sinittext = .;
  29                 *(.text.head)
  30         }
  31
  32         .init : {                       /* Init code and data           */
  33                         INIT_TEXT
  34                 _einittext = .;
  35                 __proc_info_begin = .;
  36                         *(.proc.info.init)
  37                 __proc_info_end = .;
  38                 __arch_info_begin = .;
  39                         *(.arch.info.init)
  40                 __arch_info_end = .;
  41                 __tagtable_begin = .;
  42                         *(.taglist.init)
  43                 __tagtable_end = .;
  44                 . = ALIGN(16);
  45                 __setup_start = .;
  46                         *(.init.setup)
  47                 __setup_end = .;
  48                 __early_begin = .;
  49                         *(.early_param.init)
  50                 __early_end = .;
  51                 __initcall_start = .;
  52                         INITCALLS
  53                 __initcall_end = .;
  54                 __con_initcall_start = .;
  55                         *(.con_initcall.init)
  56                 __con_initcall_end = .;
  57                 __security_initcall_start = .;
  58                         *(.security_initcall.init)
  59                 __security_initcall_end = .;
  60 #ifdef CONFIG_BLK_DEV_INITRD
  61                 . = ALIGN(32);
  62                 __initramfs_start = .;
  63                         usr/built-in.o(.init.ramfs)
  64                 __initramfs_end = .;
  65 #endif
  66                 . = ALIGN(4096);
  67                 __per_cpu_start = .;
  68                         *(.data.percpu)
  69                         *(.data.percpu.shared_aligned)
  70                 __per_cpu_end = .;
  71 #ifndef CONFIG_XIP_KERNEL
  72                 __init_begin = _stext;
  73                 INIT_DATA
  74                 . = ALIGN(4096);
  75                 __init_end = .;
  76 #endif
  77         }
  78
  79         /DISCARD/ : {                   /* Exit code and data           */
  80                 EXIT_TEXT
  81                 EXIT_DATA
  82                 *(.exitcall.exit)
  83                 *(.ARM.exidx.exit.text)
  84                 *(.ARM.extab.exit.text)
  85 #ifndef CONFIG_MMU
  86                 *(.fixup)
  87                 *(__ex_table)
  88 #endif
  89         }
  90
  91         .text : {                       /* Real text segment            */
  92                 _text = .;              /* Text and read-only data      */
  93                         __exception_text_start = .;
  94                         *(.exception.text)
  95                         __exception_text_end = .;
  96                         TEXT_TEXT
  97                         SCHED_TEXT
  98                         LOCK_TEXT
  99                         KPROBES_TEXT
 100 #ifdef CONFIG_MMU
 101                         *(.fixup)
 102 #endif
 103                         *(.gnu.warning)
 104                         *(.rodata)
 105                         *(.rodata.*)
 106                         *(.glue_7)
 107                         *(.glue_7t)
 108                 *(.got)                 /* Global offset table          */
 109         }
 110
 111         RODATA
 112
 113         _etext = .;                     /* End of text and rodata section */
 114
 115 #ifdef CONFIG_ARM_UNWIND
 116         /*
 117          * Stack unwinding tables
 118          */
 119         . = ALIGN(8);
 120         .ARM.unwind_idx : {
 121                 __start_unwind_idx = .;
 122                 *(.ARM.exidx*)
 123                 __stop_unwind_idx = .;
 124         }
 125         .ARM.unwind_tab : {
 126                 __start_unwind_tab = .;
 127                 *(.ARM.extab*)
 128                 __stop_unwind_tab = .;
 129         }
 130 #endif
 131
 132 #ifdef CONFIG_XIP_KERNEL
 133         __data_loc = ALIGN(4);          /* location in binary */
 134         . = PAGE_OFFSET + TEXT_OFFSET;
 135 #else
 136         . = ALIGN(THREAD_SIZE);
 137         __data_loc = .;
 138 #endif
 139
 140         .data : AT(__data_loc) {
 141                 _data = .;              /* address in memory */
 142
 143                 /*
 144                  * first, the init task union, aligned
 145                  * to an 8192 byte boundary.
 146                  */
 147                 *(.data.init_task)
 148
 149 #ifdef CONFIG_XIP_KERNEL
 150                 . = ALIGN(4096);
 151                 __init_begin = .;
 152                 INIT_DATA
 153                 . = ALIGN(4096);
 154                 __init_end = .;
 155 #endif
 156
 157                 . = ALIGN(4096);
 158                 __nosave_begin = .;
 159                 *(.data.nosave)
 160                 . = ALIGN(4096);
 161                 __nosave_end = .;
 162
 163                 /*
 164                  * then the cacheline aligned data
 165                  */
 166                 . = ALIGN(32);
 167                 *(.data.cacheline_aligned)
 168
 169                 /*
 170                  * The exception fixup table (might need resorting at runtime)
 171                  */
 172                 . = ALIGN(32);
 173                 __start___ex_table = .;
 174 #ifdef CONFIG_MMU
 175                 *(__ex_table)
 176 #endif
 177                 __stop___ex_table = .;
 178
 179                 /*
 180                  * and the usual data section
 181                  */
 182                 DATA_DATA
 183                 CONSTRUCTORS
 184
 185                 _edata = .;
 186         }
 187         _edata_loc = __data_loc + SIZEOF(.data);
 188
 189         .bss : {
 190                 __bss_start = .;        /* BSS                          */
 191                 *(.bss)
 192                 *(COMMON)
 193                 _end = .;
 194         }
 195                                         /* Stabs debugging sections.    */
 196         .stab 0 : { *(.stab) }
 197         .stabstr 0 : { *(.stabstr) }
 198         .stab.excl 0 : { *(.stab.excl) }
 199         .stab.exclstr 0 : { *(.stab.exclstr) }
 200         .stab.index 0 : { *(.stab.index) }
 201         .stab.indexstr 0 : { *(.stab.indexstr) }
 202         .comment 0 : { *(.comment) }
 203 }
 204
 205 /*
 206  * These must never be empty
 207  * If you have to comment these two assert statements out, your
 208  * binutils is too old (for other reasons as well)
 209  */
 210 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 211 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")