transmission : make use .inc file as all recipes are pretty identical.

[openembedded.git] / recipes / transmission / transmission.inc

diff --git a/recipes/transmission/transmission.inc b/recipes/transmission/transmission.inc
new file mode 100644 (file)
index 0000000..1601f09
--- /dev/null
+++ b/recipes/transmission/transmission.inc
@@ -0,0 +1,38 @@
+DESCRIPTION = "Transmission is a BitTorrent client w/ a built-in Ajax-Powered Webif GUI."
+SECTION = "network"
+HOMEPAGE = "www.transmissionbt.com/"
+DEPENDS = "gtk+ gnutls openssl gettext libtool intltool-native curl glib-2.0-native"
+LICENSE = "GPLv2"
+PR = "r2"
+SRC_URI = "http://mirrors.m0k.org/transmission/files/transmission-${PV}.tar.bz2 \
+           file://init \
+           file://config"
+
+INITSCRIPT_NAME = "transmission"
+INITSCRIPT_PARAMS = "defaults 60 "
+
+inherit autotools update-rc.d
+
+do_install_append() {
+       install -d ${D}${sysconfdir}/init.d
+       install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/transmission
+       install -d ${D}${sysconfdir}/default
+       install -m 0755 ${WORKDIR}/config ${D}${sysconfdir}/default/transmission-daemon
+       install -d ${D}${localstatedir}/lib/transmission-daemon
+}
+
+FILES_${PN} += "${datadir}/icons"
+CONFFILES_${PN} = "${sysconfdir}/default/transmission-daemon"
+
+# No need for online check, since update-rc.d will prepend it to here
+pkg_postinst_${PN}() {
+grep -q transmission  ${sysconfdir}/group || addgroup transmission
+grep -q transmission ${sysconfdir}/passwd || adduser -h ${localstatedir}/lib/transmission-daemon -S -D -G transmission -s ${base_bindir}/false transmission
+chown -R transmission:transmission /var/lib/transmission-daemon/
+}
+
+pkg_postrm_${PN}() {
+delgroup transmission
+deluser transmission
+}
+