recipes/gtk+/gtk-2.10.inc

   1 LICENSE = "LGPL"
   2 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   3 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   4 HOMEPAGE = "http://www.gtk.org"
   5 SECTION = "libs"
   6 PRIORITY = "optional"
   7 DEPENDS = "glib-2.0 pango atk jpeg libpng libxext libxcursor gtk-doc libgcrypt cairo cups"
   8
   9 inherit autotools pkgconfig
  10
  11 FILES_${PN} = "${bindir}/gdk-pixbuf-query-loaders \
  12         ${bindir}/gtk-update-icon-cache \
  13         ${bindir}/gtk-query-immodules-2.0 \
  14         ${libdir}/lib*.so.* \
  15         ${datadir}/themes ${sysconfdir} \
  16         ${libdir}/gtk-2.0/${LIBV}/engines/libpixmap.so \
  17 "
  18 FILES_${PN}-dev += " \
  19         ${datadir}/gtk-2.0/include \
  20         ${libdir}/gtk-2.0/include \
  21         ${libdir}/gtk-2.0/${LIBV}/loaders/*.la \
  22         ${libdir}/gtk-2.0/${LIBV}/immodules/*.la \
  23         ${libdir}/gtk-2.0/${LIBV}/engines/*.la \
  24         ${libdir}/gtk-2.0/${LIBV}/printbackends/*.la \
  25         ${bindir}/gdk-pixbuf-csource"
  26 FILES_${PN}-dbg += " \
  27         ${libdir}/gtk-2.0/${LIBV}/loaders/.debug/* \
  28         ${libdir}/gtk-2.0/${LIBV}/immodules/.debug/* \
  29         ${libdir}/gtk-2.0/${LIBV}/engines/.debug/* \
  30         ${libdir}/gtk-2.0/${LIBV}/printbackends/.debug/*"
  31
  32
  33 NEATSTUFF = " ttf-dejavu-sans gdk-pixbuf-loader-png gdk-pixbuf-loader-jpeg gdk-pixbuf-loader-gif gdk-pixbuf-loader-xpm "
  34
  35 RRECOMMENDS_${PN} = " ${NEATSTUFF} "
  36 RRECOMMENDS_${PN}_linux = " ${NEATSTUFF} glibc-gconv-iso8859-1 "
  37 RRECOMMENDS_${PN}_linux-gnueabi = " ${NEATSTUFF} glibc-gconv-iso8859-1"
  38
  39 EXTRA_OECONF = "--without-libtiff --disable-xkb --disable-glibtest --enable-display-migration"
  40
  41 export GDKTARGET="x11"
  42
  43 LIBV = "2.10.0"
  44
  45 do_stage () {
  46         oe_libinstall -so -C gtk libgtk-$GDKTARGET-2.0 ${STAGING_LIBDIR}
  47         oe_libinstall -so -C gdk libgdk-$GDKTARGET-2.0 ${STAGING_LIBDIR}
  48         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  49         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  50
  51         autotools_stage_includes
  52
  53         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  54         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  55         # Copy over all headers, since the maemo stuff needs access to the private api. *sigh*
  56         cp gtk/*.h ${STAGING_INCDIR}/gtk-2.0/gtk/
  57         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  58 }
  59
  60 do_install_append () {
  61         install -d ${D}${sysconfdir}/gtk-2.0
  62 }
  63
  64 postinst_prologue() {
  65 if [ "x$D" != "x" ]; then
  66   exit 1
  67 fi
  68
  69 }
  70
  71 PACKAGES_DYNAMIC = "gdk-pixbuf-loader-* gtk-immodule-* gtk-printbackend-*"
  72
  73 python populate_packages_prepend () {
  74         import os.path
  75
  76         prologue = bb.data.getVar("postinst_prologue", d, 1)
  77
  78         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  79         loaders_root = os.path.join(gtk_libdir, 'loaders')
  80         immodules_root = os.path.join(gtk_libdir, 'immodules')
  81         printmodules_root = os.path.join(gtk_libdir, 'printbackends');
  82
  83         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
  84         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules')
  85         do_split_packages(d, printmodules_root, '^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s')
  86
  87         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  88                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  89 }