conf/bitbake.conf

   1 ##################################################################
   2 # Recipe Parsing
   3 ##################################################################
   4 BBMASK = "/(nonworking|obsolete)/"
   5
   6 ##################################################################
   7 # Standard target filesystem layout.
   8 ##################################################################
   9
  10 # Path prefixes
  11 layout_prefix = "/usr"
  12 layout_exec_prefix = "/usr"
  13 layout_base_prefix = ""
  14
  15 # Base paths
  16 layout_base_bindir = "${layout_base_prefix}/bin"
  17 layout_base_sbindir = "${layout_base_prefix}/sbin"
  18 layout_base_libdir = "${layout_base_prefix}/lib"
  19
  20 # Architecture independent paths
  21 layout_sysconfdir = "${layout_base_prefix}/etc"
  22 layout_localstatedir = "${layout_base_prefix}/var"
  23 layout_servicedir = "${layout_base_prefix}/srv"
  24 layout_sharedstatedir = "${layout_prefix}/com"
  25 layout_datadir = "${layout_prefix}/share"
  26 layout_infodir = "${layout_datadir}/info"
  27 layout_mandir = "${layout_datadir}/man"
  28 layout_docdir = "${layout_datadir}/doc"
  29
  30 # Architecture dependent paths
  31 layout_bindir = "${layout_exec_prefix}/bin"
  32 layout_sbindir = "${layout_exec_prefix}/sbin"
  33 layout_libdir = "${layout_exec_prefix}/lib"
  34 layout_includedir = "${layout_exec_prefix}/include"
  35 layout_libexecdir = "${layout_exec_prefix}/libexec"
  36
  37 ##################################################################
  38 # Standard target filesystem paths.
  39 ##################################################################
  40
  41 # Path prefixes
  42 export base_prefix = ""
  43 export prefix = "${layout_prefix}"
  44 export exec_prefix = "${layout_exec_prefix}"
  45
  46 # Base paths
  47 export base_bindir = "${layout_base_bindir}"
  48 export base_sbindir = "${layout_base_sbindir}"
  49 export base_libdir = "${layout_base_libdir}"
  50
  51 # Architecture independent paths
  52 export datadir = "${layout_datadir}"
  53 export sysconfdir = "${layout_sysconfdir}"
  54 export sharedstatedir = "${layout_sharedstatedir}"
  55 export localstatedir = "${layout_localstatedir}"
  56 export infodir = "${layout_infodir}"
  57 export mandir = "${layout_mandir}"
  58 export docdir = "${layout_docdir}"
  59 export servicedir = "${layout_servicedir}"
  60
  61 # Architecture dependent paths
  62 export bindir = "${layout_bindir}"
  63 export sbindir = "${layout_sbindir}"
  64 export libexecdir = "${layout_libexecdir}"
  65 export libdir = "${layout_libdir}"
  66 export includedir = "${layout_includedir}"
  67 export oldincludedir = "${layout_includedir}"
  68
  69 ##################################################################
  70 # Architecture-dependent build variables.
  71 ##################################################################
  72
  73 BUILD_ARCH = "${@os.uname()[4]}"
  74 BUILD_OS = "${@os.uname()[0].lower()}"
  75 BUILD_VENDOR = ""
  76 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  77 BUILD_PREFIX = ""
  78 BUILD_CC_ARCH = ""
  79 BUILD_EXEEXT = ""
  80
  81 HOST_ARCH = "${TARGET_ARCH}"
  82 HOST_OS = "${TARGET_OS}"
  83 HOST_VENDOR = "${TARGET_VENDOR}"
  84 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  85 HOST_PREFIX = "${TARGET_PREFIX}"
  86 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  87 HOST_EXEEXT = ""
  88
  89 TARGET_ARCH ?= "INVALID"
  90 TARGET_OS = "INVALID"
  91 TARGET_VENDOR = "${BUILD_VENDOR}"
  92 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
  93 TARGET_PREFIX = "${TARGET_SYS}-"
  94 TARGET_CC_ARCH = ""
  95 TARGET_EXEEXT = ""
  96
  97 SDK_ARCH ?= "${BUILD_ARCH}"
  98 SDK_OS ?= "${BUILD_OS}"
  99 SDK_VENDOR ?= "${BUILD_VENDOR}"
 100 SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + bb.data.getVar('SDK_OS', d, 1), ''][bb.data.getVar('SDK_OS', d, 1) == ('' or 'custom')]}"
 101 SDK_PREFIX = "${SDK_SYS}-"
 102 SDK_CC_ARCH ?= "${BUILD_CC_ARCH}"
 103 SDK_EXEEXT = ""
 104
 105 # A shortcut for the commonly used value
 106 EXEEXT = "${HOST_EXEEXT}"
 107
 108 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
 109 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
 110 PACKAGE_EXTRA_ARCHS ?= ""
 111 MACHINE_ARCH = "${@[bb.data.getVar('HOST_ARCH', d, 1), bb.data.getVar('MACHINE', d, 1)][bool(bb.data.getVar('MACHINE', d, 1))]}"
 112 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
 113
 114 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
 115 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 116 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
 117 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
 118 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 119
 120 # select proper CPU to get binary locales generated
 121 QEMU_OPTIONS = ""
 122 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 123 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 124 QEMU_OPTIONS_armv6-novfp = "-cpu arm1136"
 125 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 126
 127 ##################################################################
 128 # Date/time variables.
 129 ##################################################################
 130
 131 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 132 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 133 DATETIME = "${DATE}${TIME}"
 134
 135 ##################################################################
 136 # Openembedded Software Prerequisites.
 137 ##################################################################
 138
 139 # python-native should be here but python relies on building
 140 # its own in staging
 141 ASSUME_PROVIDED = "\
 142     bc-native \
 143     bzip2-native \
 144     cvs-native \
 145     diffstat-native \
 146     patch-native \
 147     perl-native-runtime \
 148     python-native-runtime \
 149     svn-native \
 150     texinfo-native \
 151     util-linux-native \
 152     "
 153
 154 ##################################################################
 155 # Package default variables.
 156 ##################################################################
 157 PN = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[0] or 'defaultpkgname'}"
 158 PV = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[1] or '1.0'}"
 159 PR = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[2] or 'r0'}"
 160 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 161 EXTENDPE = "${@['','${PE\x7d_'][bb.data.getVar('PE',d,1) > 0]}"
 162 EXTENDPEVER = "${@['','${PE\x7d:'][bb.data.getVar('PE',d,1) > 0]}"
 163 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 164 P = "${PN}-${PV}"
 165
 166 # Define a PR for kernels that machines can override so things like
 167 # modules get rebuilt
 168 MACHINE_KERNEL_PR = ""
 169
 170 # Base package name
 171 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 172 # otherwise it is the same as PN and P
 173 BPN = "${@base_package_name(d)}"
 174 BP = "${BPN}-${PV}"
 175
 176 # Package info.
 177
 178 SECTION = "base"
 179 PRIORITY = "optional"
 180 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 181 LICENSE = "unknown"
 182 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 183 HOMEPAGE = "unknown"
 184
 185 # Package dependencies and provides.
 186
 187 # Ensure that -dev packages recommend the corresponding -dev packages of their
 188 # deps, and the same for -dbg.
 189 DEPCHAIN_PRE  = ""
 190 DEPCHAIN_POST = "-dev -dbg"
 191
 192 DEPENDS = ""
 193 RDEPENDS = ""
 194 PROVIDES = ""
 195 PROVIDES_prepend = "${P} ${PF} ${PN} "
 196 RPROVIDES = ""
 197
 198 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 199
 200 SOLIBS = ".so.*"
 201 SOLIBS_darwin = ".*.dylib"
 202 SOLIBS_darwin8 = ".*.dylib"
 203 SOLIBS_darwin9 = ".*.dylib"
 204
 205 SOLIBSDEV = ".so"
 206 SOLIBSDEV_darwin = ".dylib"
 207 SOLIBSDEV_darwin8 = ".dylib"
 208 SOLIBSDEV_darwin9 = ".dylib"
 209
 210 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-static ${PN}-locale"
 211 #enable this when bitbake is upgraded to cope with ++ values in the field
 212 PACKAGES_DYNAMIC = "${PN}-locale-*"
 213 FILES = ""
 214
 215 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
 216             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 217             ${base_bindir}/* ${base_sbindir}/* \
 218             ${base_libdir}/*${SOLIBS} \
 219             ${datadir}/${PN} ${libdir}/${PN}/* \
 220             ${datadir}/pixmaps ${datadir}/applications \
 221             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 222             ${libdir}/bonobo/servers"
 223
 224 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 225             ${datadir}/gnome/help"
 226 SECTION_${PN}-doc = "doc"
 227
 228 FILES_${PN}-static = "${libdir}/*.a ${base_libdir}/*.a"
 229
 230 FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
 231                 ${libdir}/*.o ${libdir}/pkgconfig \
 232                 ${base_libdir}/*.o ${datadir}/aclocal ${datadir}/pkgconfig"
 233 SECTION_${PN}-dev = "devel"
 234 ALLOW_EMPTY_${PN}-dev = "1"
 235 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 236
 237 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 238             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 239             ${libdir}/matchbox-panel/.debug"
 240 SECTION_${PN}-dbg = "devel"
 241 ALLOW_EMPTY_${PN}-dbg = "1"
 242 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 243
 244 FILES_${PN}-locale = "${datadir}/locale"
 245
 246 # File manifest
 247
 248 export MANIFEST = "${FILESDIR}/manifest"
 249
 250 # file:// search paths
 251 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 252 FILESPATHBASE = "${FILE_DIRNAME}"
 253 FILESPATHPKG = "${PF}:${P}:${PN}:${BP}:${BPN}:files:."
 254 FILESPATH = "${@':'.join([os.path.normpath(os.path.join(fp, p, o)) for fp in d.getVar('FILESPATHBASE', 1).split(':') for p in d.getVar('FILESPATHPKG', 1).split(':') for o in (d.getVar('OVERRIDES', 1) + ':').split(':') if os.path.exists(os.path.join(fp, p, o))])}"
 255 FILESDIR = "${@bb.which(d.getVar('FILESPATH', 1), '.')}"
 256
 257 ##################################################################
 258 # General work and output directories for the build system.
 259 ##################################################################
 260
 261 TMPDIR = "${TOPDIR}/tmp"
 262 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 263 CO_DIR = "${DL_DIR}"
 264 CVSDIR = "${CO_DIR}/cvs"
 265 SVNDIR = "${CO_DIR}/svn"
 266 GITDIR = "${CO_DIR}/git"
 267 BZRDIR = "${CO_DIR}/bzr"
 268 HGDIR = "${CO_DIR}/hg"
 269
 270 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 271 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 272 T = "${WORKDIR}/temp"
 273 D = "${WORKDIR}/image"
 274 S = "${WORKDIR}/${BP}"
 275 B = "${S}"
 276
 277 STAGING_DIR = "${TMPDIR}/staging"
 278
 279 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 280 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_bindir}"
 281 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${layout_bindir}/${MULTIMACH_HOST_SYS}"
 282 STAGING_BINDIR_CROSS_BASEPKG = "${STAGING_DIR_NATIVE}${layout_bindir}/${BASEPKG_TARGET_SYS}"
 283 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_libdir}"
 284 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_includedir}"
 285 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_sysconfdir}"
 286 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_datadir}"
 287
 288 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 289 # specific packages - hack around it for now.
 290 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 291 STAGING_BINDIR = "${STAGING_DIR_HOST}${layout_bindir}"
 292 STAGING_LIBDIR = "${STAGING_DIR_HOST}${layout_libdir}"
 293 STAGING_INCDIR = "${STAGING_DIR_HOST}${layout_includedir}"
 294 STAGING_DATADIR = "${STAGING_DIR_HOST}${layout_datadir}"
 295 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${layout_exec_prefix}"
 296 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 297 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 298 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 299
 300 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 301 # specific packages - hack around it for now.
 302 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 303
 304 STAGING_DIR_SDK = "${STAGING_DIR}/${SDK_SYS}"
 305
 306 # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
 307 # packaged staging and/or multimachine.
 308 DEPLOY_DIR ?= "${TMPDIR}/deploy"
 309 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 310 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 311 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 312 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 313 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 314 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 315
 316 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 317
 318 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 319 SDK_PATH = "/usr/local/${SDK_NAME}"
 320
 321 ##################################################################
 322 # Kernel info.
 323 ##################################################################
 324
 325 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 326
 327 ##################################################################
 328 # Specific image creation and rootfs population info.
 329 ##################################################################
 330
 331 IMAGE_ROOTFS = "${TMPDIR}/rootfs/${PN}"
 332 IMAGE_BASENAME = "${PN}"
 333 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 334 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 335 IMAGE_EXTRA_SPACE = 10240
 336
 337 UBI_VOLNAME ?= "${MACHINE}-rootfs"
 338
 339 IMAGE_CMD = ""
 340 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 341 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 342 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 343 IMAGE_CMD_ext2 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 344 IMAGE_CMD_ext2.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz"
 345 IMAGE_CMD_ext3 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 346 IMAGE_CMD_ext3.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz"
 347 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 348 IMAGE_CMD_squashfs-lzma = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend -lzma"
 349 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 350 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 351 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 352 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio) ${EXTRA_IMAGECMD}"
 353 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}"
 354 IMAGE_CMD_cpio.lzma = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | lzma -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.lzma) ${EXTRA_IMAGECMD}"
 355 IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
 356 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 357
 358 EXTRA_IMAGECMD = ""
 359 EXTRA_IMAGECMD_jffs2 = ""
 360 EXTRA_IMAGECMD_yaffs2 = "1"
 361 EXTRA_IMAGECMD_squashfs = ""
 362 EXTRA_IMAGECMD_squashfs-lzma = ""
 363 EXTRA_IMAGECMD_cpio = ""
 364 EXTRA_IMAGECMD_cpio.gz = ""
 365 EXTRA_IMAGECMD_cpio.lzma = ""
 366 EXTRA_IMAGECMD_ubi = ""
 367 EXTRA_IMAGECMD_ubifs = ""
 368
 369 IMAGE_DEPENDS = ""
 370 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 371 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 372 IMAGE_DEPENDS_cramfs = "cramfs-native"
 373 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 374 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 375 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 376 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 377 IMAGE_DEPENDS_cpio.lzma = "lzma-native"
 378 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 379 IMAGE_DEPENDS_squashfs-lzma = "squashfs-tools-native"
 380 IMAGE_DEPENDS_ubi = "mtd-utils-native"
 381 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 382
 383 EXTRA_IMAGEDEPENDS = ""
 384
 385 ##################################################################
 386 # Toolchain info.
 387 ##################################################################
 388
 389 CROSS_DIR = "${TMPDIR}/cross/${BASE_PACKAGE_ARCH}"
 390 CROSS_DATADIR = "${CROSS_DIR}/share"
 391 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_BINDIR_CROSS_BASEPKG}:${STAGING_DIR_NATIVE}${layout_sbindir}:${STAGING_BINDIR_NATIVE}:${CROSS_DIR}/bin:${STAGING_DIR_NATIVE}${layout_base_sbindir}:${STAGING_DIR_NATIVE}${layout_base_bindir}:"
 392 export PATH
 393
 394 ##################################################################
 395 # Build utility info.
 396 ##################################################################
 397
 398 CCACHE = "${@bb.which(bb.data.getVar('PATH', d, 1), 'ccache') and 'ccache '}"
 399 TOOLCHAIN_OPTIONS = ""
 400 TOOLCHAIN_PATH ?= ""
 401 TOOLCHAIN_SYSPATH ?= ""
 402
 403 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 404 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 405 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 406 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 407 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 408 export CCLD = "${CC}"
 409 export AR = "${HOST_PREFIX}ar"
 410 export AS = "${HOST_PREFIX}as"
 411 export RANLIB = "${HOST_PREFIX}ranlib"
 412 export STRIP = "${HOST_PREFIX}strip"
 413 export OBJCOPY = "${HOST_PREFIX}objcopy"
 414 export OBJDUMP = "${HOST_PREFIX}objdump"
 415 export NM = "${HOST_PREFIX}nm"
 416 PYTHON = "${@sys.executable}"
 417
 418 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 419 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 420 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 421 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 422 export BUILD_LD = "${BUILD_PREFIX}ld"
 423 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 424 export BUILD_AR = "${BUILD_PREFIX}ar"
 425 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 426 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 427
 428 export MAKE = "make"
 429 EXTRA_OEMAKE = "-e MAKEFLAGS="
 430
 431 ##################################################################
 432 # Patch handling.
 433 ##################################################################
 434 PATCHTOOL = 'quilt'
 435 PATCHRESOLVE = 'noop'
 436
 437 ##################################################################
 438 # Build flags and options.
 439 ##################################################################
 440
 441 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 442 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 443 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${layout_includedir}"
 444 export SDK_CPPFLAGS = "-isystem${STAGING_DIR_SDK}${layout_includedir} -isystem${STAGING_DIR_HOST}${layout_includedir}"
 445
 446 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 447 export CFLAGS = "${TARGET_CFLAGS}"
 448 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 449 export SDK_CFLAGS = "${SDK_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 450
 451 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 452 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 453 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 454 export SDK_CXXFLAGS = "${SDK_CFLAGS} -fpermissive"
 455
 456 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 457                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 458                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 459
 460 export LDFLAGS = "${TARGET_LDFLAGS}"
 461 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${layout_libdir} \
 462                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${layout_libdir} \
 463                          -Wl,-O1 \
 464                          ${TARGET_LINK_HASH_STYLE}"
 465 export SDK_LDFLAGS = "-L${STAGING_DIR_SDK}${layout_libdir} \
 466                          -Wl,-rpath-link,${STAGING_DIR_SDK}${layout_libdir} \
 467                          -Wl,-O1"
 468
 469 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 470 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 471
 472 # Pass parallel make options to the compile task only
 473 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 474 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 475
 476 ##################################################################
 477 # Optimization flags.
 478 ##################################################################
 479
 480 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 481 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 482 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 483 BUILD_OPTIMIZATION = "-O2 -g"
 484
 485 ##################################################################
 486 # Bootstrap stuff.
 487 ##################################################################
 488
 489 BOOTSTRAP_EXTRA_RDEPENDS = ""
 490 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 491
 492 ##################################################################
 493 # Palmtop stuff.
 494 ##################################################################
 495
 496 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 497 export QPEDIR = "${STAGING_DIR_HOST}"
 498 export OPIEDIR = "${STAGING_DIR_HOST}"
 499 export palmtopdir = "${libdir}/opie"
 500 export palmqtdir = "${palmtopdir}"
 501
 502 ##################################################################
 503 # Download locations and utilities.
 504 ##################################################################
 505
 506 OE_STRICT_CHECKSUMS ?= "1"
 507
 508 ADOBE_MIRROR = "http://fpdownload.macromedia.com/get/flashplayer/current/"
 509 APACHE_MIRROR = "http://www.apache.org/dist"
 510 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 511 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 512 E_URI = "http://enlightenment.freedesktop.org/files"
 513 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 514 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 515 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 516 GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
 517 GNOME_GIT = "git://git.gnome.org"
 518 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 519 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 520 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 521 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 522 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 523 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 524 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 525 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 526 KERNELORG_MIRROR = "http://kernel.org"
 527 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 528 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 529 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 530
 531 # You can use the mirror of your country to get faster downloads by putting
 532 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 533 #     into your local.conf
 534
 535 FETCHCMD_svn = "/usr/bin/env svn"
 536 FETCHCMD_cvs = "/usr/bin/env cvs"
 537 FETCHCMD_wget = "/usr/bin/env wget -t 5 --no-check-certificate"
 538 FETCHCMD_bzr = "/usr/bin/env bzr"
 539 FETCHCMD_hg = "/usr/bin/env hg"
 540
 541 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 542 FETCHCOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} ${URI}"
 543 FETCHCOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 544 FETCHCOMMAND_svn = "/usr/bin/env svn co ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 545 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 546 RESUMECOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -c -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} ${URI}"
 547 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 548 UPDATECOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 549 UPDATECOMMAND_svn = "/usr/bin/env svn update ${SVNCOOPTS}"
 550 SRCDATE = "${DATE}"
 551 SRCREV = "1"
 552 AUTOREV = "${@bb.fetch.get_srcrev(d)}"
 553
 554 SRC_URI = "file://${FILE}"
 555
 556 ##################################################################
 557 # UI/Interaction Configuration
 558 ##################################################################
 559
 560 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 561 export SHELLCMDS = "${SHELLRCCMD}"
 562 # Some common terminal programs to choose from
 563 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 564 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 565 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 566 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 567 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 568 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 569 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 570 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 571
 572 # Set a default
 573 TERMCMD ?= "${GNOME_TERMCMD}"
 574 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 575
 576 ##################################################################
 577 # Miscellaneous utilities.
 578 ##################################################################
 579
 580 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 581 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 582
 583 # GNU patch tries to be intellgent about checking out read-only files from
 584 # a RCS, which freaks out those special folks with active Perforce clients
 585 # the following makes patch ignore RCS:
 586
 587 export PATCH_GET="0"
 588
 589 # Program to be used to build ipkg packages
 590
 591 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 592
 593 ##################################################################
 594 # Not sure about the rest of this yet.
 595 ##################################################################
 596
 597 # slot - currently unused by OE. portage remnants
 598 SLOT = "0"
 599
 600 # Other
 601
 602 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${layout_libdir}/pkgconfig"
 603 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 604 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 605 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 606
 607 export XDG_DATA_DIRS = "${STAGING_DATADIR}"
 608
 609 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 610 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 611 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 612
 613 # library package naming
 614 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 615
 616 # Globally toggle certain dependencies
 617 ENTERPRISE_DISTRO ?= "0"
 618
 619 # Pre-build configuration output
 620
 621 BUILDCFG_HEADER = "Build Configuration:"
 622 BUILDCFG_VARS ?= "BB_VERSION METADATA_BRANCH METADATA_REVISION TARGET_ARCH TARGET_OS MACHINE DISTRO DISTRO_VERSION"
 623 BUILDCFG_VARS_append_arm = " TARGET_FPU"
 624 BUILDCFG_VARS_append_armeb = " TARGET_FPU"
 625 BUILDCFG_NEEDEDVARS ?= "TARGET_ARCH TARGET_OS"
 626
 627 ###
 628 ### Config file processing
 629 ###
 630
 631 # This means that an envionment variable named '<foo>_arm' overrides an
 632 # environment variable '<foo>' (when ${TARGET_ARCH} is arm). And the same: an
 633 # environment variable '<foo>_ramses' overrides both '<foo>' and '<foo>_arm
 634 # when ${MACHINE} is 'ramses'. And finally '<foo>_local' overrides anything.
 635 #
 636 # This works for  functions as well, they are really just environment variables.
 637 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 638 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 639 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 640 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 641
 642 ##################################################################
 643 # Include the rest of the config files.
 644 ##################################################################
 645
 646 require conf/collections.inc
 647 include conf/site.conf
 648 include conf/auto.conf
 649 include conf/local.conf
 650 # USERDISTRO should always contain original DISTRO value as set by user
 651 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 652 # overrides like it wants), USERDISTRO must be reassigned with := first
 653 USERDISTRO = "${DISTRO}"
 654 include conf/build/${BUILD_SYS}.conf
 655 include conf/target/${TARGET_SYS}.conf
 656 include conf/machine/${MACHINE}.conf
 657 include conf/distro/${DISTRO}.conf
 658 include conf/documentation.conf
 659 require conf/sanity.conf
 660 require conf/abi_version.conf
 661 require conf/enterprise.conf
 662
 663 ##################################################################
 664 # Weak variables (usually to retain backwards compatibility)
 665 ##################################################################
 666
 667 DL_DIR ?= "${TMPDIR}/downloads"
 668 IMAGE_FSTYPES ?= "tar.gz"
 669 PCMCIA_MANAGER ?= "pcmcia-cs"
 670 DEFAULT_TASK_PROVIDER ?= "task-base"
 671 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 672 IMAGE_ROOTFS_SIZE ?= "65536"
 673 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 674 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 675 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 676 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 677 DISTRO_PR ?= ""
 678
 679 # Forcefully set CACHE now so future changes to things like
 680 # MACHINE don't change the path to the cache
 681 CACHE := "${CACHE}"
 682
 683 # Default to disabling packaged staging code
 684 export PSTAGING_ACTIVE = "0"
 685
 686 ##################################################################
 687 # Magic Cookie for SANITY CHECK
 688 ##################################################################
 689 OES_BITBAKE_CONF = "1"
 690
 691 ##################################################################
 692 # Machine properties and task-base stuff
 693 ##################################################################
 694
 695 MACHINE_FEATURES ?= "kernel26"
 696 DISTRO_FEATURES ?= ""
 697
 698 # This is used to limit what packages goes into images built, so set big by default
 699 ROOT_FLASH_SIZE ?= "256"
 700
 701 MACHINE_GUI_CLASS ?= "smallscreen"
 702 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 703 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 704 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 705 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 706 MACHINE_DISPLAY_ORIENTATION ?= "0"
 707 MACHINE_DISPLAY_BPP ?= "16"
 708
 709 DISTRO_EXTRA_RDEPENDS ?= ""
 710 DISTRO_EXTRA_RRECOMMENDS ?= ""
 711 MACHINE_EXTRA_RDEPENDS ?= ""
 712 MACHINE_EXTRA_RRECOMMENDS ?= ""
 713 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 714 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 715
 716 COMBINED_FEATURES = "\
 717     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 718     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 719     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 720     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 721     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 722     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 723     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 724     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 725     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 726     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 727
 728 # We want madwifi if all of the following are true:
 729 # - distro has pci, wifi, and madwifi in its features
 730 # - machine has pci in its features
 731 COMBINED_FEATURES += "${@base_ifelse( \
 732     base_contains('DISTRO_FEATURES', ('pci', 'wifi', 'madwifi'), True, False, d) and \
 733     base_contains('MACHINE_FEATURES', 'pci', True, False, d), \
 734     'madwifi', '')}"
 735
 736 # We want hostap if all of the following are true:
 737 # - 'wifi' and 'hostap' are in distro features
 738 # - either 'pci' or 'pcmcia' are in both distro and machine features
 739 COMBINED_FEATURES += "${@base_ifelse( \
 740     base_contains('DISTRO_FEATURES', ('wifi', 'hostap'), True, False, d) and \
 741     ((base_contains('MACHINE_FEATURES', 'pci', True, False, d) and \
 742       base_contains('DISTRO_FEATURES', 'pci', True, False, d)) or \
 743      (base_contains('MACHINE_FEATURES', 'pcmcia', True, False, d) and \
 744       base_contains('DISTRO_FEATURES', 'pcmcia', True, False, d))), \
 745     'hostap', '')}"