gcc-snapshot/gcc-snapshot_cvs.oe

   1 SECTION = "devel"
   2 inherit autotools gettext
   3
   4 PV = "${CVSDATE}"
   5 DESCRIPTION = "The GNU cc and gcc C compilers."
   6 LICENSE = "GPL"
   7 MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
   8
   9 # libgcc libstdc++ libg2c are listed in our FILES_*, but are actually
  10 # packaged in the respective cross packages.
  11 PACKAGES = "${PN} ${PN}-symlinks \
  12             ${PN}-c++ ${PN}-c++-symlinks \
  13             ${PN}-f77 ${PN}-f77-symlinks \
  14             libstdc++-dev libg2c-dev \
  15             ${PN}-doc"
  16
  17 FILES_${PN} = "${bindir}/${TARGET_PREFIX}gcc \
  18                ${bindir}/${TARGET_PREFIX}cpp \
  19                ${bindir}/${TARGET_PREFIX}gcov \
  20                ${bindir}/${TARGET_PREFIX}gccbug \
  21                ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1 \
  22                ${libexecdir}/gcc/${TARGET_SYS}/${PV}/collect2 \
  23                ${libdir}/gcc/${TARGET_SYS}/${PV}/*.o \
  24                ${libdir}/gcc/${TARGET_SYS}/${PV}/specs \
  25                ${libdir}/gcc/${TARGET_SYS}/${PV}/lib* \
  26                ${libdir}/gcc/${TARGET_SYS}/${PV}/include"
  27
  28 FILES_${PN}-symlinks = "${bindir}/cc \
  29                         ${bindir}/gcc \
  30                         ${bindir}/cpp \
  31                         ${bindir}/gcov \
  32                         ${bindir}/gccbug"
  33
  34 FILES_${PN}-f77 = "${bindir}/${TARGET_PREFIX}g77 \
  35                    ${libexecdir}/gcc/${TARGET_SYS}/${PV}/f771"
  36
  37 FILES_${PN}-f77-symlinks = "${bindir}/g77 \
  38                             ${bindir}/f77"
  39
  40 # Called from within gcc-cross, so libdir is set wrong
  41 #FILES_libg2c = "${libdir}/libg2c.so.*"
  42 FILES_libg2c = "/usr/lib/libg2c.so.*"
  43
  44 FILES_libg2c-dev = "${libdir}/libg2c.so \
  45                           ${libdir}/libg2c.a \
  46                           ${libdir}/libfrtbegin.a"
  47
  48 FILES_${PN}-c++ = "${bindir}/${TARGET_PREFIX}g++ \
  49                    ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1plus"
  50
  51 FILES_${PN}-c++-symlinks = "${bindir}/c++ \
  52                             ${bindir}/g++"
  53
  54 FILES_libgcc = "/lib/libgcc_s.so.*"
  55
  56 # Called from within gcc-cross, so libdir is set wrong
  57 #FILES_libstdc++ = "${libdir}/libstdc++.so.*"
  58 FILES_libstdc++ = "/usr/lib/libstdc++.so.*"
  59
  60 FILES_libstdc++-dev = "${includedir}/c++/${PV} \
  61                        ${libdir}/libstdc++.so \
  62                        ${libdir}/libstdc++.la \
  63                        ${libdir}/libstdc++.a \
  64                        ${libdir}/libsupc++.la \
  65                        ${libdir}/libsupc++.a"
  66
  67 FILES_${PN}-doc = "${infodir} \
  68                    ${mandir} \
  69                    ${libdir}/gcc/${TARGET_SYS}/${PV}/include/README"
  70
  71 SRC_URI = "cvs://anoncvs:@savannah.gnu.org/cvsroot/gcc;module=gcc;method=ext;rsh=ssh"
  72
  73 gccbuild_uclibc_do_patch () {
  74         #
  75         # Hack things to use the correct shared lib loader
  76         #
  77         #LIST=`grep -lr -- "-dynamic-linker.*\.so[\.0-9]*" .`
  78         #if [ -n "$LIST" ] ; then
  79         #       perl -i -p -e "s,-dynamic-linker.*\.so[\.0-9]*},-dynamic-linker /lib/ld-uClibc.so.0},;" $LIST
  80         #fi
  81
  82         #
  83         # Prevent system glibc start files from leaking in uninvited...
  84         #
  85         perl -i -p -e "s,standard_startfile_prefix_1 = \".*,standard_startfile_prefix_1 = \"${CROSS_DIR}/${TARGET_SYS}/lib/\";,;" gcc/gcc.c
  86         perl -i -p -e "s,standard_startfile_prefix_2 = \".*,standard_startfile_prefix_2 = \"${CROSS_DIR}/${TARGET_SYS}/usr/lib/\";,;" gcc/gcc.c
  87
  88         #
  89         # Prevent system glibc include files from leaking in uninvited...
  90         #
  91         perl -i -p -e "s,^NATIVE_SYSTEM_HEADER_DIR.*,NATIVE_SYSTEM_HEADER_DIR=${CROSS_DIR}/${TARGET_SYS}/include,;" gcc/Makefile.in
  92         perl -i -p -e "s,^CROSS_SYSTEM_HEADER_DIR.*,CROSS_SYSTEM_HEADER_DIR=${CROSS_DIR}/${TARGET_SYS}/include,;" gcc/Makefile.in
  93         perl -i -p -e "s,^#define.*STANDARD_INCLUDE_DIR.*,#define STANDARD_INCLUDE_DIR \"${CROSS_DIR}/${TARGET_SYS}/include\",;" gcc/cppdefault.h
  94
  95         #
  96         # Prevent system glibc libraries from being found by collect2
  97         # when it calls locatelib() and rummages about the system looking
  98         # for libraries with the correct name...
  99         #
 100         perl -i -p -e "s,\"/lib,\"${CROSS_DIR}/${TARGET_SYS}/lib,g;" \
 101                 gcc/collect2.c
 102         perl -i -p -e "s,\"/usr/,\"${CROSS_DIR}/${TARGET_SYS}/usr/,g;" \
 103                 gcc/collect2.c
 104
 105         #
 106         # Prevent gcc from using the unwind-dw2-fde-glibc code
 107         #
 108         perl -i -p -e "s,^#ifndef inhibit_libc,#define inhibit_libc
 109 #ifndef inhibit_libc,g;" gcc/unwind-dw2-fde-glibc.c
 110 }
 111
 112 python do_patch () {
 113     import oe, re
 114     oe.build.exec_func('base_do_patch', d)
 115     if (re.match('.*uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None):
 116         oe.build.exec_func('gccbuild_uclibc_do_patch', d)
 117 }
 118
 119 S = "${WORKDIR}/gcc"
 120 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
 121
 122 EXTRA_OECONF = "--with-gnu-ld \
 123                 --enable-shared \
 124                 --enable-multilib \
 125                 --enable-target-optspace \
 126                 --enable-languages=c,c++,f77 \
 127                 --enable-threads=posix \
 128                 --enable-c99 \
 129                 --enable-long-long \
 130                 --enable-symvers=gnu \
 131                 --program-prefix=${TARGET_PREFIX} \
 132                 ${EXTRA_OECONF_PATHS} \
 133                 ${EXTRA_OECONF_DEP}"
 134
 135 EXTRA_OECONF_PATHS = "--with-local-prefix=${prefix}/local \
 136                       --with-gxx-include-dir=${includedir}/c++/${PV}"
 137
 138 EXTRA_OECONF_DEP = ""
 139 EXTRA_OECONF_uclibc = "--disable-__cxa_atexit"
 140 EXTRA_OECONF_glibc = "--enable-__cxa_atexit"
 141
 142 python __anonymous () {
 143     import oe, re
 144     if (re.match('linux-uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None):
 145         oe.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_uclibc}', d)
 146     elif (re.match('linux$', oe.data.getVar('TARGET_OS', d, 1)) != None):
 147         oe.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_glibc}', d)
 148 }
 149
 150 do_configure () {
 151         # Setup these vars for cross building only
 152         if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
 153                 export CC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
 154                 export GCC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
 155                 export CXX_FOR_TARGET="${CCACHE} ${HOST_PREFIX}g++"
 156                 export AS_FOR_TARGET="${HOST_PREFIX}as"
 157                 export LD_FOR_TARGET="${HOST_PREFIX}ld"
 158                 export NM_FOR_TARGET="${HOST_PREFIX}nm"
 159                 export AR_FOR_TARGET="${HOST_PREFIX}ar"
 160                 export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
 161         fi
 162         (cd ${S} && gnu-configize) || die "failure running gnu-configize"
 163         oe_runconf
 164 }
 165
 166 do_install () {
 167         autotools_do_install
 168
 169         # Cleanup some of the /usr/lib{,exec}/gcc stuff ...
 170         rm -r ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/install-tools
 171         rm -r ${D}/${libexecdir}/gcc/${TARGET_SYS}/${PV}/install-tools
 172
 173         # Move libgcc_s into /lib
 174         mkdir -p ${D}/lib
 175         mv ${D}/${libdir}/libgcc_s.so.* ${D}/lib
 176         rm ${D}/${libdir}/libgcc_s.so
 177         ln -sf `echo ${libdir}/gcc/${TARGET_SYS}/${PV} \
 178                 | tr -s / \
 179                 | sed -e 's,^/,,' -e 's,[^/]*,..,g'`/lib/libgcc_s.so.? \
 180                       ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/libgcc_s.so
 181
 182         # We don't need libtool libraries
 183         rm ${D}/${libdir}/libg2c.la
 184
 185         # Cleanup manpages..
 186         rm -r ${D}/${mandir}/man7
 187
 188         # We use libiberty from binutils
 189         rm ${D}/${libdir}/libiberty.a
 190
 191         cd ${D}/${bindir}
 192
 193         # We care about g++ not c++
 194         rm *c++
 195
 196         # We don't care about the gcc-<version> ones for this
 197         rm *gcc-?.?*
 198
 199         # These sometimes show up, they are strange, we remove them
 200         rm -f ${TARGET_ARCH}-*${TARGET_ARCH}-*
 201
 202         # Symlinks so we can use these trivially on the target
 203         ln -sf ${TARGET_SYS}-g77 g77
 204         ln -sf ${TARGET_SYS}-g++ g++
 205         ln -sf ${TARGET_SYS}-gcc gcc
 206         ln -sf g77 f77
 207         ln -sf g++ c++
 208         ln -sf gcc cc
 209 }