gcc/gcc3-cross-build.inc

   1 OLD_INHIBIT_PACKAGE_STRIP := "${INHIBIT_PACKAGE_STRIP}"
   2 INHIBIT_PACKAGE_STRIP = "1"
   3
   4 EXTRA_OECONF_PATHS = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
   5                       --with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++"
   6
   7 do_configure_prepend () {
   8         rm -f ${CROSS_DIR}/lib/gcc/${TARGET_SYS}/${PV}/libgcc_eh.a
   9 }
  10
  11 do_compile_prepend () {
  12         export CC="${BUILD_CC}"
  13         export AR_FOR_TARGET="${TARGET_SYS}-ar"
  14         export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
  15         export LD_FOR_TARGET="${TARGET_SYS}-ld"
  16         export NM_FOR_TARGET="${TARGET_SYS}-nm"
  17         export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
  18 }
  19
  20 do_stage_append () {
  21         for d in info man share/doc share/locale ; do
  22                 rm -rf ${CROSS_DIR}/$d
  23         done
  24
  25         # These aren't useful on the cross toolchain
  26         rm -f ${CROSS_DIR}/bin/*gcov
  27         rm -f ${CROSS_DIR}/bin/*gccbug
  28
  29         # Fix a few include links so cross builds are happier
  30         if [ ! -e ${STAGING_INCDIR}/c++ ]; then
  31                 mkdir -p ${STAGING_INCDIR}
  32                 ln -sf ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
  33                         ${STAGING_INCDIR}/
  34         fi
  35
  36         # We use libiberty from binutils
  37         rm -f ${CROSS_DIR}/lib/libiberty.a
  38
  39         # We probably don't need these
  40         rmdir ${CROSS_DIR}/include || :
  41
  42         # We don't really need to keep this around
  43         rm -rf ${CROSS_DIR}/share
  44 }
  45
  46 python do_package() {
  47         if bb.data.getVar('DEBIAN_NAMES', d, 1):
  48                 bb.data.setVar('PKG_libgcc', 'libgcc1', d)
  49         bb.build.exec_func('package_do_package', d)
  50 }
  51
  52 do_install () {
  53         oe_runmake 'DESTDIR=${D}' install
  54
  55         # Move libgcc_s into /lib
  56         mkdir -p ${D}/lib
  57         if [ -f ${D}/lib/libgcc_s.so.? ]; then
  58                 # Already in the right location
  59                 :
  60         elif [ -f ${D}/${prefix}/lib/libgcc_s.so.? ]; then
  61                 mv -f ${D}/${prefix}/lib/libgcc_s.so.* ${D}/lib
  62         else
  63                 mv -f ${D}/${prefix}/*/lib/libgcc_s.so.* ${D}/lib
  64         fi
  65
  66         # Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
  67         TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
  68         mkdir -p ${D}/${TGT_LIBDIR}
  69         mv -f ${D}/${prefix}/*/lib/libstdc++.so.* ${D}/${TGT_LIBDIR}
  70         mv -f ${D}/${prefix}/*/lib/libg2c.so.* ${D}/${TGT_LIBDIR}
  71
  72         # Manually run the target stripper since we won't get it run by
  73         # the packaging.
  74         if [ "x${OLD_INHIBIT_PACKAGE_STRIP}" != "x1" ]; then
  75                 ${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libstdc++.so.*
  76                 ${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libg2c.so.*
  77                 ${TARGET_PREFIX}strip ${D}/lib/libgcc_s.so.*
  78         fi
  79 }