recipes/freesmartphone/frameworkd_git.bb

   1 DESCRIPTION = "The reference implementation of the freesmartphone.org framework APIs"
   2 HOMEPAGE = "http://www.freesmartphone.org"
   3 AUTHOR = "FreeSmartphone.Org Development Team"
   4 SECTION = "console/network"
   5 DEPENDS = "python-cython-native python-pyrex-native"
   6 LICENSE = "GPL"
   7 PV = "0.9.5.9+gitr${SRCREV}"
   8 PR = "r0"
   9
  10 inherit distutils update-rc.d
  11
  12 INITSCRIPT_NAME = "frameworkd"
  13 INITSCRIPT_PARAMS = "defaults 29"
  14
  15 SRC_URI = "${FREESMARTPHONE_GIT}/framework.git;protocol=git;branch=master \
  16            file://frameworkd \
  17            file://frameworkd.conf \
  18            "
  19 SRC_URI_append_shr = "file://oeventsd-use-opimd-signals.patch;patch=1"
  20
  21 S = "${WORKDIR}/git"
  22
  23 do_configure_append() {
  24         echo "version=\"${PV}\"" >framework/__version__.py
  25 }
  26
  27 do_install_append() {
  28         install -d ${D}${sysconfdir}/init.d/
  29         install -m 0755 ${WORKDIR}/frameworkd ${D}${sysconfdir}/init.d/
  30         install -m 0644 ${WORKDIR}/frameworkd.conf ${D}${sysconfdir}
  31 }
  32
  33 RDEPENDS_${PN} += "\
  34   fsousaged \
  35 "
  36
  37 RDEPENDS_${PN} += "\
  38   python-ctypes \
  39   python-dbus \
  40   python-datetime \
  41   python-difflib \
  42   python-logging \
  43   python-pprint \
  44   python-pyalsaaudio \
  45   python-pygobject \
  46   python-pyrtc \
  47   python-pyserial \
  48   python-pyyaml \
  49   python-shell \
  50   python-subprocess \
  51   python-syslog \
  52   python-textutils \
  53   python-multiprocessing \
  54   ${PN}-config \
  55 "
  56
  57 RRECOMMENDS_${PN} += "\
  58   alsa-utils-amixer \
  59   python-gst \
  60   python-phoneutils \
  61   python-vobject \
  62   ppp \
  63 "
  64
  65 PACKAGES =+ "${PN}-config"
  66 PACKAGE_ARCH_${PN}-config = "${MACHINE_ARCH}"
  67
  68 # machine specific stuff, should ideally be elsewhere
  69 # - recommend MUXer on platforms that require one
  70 RDEPENDS_${PN}-config_append_om-gta01 = " fso-abyss"
  71 RDEPENDS_${PN}-config_append_om-gta02 = " fso-abyss"
  72 # - add wmiconfig for wireless configuration
  73 RDEPENDS_${PN}-config_append_om-gta02 = " wmiconfig"
  74
  75 FILES_${PN}-config = "\
  76   ${sysconfdir}/frameworkd.conf \
  77   ${sysconfdir}/freesmartphone \
  78   "
  79 CONFFILES_${PN}-config = "\
  80   ${sysconfdir}/frameworkd.conf \
  81   ${sysconfdir}/freesmartphone/opreferences/conf/phone/silent.yaml \
  82   ${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml \
  83   ${sysconfdir}/freesmartphone/opreferences/conf/profiles/default.yaml \
  84   ${sysconfdir}/freesmartphone/opreferences/conf/rules/silent.yaml \
  85   ${sysconfdir}/freesmartphone/opreferences/conf/rules/default.yaml \
  86   ${sysconfdir}/freesmartphone/oevents/rules.yaml \
  87   ${sysconfdir}/freesmartphone/ogsmd/networks.tab \
  88   "
  89
  90 PACKAGE_ARCH_${PN} = "${BASE_PACKAGE_ARCH}"
  91 FILES_${PN} += "${sysconfdir}/dbus-1 ${sysconfdir}/freesmartphone ${sysconfdir}/init.d ${datadir}"
  92 FILES_${PN}-dbg += "${libdir}/${PYTHON_DIR}/site-packages/framework/subsystems/*/.debug"