recipes/util-linux-ng/util-linux-ng.inc

   1 DESCRIPTION = "Util-linux-ng is a suite of essential utilities for any Linux system."
   2 SECTION = "base"
   3 LICENSE = "GPL"
   4 DEPENDS = "udev zlib ncurses virtual/libintl e2fsprogs-libs"
   5
   6 inherit autotools_stage
   7 AUTOTOOLS_STAGE_PKGCONFIG = "1"
   8
   9 DEFAULT_PREFERENCE = "-1"
  10
  11 # allows for a release candidate
  12 RC ?= ""
  13
  14 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/utils/util-linux-ng/v${PV}/util-linux-ng-${PV}${RC}.tar.bz2"
  15
  16 PACKAGES =+ "util-linux-ng-fdisk util-linux-ng-cfdisk util-linux-ng-sfdisk util-linux-ng-swaponoff util-linux-ng-losetup util-linux-ng-umount util-linux-ng-mount util-linux-ng-readprofile "
  17 PACKAGES_DYNAMIC = "libblkid*"
  18
  19 FILES_${PN}-doc += "/usr/share/misc/getopt/getopt-*.*"
  20 FILES_${PN} = "${bindir} ${sbindir} ${base_bindir} ${base_sbindir}"
  21
  22 FILES_util-linux-ng-fdisk = "/sbin/fdisk.${PN}"
  23 FILES_util-linux-ng-cfdisk = "/sbin/cfdisk"
  24 FILES_util-linux-ng-sfdisk = "/sbin/sfdisk"
  25 FILES_util-linux-ng-swaponoff = "/sbin/swapon.${PN} /sbin/swapoff.${PN}"
  26 FILES_util-linux-ng-losetup = "/sbin/losetup.${PN}"
  27 FILES_util-linux-ng-mount = "/bin/mount.${PN} ${sysconfdir}/default/mountall"
  28 FILES_util-linux-ng-umount = "/bin/umount.${PN}"
  29 FILES_util-linux-ng-readprofile = "/usr/sbin/readprofile.${PN}"
  30
  31 PACKAGES =+ "${PN}-mountall"
  32 FILES_${PN}-mountall = "${sysconfdir}/default/mountall"
  33 RREPLACES_${PN}-mountall = "busybox-mountall"
  34
  35 RRECOMMENDS_${PN} = "util-linux-ng-fdisk util-linux-ng-cfdisk util-linux-ng-sfdisk util-linux-ng-mount util-linux-ng-readprofile "
  36 RDEPENDS_${PN} = "${PN}-mountall util-linux-ng-umount util-linux-ng-swaponoff util-linux-ng-losetup"
  37
  38 EXTRA_OECONF = "--disable-use-tty-group --disable-makeinstall-chown \
  39 --enable-kill --enable-last --enable-mesg --enable-raw --enable-login-utils \
  40 --enable-arch --enable-init --enable-partx --enable-schedutils \
  41 --with-fsprobe=builtin"
  42
  43 S = "${WORKDIR}/util-linux-ng-${PV}${RC}"
  44
  45 do_compile () {
  46         set -e
  47 #       install ${WORKDIR}/MCONFIG ${S}/MCONFIG
  48 #       install ${WORKDIR}/make_include ${S}/make_include
  49 #       install ${WORKDIR}/swapargs.h ${S}/mount/swapargs.h
  50 #       install ${WORKDIR}/defines.h ${S}/defines.h
  51         oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= \
  52                 'OPT=${CFLAGS}' 'CC=${CC}' 'LD=${LD}' \
  53                 'LDFLAGS=${LDFLAGS}'
  54 }
  55
  56 checklink() {
  57         local targ link value
  58         targ="$1"
  59         link="$2"
  60         ext="$3"
  61         if test -h "$link"
  62         then
  63                 value="$(readlink "$link")"
  64                 if test "$value" = "$targ"
  65                 then
  66                         rm "$link"
  67                         ln -s "$targ"."${PN}" "$link$ext"
  68                         return 0
  69                 else
  70                         echo "$link: '$value' found '$targ' expected" >&2
  71                         return 1
  72                 fi
  73         else
  74                 echo "$link: not a symbolic link" >&2
  75                 return 1
  76         fi
  77 }
  78
  79 do_install () {
  80         # with ccache the timestamps on compiled files may
  81         # end up earlier than on their inputs, this allows
  82         # for the resultant compilation in the install step.
  83         oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= \
  84                 'OPT=${CFLAGS}' 'CC=${CC}' 'LD=${LD}' \
  85                 'LDFLAGS=${LDFLAGS}' 'DESTDIR=${D}' install
  86         mkdir -p ${D}${base_bindir}
  87
  88         sbinprogs="agetty blockdev ctrlaltdel cfdisk"
  89         sbinprogs_a="pivot_root hwclock mkswap shutdown mkfs.minix fsck.minix losetup swapon fdisk readprofile"
  90         usrbinprogs_a="hexdump last logger mesg renice wall"
  91         binprogs_a="dmesg kill more umount mount"
  92
  93         if [ "${base_sbindir}" != "${sbindir}" ]; then
  94                 mkdir -p ${D}${base_sbindir}
  95                 for p in $sbinprogs $sbinprogs_a; do
  96                         if [ -f "${D}${sbindir}/$p" ]; then
  97                                 mv "${D}${sbindir}/$p" "${D}${base_sbindir}/$p"
  98                         fi
  99                 done
 100         fi
 101
 102         if [ "${base_bindir}" != "${bindir}" ]; then
 103                 mkdir -p ${D}${base_bindir}
 104                 for p in $binprogs_a; do
 105                         if [ -f "${D}${bindir}/$p" ]; then
 106                                 mv "${D}${bindir}/$p" "${D}${base_bindir}/$p"
 107                         fi
 108                 done
 109         fi
 110
 111         for p in $usrbinprogs_a; do
 112                 if [ -f "${D}${bindir}/$p" ]; then
 113                         mv "${D}${bindir}/$p" "${D}${bindir}/$p.${PN}"
 114                 fi
 115         done
 116
 117         for p in $binprogs_a; do
 118                 if [ -f "${D}${base_bindir}/$p" ]; then
 119                         mv "${D}${base_bindir}/$p" "${D}${base_bindir}/$p.${PN}"
 120                 fi
 121         done
 122
 123         for p in $sbinprogs_a; do
 124                 if [ -f "${D}${base_sbindir}/$p" ]; then
 125                         mv "${D}${base_sbindir}/$p" "${D}${base_sbindir}/$p.${PN}"
 126                 fi
 127         done
 128
 129         install -d ${D}${sysconfdir}/default/
 130         echo 'MOUNTALL="-t nonfs,nosmbfs,noncpfs"' > ${D}${sysconfdir}/default/mountall
 131
 132         ln -sf ${sbindir}/swapon ${D}${sbindir}/swapoff.${PN}
 133         ln -sf ${sbindir}/shutdown ${D}${sbindir}/reboot.${PN}
 134         ln -sf ${sbindir}/shutdown ${D}${sbindir}/halt.${PN}
 135         ln -sf ${sbindir}/shutdown ${D}${sbindir}/fastboot
 136         ln -sf ${sbindir}/shutdown ${D}${sbindir}/fasthalt
 137 }
 138
 139 python populate_packages_prepend () {
 140         ulinxng_libdir = bb.data.expand('${libdir}', d)
 141         ulinxng_libdir_dbg = bb.data.expand('${libdir}/.debug', d)
 142         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'util-linux-ng %s development package', extra_depends='${PN}-dev', allow_links=True)
 143         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'util-linux-ng %s development package', extra_depends='${PN}-dev')
 144         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'util-linux-ng %s development package', extra_depends='${PN}-dev')
 145         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.so\.*', 'lib%s', 'util-linux-ng %s library', extra_depends='', allow_links=True)
 146 }
 147
 148
 149 pkg_postinst_${PN} () {
 150         update-alternatives --install ${base_bindir}/dmesg dmesg dmesg.${PN} 100
 151         update-alternatives --install ${base_bindir}/kill kill kill.${PN} 100
 152         update-alternatives --install ${base_bindir}/more more more.${PN} 100
 153         update-alternatives --install ${base_sbindir}/mkswap mkswap mkswap.${PN} 100
 154         test -x ${base_sbindir}/pivot_root.${PN} && \
 155         update-alternatives --install ${base_sbindir}/pivot_root pivot_root pivot_root.${PN} 100
 156         update-alternatives --install ${base_sbindir}/sln sln sln.${PN} 100
 157         update-alternatives --install ${base_sbindir}/mkfs.minix mkfs.minix mkfs.minix.${PN} 100
 158         update-alternatives --install ${base_sbindir}/fsck.minix fsck.minix fsck.minix.${PN} 100
 159         update-alternatives --install ${bindir}/hexdump hexdump hexdump.${PN} 100
 160         update-alternatives --install ${bindir}/last last last.${PN} 100
 161         update-alternatives --install ${bindir}/logger logger logger.${PN} 100
 162         update-alternatives --install ${bindir}/mesg mesg mesg.${PN} 100
 163         update-alternatives --install ${bindir}/renice renice renice.${PN} 100
 164         update-alternatives --install ${bindir}/wall wall wall.${PN} 100
 165
 166         # There seems to be problem, atleast on nslu2, with these, until they are
 167         # fixed the busybox ones have higher priority
 168         update-alternatives --install ${base_sbindir}/hwclock hwclock hwclock.${PN} 10
 169         update-alternatives --install ${base_sbindir}/shutdown shutdown shutdown.${PN} 10
 170         update-alternatives --install ${base_sbindir}/reboot reboot reboot.${PN} 10
 171         update-alternatives --install ${base_sbindir}/halt halt halt.${PN} 10
 172 }
 173
 174 pkg_prerm_${PN} () {
 175         test -x ${base_sbindir}/pivot_root.${PN} && \
 176         update-alternatives --remove pivot_root pivot_root.${PN}
 177         update-alternatives --remove dmesg dmesg.${PN}
 178         update-alternatives --remove kill kill.${PN}
 179         update-alternatives --remove more more.${PN}
 180         update-alternatives --remove halt halt.${PN}
 181         update-alternatives --remove hwclock hwclock.${PN}
 182         update-alternatives --remove mkswap mkswap.${PN}
 183         update-alternatives --remove reboot reboot.${PN}
 184         update-alternatives --remove shutdown shutdown.${PN}
 185         update-alternatives --remove sln sln.${PN}
 186         update-alternatives --remove mkfs.minix mkfs.minix.${PN}
 187         update-alternatives --remove fsck.minix fsck.minix.${PN}
 188         update-alternatives --remove hexdump hexdump.${PN}
 189         update-alternatives --remove last last.${PN}
 190         update-alternatives --remove logger logger.${PN}
 191         update-alternatives --remove mesg mesg.${PN}
 192         update-alternatives --remove renice renice.${PN}
 193         update-alternatives --remove wall wall.${PN}
 194 }
 195
 196 pkg_postinst_util-linux-ng-fdisk () {
 197         update-alternatives --install ${base_sbindir}/fdisk fdisk fdisk.${PN} 100
 198 }
 199
 200 pkg_prerm_util-linux-ng-fdisk () {
 201         update-alternatives --remove fdisk fdisk.${PN}
 202 }
 203
 204 pkg_postinst_util-linux-ng-mount () {
 205         update-alternatives --install ${base_bindir}/mount mount mount.${PN} 100
 206 }
 207
 208 pkg_prerm_util-linux-ng-mount () {
 209         update-alternatives --remove mount mount.${PN}
 210 }
 211
 212 pkg_postinst_util-linux-ng-umount () {
 213         update-alternatives --install ${base_bindir}/umount umount umount.${PN} 100
 214 }
 215
 216 pkg_prerm_util-linux-ng-umount () {
 217         update-alternatives --remove umount umount.${PN}
 218 }
 219
 220 pkg_postinst_util-linux-ng-losetup () {
 221         update-alternatives --install ${base_sbindir}/losetup losetup losetup.${PN} 100
 222 }
 223
 224 pkg_prerm_util-linux-ng-losetup () {
 225         update-alternatives --remove losetup losetup.${PN}
 226 }
 227
 228 pkg_postinst_util-linux-ng-swaponoff () {
 229         update-alternatives --install ${base_sbindir}/swapoff swapoff swapoff.${PN} 100
 230         update-alternatives --install ${base_sbindir}/swapon swapon swapon.${PN} 100
 231 }
 232
 233 pkg_prerm_util-linux-ng-swaponoff () {
 234         update-alternatives --remove swapoff swapoff.${PN}
 235         update-alternatives --remove swapon swapon.${PN}
 236 }
 237
 238 pkg_postinst_util-linux-ng-readprofile() {
 239     update-alternatives --install ${sbindir}/readprofile readprofile readprofile.${PN} 100
 240 }
 241
 242 pkg_prerm_util-linux-ng-readprofile () {
 243     update-alternatives --remove readprofile readprofile.${PN} 100
 244 }
 245