sablevm(-classpath): add 1.12 release.

diff --git a/packages/sablevm/sablevm-classpath_1.12.bb b/packages/sablevm/sablevm-classpath_1.12.bb
new file mode 100644 (file)
index 0000000..b712816
--- /dev/null
+++ b/packages/sablevm/sablevm-classpath_1.12.bb
@@ -0,0 +1,27 @@
+DESCRIPTION = "GNU Classpath modified to work with SableVM"
+HOMEPAGE = "http://sablevm.org"
+LICENSE = "Classpath"
+PRIORITY = "optional"
+MAINTAINER = "Rene Wagner <rw@handhelds.org>"
+SECTION = "libs"
+
+DEPENDS = "glib-2.0 gtk+ libart-lgpl pango xtst jikes-native zip-native"
+RDEPENDS_${PN} = "${PN}-native (>= ${PV})"
+
+SRC_URI = "http://sablevm.org/download/release/${PV}/${PN}-${PV}.tar.gz \
+           file://disable-automake-checks.patch;patch=1"
+
+inherit autotools
+
+EXTRA_OECONF = "--with-compressed-classes=zip"
+
+PACKAGES += " ${PN}-native"
+
+FILES_${PN} = "${datadir}/${PN} \
+               ${libdir}/sablevm"
+FILES_${PN}-native = "${libdir}/${PN}"
+
+do_install() {
+       autotools_do_install
+       mv ${D}${libdir}/security ${D}${libdir}/${PN}
+}

diff --git a/packages/sablevm/sablevm_1.12.bb b/packages/sablevm/sablevm_1.12.bb
new file mode 100644 (file)
index 0000000..030d802
--- /dev/null
+++ b/packages/sablevm/sablevm_1.12.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = "A highly-portable Java virtual machine implementing the Java virtual machine specification, second edition."
+HOMEPAGE = "http://sablevm.org"
+LICENSE = "LGPL"
+PRIORITY = "optional"
+MAINTAINER = "Rene Wagner <rw@handhelds.org>"
+SECTION = "interpreters"
+
+DEPENDS = "libffi libtool popt \
+           sablevm-classpath"
+#          unzip"
+RRECOMMENDS = "sablevm-classpath (>= ${PV})"
+
+SRC_URI = "http://sablevm.org/download/release/${PV}/${PN}-${PV}.tar.gz \
+           file://no-internal-libs.patch;patch=1"
+
+inherit autotools update-alternatives
+
+EXTRA_OECONF = "--enable-real-life-brokenness \
+                --disable-errors-on-warnings --disable-signals-for-exceptions"
+
+PROVIDES = "virtual/java"
+ALTERNATIVE_NAME = "java"
+ALTERNATIVE_PATH = "${bindir}/java-sablevm"
+ALTERNATIVE_PRIORITY = "350"
+
+PACKAGES = "${PN} ${PN}-doc lib${PN} lib${PN}-dev"
+
+FILES_${PN} = "${bindir} \
+              ${libdir}/${PN}/bin"
+
+FILES_lib${PN} = "${libdir}/lib${PN}-*.so"
+
+FILES_lib${PN}-dev = "${includedir}/jni* \
+                     ${libdir}/lib${PN}.so \
+                     ${libdir}/lib${PN}.la"
+
+do_configure() {
+       # remove internal copies of libpopt and libffi
+       rm -rf src/libpopt src/libffi
+
+       autotools_do_configure
+}
+
+do_install() {
+       autotools_do_install
+
+       install -d ${D}${docdir}
+       mv ${D}${datadir}/${PN} ${D}${docdir}/
+
+       # symlink only present in the deb...
+       install -d ${D}${libdir}/${PN}/bin
+       cd ${D}${libdir}/${PN}/bin && ln -sf ../../../bin/java-sablevm java
+}