add crimsonfields, a popular tactical war game in the tradition of Battle Isle

NOTE: this was pretty complex and annoying as I had to add a native libsdl and
a native libsdl-ttf as well as a native version of the crimsonfields tools :/

diff --git a/packages/libsdl/libsdl-x11-1.2.7/.mtn2git_empty b/packages/crimsonfields/.mtn2git_empty
similarity index 100%
rename from packages/libsdl/libsdl-x11-1.2.7/.mtn2git_empty
rename to packages/crimsonfields/.mtn2git_empty

diff --git a/packages/crimsonfields/crimsonfields-native_0.4.8.bb b/packages/crimsonfields/crimsonfields-native_0.4.8.bb
new file mode 100644 (file)
index 0000000..1e28caf
--- /dev/null
+++ b/packages/crimsonfields/crimsonfields-native_0.4.8.bb
@@ -0,0 +1,27 @@
+include crimsonfields_${PV}.bb
+inherit native
+
+DEPENDS = "libsdl-native libsdl-ttf-native"
+export SDL_CONFIG = "${STAGING_BINDIR}/sdl-config-native"
+
+do_configure() {
+       gnu-configize
+       oe_runconf
+}
+
+do_compile() {
+       cd tools && oe_runmake
+}
+
+do_stage() {
+       for binary in ${HOST_TOOLS}
+       do
+               install -m 0755 tools/$binary ${STAGING_BINDIR}
+       done
+       install -m 0644 tools/default.* ${STAGING_DATADIR}
+}
+
+do_install() {
+       :
+}
+

diff --git a/packages/crimsonfields/crimsonfields_0.4.8.bb b/packages/crimsonfields/crimsonfields_0.4.8.bb
new file mode 100644 (file)
index 0000000..7afd205
--- /dev/null
+++ b/packages/crimsonfields/crimsonfields_0.4.8.bb
@@ -0,0 +1,33 @@
+DESCRIPTION = "Crimson Fields is a tactical war game in the tradition of Battle Isle."
+SECTION = "games"
+DEPENDS = "crimsonfields-native virtual/libsdl libsdl-mixer libsdl-ttf"
+MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
+LICENSE = "GPL"
+PR = "r0"
+
+SRC_URI = "http://crimson.seul.org/files/crimson-${PV}.tar.bz2 \
+           file://native-tools.patch;patch=1"
+S = "${WORKDIR}/crimson-${PV}"
+
+inherit autotools 
+
+HOST_TOOLS = "cfed mkdatafile mklocale mktileset mkunitset"
+
+do_configure() {
+       gnu-configize
+       oe_runconf
+       for binary in ${HOST_TOOLS}
+       do
+               install -m 0755 ${STAGING_DIR}/${BUILD_SYS}/bin/$binary tools/
+       done
+       install -m 0644 ${STAGING_DIR}/${BUILD_SYS}/share/default.* tools/
+}
+
+do_install_append() {
+       install -d ${D}${palmtopdir}/apps/Games/
+       install -d ${D}${palmtopdir}/pics/
+       install -m 0644 ${D}${datadir}/applications/crimson.desktop ${D}${palmtopdir}/apps/Games/
+       install -m 0644 ${D}${datadir}/pixmaps/*.png ${D}${palmtopdir}/pics/
+}
+
+FILES_${PN} = "${bindir} ${datadir} ${palmtopdir}"

diff --git a/packages/nonworking/crimsonfields/.mtn2git_empty b/packages/crimsonfields/files/.mtn2git_empty
similarity index 100%
rename from packages/nonworking/crimsonfields/.mtn2git_empty
rename to packages/crimsonfields/files/.mtn2git_empty

diff --git a/packages/crimsonfields/files/native-tools.patch b/packages/crimsonfields/files/native-tools.patch
new file mode 100644 (file)
index 0000000..aa5ecc4
--- /dev/null
+++ b/packages/crimsonfields/files/native-tools.patch
@@ -0,0 +1,16 @@
+
+#
+# Patch managed by http://www.holgerschurig.de/patcher.html
+#
+
+--- crimson-0.4.8/Makefile.in~native-tools
++++ crimson-0.4.8/Makefile.in
+@@ -170,7 +170,7 @@
+ sysconfdir = @sysconfdir@
+ target_alias = @target_alias@
+ EXTRA_DIST = crimson.desktop crimson.spec.in README.bi2cf README.CoMET
+-SUBDIRS = doc src tools gfx levels locale music sfx
++SUBDIRS = doc src gfx levels locale music sfx
+ DISTCHECK_CONFIGURE_FLAGS = --enable-bi2cf --enable-cf2bmp --enable-cfed --enable-comet
+ desktopdir = $(datadir)/applications
+ desktop_DATA = crimson.desktop

diff --git a/packages/libsdl/files/.mtn2git_empty b/packages/libsdl/files/.mtn2git_empty
new file mode 100644 (file)
index 0000000..e69de29

diff --git a/packages/libsdl/libsdl-x11-1.2.7/acinclude.m4 b/packages/libsdl/files/acinclude.m4
similarity index 100%
rename from packages/libsdl/libsdl-x11-1.2.7/acinclude.m4
rename to packages/libsdl/files/acinclude.m4

diff --git a/packages/libsdl/libsdl-x11-1.2.7/extra-keys.patch b/packages/libsdl/files/extra-keys.patch
similarity index 100%
rename from packages/libsdl/libsdl-x11-1.2.7/extra-keys.patch
rename to packages/libsdl/files/extra-keys.patch

diff --git a/packages/libsdl/libsdl-native_1.2.7.bb b/packages/libsdl/libsdl-native_1.2.7.bb
new file mode 100644 (file)
index 0000000..9d1a73b
--- /dev/null
+++ b/packages/libsdl/libsdl-native_1.2.7.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = "Simple DirectMedia Layer - native Edition"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "LGPL"
+PR = "r0"
+
+SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz \
+          file://extra-keys.patch;patch=1 \
+          file://acinclude.m4"
+S = "${WORKDIR}/SDL-${PV}"
+
+inherit autotools native
+
+EXTRA_OECONF = "--disable-debug --disable-cdrom --enable-threads --enable-timers --enable-endian \
+                --enable-file --disable-oss --disable-alsa --disable-esd --disable-arts \
+                --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
+                --disable-mintaudio --disable-nasm --disable-video-x11 --disable-video-dga \
+                --disable-video-fbcon --disable-video-directfb --disable-video-ps2gs \
+                --disable-video-xbios --disable-video-gem --disable-video-dummy \
+                --disable-video-opengl --enable-input-events --enable-pthreads \
+                --disable-video-picogui --disable-video-qtopia --enable-dlopen"
+
+do_configure_prepend() {
+       rm -f ${S}/acinclude.m4
+       cp ${WORKDIR}/acinclude.m4 ${S}/
+}
+
+do_configure_append () {
+       cd ${S}
+
+       # prevent libtool from linking libs against libstdc++, libgcc, ...
+       cat ${TARGET_PREFIX}libtool | sed -e 's/postdeps=".*"/postdeps=""/' > ${TARGET_PREFIX}libtool.tmp
+       mv ${TARGET_PREFIX}libtool.tmp ${TARGET_PREFIX}libtool
+}
+
+do_stage() {
+       oe_libinstall -so -C src libSDL ${STAGING_LIBDIR}
+       ln -sf libSDL.so ${STAGING_LIBDIR}/libSDL-1.2.so
+       #oe_libinstall -a -C src/main libSDLmain ${STAGING_LIBDIR}
+       install -m 0644 src/main/libSDLmain.a ${STAGING_LIBDIR}
+
+       install -d ${STAGING_INCDIR}/SDL
+       for f in include/*.h
+       do
+               install -m 0644 $f ${STAGING_INCDIR}/SDL/
+       done
+
+       cat >${STAGING_BINDIR}/sdl-config-native <<EOF
+#!/bin/sh
+echo ""
+EOF
+       chmod a+rx ${STAGING_BINDIR}/sdl-config-native
+}

diff --git a/packages/libsdl/libsdl-ttf-native_2.0.3.bb b/packages/libsdl/libsdl-ttf-native_2.0.3.bb
new file mode 100644 (file)
index 0000000..ced6862
--- /dev/null
+++ b/packages/libsdl/libsdl-ttf-native_2.0.3.bb
@@ -0,0 +1,10 @@
+include libsdl-ttf_${PV}.bb
+inherit native
+
+DEPENDS = "libsdl-native"
+FILESPATH = "${FILE_DIRNAME}/libsdl-ttf-${PV}:${FILE_DIRNAME}/libsdl-ttf:${FILE_DIRNAME}/files"
+
+EXTRA_OECONF = "--disable-sdltest --with-sdl-prefix=${STAGING_LIBDIR}/.."
+
+export SDL_CONFIG = "${STAGING_BINDIR}/sdl-config-native"
+

diff --git a/packages/nonworking/crimsonfields/crimsonfields_0.4.6.bb b/packages/nonworking/crimsonfields/crimsonfields_0.4.6.bb
deleted file mode 100644 (file)
index 0674506..0000000
--- a/packages/nonworking/crimsonfields/crimsonfields_0.4.6.bb
+++ /dev/null
@@ -1,25 +0,0 @@
-DESCRIPTION = "Crimson Fields is a tactical war game in the tradition of Battle Isle."
-SECTION = "games"
-PRIORITY = "optional"
-DEPENDS = "virtual/libsdl libsdl-mixer libsdl-ttf"
-MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
-LICENSE = "GPL"
-
-SRC_URI = "http://crimson.seul.org/files/crimson-${PV}.tar.bz2"
-S = "${WORKDIR}/crimson-${PV}"
-
-inherit autotools 
-
-do_configure() {
-       gnu-configize
-       oe_runconf
-}
-
-do_compile() {
-       cd tools && oe_runmake \
-               CC="${BUILD_CC}" CXX="${BUILD_CXX}" LD="${BUILD_CCLD}" \
-               CFLAGS="${BUILD_CFLAGS}" CXXFLAGS="${BUILD_CXXFLAGS}" LDFLAGS="${BUILD_LDFLAGS}"
-       cd ${S} && oe_runmake
-}
-
-# FIXME: Add .desktop file for Opie/Qtopia