recipes/e2fsprogs/e2fsprogs.inc

   1 DESCRIPTION = "EXT2 Filesystem Utilities"
   2 HOMEPAGE = "http://e2fsprogs.sf.net"
   3 LICENSE = "GPL"
   4 SECTION = "base"
   5 DEPENDS = "gettext-native util-linux-ng"
   6 DEPENDS_virtclass-native = "gettext-native"
   7
   8 SRC_URI = "${SOURCEFORGE_MIRROR}/e2fsprogs/e2fsprogs-${PV}.tar.gz"
   9
  10 S = "${WORKDIR}/e2fsprogs-${PV}"
  11
  12 INC_PR = "r21a"
  13
  14 inherit autotools
  15
  16 #if uclibc ntpl is merged into trunk we can enable tls for armv4 again
  17 EXTRA_OECONF = "${@['','--disable-tls'][bb.data.getVar('ARM_ABI', d, 1) == 'oabi' and \
  18                 bb.data.getVar('TARGET_OS', d, 1).find('uclibc') >= 0 ]} \
  19                 --enable-dynamic-e2fsck --disable-nls --sbindir=${base_sbindir} \
  20                 --disable-libuuid --disable-libblkid --disable-fsck"
  21
  22 PARALLEL_MAKE = ""
  23
  24 do_compile_prepend () {
  25         find ./ -print|xargs chmod u=rwX
  26         ( cd util; ${BUILD_CC} subst.c -o subst )
  27 }
  28
  29 e2miscbins = "mke2fs badblocks tune2fs dumpe2fs blkid logsave e2image \
  30               e2undo chattr lsattr uuidgen mklost+found filefrag uuidd e2initrd_helper"
  31
  32 ext2fsheaders = "ext2_ext_attr.h bitops.h ext2_err.h \
  33                  ext2_types.h ext2_fs.h ext2_io.h \
  34                  ext2fs.h"
  35 e2pheaders = "e2p.h"
  36
  37 do_install_append () {
  38         oe_libinstall -a -C lib libe2p    ${D}${libdir}/
  39         oe_libinstall -a -C lib libext2fs ${D}${libdir}/
  40
  41         install -d ${D}${includedir}/e2p
  42         for h in ${e2pheaders}; do
  43                 install -m 0644 lib/e2p/$h ${D}${includedir}/e2p/ || die "failed to install $h"
  44         done
  45
  46         install -d ${D}${includedir}/ext2fs
  47         for h in ${ext2fsheaders}; do
  48                 install -m 0644 lib/ext2fs/$h ${D}${includedir}/ext2fs/ || die "failed to install $h"
  49         done
  50
  51         mv ${D}${base_sbindir}/e2fsck ${D}${base_sbindir}/e2fsck.${PN}
  52         rm ${D}${base_sbindir}/fsck.ext2
  53         rm ${D}${base_sbindir}/fsck.ext3
  54         rm ${D}${base_sbindir}/fsck.ext4*
  55         mv ${D}${base_sbindir}/mke2fs ${D}${base_sbindir}/mke2fs.${PN}
  56         rm ${D}${base_sbindir}/mkfs.ext2
  57         rm ${D}${base_sbindir}/mkfs.ext3
  58         rm ${D}${base_sbindir}/mkfs.ext4*
  59
  60         cd ${D}/${base_sbindir}
  61         ln -sf ./e2fsck.${PN} fsck.ext2.${PN}
  62         ln -sf ./e2fsck.${PN} fsck.ext3.${PN}
  63         ln -sf ./e2fsck.${PN} fsck.ext4.${PN}
  64         ln -sf ./e2fsck.${PN} fsck.ext4dev.${PN}
  65         ln -sf ./mke2fs.${PN} mkfs.ext2.${PN}
  66         ln -sf ./mke2fs.${PN} mkfs.ext3.${PN}
  67         ln -sf ./mke2fs.${PN} mkfs.ext4.${PN}
  68         ln -sf ./mke2fs.${PN} mkfs.ext4dev.${PN}
  69
  70         ln -sf ./tune2fs findfs
  71         ln -sf ./tune2fs e2label
  72
  73         mv ${D}${bindir}/chattr ${D}${bindir}/chattr.${PN}
  74 }
  75
  76 pkg_postinst_e2fsprogs () {
  77         update-alternatives --install ${base_bindir}/chattr chattr chattr.${PN} 100
  78 }
  79
  80 pkg_prerm_e2fsprogs () {
  81         update-alternatives --remove chattr chattr.${PN}
  82 }
  83
  84
  85 pkg_postinst_e2fsprogs-blkid () {
  86     update-alternatives --install ${base_sbindir}/blkid blkid blkid.${PN} 100
  87 }
  88
  89 pkg_prerm_e2fsprogs-blkid () {
  90     update-alternatives --remove blkid blkid.${PN}
  91 }
  92
  93 pkg_postinst_e2fsprogs-e2fsck () {
  94         update-alternatives --install ${base_sbindir}/e2fsck e2fsck e2fsck.${PN} 100
  95         update-alternatives --install ${base_sbindir}/fsck.ext2 fsck.ext2 fsck.ext2.${PN} 100
  96         update-alternatives --install ${base_sbindir}/fsck.ext3 fsck.ext3 fsck.ext3.${PN} 100
  97         update-alternatives --install ${base_sbindir}/fsck.ext4 fsck.ext4 fsck.ext4.${PN} 100
  98         update-alternatives --install ${base_sbindir}/fsck.ext4dev fsck.ext4dev fsck.ext4dev.${PN} 100
  99 }
 100
 101 pkg_prerm_e2fsprogs-e2fsck () {
 102         update-alternatives --remove e2fsck e2fsck.${PN}
 103         update-alternatives --remove fsck.ext2 fsck.ext2.${PN}
 104         update-alternatives --remove fsck.ext3 fsck.ext3.${PN}
 105         update-alternatives --remove fsck.ext4 fsck.ext4.${PN}
 106         update-alternatives --remove fsck.ext4dev fsck.ext4dev.${PN}
 107 }
 108
 109 pkg_postinst_e2fsprogs-mke2fs () {
 110         update-alternatives --install ${base_sbindir}/mke2fs mke2fs mke2fs.${PN} 100
 111         update-alternatives --install ${base_sbindir}/mkfs.ext2 mkfs.ext2 mkfs.ext2.${PN} 100
 112         update-alternatives --install ${base_sbindir}/mkfs.ext3 mkfs.ext3 mkfs.ext3.${PN} 100
 113         update-alternatives --install ${base_sbindir}/mkfs.ext4 mkfs.ext4 mkfs.ext4.${PN} 100
 114         update-alternatives --install ${base_sbindir}/mkfs.ext4dev mkfs.ext4dev mkfs.ext4dev.${PN} 100
 115 }
 116
 117 pkg_prerm_e2fsprogs-mke2fs () {
 118         update-alternatives --remove mke2fs mke2fs.${PN}
 119         update-alternatives --remove mkfs.ext2 mkfs.ext2.${PN}
 120         update-alternatives --remove mkfs.ext3 mkfs.ext3.${PN}
 121         update-alternatives --remove mkfs.ext4 mkfs.ext4.${PN}
 122         update-alternatives --remove mkfs.ext4dev mkfs.ext4dev.${PN}
 123 }
 124
 125 # blkid used to be part of e2fsprogs but is useful outside, add it
 126 # as an RDEPENDS so that anything relying on it being in e2fsprogs
 127 # still works
 128 RDEPENDS_e2fsprogs = "util-linux-ng e2fsprogs-badblocks"
 129
 130 FILES_${PN} += "${libdir}/e2initrd_helper"
 131
 132 PACKAGES =+ "e2fsprogs-e2fsck e2fsprogs-mke2fs e2fsprogs-tune2fs e2fsprogs-badblocks"
 133 FILES_e2fsprogs-e2fsck = "${base_sbindir}/e2fsck.${PN} ${base_sbindir}/fsck.ext*.${PN}"
 134 FILES_e2fsprogs-mke2fs = "${base_sbindir}/mke2fs.${PN} ${base_sbindir}/mkfs.ext*.${PN}"
 135 FILES_e2fsprogs-tune2fs = "${base_sbindir}/tune2fs ${base_sbindir}/e2label ${base_sbindir}/findfs"
 136 FILES_e2fsprogs-badblocks = "${base_sbindir}/badblocks"
 137
 138 BBCLASSEXTEND = "native"