arch/arm/kernel/entry-header.S

   1 #include <linux/init.h>
   2 #include <linux/linkage.h>
   3
   4 #include <asm/assembler.h>
   5 #include <asm/asm-offsets.h>
   6 #include <asm/errno.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/v7m.h>
   9
  10 @ Bad Abort numbers
  11 @ -----------------
  12 @
  13 #define BAD_PREFETCH    0
  14 #define BAD_DATA        1
  15 #define BAD_ADDREXCPTN  2
  16 #define BAD_IRQ         3
  17 #define BAD_UNDEFINSTR  4
  18
  19 @
  20 @ Most of the stack format comes from struct pt_regs, but with
  21 @ the addition of 8 bytes for storing syscall args 5 and 6.
  22 @ This _must_ remain a multiple of 8 for EABI.
  23 @
  24 #define S_OFF           8
  25
  26 /*
  27  * The SWI code relies on the fact that R0 is at the bottom of the stack
  28  * (due to slow/fast restore user regs).
  29  */
  30 #if S_R0 != 0
  31 #error "Please fix"
  32 #endif
  33
  34         .macro  zero_fp
  35 #ifdef CONFIG_FRAME_POINTER
  36         mov     fp, #0
  37 #endif
  38         .endm
  39
  40 #ifdef CONFIG_ALIGNMENT_TRAP
  41 #define ATRAP(x...) x
  42 #else
  43 #define ATRAP(x...)
  44 #endif
  45
  46         .macro  alignment_trap, rtmp1, rtmp2, label
  47 #ifdef CONFIG_ALIGNMENT_TRAP
  48         mrc     p15, 0, \rtmp2, c1, c0, 0
  49         ldr     \rtmp1, \label
  50         ldr     \rtmp1, [\rtmp1]
  51         teq     \rtmp1, \rtmp2
  52         mcrne   p15, 0, \rtmp1, c1, c0, 0
  53 #endif
  54         .endm
  55
  56 #ifdef CONFIG_CPU_V7M
  57 /*
  58  * ARMv7-M exception entry/exit macros.
  59  *
  60  * xPSR, ReturnAddress(), LR (R14), R12, R3, R2, R1, and R0 are
  61  * automatically saved on the current stack (32 words) before
  62  * switching to the exception stack (SP_main).
  63  *
  64  * If exception is taken while in user mode, SP_main is
  65  * empty. Otherwise, SP_main is aligned to 64 bit automatically
  66  * (CCR.STKALIGN set).
  67  *
  68  * Linux assumes that the interrupts are disabled when entering an
  69  * exception handler and it may BUG if this is not the case. Interrupts
  70  * are disabled during entry and reenabled in the exit macro.
  71  *
  72  * v7m_exception_slow_exit is used when returning from SVC or PendSV.
  73  * When returning to kernel mode, we don't return from exception.
  74  */
  75         .macro  v7m_exception_entry
  76         @ determine the location of the registers saved by the core during
  77         @ exception entry. Depending on the mode the cpu was in when the
  78         @ exception happend that is either on the main or the process stack.
  79         @ Bit 2 of EXC_RETURN stored in the lr register specifies which stack
  80         @ was used.
  81         tst     lr, #EXC_RET_STACK_MASK
  82         mrsne   r12, psp
  83         moveq   r12, sp
  84
  85         @ we cannot rely on r0-r3 and r12 matching the value saved in the
  86         @ exception frame because of tail-chaining. So these have to be
  87         @ reloaded.
  88         ldmia   r12!, {r0-r3}
  89
  90         @ Linux expects to have irqs off. Do it here before taking stack space
  91         cpsid   i
  92
  93         sub     sp, #S_FRAME_SIZE-S_IP
  94         stmdb   sp!, {r0-r11}
  95
  96         @ load saved r12, lr, return address and xPSR.
  97         @ r0-r7 are used for signals and never touched from now on. Clobbering
  98         @ r8-r12 is OK.
  99         mov     r9, r12
 100         ldmia   r9!, {r8, r10-r12}
 101
 102         @ calculate the original stack pointer value.
 103         @ r9 currently points to the memory location just above the auto saved
 104         @ xPSR.
 105         @ The cpu might automatically 8-byte align the stack. Bit 9
 106         @ of the saved xPSR specifies if stack aligning took place. In this case
 107         @ another 32-bit value is included in the stack.
 108
 109         tst     r12, V7M_xPSR_FRAMEPTRALIGN
 110         addne   r9, r9, #4
 111
 112         @ store saved r12 using str to have a register to hold the base for stm
 113         str     r8, [sp, #S_IP]
 114         add     r8, sp, #S_SP
 115         @ store r13-r15, xPSR
 116         stmia   r8!, {r9-r12}
 117         @ store old_r0
 118         str     r0, [r8]
 119         .endm
 120
 121         /*
 122          * PENDSV and SVCALL are configured to have the same exception
 123          * priorities. As a kernel thread runs at SVCALL execution priority it
 124          * can never be preempted and so we will never have to return to a
 125          * kernel thread here.
 126          */
 127         .macro  v7m_exception_slow_exit ret_r0
 128         cpsid   i
 129         ldr     lr, =EXC_RET_THREADMODE_PROCESSSTACK
 130
 131         @ read original r12, sp, lr, pc and xPSR
 132         add     r12, sp, #S_IP
 133         ldmia   r12, {r1-r5}
 134
 135         @ an exception frame is always 8-byte aligned. To tell the hardware if
 136         @ the sp to be restored is aligned or not set bit 9 of the saved xPSR
 137         @ accordingly.
 138         tst     r2, #4
 139         subne   r2, r2, #4
 140         orrne   r5, V7M_xPSR_FRAMEPTRALIGN
 141         biceq   r5, V7M_xPSR_FRAMEPTRALIGN
 142
 143         @ ensure bit 0 is cleared in the PC, otherwise behaviour is
 144         @ unpredictable
 145         bic     r4, #1
 146
 147         @ write basic exception frame
 148         stmdb   r2!, {r1, r3-r5}
 149         ldmia   sp, {r1, r3-r5}
 150         .if     \ret_r0
 151         stmdb   r2!, {r0, r3-r5}
 152         .else
 153         stmdb   r2!, {r1, r3-r5}
 154         .endif
 155
 156         @ restore process sp
 157         msr     psp, r2
 158
 159         @ restore original r4-r11
 160         ldmia   sp!, {r0-r11}
 161
 162         @ restore main sp
 163         add     sp, sp, #S_FRAME_SIZE-S_IP
 164
 165         cpsie   i
 166         bx      lr
 167         .endm
 168 #endif  /* CONFIG_CPU_V7M */
 169
 170         @
 171         @ Store/load the USER SP and LR registers by switching to the SYS
 172         @ mode. Useful in Thumb-2 mode where "stm/ldm rd, {sp, lr}^" is not
 173         @ available. Should only be called from SVC mode
 174         @
 175         .macro  store_user_sp_lr, rd, rtemp, offset = 0
 176         mrs     \rtemp, cpsr
 177         eor     \rtemp, \rtemp, #(SVC_MODE ^ SYSTEM_MODE)
 178         msr     cpsr_c, \rtemp                  @ switch to the SYS mode
 179
 180         str     sp, [\rd, #\offset]             @ save sp_usr
 181         str     lr, [\rd, #\offset + 4]         @ save lr_usr
 182
 183         eor     \rtemp, \rtemp, #(SVC_MODE ^ SYSTEM_MODE)
 184         msr     cpsr_c, \rtemp                  @ switch back to the SVC mode
 185         .endm
 186
 187         .macro  load_user_sp_lr, rd, rtemp, offset = 0
 188         mrs     \rtemp, cpsr
 189         eor     \rtemp, \rtemp, #(SVC_MODE ^ SYSTEM_MODE)
 190         msr     cpsr_c, \rtemp                  @ switch to the SYS mode
 191
 192         ldr     sp, [\rd, #\offset]             @ load sp_usr
 193         ldr     lr, [\rd, #\offset + 4]         @ load lr_usr
 194
 195         eor     \rtemp, \rtemp, #(SVC_MODE ^ SYSTEM_MODE)
 196         msr     cpsr_c, \rtemp                  @ switch back to the SVC mode
 197         .endm
 198
 199 #ifndef CONFIG_THUMB2_KERNEL
 200         .macro  svc_exit, rpsr, irq = 0
 201         .if     \irq != 0
 202         @ IRQs already off
 203 #ifdef CONFIG_TRACE_IRQFLAGS
 204         @ The parent context IRQs must have been enabled to get here in
 205         @ the first place, so there's no point checking the PSR I bit.
 206         bl      trace_hardirqs_on
 207 #endif
 208         .else
 209         @ IRQs off again before pulling preserved data off the stack
 210         disable_irq_notrace
 211 #ifdef CONFIG_TRACE_IRQFLAGS
 212         tst     \rpsr, #PSR_I_BIT
 213         bleq    trace_hardirqs_on
 214         tst     \rpsr, #PSR_I_BIT
 215         blne    trace_hardirqs_off
 216 #endif
 217         .endif
 218         msr     spsr_cxsf, \rpsr
 219 #if defined(CONFIG_CPU_V6)
 220         ldr     r0, [sp]
 221         strex   r1, r2, [sp]                    @ clear the exclusive monitor
 222         ldmib   sp, {r1 - pc}^                  @ load r1 - pc, cpsr
 223 #elif defined(CONFIG_CPU_32v6K)
 224         clrex                                   @ clear the exclusive monitor
 225         ldmia   sp, {r0 - pc}^                  @ load r0 - pc, cpsr
 226 #else
 227         ldmia   sp, {r0 - pc}^                  @ load r0 - pc, cpsr
 228 #endif
 229         .endm
 230
 231         .macro  restore_user_regs, fast = 0, offset = 0
 232         ldr     r1, [sp, #\offset + S_PSR]      @ get calling cpsr
 233         ldr     lr, [sp, #\offset + S_PC]!      @ get pc
 234         msr     spsr_cxsf, r1                   @ save in spsr_svc
 235 #if defined(CONFIG_CPU_V6)
 236         strex   r1, r2, [sp]                    @ clear the exclusive monitor
 237 #elif defined(CONFIG_CPU_32v6K)
 238         clrex                                   @ clear the exclusive monitor
 239 #endif
 240         .if     \fast
 241         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
 242         .else
 243         ldmdb   sp, {r0 - lr}^                  @ get calling r0 - lr
 244         .endif
 245         mov     r0, r0                          @ ARMv5T and earlier require a nop
 246                                                 @ after ldm {}^
 247         add     sp, sp, #S_FRAME_SIZE - S_PC
 248         movs    pc, lr                          @ return & move spsr_svc into cpsr
 249         .endm
 250
 251 #else   /* CONFIG_THUMB2_KERNEL */
 252         .macro  svc_exit, rpsr, irq = 0
 253         .if     \irq != 0
 254         @ IRQs already off
 255 #ifdef CONFIG_TRACE_IRQFLAGS
 256         @ The parent context IRQs must have been enabled to get here in
 257         @ the first place, so there's no point checking the PSR I bit.
 258         bl      trace_hardirqs_on
 259 #endif
 260         .else
 261         @ IRQs off again before pulling preserved data off the stack
 262         disable_irq_notrace
 263 #ifdef CONFIG_TRACE_IRQFLAGS
 264         tst     \rpsr, #PSR_I_BIT
 265         bleq    trace_hardirqs_on
 266         tst     \rpsr, #PSR_I_BIT
 267         blne    trace_hardirqs_off
 268 #endif
 269         .endif
 270         ldr     lr, [sp, #S_SP]                 @ top of the stack
 271         ldrd    r0, r1, [sp, #S_LR]             @ calling lr and pc
 272         clrex                                   @ clear the exclusive monitor
 273         stmdb   lr!, {r0, r1, \rpsr}            @ calling lr and rfe context
 274         ldmia   sp, {r0 - r12}
 275         mov     sp, lr
 276         ldr     lr, [sp], #4
 277         rfeia   sp!
 278         .endm
 279
 280 #ifdef CONFIG_CPU_V7M
 281         /*
 282          * Note we don't need to do clrex here as clearing the local monitor is
 283          * part of each exception entry and exit sequence.
 284          */
 285         .macro  restore_user_regs, fast = 0, offset = 0
 286         .if     \offset
 287         add     sp, #\offset
 288         .endif
 289         v7m_exception_slow_exit ret_r0 = \fast
 290         .endm
 291 #else   /* ifdef CONFIG_CPU_V7M */
 292         .macro  restore_user_regs, fast = 0, offset = 0
 293         clrex                                   @ clear the exclusive monitor
 294         mov     r2, sp
 295         load_user_sp_lr r2, r3, \offset + S_SP  @ calling sp, lr
 296         ldr     r1, [sp, #\offset + S_PSR]      @ get calling cpsr
 297         ldr     lr, [sp, #\offset + S_PC]       @ get pc
 298         add     sp, sp, #\offset + S_SP
 299         msr     spsr_cxsf, r1                   @ save in spsr_svc
 300         .if     \fast
 301         ldmdb   sp, {r1 - r12}                  @ get calling r1 - r12
 302         .else
 303         ldmdb   sp, {r0 - r12}                  @ get calling r0 - r12
 304         .endif
 305         add     sp, sp, #S_FRAME_SIZE - S_SP
 306         movs    pc, lr                          @ return & move spsr_svc into cpsr
 307         .endm
 308 #endif  /* ifdef CONFIG_CPU_V7M / else */
 309 #endif  /* !CONFIG_THUMB2_KERNEL */
 310
 311 /*
 312  * Context tracking subsystem.  Used to instrument transitions
 313  * between user and kernel mode.
 314  */
 315         .macro ct_user_exit, save = 1
 316 #ifdef CONFIG_CONTEXT_TRACKING
 317         .if     \save
 318         stmdb   sp!, {r0-r3, ip, lr}
 319         bl      context_tracking_user_exit
 320         ldmia   sp!, {r0-r3, ip, lr}
 321         .else
 322         bl      context_tracking_user_exit
 323         .endif
 324 #endif
 325         .endm
 326
 327         .macro ct_user_enter, save = 1
 328 #ifdef CONFIG_CONTEXT_TRACKING
 329         .if     \save
 330         stmdb   sp!, {r0-r3, ip, lr}
 331         bl      context_tracking_user_enter
 332         ldmia   sp!, {r0-r3, ip, lr}
 333         .else
 334         bl      context_tracking_user_enter
 335         .endif
 336 #endif
 337         .endm
 338
 339 /*
 340  * These are the registers used in the syscall handler, and allow us to
 341  * have in theory up to 7 arguments to a function - r0 to r6.
 342  *
 343  * r7 is reserved for the system call number for thumb mode.
 344  *
 345  * Note that tbl == why is intentional.
 346  *
 347  * We must set at least "tsk" and "why" when calling ret_with_reschedule.
 348  */
 349 scno    .req    r7              @ syscall number
 350 tbl     .req    r8              @ syscall table pointer
 351 why     .req    r8              @ Linux syscall (!= 0)
 352 tsk     .req    r9              @ current thread_info