classes/update-rc.d.bbclass

   1 DEPENDS_append = " update-rc.d"
   2 RDEPENDS_append = " update-rc.d"
   3
   4 INITSCRIPT_PARAMS ?= "defaults"
   5
   6 INIT_D_DIR = "${sysconfdir}/init.d"
   7
   8 updatercd_postinst() {
   9 if test "x$D" != "x"; then
  10         D="-r $D"
  11 else
  12         D="-s"
  13 fi
  14 update-rc.d $D ${INITSCRIPT_NAME} ${INITSCRIPT_PARAMS}
  15 }
  16
  17 updatercd_prerm() {
  18 if test "x$D" != "x"; then
  19         D="-r $D"
  20 else
  21         ${INIT_D_DIR}/${INITSCRIPT_NAME} stop
  22 fi
  23 update-rc.d $D ${INITSCRIPT_NAME} remove
  24 }
  25
  26 python __anonymous() {
  27         if bb.data.getVar('INITSCRIPT_PACKAGES', d) == None:
  28                 if bb.data.getVar('INITSCRIPT_NAME', d) == None:
  29                         raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_NAME" % bb.data.getVar('FILE', d)
  30                 if bb.data.getVar('INITSCRIPT_PARAMS', d) == None:
  31                         raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_PARAMS" % bb.data.getVar('FILE', d)
  32 }
  33
  34 python populate_packages_prepend () {
  35         def update_rcd_package(pkg):
  36                 bb.debug(1, 'adding update-rc.d calls to postinst/postrm for %s' % pkg)
  37                 localdata = bb.data.createCopy(d)
  38                 overrides = bb.data.getVar("OVERRIDES", localdata, 1)
  39                 bb.data.setVar("OVERRIDES", "%s:%s" % (pkg, overrides), localdata)
  40                 bb.data.update_data(localdata)
  41
  42                 postinst = bb.data.getVar('pkg_postinst', localdata, 1)
  43                 if not postinst:
  44                         postinst = '#!/bin/sh\n'
  45                 postinst += bb.data.getVar('updatercd_postinst', localdata, 1)
  46                 bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
  47                 prerm = bb.data.getVar('pkg_prerm', localdata, 1)
  48                 if not prerm:
  49                         prerm = '#!/bin/sh\n'
  50                 prerm += bb.data.getVar('updatercd_prerm', localdata, 1)
  51                 bb.data.setVar('pkg_prerm_%s' % pkg, prerm, d)
  52
  53         pkgs = bb.data.getVar('INITSCRIPT_PACKAGES', d, 1)
  54         if pkgs == None:
  55                 pkgs = bb.data.getVar('PN', d, 1)
  56                 packages = (bb.data.getVar('PACKAGES', d, 1) or "").split()
  57                 if not pkgs in packages:
  58                         pkgs = packages[0]
  59         for pkg in pkgs.split():
  60                 update_rcd_package(pkg)
  61 }