recipes/gtk+/gtk+_2.14.2.bb

   1 require gtk+.inc
   2
   3 PR = "r3"
   4
   5 DEPENDS += "cairo jasper"
   6
   7 SRC_URI = "http://download.gnome.org/sources/gtk+/2.14/gtk+-${PV}.tar.bz2 \
   8            file://xsettings.patch;patch=1 \
   9            file://run-iconcache.patch;patch=1 \
  10            file://hardcoded_libtool.patch;patch=1 \
  11            file://no-demos.patch;patch=1 \
  12            file://toggle-font.diff;patch=1;pnum=0 \
  13            file://smallscreen_filechooser.patch;patch=1 \
  14           "
  15
  16 EXTRA_OECONF = "--with-libtiff --disable-xkb --disable-glibtest --enable-display-migration gio_can_sniff=yes"
  17
  18 LIBV = "2.10.0"
  19
  20 PACKAGES_DYNAMIC = "gtk-module-* gdk-pixbuf-loader-* gtk-immodule-* gtk-printbackend-*"
  21
  22 python populate_packages_prepend () {
  23         import os.path
  24
  25         prologue = bb.data.getVar("postinst_prologue", d, 1)
  26
  27         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  28         loaders_root = os.path.join(gtk_libdir, 'loaders')
  29         immodules_root = os.path.join(gtk_libdir, 'immodules')
  30         printmodules_root = os.path.join(gtk_libdir, 'printbackends');
  31         modules_root = bb.data.expand('${libdir}/gtk-2.0/modules/',d)
  32
  33         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders', extra_depends='')
  34         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules', extra_depends='')
  35         do_split_packages(d, printmodules_root, '^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s', extra_depends='')
  36         do_split_packages(d, modules_root, '^lib(.*)\.so$', 'gtk-module-%s', 'GTK module for %s', extra_depends='')
  37
  38         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  39                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  40 }
  41
  42 RPROVIDES_${PN} = "libgailutil18"
  43 RCONFLICTS_${PN} = "libgailutil18"
  44 RREPLACES_${PN} = "libgailutil18"
  45