classes/binconfig.bbclass

   1 inherit base
   2
   3 # The namespaces can clash here hence the two step replace
   4 def get_binconfig_mangle(d):
   5         import bb.data
   6         s = "-e ''"
   7         if not bb.data.inherits_class('native', d):
   8                 optional_quote = r"\(\"\?\)"
   9                 s += " -e 's:=%s${libdir}:=\\1OELIBDIR:;'" % optional_quote
  10                 s += " -e 's:=%s${includedir}:=\\1OEINCDIR:;'" % optional_quote
  11                 s += " -e 's:=%s${datadir}:=\\1OEDATADIR:'" % optional_quote
  12                 s += " -e 's:=%s${prefix}:=\\1OEPREFIX:'" % optional_quote
  13                 s += " -e 's:=%s${exec_prefix}:=\\1OEEXECPREFIX:'" % optional_quote
  14                 s += " -e 's:-L${libdir}:-LOELIBDIR:;'"
  15                 s += " -e 's:-I${includedir}:-IOEINCDIR:;'"
  16                 s += " -e 's:OELIBDIR:${STAGING_LIBDIR}:;'"
  17                 s += " -e 's:OEINCDIR:${STAGING_INCDIR}:;'"
  18                 s += " -e 's:OEDATADIR:${STAGING_DATADIR}:'"
  19                 s += " -e 's:OEPREFIX:${STAGING_LIBDIR}/..:'"
  20                 s += " -e 's:OEEXECPREFIX:${STAGING_LIBDIR}/..:'"
  21         return s
  22
  23 # Native package configurations go in ${BINDIR}/<name>-config-native to prevent a collision with cross packages
  24 def is_native(d):
  25         import bb.data
  26         return ["","-native"][bb.data.inherits_class('native', d)]
  27
  28 BINCONFIG_GLOB ?= "*-config"
  29
  30 do_install_append() {
  31
  32     #the 'if' protects native packages, since we can't easily check for bb.data.inherits_class('native', d) in shell
  33     if [ -e ${D}${bindir} ] ; then
  34         for config in `find ${S} -name '${BINCONFIG_GLOB}'`; do
  35                 cat $config | sed \
  36                 -e 's:${STAGING_LIBDIR}:${libdir}:g;' \
  37                 -e 's:${STAGING_INCDIR}:${includedir}:g;' \
  38                 -e 's:${STAGING_DATADIR}:${datadir}:' \
  39                 -e 's:${STAGING_LIBDIR}/..:${prefix}:' > ${D}${bindir}/`basename $config`
  40         done
  41     fi
  42
  43         for lafile in `find ${D} -name *.la` ; do
  44                 sed -i \
  45                     -e 's:${STAGING_LIBDIR}:${libdir}:g;' \
  46                     -e 's:${STAGING_INCDIR}:${includedir}:g;' \
  47                     -e 's:${STAGING_DATADIR}:${datadir}:' \
  48                     -e 's:${STAGING_LIBDIR}/..:${prefix}:' \
  49                     $lafile
  50         done
  51 }
  52
  53 do_stage_append() {
  54         for config in `find ${S} -name '${BINCONFIG_GLOB}'`; do
  55                 configname=`basename $config`${@is_native(d)}
  56                 install -d ${STAGING_BINDIR}
  57                 cat $config | sed ${@get_binconfig_mangle(d)} > ${STAGING_BINDIR}/$configname
  58                 chmod u+x ${STAGING_BINDIR}/$configname
  59         done
  60 }