recipes/xorg-xserver/xserver-xorg_1.7.7.bb

   1 require xorg-xserver-common.inc
   2
   3 DESCRIPTION = "the X.Org X server"
   4 DEPENDS += "pixman libpciaccess openssl dri2proto glproto xorg-minimal-fonts"
   5 PE = "2"
   6 PR = "${INC_PR}.2"
   7
   8 SRC_URI = " http://xorg.freedesktop.org/archive/individual/xserver/${XORG_PN}-${PV}.tar.bz2;name=archive \
   9             file://sysroot_fix.patch;patch=1 \
  10             file://dolt-fix-1.7.0.patch;patch=1 \
  11             file://randr-support-1.7.0.patch;patch=1 \
  12             file://hack-fbdev-ignore-return-mode.patch;patch=1 \
  13            "
  14
  15 SRC_URI_append_angstrom = " file://hack-assume-pixman-supports-overlapped-blt.patch;patch=1"
  16 SRC_URI_append_shr = " file://hack-assume-pixman-supports-overlapped-blt.patch;patch=1"
  17
  18 # OpenPandora HACK! - Temp! - Do NOT put into mainline.
  19 SRC_URI_append_omap3-pandora = " \
  20             file://pnd-inputswitch-perf-hack.patch;patch=1 \
  21             file://xorg-kill-ugly-pattern.patch;patch=1 \
  22 "
  23
  24 do_install_prepend() {
  25         mkdir -p ${D}/${libdir}/X11/fonts
  26 }
  27
  28 # The NVidia driver requires Xinerama support in the X server. Ion uses it.
  29 XINERAMA = "${@['--disable-xinerama','--enable-xinerama'][bb.data.getVar('MACHINE',d) in ['ion']]}"
  30
  31 EXTRA_OECONF += " ${CONFIG_MANAGER_OPTION} ${XINERAMA} --disable-kdrive --disable-xephyr --disable-xsdl --disable-xfake --disable-xfbdev --disable-dmx"
  32 EXTRA_OECONF += " --disable-glx-tls --enable-dri2 --disable-unit-tests "
  33
  34 export LDFLAGS += " -ldl "
  35
  36 SRC_URI[archive.md5sum] = "8c0146330fb155c23d947ac37d431d4b"
  37 SRC_URI[archive.sha256sum] = "54c4d32bfeb8852adbea3ddae6981f3bc2eadb330124d9b35226c617c01926ff"