arch/arm/kernel/sleep.S

   1 #include <linux/linkage.h>
   2 #include <linux/threads.h>
   3 #include <asm/asm-offsets.h>
   4 #include <asm/assembler.h>
   5 #include <asm/glue-cache.h>
   6 #include <asm/glue-proc.h>
   7 #include <asm/system.h>
   8         .text
   9
  10 /*
  11  * Save CPU state for a suspend
  12  *  r1 = v:p offset
  13  *  r3 = virtual return function
  14  * Note: sp is decremented to allocate space for CPU state on stack
  15  * r0-r3,ip,lr corrupted
  16  */
  17 ENTRY(cpu_suspend)
  18         stmfd   sp!, {r3}
  19         stmfd   sp!, {r4 - r11}
  20         mov     r9, lr
  21 #ifdef MULTI_CPU
  22         ldr     r10, =processor
  23         ldr     r0, [r10, #CPU_SLEEP_SIZE] @ size of CPU sleep state
  24         ldr     ip, [r10, #CPU_DO_RESUME] @ virtual resume function
  25 #else
  26         ldr     r0, =cpu_suspend_size
  27         ldr     ip, =cpu_do_resume
  28 #endif
  29         mov     r2, sp                  @ current virtual SP
  30         sub     sp, sp, r0              @ allocate CPU state on stack
  31         mov     r0, sp                  @ save pointer
  32         add     ip, ip, r1              @ convert resume fn to phys
  33         stmfd   sp!, {r1, r2, ip}       @ save v:p, virt SP, phys resume fn
  34         ldr     r3, =sleep_save_sp
  35         add     r2, sp, r1              @ convert SP to phys
  36 #ifdef CONFIG_SMP
  37         ALT_SMP(mrc p15, 0, lr, c0, c0, 5)
  38         ALT_UP(mov lr, #0)
  39         and     lr, lr, #15
  40         str     r2, [r3, lr, lsl #2]    @ save phys SP
  41 #else
  42         str     r2, [r3]                @ save phys SP
  43 #endif
  44 #ifdef MULTI_CPU
  45         mov     lr, pc
  46         ldr     pc, [r10, #CPU_DO_SUSPEND] @ save CPU state
  47 #else
  48         bl      cpu_do_suspend
  49 #endif
  50
  51         @ flush data cache
  52 #ifdef MULTI_CACHE
  53         ldr     r10, =cpu_cache
  54         mov     lr, r9
  55         ldr     pc, [r10, #CACHE_FLUSH_KERN_ALL]
  56 #else
  57         mov     lr, r9
  58         b       __cpuc_flush_kern_all
  59 #endif
  60 ENDPROC(cpu_suspend)
  61         .ltorg
  62
  63 /*
  64  * r0 = control register value
  65  * r1 = v:p offset (preserved by cpu_do_resume)
  66  * r2 = phys page table base
  67  * r3 = L1 section flags
  68  */
  69 ENTRY(cpu_resume_mmu)
  70         adr     r4, cpu_resume_turn_mmu_on
  71         mov     r4, r4, lsr #20
  72         orr     r3, r3, r4, lsl #20
  73         ldr     r5, [r2, r4, lsl #2]    @ save old mapping
  74         str     r3, [r2, r4, lsl #2]    @ setup 1:1 mapping for mmu code
  75         sub     r2, r2, r1
  76         ldr     r3, =cpu_resume_after_mmu
  77         bic     r1, r0, #CR_C           @ ensure D-cache is disabled
  78         b       cpu_resume_turn_mmu_on
  79 ENDPROC(cpu_resume_mmu)
  80         .ltorg
  81         .align  5
  82 cpu_resume_turn_mmu_on:
  83         mcr     p15, 0, r1, c1, c0, 0   @ turn on MMU, I-cache, etc
  84         mrc     p15, 0, r1, c0, c0, 0   @ read id reg
  85         mov     r1, r1
  86         mov     r1, r1
  87         mov     pc, r3                  @ jump to virtual address
  88 ENDPROC(cpu_resume_turn_mmu_on)
  89 cpu_resume_after_mmu:
  90         str     r5, [r2, r4, lsl #2]    @ restore old mapping
  91         mcr     p15, 0, r0, c1, c0, 0   @ turn on D-cache
  92         ldmfd   sp!, {r4 - r11, pc}
  93 ENDPROC(cpu_resume_after_mmu)
  94
  95 /*
  96  * Note: Yes, part of the following code is located into the .data section.
  97  *       This is to allow sleep_save_sp to be accessed with a relative load
  98  *       while we can't rely on any MMU translation.  We could have put
  99  *       sleep_save_sp in the .text section as well, but some setups might
 100  *       insist on it to be truly read-only.
 101  */
 102         .data
 103         .align
 104 ENTRY(cpu_resume)
 105 #ifdef CONFIG_SMP
 106         adr     r0, sleep_save_sp
 107         ALT_SMP(mrc p15, 0, r1, c0, c0, 5)
 108         ALT_UP(mov r1, #0)
 109         and     r1, r1, #15
 110         ldr     r0, [r0, r1, lsl #2]    @ stack phys addr
 111 #else
 112         ldr     r0, sleep_save_sp       @ stack phys addr
 113 #endif
 114         setmode PSR_I_BIT | PSR_F_BIT | SVC_MODE, r1  @ set SVC, irqs off
 115         @ load v:p, stack, resume fn
 116   ARM(  ldmia   r0!, {r1, sp, pc}       )
 117 THUMB(  ldmia   r0!, {r1, r2, r3}       )
 118 THUMB(  mov     sp, r2                  )
 119 THUMB(  bx      r3                      )
 120 ENDPROC(cpu_resume)
 121
 122 sleep_save_sp:
 123         .rept   CONFIG_NR_CPUS
 124         .long   0                               @ preserve stack phys ptr here
 125         .endr