arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <mach/entry-macro.S>
  14 #include <asm/unwind.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26  UNWIND(.fnstart        )
  27  UNWIND(.cantunwind     )
  28         disable_irq                             @ disable interrupts
  29         ldr     r1, [tsk, #TI_FLAGS]
  30         tst     r1, #_TIF_WORK_MASK
  31         bne     fast_work_pending
  32
  33         /* perform architecture specific actions before user return */
  34         arch_ret_to_user r1, lr
  35
  36         restore_user_regs fast = 1, offset = S_OFF
  37  UNWIND(.fnend          )
  38
  39 /*
  40  * Ok, we need to do extra processing, enter the slow path.
  41  */
  42 fast_work_pending:
  43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  44 work_pending:
  45         tst     r1, #_TIF_NEED_RESCHED
  46         bne     work_resched
  47         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
  48         beq     no_work_pending
  49         mov     r0, sp                          @ 'regs'
  50         mov     r2, why                         @ 'syscall'
  51         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
  52         movne   why, #0                         @ prevent further restarts
  53         bl      do_notify_resume
  54         b       ret_slow_syscall                @ Check work again
  55
  56 work_resched:
  57         bl      schedule
  58 /*
  59  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  60  */
  61 ENTRY(ret_to_user)
  62 ret_slow_syscall:
  63         disable_irq                             @ disable interrupts
  64         ldr     r1, [tsk, #TI_FLAGS]
  65         tst     r1, #_TIF_WORK_MASK
  66         bne     work_pending
  67 no_work_pending:
  68         /* perform architecture specific actions before user return */
  69         arch_ret_to_user r1, lr
  70
  71         restore_user_regs fast = 0, offset = 0
  72 ENDPROC(ret_to_user)
  73
  74 /*
  75  * This is how we return from a fork.
  76  */
  77 ENTRY(ret_from_fork)
  78         bl      schedule_tail
  79         get_thread_info tsk
  80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  81         mov     why, #1
  82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  83         beq     ret_slow_syscall
  84         mov     r1, sp
  85         mov     r0, #1                          @ trace exit [IP = 1]
  86         bl      syscall_trace
  87         b       ret_slow_syscall
  88 ENDPROC(ret_from_fork)
  89
  90         .equ NR_syscalls,0
  91 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  92 #include "calls.S"
  93 #undef CALL
  94 #define CALL(x) .long x
  95
  96 #ifdef CONFIG_FUNCTION_TRACER
  97 /*
  98  * When compiling with -pg, gcc inserts a call to the mcount routine at the
  99  * start of every function.  In mcount, apart from the function's address (in
 100  * lr), we need to get hold of the function's caller's address.
 101  *
 102  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 103  *
 104  *      bl      mcount
 105  *
 106  * These versions have the limitation that in order for the mcount routine to
 107  * be able to determine the function's caller's address, an APCS-style frame
 108  * pointer (which is set up with something like the code below) is required.
 109  *
 110  *      mov     ip, sp
 111  *      push    {fp, ip, lr, pc}
 112  *      sub     fp, ip, #4
 113  *
 114  * With EABI, these frame pointers are not available unless -mapcs-frame is
 115  * specified, and if building as Thumb-2, not even then.
 116  *
 117  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 118  * with call sites like:
 119  *
 120  *      push    {lr}
 121  *      bl      __gnu_mcount_nc
 122  *
 123  * With these compilers, frame pointers are not necessary.
 124  *
 125  * mcount can be thought of as a function called in the middle of a subroutine
 126  * call.  As such, it needs to be transparent for both the caller and the
 127  * callee: the original lr needs to be restored when leaving mcount, and no
 128  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 129  * clobber the ip register.  This is OK because the ARM calling convention
 130  * allows it to be clobbered in subroutines and doesn't use it to hold
 131  * parameters.)
 132  *
 133  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 134  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 135  * arch/arm/kernel/ftrace.c).
 136  */
 137
 138 #ifndef CONFIG_OLD_MCOUNT
 139 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 140 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 141 #endif
 142 #endif
 143
 144 #ifdef CONFIG_DYNAMIC_FTRACE
 145 ENTRY(__gnu_mcount_nc)
 146         mov     ip, lr
 147         ldmia   sp!, {lr}
 148         mov     pc, ip
 149 ENDPROC(__gnu_mcount_nc)
 150
 151 ENTRY(ftrace_caller)
 152         stmdb   sp!, {r0-r3, lr}
 153         mov     r0, lr
 154         sub     r0, r0, #MCOUNT_INSN_SIZE
 155         ldr     r1, [sp, #20]
 156
 157         .global ftrace_call
 158 ftrace_call:
 159         bl      ftrace_stub
 160         ldmia   sp!, {r0-r3, ip, lr}
 161         mov     pc, ip
 162 ENDPROC(ftrace_caller)
 163
 164 #ifdef CONFIG_OLD_MCOUNT
 165 ENTRY(mcount)
 166         stmdb   sp!, {lr}
 167         ldr     lr, [fp, #-4]
 168         ldmia   sp!, {pc}
 169 ENDPROC(mcount)
 170
 171 ENTRY(ftrace_caller_old)
 172         stmdb   sp!, {r0-r3, lr}
 173         ldr     r1, [fp, #-4]
 174         mov     r0, lr
 175         sub     r0, r0, #MCOUNT_INSN_SIZE
 176
 177         .globl ftrace_call_old
 178 ftrace_call_old:
 179         bl      ftrace_stub
 180         ldr     lr, [fp, #-4]                   @ restore lr
 181         ldmia   sp!, {r0-r3, pc}
 182 ENDPROC(ftrace_caller_old)
 183 #endif
 184
 185 #else
 186
 187 ENTRY(__gnu_mcount_nc)
 188         stmdb   sp!, {r0-r3, lr}
 189         ldr     r0, =ftrace_trace_function
 190         ldr     r2, [r0]
 191         adr     r0, .Lftrace_stub
 192         cmp     r0, r2
 193         bne     gnu_trace
 194         ldmia   sp!, {r0-r3, ip, lr}
 195         mov     pc, ip
 196
 197 gnu_trace:
 198         ldr     r1, [sp, #20]                   @ lr of instrumented routine
 199         mov     r0, lr
 200         sub     r0, r0, #MCOUNT_INSN_SIZE
 201         adr     lr, BSYM(1f)
 202         mov     pc, r2
 203 1:
 204         ldmia   sp!, {r0-r3, ip, lr}
 205         mov     pc, ip
 206 ENDPROC(__gnu_mcount_nc)
 207
 208 #ifdef CONFIG_OLD_MCOUNT
 209 /*
 210  * This is under an ifdef in order to force link-time errors for people trying
 211  * to build with !FRAME_POINTER with a GCC which doesn't use the new-style
 212  * mcount.
 213  */
 214 ENTRY(mcount)
 215         stmdb   sp!, {r0-r3, lr}
 216         ldr     r0, =ftrace_trace_function
 217         ldr     r2, [r0]
 218         adr     r0, ftrace_stub
 219         cmp     r0, r2
 220         bne     trace
 221         ldr     lr, [fp, #-4]                   @ restore lr
 222         ldmia   sp!, {r0-r3, pc}
 223
 224 trace:
 225         ldr     r1, [fp, #-4]                   @ lr of instrumented routine
 226         mov     r0, lr
 227         sub     r0, r0, #MCOUNT_INSN_SIZE
 228         mov     lr, pc
 229         mov     pc, r2
 230         ldr     lr, [fp, #-4]                   @ restore lr
 231         ldmia   sp!, {r0-r3, pc}
 232 ENDPROC(mcount)
 233 #endif
 234
 235 #endif /* CONFIG_DYNAMIC_FTRACE */
 236
 237 ENTRY(ftrace_stub)
 238 .Lftrace_stub:
 239         mov     pc, lr
 240 ENDPROC(ftrace_stub)
 241
 242 #endif /* CONFIG_FUNCTION_TRACER */
 243
 244 /*=============================================================================
 245  * SWI handler
 246  *-----------------------------------------------------------------------------
 247  */
 248
 249         /* If we're optimising for StrongARM the resulting code won't
 250            run on an ARM7 and we can save a couple of instructions.
 251                                                                 --pb */
 252 #ifdef CONFIG_CPU_ARM710
 253 #define A710(code...) code
 254 .Larm710bug:
 255         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 256         mov     r0, r0
 257         add     sp, sp, #S_FRAME_SIZE
 258         subs    pc, lr, #4
 259 #else
 260 #define A710(code...)
 261 #endif
 262
 263         .align  5
 264 ENTRY(vector_swi)
 265         sub     sp, sp, #S_FRAME_SIZE
 266         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 267  ARM(   add     r8, sp, #S_PC           )
 268  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 269  THUMB( mov     r8, sp                  )
 270  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 271         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 272         str     lr, [sp, #S_PC]                 @ Save calling PC
 273         str     r8, [sp, #S_PSR]                @ Save CPSR
 274         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 275         zero_fp
 276
 277         /*
 278          * Get the system call number.
 279          */
 280
 281 #if defined(CONFIG_OABI_COMPAT)
 282
 283         /*
 284          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 285          * value to determine if it is an EABI or an old ABI call.
 286          */
 287 #ifdef CONFIG_ARM_THUMB
 288         tst     r8, #PSR_T_BIT
 289         movne   r10, #0                         @ no thumb OABI emulation
 290         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 291 #else
 292         ldr     r10, [lr, #-4]                  @ get SWI instruction
 293   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 294   A710( teq     ip, #0x0f000000                                         )
 295   A710( bne     .Larm710bug                                             )
 296 #endif
 297 #ifdef CONFIG_CPU_ENDIAN_BE8
 298         rev     r10, r10                        @ little endian instruction
 299 #endif
 300
 301 #elif defined(CONFIG_AEABI)
 302
 303         /*
 304          * Pure EABI user space always put syscall number into scno (r7).
 305          */
 306   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 307   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 308   A710( teq     ip, #0x0f000000                                         )
 309   A710( bne     .Larm710bug                                             )
 310
 311 #elif defined(CONFIG_ARM_THUMB)
 312
 313         /* Legacy ABI only, possibly thumb mode. */
 314         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 315         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 316         ldreq   scno, [lr, #-4]
 317
 318 #else
 319
 320         /* Legacy ABI only. */
 321         ldr     scno, [lr, #-4]                 @ get SWI instruction
 322   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 323   A710( teq     ip, #0x0f000000                                         )
 324   A710( bne     .Larm710bug                                             )
 325
 326 #endif
 327
 328 #ifdef CONFIG_ALIGNMENT_TRAP
 329         ldr     ip, __cr_alignment
 330         ldr     ip, [ip]
 331         mcr     p15, 0, ip, c1, c0              @ update control register
 332 #endif
 333         enable_irq
 334
 335         get_thread_info tsk
 336         adr     tbl, sys_call_table             @ load syscall table pointer
 337         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 338
 339 #if defined(CONFIG_OABI_COMPAT)
 340         /*
 341          * If the swi argument is zero, this is an EABI call and we do nothing.
 342          *
 343          * If this is an old ABI call, get the syscall number into scno and
 344          * get the old ABI syscall table address.
 345          */
 346         bics    r10, r10, #0xff000000
 347         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 348         ldrne   tbl, =sys_oabi_call_table
 349 #elif !defined(CONFIG_AEABI)
 350         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 351         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 352 #endif
 353
 354         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 355         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 356         bne     __sys_trace
 357
 358         cmp     scno, #NR_syscalls              @ check upper syscall limit
 359         adr     lr, BSYM(ret_fast_syscall)      @ return address
 360         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 361
 362         add     r1, sp, #S_OFF
 363 2:      mov     why, #0                         @ no longer a real syscall
 364         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 365         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 366         bcs     arm_syscall
 367         b       sys_ni_syscall                  @ not private func
 368 ENDPROC(vector_swi)
 369
 370         /*
 371          * This is the really slow path.  We're going to be doing
 372          * context switches, and waiting for our parent to respond.
 373          */
 374 __sys_trace:
 375         mov     r2, scno
 376         add     r1, sp, #S_OFF
 377         mov     r0, #0                          @ trace entry [IP = 0]
 378         bl      syscall_trace
 379
 380         adr     lr, BSYM(__sys_trace_return)    @ return address
 381         mov     scno, r0                        @ syscall number (possibly new)
 382         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 383         cmp     scno, #NR_syscalls              @ check upper syscall limit
 384         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 385         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 386         b       2b
 387
 388 __sys_trace_return:
 389         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 390         mov     r2, scno
 391         mov     r1, sp
 392         mov     r0, #1                          @ trace exit [IP = 1]
 393         bl      syscall_trace
 394         b       ret_slow_syscall
 395
 396         .align  5
 397 #ifdef CONFIG_ALIGNMENT_TRAP
 398         .type   __cr_alignment, #object
 399 __cr_alignment:
 400         .word   cr_alignment
 401 #endif
 402         .ltorg
 403
 404 /*
 405  * This is the syscall table declaration for native ABI syscalls.
 406  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 407  */
 408 #define ABI(native, compat) native
 409 #ifdef CONFIG_AEABI
 410 #define OBSOLETE(syscall) sys_ni_syscall
 411 #else
 412 #define OBSOLETE(syscall) syscall
 413 #endif
 414
 415         .type   sys_call_table, #object
 416 ENTRY(sys_call_table)
 417 #include "calls.S"
 418 #undef ABI
 419 #undef OBSOLETE
 420
 421 /*============================================================================
 422  * Special system call wrappers
 423  */
 424 @ r0 = syscall number
 425 @ r8 = syscall table
 426 sys_syscall:
 427                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 428                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 429                 cmpne   scno, #NR_syscalls      @ check range
 430                 stmloia sp, {r5, r6}            @ shuffle args
 431                 movlo   r0, r1
 432                 movlo   r1, r2
 433                 movlo   r2, r3
 434                 movlo   r3, r4
 435                 ldrlo   pc, [tbl, scno, lsl #2]
 436                 b       sys_ni_syscall
 437 ENDPROC(sys_syscall)
 438
 439 sys_fork_wrapper:
 440                 add     r0, sp, #S_OFF
 441                 b       sys_fork
 442 ENDPROC(sys_fork_wrapper)
 443
 444 sys_vfork_wrapper:
 445                 add     r0, sp, #S_OFF
 446                 b       sys_vfork
 447 ENDPROC(sys_vfork_wrapper)
 448
 449 sys_execve_wrapper:
 450                 add     r3, sp, #S_OFF
 451                 b       sys_execve
 452 ENDPROC(sys_execve_wrapper)
 453
 454 sys_clone_wrapper:
 455                 add     ip, sp, #S_OFF
 456                 str     ip, [sp, #4]
 457                 b       sys_clone
 458 ENDPROC(sys_clone_wrapper)
 459
 460 sys_sigreturn_wrapper:
 461                 add     r0, sp, #S_OFF
 462                 mov     why, #0         @ prevent syscall restart handling
 463                 b       sys_sigreturn
 464 ENDPROC(sys_sigreturn_wrapper)
 465
 466 sys_rt_sigreturn_wrapper:
 467                 add     r0, sp, #S_OFF
 468                 mov     why, #0         @ prevent syscall restart handling
 469                 b       sys_rt_sigreturn
 470 ENDPROC(sys_rt_sigreturn_wrapper)
 471
 472 sys_sigaltstack_wrapper:
 473                 ldr     r2, [sp, #S_OFF + S_SP]
 474                 b       do_sigaltstack
 475 ENDPROC(sys_sigaltstack_wrapper)
 476
 477 sys_statfs64_wrapper:
 478                 teq     r1, #88
 479                 moveq   r1, #84
 480                 b       sys_statfs64
 481 ENDPROC(sys_statfs64_wrapper)
 482
 483 sys_fstatfs64_wrapper:
 484                 teq     r1, #88
 485                 moveq   r1, #84
 486                 b       sys_fstatfs64
 487 ENDPROC(sys_fstatfs64_wrapper)
 488
 489 /*
 490  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 491  * offset, we return EINVAL.
 492  */
 493 sys_mmap2:
 494 #if PAGE_SHIFT > 12
 495                 tst     r5, #PGOFF_MASK
 496                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 497                 streq   r5, [sp, #4]
 498                 beq     sys_mmap_pgoff
 499                 mov     r0, #-EINVAL
 500                 mov     pc, lr
 501 #else
 502                 str     r5, [sp, #4]
 503                 b       sys_mmap_pgoff
 504 #endif
 505 ENDPROC(sys_mmap2)
 506
 507 #ifdef CONFIG_OABI_COMPAT
 508
 509 /*
 510  * These are syscalls with argument register differences
 511  */
 512
 513 sys_oabi_pread64:
 514                 stmia   sp, {r3, r4}
 515                 b       sys_pread64
 516 ENDPROC(sys_oabi_pread64)
 517
 518 sys_oabi_pwrite64:
 519                 stmia   sp, {r3, r4}
 520                 b       sys_pwrite64
 521 ENDPROC(sys_oabi_pwrite64)
 522
 523 sys_oabi_truncate64:
 524                 mov     r3, r2
 525                 mov     r2, r1
 526                 b       sys_truncate64
 527 ENDPROC(sys_oabi_truncate64)
 528
 529 sys_oabi_ftruncate64:
 530                 mov     r3, r2
 531                 mov     r2, r1
 532                 b       sys_ftruncate64
 533 ENDPROC(sys_oabi_ftruncate64)
 534
 535 sys_oabi_readahead:
 536                 str     r3, [sp]
 537                 mov     r3, r2
 538                 mov     r2, r1
 539                 b       sys_readahead
 540 ENDPROC(sys_oabi_readahead)
 541
 542 /*
 543  * Let's declare a second syscall table for old ABI binaries
 544  * using the compatibility syscall entries.
 545  */
 546 #define ABI(native, compat) compat
 547 #define OBSOLETE(syscall) syscall
 548
 549         .type   sys_oabi_call_table, #object
 550 ENTRY(sys_oabi_call_table)
 551 #include "calls.S"
 552 #undef ABI
 553 #undef OBSOLETE
 554
 555 #endif
 556