classes/glibc-package.bbclass

   1 #
   2 # This class knows how to package up glibc. Its shared since prebuild binary toolchains
   3 # may need packaging and its pointless to duplicate this code.
   4 #
   5 # Caller should set GLIBC_INTERNAL_USE_BINARY_LOCALE to one of:
   6 #  "compile" - Use QEMU to generate the binary locale files
   7 #  "precompiled" - The binary locale files are pregenerated and already present
   8 #  "ondevice" - The device will build the locale files upon first boot through the postinst
   9
  10 GLIBC_INTERNAL_USE_BINARY_LOCALE ?= "ondevice"
  11
  12 PACKAGES = "glibc-dbg glibc catchsegv sln nscd ldd localedef glibc-utils glibc-dev glibc-static glibc-doc glibc-locale libcidn libmemusage libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
  13 PACKAGES_DYNAMIC = "glibc-gconv-* glibc-charmap-* glibc-localedata-* locale-base-* glibc-binary-localedata-*"
  14
  15 INSANE_SKIP_glibc-dbg = True
  16
  17 libc_baselibs = "${base_libdir}/libcrypt*.so.* ${base_libdir}/libcrypt-*.so ${base_libdir}/libc*.so.* ${base_libdir}/libc-*.so ${base_libdir}/libm*.so.* ${base_libdir}/libm-*.so ${base_libdir}/ld*.so.* ${base_libdir}/ld-*.so ${base_libdir}/libpthread*.so.* ${base_libdir}/libpthread-*.so ${base_libdir}/libresolv*.so.* ${base_libdir}/libresolv-*.so ${base_libdir}/librt*.so.* ${base_libdir}/librt-*.so ${base_libdir}/libutil*.so.* ${base_libdir}/libutil-*.so ${base_libdir}/libnsl*.so.* ${base_libdir}/libnsl-*.so ${base_libdir}/libnss_files*.so.* ${base_libdir}/libnss_files-*.so ${base_libdir}/libnss_compat*.so.* ${base_libdir}/libnss_compat-*.so ${base_libdir}/libnss_dns*.so.* ${base_libdir}/libnss_dns-*.so ${base_libdir}/libdl*.so.* ${base_libdir}/libdl-*.so ${base_libdir}/libanl*.so.* ${base_libdir}/libanl-*.so ${base_libdir}/libBrokenLocale*.so.* ${base_libdir}/libBrokenLocale-*.so"
  18
  19 FILES_glibc = "${libc_baselibs} ${libexecdir}/* ${datadir}/zoneinfo ${@base_conditional('USE_LDCONFIG', '1', '${base_sbindir}/ldconfig', '', d)}"
  20 FILES_ldd = "${bindir}/ldd"
  21 FILES_libsegfault = "${base_libdir}/libSegFault*"
  22 FILES_libcidn = "${base_libdir}/libcidn*.so"
  23 FILES_libmemusage = "${base_libdir}/libmemusage.so"
  24 FILES_glibc-extra-nss = "${base_libdir}/libnss*"
  25 FILES_sln = "${base_sbindir}/sln"
  26 FILES_glibc-dev_append = " ${libdir}/*.o ${bindir}/rpcgen ${libdir}/*nonshared.a"
  27 FILES_nscd = "${sbindir}/nscd* ${sysconfdir}/nscd* ${sysconfdir}/init.d/nscd*"
  28 FILES_glibc-utils = "${bindir}/* ${sbindir}/*"
  29 FILES_glibc-gconv = "${libdir}/gconv/*"
  30 FILES_glibc-dbg = "${bindir}/.debug ${sbindir}/.debug ${libdir}/.debug \
  31                   ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug \
  32                   ${libdir}/gconv/.debug ${libexecdir}/*/.debug"
  33 FILES_catchsegv = "${bindir}/catchsegv"
  34 RDEPENDS_catchsegv = "libsegfault"
  35 FILES_glibc-pcprofile = "${base_libdir}/libpcprofile.so"
  36 FILES_glibc-thread-db = "${base_libdir}/libthread_db*"
  37 FILES_localedef = "${bindir}/localedef"
  38 RPROVIDES_glibc-dev += "libc-dev"
  39
  40 DESCRIPTION_sln = "glibc: create symbolic links between files"
  41 DESCRIPTION_nscd = "glibc: name service cache daemon for passwd, group, and hosts"
  42 DESCRIPTION_glibc-extra-nss = "glibc: nis, nisplus and hesiod search services"
  43 DESCRIPTION_ldd = "glibc: print shared library dependencies"
  44 DESCRIPTION_localedef = "glibc: compile locale definition files"
  45 DESCRIPTION_glibc-utils = "glibc: misc utilities like iconf, local, gencat, tzselect, rpcinfo, ..."
  46
  47 TMP_LOCALE="/tmp/locale${libdir}/locale"
  48
  49 locale_base_postinst() {
  50 #!/bin/sh
  51
  52 if [ "x$D" != "x" ]; then
  53   exit 1
  54 fi
  55
  56 rm -rf ${TMP_LOCALE}
  57 mkdir -p ${TMP_LOCALE}
  58 if [ -f ${libdir}/locale/locale-archive ]; then
  59         cp ${libdir}/locale/locale-archive ${TMP_LOCALE}/
  60 fi
  61 localedef --inputfile=${datadir}/i18n/locales/%s --charmap=%s --prefix=/tmp/locale %s
  62 mkdir -p ${libdir}/locale/
  63 mv ${TMP_LOCALE}/locale-archive ${libdir}/locale/
  64 rm -rf ${TMP_LOCALE}
  65 }
  66
  67 locale_base_postrm() {
  68 #!/bin/sh
  69
  70 rm -rf ${TMP_LOCALE}
  71 mkdir -p ${TMP_LOCALE}
  72 if [ -f ${libdir}/locale/locale-archive ]; then
  73         cp ${libdir}/locale/locale-archive ${TMP_LOCALE}/
  74 fi
  75 localedef --delete-from-archive --inputfile=${datadir}/locales/%s --charmap=%s --prefix=/tmp/locale %s
  76 mv ${TMP_LOCALE}/locale-archive ${libdir}/locale/
  77 rm -rf ${TMP_LOCALE}
  78 }
  79
  80 do_prep_locale_tree() {
  81         treedir=${WORKDIR}/locale-tree
  82         rm -rf $treedir
  83         mkdir -p $treedir/bin $treedir/lib $treedir/${datadir} $treedir/${libdir}/locale
  84         cp -pPR ${PKGD}${datadir}/i18n $treedir/${datadir}/i18n
  85         # unzip to avoid parsing errors
  86         for i in $treedir/${datadir}/i18n/charmaps/*gz; do
  87                 gunzip $i
  88         done
  89         ls -d ${PKGD}${base_libdir}/* | xargs -iBLAH cp -pPR BLAH $treedir/lib
  90         if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so ]; then
  91                 cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so $treedir/lib
  92         fi
  93         if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.* ]; then
  94                 cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.* $treedir/lib
  95         fi
  96         install -m 0755 ${PKGD}${bindir}/localedef $treedir/bin
  97 }
  98
  99 do_collect_bins_from_locale_tree() {
 100         treedir=${WORKDIR}/locale-tree
 101
 102         mkdir -p ${PKGD}${libdir}
 103         cp -pPR $treedir/${libdir}/locale ${PKGD}${libdir}
 104 }
 105
 106 python package_do_split_gconvs () {
 107         import os, re
 108         if (bb.data.getVar('PACKAGE_NO_GCONV', d, 1) == '1'):
 109                 bb.note("package requested not splitting gconvs")
 110                 return
 111
 112         if not bb.data.getVar('PACKAGES', d, 1):
 113                 return
 114
 115         libdir = bb.data.getVar('libdir', d, 1)
 116         if not libdir:
 117                 bb.error("libdir not defined")
 118                 return
 119         datadir = bb.data.getVar('datadir', d, 1)
 120         if not datadir:
 121                 bb.error("datadir not defined")
 122                 return
 123
 124         gconv_libdir = base_path_join(libdir, "gconv")
 125         charmap_dir = base_path_join(datadir, "i18n", "charmaps")
 126         locales_dir = base_path_join(datadir, "i18n", "locales")
 127         binary_locales_dir = base_path_join(libdir, "locale")
 128
 129         do_split_packages(d, gconv_libdir, file_regex='^(.*)\.so$', output_pattern='glibc-gconv-%s', description='gconv module for character set %s', extra_depends='glibc-gconv')
 130
 131         do_split_packages(d, charmap_dir, file_regex='^(.*)\.gz$', output_pattern='glibc-charmap-%s', description='character map for %s encoding', extra_depends='')
 132
 133         def calc_locale_deps(fn, pkg, file_regex, output_pattern, group):
 134                 deps = []
 135                 f = open(fn, "r")
 136                 c_re = re.compile('^copy "(.*)"')
 137                 i_re = re.compile('^include "(\w+)".*')
 138                 for l in f.readlines():
 139                         m = c_re.match(l) or i_re.match(l)
 140                         if m:
 141                                 dp = legitimize_package_name('glibc-localedata-%s' % m.group(1))
 142                                 if not dp in deps:
 143                                         deps.append(dp)
 144                 f.close()
 145                 if deps != []:
 146                         bb.data.setVar('RDEPENDS_%s' % pkg, " ".join(deps), d)
 147
 148         do_split_packages(d, locales_dir, file_regex='(.*)', output_pattern='glibc-localedata-%s', description='locale definition for %s', hook=calc_locale_deps, extra_depends='')
 149         bb.data.setVar('PACKAGES', bb.data.getVar('PACKAGES', d) + ' glibc-gconv', d)
 150
 151         supported = bb.data.getVar('GLIBC_GENERATE_LOCALES', d, 1)
 152         if not supported or supported == "all":
 153             f = open(base_path_join(bb.data.getVar('WORKDIR', d, 1), "SUPPORTED"), "r")
 154             supported = f.readlines()
 155             f.close()
 156         else:
 157             supported = supported.split()
 158             supported = map(lambda s:s.replace(".", " ") + "\n", supported)
 159
 160         dot_re = re.compile("(.*)\.(.*)")
 161
 162         # Collate the locales by base and encoding
 163         utf8_only = int(bb.data.getVar('LOCALE_UTF8_ONLY', d, 1) or 0)
 164         encodings = {}
 165         for l in supported:
 166                 l = l[:-1]
 167                 (locale, charset) = l.split(" ")
 168                 if utf8_only and charset != 'UTF-8':
 169                         continue
 170                 m = dot_re.match(locale)
 171                 if m:
 172                         locale = m.group(1)
 173                 if not encodings.has_key(locale):
 174                         encodings[locale] = []
 175                 encodings[locale].append(charset)
 176
 177         def output_locale_source(name, locale, encoding):
 178                 pkgname = 'locale-base-' + legitimize_package_name(name)
 179
 180                 bb.data.setVar('RDEPENDS_%s' % pkgname, 'localedef glibc-localedata-%s glibc-charmap-%s' % (legitimize_package_name(locale), legitimize_package_name(encoding)), d)
 181                 rprovides = 'virtual-locale-%s' % legitimize_package_name(name)
 182                 m = re.match("(.*)_(.*)", name)
 183                 if m:
 184                         rprovides += ' virtual-locale-%s' % m.group(1)
 185                 bb.data.setVar('RPROVIDES_%s' % pkgname, rprovides, d)
 186                 bb.data.setVar('PACKAGES', '%s %s' % (pkgname, bb.data.getVar('PACKAGES', d, 1)), d)
 187                 bb.data.setVar('ALLOW_EMPTY_%s' % pkgname, '1', d)
 188                 bb.data.setVar('pkg_postinst_%s' % pkgname, bb.data.getVar('locale_base_postinst', d, 1) % (locale, encoding, locale), d)
 189                 bb.data.setVar('pkg_postrm_%s' % pkgname, bb.data.getVar('locale_base_postrm', d, 1) % (locale, encoding, locale), d)
 190
 191         def output_locale_binary(name, locale, encoding):
 192                 target_arch = bb.data.getVar("TARGET_ARCH", d, 1)
 193                 if target_arch in ("i486", "i586", "i686"):
 194                         target_arch = "i386"
 195                 elif target_arch == "powerpc":
 196                         target_arch = "ppc"
 197
 198                 # This is a hack till linux-libc-headers gets patched for the missing arm syscalls and all arm device kernels as well
 199                 if bb.data.getVar("DISTRO_NAME", d, 1) == "Angstrom":
 200                         kernel_ver = "2.6.24"
 201                 elif bb.data.getVar("DISTRO_NAME", d, 1) == "KaeilOS":
 202                         kernel_ver = "2.6.24"
 203                 else:
 204                         kernel_ver = bb.data.getVar("OLDEST_KERNEL", d, 1)
 205
 206                 if kernel_ver is None:
 207                         qemu = "qemu-%s  -s 1048576" % target_arch
 208                 else:
 209                         qemu = "qemu-%s  -s 1048576 -r %s" % (target_arch, kernel_ver)
 210                 pkgname = 'locale-base-' + legitimize_package_name(name)
 211                 m = re.match("(.*)\.(.*)", name)
 212                 if m:
 213                         glibc_name = "%s.%s" % (m.group(1), m.group(2).lower().replace("-",""))
 214                 else:
 215                         glibc_name = name
 216                 bb.data.setVar('RDEPENDS_%s' % pkgname, legitimize_package_name('glibc-binary-localedata-%s' % glibc_name), d)
 217                 rprovides = 'virtual-locale-%s' % legitimize_package_name(name)
 218                 m = re.match("(.*)_(.*)", name)
 219                 if m:
 220                         rprovides += ' virtual-locale-%s' % m.group(1)
 221                 bb.data.setVar('RPROVIDES_%s' % pkgname, rprovides, d)
 222                 bb.data.setVar('ALLOW_EMPTY_%s' % pkgname, '1', d)
 223                 bb.data.setVar('PACKAGES', '%s %s' % (pkgname, bb.data.getVar('PACKAGES', d, 1)), d)
 224
 225                 treedir = base_path_join(bb.data.getVar("WORKDIR", d, 1), "locale-tree")
 226                 ldlibdir = "%s/lib" % treedir
 227                 path = bb.data.getVar("PATH", d, 1)
 228                 i18npath = base_path_join(treedir, datadir, "i18n")
 229
 230                 localedef_opts = "--force --old-style --no-archive --prefix=%s --inputfile=%s/i18n/locales/%s --charmap=%s %s" % (treedir, datadir, locale, encoding, name)
 231
 232                 qemu_options = bb.data.getVar("QEMU_OPTIONS_%s" % bb.data.getVar('PACKAGE_ARCH', d, 1), d, 1)
 233                 if not qemu_options:
 234                         qemu_options = bb.data.getVar('QEMU_OPTIONS', d, 1)
 235
 236                 cmd = "PATH=\"%s\" I18NPATH=\"%s\" %s -L %s -E LD_LIBRARY_PATH=%s %s %s/bin/localedef %s" % (path, i18npath, qemu, treedir, ldlibdir, qemu_options, treedir, localedef_opts)
 237                 bb.note("generating locale %s (%s)" % (locale, encoding))
 238                 if os.system(cmd):
 239                         raise bb.build.FuncFailed("localedef returned an error (command was %s)." % cmd)
 240
 241         def output_locale(name, locale, encoding):
 242                 use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
 243                 if use_bin == "compile":
 244                         output_locale_binary(name, locale, encoding)
 245                 else:
 246                         output_locale_source(name, locale, encoding)
 247
 248         use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
 249         if use_bin == "compile":
 250                 bb.note("preparing tree for binary locale generation")
 251                 bb.build.exec_func("do_prep_locale_tree", d)
 252
 253         # Reshuffle names so that UTF-8 is preferred over other encodings
 254         non_utf8 = []
 255         for l in encodings.keys():
 256                 if len(encodings[l]) == 1:
 257                         output_locale(l, l, encodings[l][0])
 258                         if encodings[l][0] != "UTF-8":
 259                                 non_utf8.append(l)
 260                 else:
 261                         if "UTF-8" in encodings[l]:
 262                                 output_locale(l, l, "UTF-8")
 263                                 encodings[l].remove("UTF-8")
 264                         else:
 265                                 non_utf8.append(l)
 266                         for e in encodings[l]:
 267                                 output_locale('%s.%s' % (l, e), l, e)
 268
 269         if non_utf8 != []:
 270                 bb.note("the following locales are supported only in legacy encodings:")
 271                 bb.note("  " + " ".join(non_utf8))
 272
 273         use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
 274         if use_bin == "compile":
 275                 bb.note("collecting binary locales from locale tree")
 276                 bb.build.exec_func("do_collect_bins_from_locale_tree", d)
 277                 do_split_packages(d, binary_locales_dir, file_regex='(.*)', output_pattern='glibc-binary-localedata-%s', description='binary locale definition for %s', extra_depends='', allow_dirs=True)
 278         else:
 279                 bb.note("generation of binary locales disabled. this may break i18n!")
 280
 281 }
 282
 283 # We want to do this indirection so that we can safely 'return'
 284 # from the called function even though we're prepending
 285 python populate_packages_prepend () {
 286         if bb.data.getVar('DEBIAN_NAMES', d, 1):
 287                 bb.data.setVar('PKG_glibc', 'libc6', d)
 288                 bb.data.setVar('PKG_glibc-dev', 'libc6-dev', d)
 289         bb.build.exec_func('package_do_split_gconvs', d)
 290 }