arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <mach/entry-macro.S>
  14 #include <asm/unwind.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26  UNWIND(.fnstart        )
  27  UNWIND(.cantunwind     )
  28         disable_irq                             @ disable interrupts
  29         ldr     r1, [tsk, #TI_FLAGS]
  30         tst     r1, #_TIF_WORK_MASK
  31         bne     fast_work_pending
  32
  33         /* perform architecture specific actions before user return */
  34         arch_ret_to_user r1, lr
  35
  36         restore_user_regs fast = 1, offset = S_OFF
  37  UNWIND(.fnend          )
  38
  39 /*
  40  * Ok, we need to do extra processing, enter the slow path.
  41  */
  42 fast_work_pending:
  43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  44 work_pending:
  45         tst     r1, #_TIF_NEED_RESCHED
  46         bne     work_resched
  47         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
  48         beq     no_work_pending
  49         mov     r0, sp                          @ 'regs'
  50         mov     r2, why                         @ 'syscall'
  51         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
  52         movne   why, #0                         @ prevent further restarts
  53         bl      do_notify_resume
  54         b       ret_slow_syscall                @ Check work again
  55
  56 work_resched:
  57         bl      schedule
  58 /*
  59  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  60  */
  61 ENTRY(ret_to_user)
  62 ret_slow_syscall:
  63         disable_irq                             @ disable interrupts
  64         ldr     r1, [tsk, #TI_FLAGS]
  65         tst     r1, #_TIF_WORK_MASK
  66         bne     work_pending
  67 no_work_pending:
  68         /* perform architecture specific actions before user return */
  69         arch_ret_to_user r1, lr
  70
  71         restore_user_regs fast = 0, offset = 0
  72 ENDPROC(ret_to_user)
  73
  74 /*
  75  * This is how we return from a fork.
  76  */
  77 ENTRY(ret_from_fork)
  78         bl      schedule_tail
  79         get_thread_info tsk
  80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  81         mov     why, #1
  82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  83         beq     ret_slow_syscall
  84         mov     r1, sp
  85         mov     r0, #1                          @ trace exit [IP = 1]
  86         bl      syscall_trace
  87         b       ret_slow_syscall
  88 ENDPROC(ret_from_fork)
  89
  90         .equ NR_syscalls,0
  91 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  92 #include "calls.S"
  93 #undef CALL
  94 #define CALL(x) .long x
  95
  96 #ifdef CONFIG_FUNCTION_TRACER
  97 /*
  98  * When compiling with -pg, gcc inserts a call to the mcount routine at the
  99  * start of every function.  In mcount, apart from the function's address (in
 100  * lr), we need to get hold of the function's caller's address.
 101  *
 102  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 103  *
 104  *      bl      mcount
 105  *
 106  * These versions have the limitation that in order for the mcount routine to
 107  * be able to determine the function's caller's address, an APCS-style frame
 108  * pointer (which is set up with something like the code below) is required.
 109  *
 110  *      mov     ip, sp
 111  *      push    {fp, ip, lr, pc}
 112  *      sub     fp, ip, #4
 113  *
 114  * With EABI, these frame pointers are not available unless -mapcs-frame is
 115  * specified, and if building as Thumb-2, not even then.
 116  *
 117  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 118  * with call sites like:
 119  *
 120  *      push    {lr}
 121  *      bl      __gnu_mcount_nc
 122  *
 123  * With these compilers, frame pointers are not necessary.
 124  *
 125  * mcount can be thought of as a function called in the middle of a subroutine
 126  * call.  As such, it needs to be transparent for both the caller and the
 127  * callee: the original lr needs to be restored when leaving mcount, and no
 128  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 129  * clobber the ip register.  This is OK because the ARM calling convention
 130  * allows it to be clobbered in subroutines and doesn't use it to hold
 131  * parameters.)
 132  */
 133 #ifdef CONFIG_DYNAMIC_FTRACE
 134 ENTRY(mcount)
 135         stmdb   sp!, {r0-r3, lr}
 136         mov     r0, lr
 137         sub     r0, r0, #MCOUNT_INSN_SIZE
 138
 139         .globl mcount_call
 140 mcount_call:
 141         bl      ftrace_stub
 142         ldr     lr, [fp, #-4]                   @ restore lr
 143         ldmia   sp!, {r0-r3, pc}
 144
 145 ENTRY(ftrace_caller)
 146         stmdb   sp!, {r0-r3, lr}
 147         ldr     r1, [fp, #-4]
 148         mov     r0, lr
 149         sub     r0, r0, #MCOUNT_INSN_SIZE
 150
 151         .globl ftrace_call
 152 ftrace_call:
 153         bl      ftrace_stub
 154         ldr     lr, [fp, #-4]                   @ restore lr
 155         ldmia   sp!, {r0-r3, pc}
 156
 157 #else
 158
 159 ENTRY(__gnu_mcount_nc)
 160         stmdb   sp!, {r0-r3, lr}
 161         ldr     r0, =ftrace_trace_function
 162         ldr     r2, [r0]
 163         adr     r0, ftrace_stub
 164         cmp     r0, r2
 165         bne     gnu_trace
 166         ldmia   sp!, {r0-r3, ip, lr}
 167         mov     pc, ip
 168
 169 gnu_trace:
 170         ldr     r1, [sp, #20]                   @ lr of instrumented routine
 171         mov     r0, lr
 172         sub     r0, r0, #MCOUNT_INSN_SIZE
 173         mov     lr, pc
 174         mov     pc, r2
 175         ldmia   sp!, {r0-r3, ip, lr}
 176         mov     pc, ip
 177
 178 ENTRY(mcount)
 179         stmdb   sp!, {r0-r3, lr}
 180         ldr     r0, =ftrace_trace_function
 181         ldr     r2, [r0]
 182         adr     r0, ftrace_stub
 183         cmp     r0, r2
 184         bne     trace
 185         ldr     lr, [fp, #-4]                   @ restore lr
 186         ldmia   sp!, {r0-r3, pc}
 187
 188 trace:
 189         ldr     r1, [fp, #-4]                   @ lr of instrumented routine
 190         mov     r0, lr
 191         sub     r0, r0, #MCOUNT_INSN_SIZE
 192         mov     lr, pc
 193         mov     pc, r2
 194         ldr     lr, [fp, #-4]                   @ restore lr
 195         ldmia   sp!, {r0-r3, pc}
 196
 197 #endif /* CONFIG_DYNAMIC_FTRACE */
 198
 199         .globl ftrace_stub
 200 ftrace_stub:
 201         mov     pc, lr
 202
 203 #endif /* CONFIG_FUNCTION_TRACER */
 204
 205 /*=============================================================================
 206  * SWI handler
 207  *-----------------------------------------------------------------------------
 208  */
 209
 210         /* If we're optimising for StrongARM the resulting code won't
 211            run on an ARM7 and we can save a couple of instructions.
 212                                                                 --pb */
 213 #ifdef CONFIG_CPU_ARM710
 214 #define A710(code...) code
 215 .Larm710bug:
 216         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 217         mov     r0, r0
 218         add     sp, sp, #S_FRAME_SIZE
 219         subs    pc, lr, #4
 220 #else
 221 #define A710(code...)
 222 #endif
 223
 224         .align  5
 225 ENTRY(vector_swi)
 226         sub     sp, sp, #S_FRAME_SIZE
 227         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 228  ARM(   add     r8, sp, #S_PC           )
 229  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 230  THUMB( mov     r8, sp                  )
 231  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 232         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 233         str     lr, [sp, #S_PC]                 @ Save calling PC
 234         str     r8, [sp, #S_PSR]                @ Save CPSR
 235         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 236         zero_fp
 237
 238         /*
 239          * Get the system call number.
 240          */
 241
 242 #if defined(CONFIG_OABI_COMPAT)
 243
 244         /*
 245          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 246          * value to determine if it is an EABI or an old ABI call.
 247          */
 248 #ifdef CONFIG_ARM_THUMB
 249         tst     r8, #PSR_T_BIT
 250         movne   r10, #0                         @ no thumb OABI emulation
 251         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 252 #else
 253         ldr     r10, [lr, #-4]                  @ get SWI instruction
 254   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 255   A710( teq     ip, #0x0f000000                                         )
 256   A710( bne     .Larm710bug                                             )
 257 #endif
 258 #ifdef CONFIG_CPU_ENDIAN_BE8
 259         rev     r10, r10                        @ little endian instruction
 260 #endif
 261
 262 #elif defined(CONFIG_AEABI)
 263
 264         /*
 265          * Pure EABI user space always put syscall number into scno (r7).
 266          */
 267   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 268   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 269   A710( teq     ip, #0x0f000000                                         )
 270   A710( bne     .Larm710bug                                             )
 271
 272 #elif defined(CONFIG_ARM_THUMB)
 273
 274         /* Legacy ABI only, possibly thumb mode. */
 275         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 276         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 277         ldreq   scno, [lr, #-4]
 278
 279 #else
 280
 281         /* Legacy ABI only. */
 282         ldr     scno, [lr, #-4]                 @ get SWI instruction
 283   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 284   A710( teq     ip, #0x0f000000                                         )
 285   A710( bne     .Larm710bug                                             )
 286
 287 #endif
 288
 289 #ifdef CONFIG_ALIGNMENT_TRAP
 290         ldr     ip, __cr_alignment
 291         ldr     ip, [ip]
 292         mcr     p15, 0, ip, c1, c0              @ update control register
 293 #endif
 294         enable_irq
 295
 296         get_thread_info tsk
 297         adr     tbl, sys_call_table             @ load syscall table pointer
 298
 299 #if defined(CONFIG_OABI_COMPAT)
 300         /*
 301          * If the swi argument is zero, this is an EABI call and we do nothing.
 302          *
 303          * If this is an old ABI call, get the syscall number into scno and
 304          * get the old ABI syscall table address.
 305          */
 306         bics    r10, r10, #0xff000000
 307         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 308         ldrne   tbl, =sys_oabi_call_table
 309 #elif !defined(CONFIG_AEABI)
 310         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 311         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 312 #endif
 313
 314         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 315         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 316
 317 #ifdef CONFIG_SECCOMP
 318         tst     r10, #_TIF_SECCOMP
 319         beq     1f
 320         mov     r0, scno
 321         bl      __secure_computing
 322         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
 323         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
 324 1:
 325 #endif
 326
 327         tst     r10, #_TIF_SYSCALL_TRACE                @ are we tracing syscalls?
 328         bne     __sys_trace
 329
 330         cmp     scno, #NR_syscalls              @ check upper syscall limit
 331         adr     lr, BSYM(ret_fast_syscall)      @ return address
 332         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 333
 334         add     r1, sp, #S_OFF
 335 2:      mov     why, #0                         @ no longer a real syscall
 336         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 337         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 338         bcs     arm_syscall
 339         b       sys_ni_syscall                  @ not private func
 340 ENDPROC(vector_swi)
 341
 342         /*
 343          * This is the really slow path.  We're going to be doing
 344          * context switches, and waiting for our parent to respond.
 345          */
 346 __sys_trace:
 347         mov     r2, scno
 348         add     r1, sp, #S_OFF
 349         mov     r0, #0                          @ trace entry [IP = 0]
 350         bl      syscall_trace
 351
 352         adr     lr, BSYM(__sys_trace_return)    @ return address
 353         mov     scno, r0                        @ syscall number (possibly new)
 354         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 355         cmp     scno, #NR_syscalls              @ check upper syscall limit
 356         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 357         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 358         b       2b
 359
 360 __sys_trace_return:
 361         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 362         mov     r2, scno
 363         mov     r1, sp
 364         mov     r0, #1                          @ trace exit [IP = 1]
 365         bl      syscall_trace
 366         b       ret_slow_syscall
 367
 368         .align  5
 369 #ifdef CONFIG_ALIGNMENT_TRAP
 370         .type   __cr_alignment, #object
 371 __cr_alignment:
 372         .word   cr_alignment
 373 #endif
 374         .ltorg
 375
 376 /*
 377  * This is the syscall table declaration for native ABI syscalls.
 378  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 379  */
 380 #define ABI(native, compat) native
 381 #ifdef CONFIG_AEABI
 382 #define OBSOLETE(syscall) sys_ni_syscall
 383 #else
 384 #define OBSOLETE(syscall) syscall
 385 #endif
 386
 387         .type   sys_call_table, #object
 388 ENTRY(sys_call_table)
 389 #include "calls.S"
 390 #undef ABI
 391 #undef OBSOLETE
 392
 393 /*============================================================================
 394  * Special system call wrappers
 395  */
 396 @ r0 = syscall number
 397 @ r8 = syscall table
 398 sys_syscall:
 399                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 400                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 401                 cmpne   scno, #NR_syscalls      @ check range
 402                 stmloia sp, {r5, r6}            @ shuffle args
 403                 movlo   r0, r1
 404                 movlo   r1, r2
 405                 movlo   r2, r3
 406                 movlo   r3, r4
 407                 ldrlo   pc, [tbl, scno, lsl #2]
 408                 b       sys_ni_syscall
 409 ENDPROC(sys_syscall)
 410
 411 sys_fork_wrapper:
 412                 add     r0, sp, #S_OFF
 413                 b       sys_fork
 414 ENDPROC(sys_fork_wrapper)
 415
 416 sys_vfork_wrapper:
 417                 add     r0, sp, #S_OFF
 418                 b       sys_vfork
 419 ENDPROC(sys_vfork_wrapper)
 420
 421 sys_execve_wrapper:
 422                 add     r3, sp, #S_OFF
 423                 b       sys_execve
 424 ENDPROC(sys_execve_wrapper)
 425
 426 sys_clone_wrapper:
 427                 add     ip, sp, #S_OFF
 428                 str     ip, [sp, #4]
 429                 b       sys_clone
 430 ENDPROC(sys_clone_wrapper)
 431
 432 sys_sigreturn_wrapper:
 433                 add     r0, sp, #S_OFF
 434                 mov     why, #0         @ prevent syscall restart handling
 435                 b       sys_sigreturn
 436 ENDPROC(sys_sigreturn_wrapper)
 437
 438 sys_rt_sigreturn_wrapper:
 439                 add     r0, sp, #S_OFF
 440                 mov     why, #0         @ prevent syscall restart handling
 441                 b       sys_rt_sigreturn
 442 ENDPROC(sys_rt_sigreturn_wrapper)
 443
 444 sys_sigaltstack_wrapper:
 445                 ldr     r2, [sp, #S_OFF + S_SP]
 446                 b       do_sigaltstack
 447 ENDPROC(sys_sigaltstack_wrapper)
 448
 449 sys_statfs64_wrapper:
 450                 teq     r1, #88
 451                 moveq   r1, #84
 452                 b       sys_statfs64
 453 ENDPROC(sys_statfs64_wrapper)
 454
 455 sys_fstatfs64_wrapper:
 456                 teq     r1, #88
 457                 moveq   r1, #84
 458                 b       sys_fstatfs64
 459 ENDPROC(sys_fstatfs64_wrapper)
 460
 461 /*
 462  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 463  * offset, we return EINVAL.
 464  */
 465 sys_mmap2:
 466 #if PAGE_SHIFT > 12
 467                 tst     r5, #PGOFF_MASK
 468                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 469                 streq   r5, [sp, #4]
 470                 beq     sys_mmap_pgoff
 471                 mov     r0, #-EINVAL
 472                 mov     pc, lr
 473 #else
 474                 str     r5, [sp, #4]
 475                 b       sys_mmap_pgoff
 476 #endif
 477 ENDPROC(sys_mmap2)
 478
 479 #ifdef CONFIG_OABI_COMPAT
 480
 481 /*
 482  * These are syscalls with argument register differences
 483  */
 484
 485 sys_oabi_pread64:
 486                 stmia   sp, {r3, r4}
 487                 b       sys_pread64
 488 ENDPROC(sys_oabi_pread64)
 489
 490 sys_oabi_pwrite64:
 491                 stmia   sp, {r3, r4}
 492                 b       sys_pwrite64
 493 ENDPROC(sys_oabi_pwrite64)
 494
 495 sys_oabi_truncate64:
 496                 mov     r3, r2
 497                 mov     r2, r1
 498                 b       sys_truncate64
 499 ENDPROC(sys_oabi_truncate64)
 500
 501 sys_oabi_ftruncate64:
 502                 mov     r3, r2
 503                 mov     r2, r1
 504                 b       sys_ftruncate64
 505 ENDPROC(sys_oabi_ftruncate64)
 506
 507 sys_oabi_readahead:
 508                 str     r3, [sp]
 509                 mov     r3, r2
 510                 mov     r2, r1
 511                 b       sys_readahead
 512 ENDPROC(sys_oabi_readahead)
 513
 514 /*
 515  * Let's declare a second syscall table for old ABI binaries
 516  * using the compatibility syscall entries.
 517  */
 518 #define ABI(native, compat) compat
 519 #define OBSOLETE(syscall) syscall
 520
 521         .type   sys_oabi_call_table, #object
 522 ENTRY(sys_oabi_call_table)
 523 #include "calls.S"
 524 #undef ABI
 525 #undef OBSOLETE
 526
 527 #endif
 528