Merge openembedded@openembedded.bkbits.net:packages

into linux.local:/home/kergoth/code/packages

2004/04/27 01:26:37-04:00 local!kergoth
Change the gcc URI to point to gcc/gcc-version rather than gcc/releases.

BKrev: 408def11ts7afuAl9NHST94oH5_wwg

diff --git a/gcc/gcc_3.3.3.oe b/gcc/gcc_3.3.3.oe
index 48358f4..d7f41c3 100644 (file)
--- a/gcc/gcc_3.3.3.oe
+++ b/gcc/gcc_3.3.3.oe
@@ -66,7 +66,7 @@ FILES_${PN}-doc = "${infodir} \
                   ${mandir} \
                   ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/include/README"
 
-SRC_URI = "${GNU_MIRROR}/gcc/releases/gcc-${PV}/gcc-${PV}.tar.bz2 \
+SRC_URI = "${GNU_MIRROR}/gcc/gcc-${PV}/gcc-${PV}.tar.bz2 \
           file://${FILESDIR}/config.sub.patch;patch=1 \
           file://${FILESDIR}/empty6.patch;patch=1 \
           file://${FILESDIR}/pr10392-1-test.patch;patch=1 \

diff --git a/gcc/gcc_3.4.0.oe b/gcc/gcc_3.4.0.oe
index e69de29..28ecd4f 100644 (file)
--- a/gcc/gcc_3.4.0.oe
+++ b/gcc/gcc_3.4.0.oe
@@ -0,0 +1,178 @@
+inherit autotools
+
+DESCRIPTION = "The GNU cc and gcc C compilers."
+LICENSE = "GPL"
+MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
+
+#
+# TODO: For shared setups with both uclibc and glibc, libstdc++ and the
+#       fortran (libg2c, libfrtbegin) will need to be moved into separate
+#       per-compiler paths.  Shared libraries will also need some
+#       separation.  This will also require changes to the dynamic linkers
+#       for the two libc's to support selection of appropriate libraries.
+#
+# This affects: binutils, gcc, uclibc, glibc
+#
+# For now, we will skip building of a gcc package if it is a uclibc one
+# and our build is not a uclibc one, and we skip a glibc one if our build
+# is a uclibc build.
+#
+
+python __anonymous () {
+    import oe, re
+    uc_pkg = (re.search('uclibc', oe.data.getVar('PN', d, 1)) != None)
+    uc_os = (re.match('.*uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None)
+    if uc_pkg != uc_os:
+        raise oe.parse.SkipPackage("incompatible with target %s" %
+                                   oe.data.getVar('TARGET_OS', d, 1))
+}
+
+DEPENDS = "glibc"
+
+# libgcc libstdc++ libg2c are listed in our FILES_*, but are actually
+# packaged in the respective cross packages.
+PACKAGES = "${PN} ${PN}-symlinks \
+            ${PN}-c++ ${PN}-c++-symlinks \
+            ${PN}-f77 ${PN}-f77-symlinks \
+            libstdc++-dev libg2c-dev \
+            ${PN}-doc"
+
+FILES_${PN} = "${bindir}/${TARGET_PREFIX}gcc \
+              ${bindir}/${TARGET_PREFIX}cpp \
+              ${bindir}/${TARGET_PREFIX}gcov \
+              ${bindir}/${TARGET_PREFIX}gccbug \
+              ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1 \
+              ${libexecdir}/gcc/${TARGET_SYS}/${PV}/collect2 \
+              ${libdir}/gcc/${TARGET_SYS}/${PV}/*.o \
+              ${libdir}/gcc/${TARGET_SYS}/${PV}/specs \
+              ${libdir}/gcc/${TARGET_SYS}/${PV}/lib* \
+              ${libdir}/gcc/${TARGET_SYS}/${PV}/include"
+
+FILES_${PN}-symlinks = "${bindir}/cc \
+                       ${bindir}/gcc \
+                       ${bindir}/cpp \
+                       ${bindir}/gcov \
+                       ${bindir}/gccbug"
+
+FILES_${PN}-f77 = "${bindir}/${TARGET_PREFIX}g77 \
+                  ${libexecdir}/gcc/${TARGET_SYS}/${PV}/f771"
+
+FILES_${PN}-f77-symlinks = "${bindir}/g77 \
+                           ${bindir}/f77"
+
+# Called from within gcc-cross, so libdir is set wrong
+#FILES_libg2c = "${libdir}/libg2c.so.*"
+FILES_libg2c = "/usr/lib/libg2c.so.*"
+
+FILES_libg2c-dev = "${libdir}/libg2c.so \
+                         ${libdir}/libg2c.a \
+                         ${libdir}/libfrtbegin.a"
+
+FILES_${PN}-c++ = "${bindir}/${TARGET_PREFIX}g++ \
+                  ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1plus"
+
+FILES_${PN}-c++-symlinks = "${bindir}/c++ \
+                           ${bindir}/g++"
+
+FILES_libgcc = "/lib/libgcc_s.so.*"
+
+# Called from within gcc-cross, so libdir is set wrong
+#FILES_libstdc++ = "${libdir}/libstdc++.so.*"
+FILES_libstdc++ = "/usr/lib/libstdc++.so.*"
+
+FILES_libstdc++-dev = "${includedir}/c++/${PV} \
+                      ${libdir}/libstdc++.so \
+                      ${libdir}/libstdc++.la \
+                      ${libdir}/libstdc++.a \
+                      ${libdir}/libsupc++.la \
+                      ${libdir}/libsupc++.a"
+
+FILES_${PN}-doc = "${infodir} \
+                  ${mandir} \
+                  ${libdir}/gcc/${TARGET_SYS}/${PV}/include/README"
+
+SRC_URI = "${GNU_MIRROR}/gcc/gcc-${PV}/gcc-${PV}.tar.bz2 \
+          file://${FILESDIR}/gcc34-reverse-compare.patch;patch=1 \
+          file://${FILESDIR}/gcc34-pre-modify.patch;patch=1 \
+          file://${FILESDIR}/gcc34-arm-ldm.patch;patch=1 \
+          file://${FILESDIR}/gcc34-arm-ldm-peephole.patch;patch=1 \
+          file://${FILESDIR}/gcc34-arm-tune.patch;patch=1"
+
+MIRRORS_prepend () {
+${GNU_MIRROR}/gcc/releases/    http://gcc.get-software.com/releases/
+}
+
+S = "${WORKDIR}/gcc-${PV}"
+B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
+
+EXTRA_OECONF = "--with-local-prefix=${prefix}/local \
+               --with-gxx-include-dir=${includedir}/c++/${PV} \
+               --enable-target-optspace \
+               --disable-nls \
+               --with-gnu-ld \
+               --disable-__cxa_atexit \
+               --enable-languages=c,c++,f77 \
+               --enable-shared \
+               --enable-multilib \
+               --program-prefix=${TARGET_PREFIX}"
+
+do_configure () {
+       # Setup these vars for cross building only
+       if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
+               export CC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
+               export GCC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
+               export CXX_FOR_TARGET="${CCACHE} ${HOST_PREFIX}g++"
+               export AS_FOR_TARGET="${HOST_PREFIX}as"
+               export LD_FOR_TARGET="${HOST_PREFIX}ld"
+               export NM_FOR_TARGET="${HOST_PREFIX}nm"
+               export AR_FOR_TARGET="${HOST_PREFIX}ar"
+               export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
+       fi
+       oe_runconf
+}
+
+do_install () {
+       autotools_do_install
+
+       # Cleanup some of the /usr/lib{,exec}/gcc stuff ...
+       rm -r ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/install-tools
+       rm -r ${D}/${libexecdir}/gcc/${TARGET_SYS}/${PV}/install-tools
+
+       # Move libgcc_s into /lib
+       mkdir -p ${D}/lib
+       mv ${D}/${libdir}/libgcc_s.so.* ${D}/lib
+       rm ${D}/${libdir}/libgcc_s.so
+       ln -s `echo ${libdir}/gcc/${TARGET_SYS}/${PV} \
+               | tr -s / \
+               | sed -e 's,^/,,' -e 's,[^/]*,..,g'`/lib/libgcc_s.so.? \
+                     ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/libgcc_s.so
+
+       # We don't need libtool libraries
+       rm ${D}/${libdir}/libg2c.la
+
+       # Cleanup manpages..
+       rm -r ${D}/${mandir}/man7
+
+       # We use libiberty from binutils
+       rm ${D}/${libdir}/libiberty.a
+
+       cd ${D}/${bindir}
+
+       # We care about g++ not c++
+       rm *c++
+
+       # We don't care about the gcc-<version> ones for this
+       rm *gcc-?.?*
+
+       # These sometimes show up, they are strange, we remove them
+       rm -f ${TARGET_ARCH}-*${TARGET_ARCH}-*
+
+       # Symlinks so we can use these trivially on the target
+       ln -s ${TARGET_SYS}-g77 g77
+       ln -s ${TARGET_SYS}-g++ g++
+       ln -s ${TARGET_SYS}-gcc gcc
+       ln -s g77 f77
+       ln -s g++ c++
+       ln -s gcc cc
+}
+