recipes/pulseaudio/pulseaudio.inc

   1 DESCRIPTION = "Pulseaudio is a sound server for Linux and Unix-like operating systems."
   2 HOMEPAGE = "http://www.pulseaudio.org"
   3 AUTHOR = "Lennart Poettering"
   4 SECTION = "libs/multimedia"
   5 LICENSE = "LGPL"
   6 DEPENDS = "bluez4 libatomics-ops liboil avahi libsamplerate0 libsndfile1 libtool hal virtual/libx11"
   7 # optional
   8 DEPENDS += "alsa-lib glib-2.0 dbus consolekit hal openssl"
   9 INC_PR = "r9"
  10
  11 SRC_URI = "http://0pointer.de/lennart/projects/pulseaudio/pulseaudio-${PV}.tar.gz \
  12            file://gcc4-compile-fix.patch;patch=1 \
  13            file://configure-ac.patch;patch=1 \
  14            file://volatiles.04_pulse"
  15
  16 inherit autotools pkgconfig
  17
  18 EXTRA_OECONF = "\
  19                 --disable-lynx \
  20                 --enable-bluez \
  21                 --disable-polkit \
  22                 --with-x \
  23                 --without-jack \
  24                 --with-glib \
  25                 --with-alsa \
  26                 --with-oss \
  27                 --with-hal \
  28 "
  29
  30 PARALLEL_MAKE = ""
  31
  32 export TARGET_PFPU = "${TARGET_FPU}"
  33
  34 # TODO: Use more fine granular version
  35 #OE_LT_RPATH_ALLOW=":${libdir}/pulse-0.9:"
  36 OE_LT_RPATH_ALLOW = "any"
  37 OE_LT_RPATH_ALLOW[export]="1"
  38
  39 do_stage() {
  40         autotools_stage_all
  41 }
  42
  43 do_install_append() {
  44         install -d ${D}${sysconfdir}/default/volatiles
  45         install -m 0644 ${WORKDIR}/volatiles.04_pulse  ${D}${sysconfdir}/default/volatiles/04_pulse
  46
  47         if [ "x${TARGET_PFPU}" == "xsoft" ] ; then
  48              sed -i -e s:\;\ resample-method\ =\ sinc-fastest:resample-method\ =\ trivial: ${D}${sysconfdir}/pulse/daemon.conf
  49         fi
  50 }
  51
  52 PACKAGES =+ "libpulsecore libpulsecommon libpulsedsp libpulse libpulse-simple libpulse-browse libpulse-mainloop-glib \
  53              pulseaudio-server pulseaudio-misc pulseaudio-gconf-helper"
  54
  55 #upgrade path:
  56 RREPLACES_pulseaudio-server = "libpulse-bin libpulse-conf"
  57
  58 PACKAGES_DYNAMIC = "pulseaudio-lib* pulseaudio-module* libpulse-lib* libpulse-module* "
  59
  60 FILES_libpulsecore = "${libdir}/libpulsecore*.so"
  61 FILES_libpulsecommon = "${libdir}/libpulsecommon*.so"
  62 FILES_libpulsedsp = "${libdir}/libpulsedsp*.so"
  63 FILES_libpulse = "${libdir}/libpulse.so.*"
  64 FILES_libpulse-simple = "${libdir}/libpulse-simple.so.*"
  65 FILES_libpulse-browse = "${libdir}/libpulse-browse.so.*"
  66 FILES_libpulse-mainloop-glib = "${libdir}/libpulse-mainloop-glib.so.*"
  67
  68 FILES_${PN}-dbg += "${libexecdir}/pulse/.debug \
  69                     ${libdir}/pulse-${PV}/modules/.debug"
  70 FILES_${PN}-dev += "${libdir}/pulse-${PV}/modules/*.la"
  71 FILES_${PN}-conf = "${sysconfdir}"
  72 FILES_${PN}-bin = "${bindir}/* \
  73                    ${sysconfdir}/default/volatiles/volatiles.04_pulse"
  74 FILES_${PN}-server = "${bindir}/pulseaudio ${bindir}/start-* ${sysconfdir} ${bindir}/pactl"
  75 FILES_${PN}-gconf-helper = "${libexecdir}/pulse/gconf-helper"
  76 FILES_${PN}-misc = "${bindir}/*"
  77
  78 # Allow the pulseaudio package to be created empty as a placeholder (-dbg and -dev depend on it)
  79 ALLOW_EMPTY_${PN} = "1"
  80
  81 CONFFILES_pulseaudio-server = "\
  82   ${sysconfdir}/pulse/default.pa \
  83   ${sysconfdir}/pulse/daemon.conf \
  84   ${sysconfdir}/pulse/client.conf \
  85   "
  86
  87 pkg_postinst_${PN}-server() {
  88         # can't do this offline
  89         if [ "x$D" != "x" ]; then
  90                 exit 1
  91         fi
  92         grep -q pulse: /etc/group || addgroup pulse
  93         grep -q pulse: /etc/passwd || \
  94             adduser --disabled-password --home=/var/run/pulse --system \
  95                     --ingroup pulse --no-create-home -g "Pulse audio daemon" pulse
  96         addgroup pulse audio
  97         /etc/init.d/populate-volatile.sh update
  98 }
  99
 100 pkg_postrm_${PN}-server() {
 101         deluser pulse || true
 102 }
 103
 104 python populate_packages_prepend() {
 105         #bb.data.setVar('PKG_pulseaudio', 'pulseaudio', d)
 106
 107         plugindir = bb.data.expand('${libdir}/pulse-${PV}/modules/', d)
 108         do_split_packages(d, plugindir, '^module-(.*)\.so$', 'pulseaudio-module-%s', 'PulseAudio module for %s', extra_depends='' )
 109         do_split_packages(d, plugindir, '^lib(.*)\.so$', 'pulseaudio-lib-%s', 'PulseAudio library for %s', extra_depends='' )
 110 }
 111
 112 RDEPENDS_pulseaudio-module-console-kit =+ "consolekit"
 113 RDEPENDS_pulseaudio-module-hal_detect =+ "hal"
 114 RDEPENDS_pulseaudio-server = " \
 115     pulseaudio-module-device-restore \
 116     pulseaudio-module-stream-restore \
 117     pulseaudio-module-card-restore \
 118     pulseaudio-module-augment-properties \
 119     pulseaudio-module-detect \
 120     pulseaudio-module-alsa-sink \
 121     pulseaudio-module-alsa-source \
 122     pulseaudio-module-alsa-card \
 123     pulseaudio-module-native-protocol-unix \
 124     pulseaudio-module-hal-detect \
 125     pulseaudio-module-default-device-restore \
 126     pulseaudio-module-rescue-streams \
 127     pulseaudio-module-always-sink \
 128     pulseaudio-module-suspend-on-idle \
 129     pulseaudio-module-console-kit \
 130     pulseaudio-module-position-event-sounds \
 131     pulseaudio-module-cork-music-on-phone "
 132