arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74 #ifdef CONFIG_SMP
  75         percpu PT_LOAD FLAGS(6);        /* RW_ */
  76 #endif
  77         init PT_LOAD FLAGS(7);          /* RWE */
  78 #endif
  79         note PT_NOTE FLAGS(0);          /* ___ */
  80 }
  81
  82 SECTIONS
  83 {
  84 #ifdef CONFIG_X86_32
  85         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  86         phys_startup_32 = startup_32 - LOAD_OFFSET;
  87 #else
  88         . = __START_KERNEL;
  89         phys_startup_64 = startup_64 - LOAD_OFFSET;
  90 #endif
  91
  92         /* Text and read-only data */
  93         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  94                 _text = .;
  95                 /* bootstrapping code */
  96                 HEAD_TEXT
  97 #ifdef CONFIG_X86_32
  98                 . = ALIGN(PAGE_SIZE);
  99                 *(.text..page_aligned)
 100 #endif
 101                 . = ALIGN(8);
 102                 _stext = .;
 103                 TEXT_TEXT
 104                 SCHED_TEXT
 105                 LOCK_TEXT
 106                 KPROBES_TEXT
 107                 ENTRY_TEXT
 108                 IRQENTRY_TEXT
 109                 *(.fixup)
 110                 *(.gnu.warning)
 111 #ifdef CONFIG_RETPOLINE
 112                 __indirect_thunk_start = .;
 113                 *(.text.__x86.indirect_thunk)
 114                 __indirect_thunk_end = .;
 115 #endif
 116
 117                 /* End of text section */
 118                 _etext = .;
 119         } :text = 0x9090
 120
 121         NOTES :text :note
 122
 123         EXCEPTION_TABLE(16) :text = 0x9090
 124
 125 #if defined(CONFIG_DEBUG_RODATA)
 126         /* .text should occupy whole number of pages */
 127         . = ALIGN(PAGE_SIZE);
 128 #endif
 129         X64_ALIGN_DEBUG_RODATA_BEGIN
 130         RO_DATA(PAGE_SIZE)
 131         X64_ALIGN_DEBUG_RODATA_END
 132
 133         /* Data */
 134         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 135                 /* Start of data section */
 136                 _sdata = .;
 137
 138                 /* init_task */
 139                 INIT_TASK_DATA(THREAD_SIZE)
 140
 141 #ifdef CONFIG_X86_32
 142                 /* 32 bit has nosave before _edata */
 143                 NOSAVE_DATA
 144 #endif
 145
 146                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 147
 148                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 149
 150                 DATA_DATA
 151                 CONSTRUCTORS
 152
 153                 /* rarely changed data like cpu maps */
 154                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 155
 156                 /* End of data section */
 157                 _edata = .;
 158         } :data
 159
 160 #ifdef CONFIG_X86_64
 161
 162         . = ALIGN(PAGE_SIZE);
 163         __vvar_page = .;
 164
 165         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 166                 /* work around gold bug 13023 */
 167                 __vvar_beginning_hack = .;
 168
 169                 /* Place all vvars at the offsets in asm/vvar.h. */
 170 #define EMIT_VVAR(name, offset)                         \
 171                 . = __vvar_beginning_hack + offset;     \
 172                 *(.vvar_ ## name)
 173 #define __VVAR_KERNEL_LDS
 174 #include <asm/vvar.h>
 175 #undef __VVAR_KERNEL_LDS
 176 #undef EMIT_VVAR
 177
 178         } :data
 179
 180        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 181
 182 #endif /* CONFIG_X86_64 */
 183
 184         /* Init code and data - will be freed after init */
 185         . = ALIGN(PAGE_SIZE);
 186         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 187                 __init_begin = .; /* paired with __init_end */
 188         }
 189
 190 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 191         /*
 192          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 193          * output PHDR, so the next output section - .init.text - should
 194          * start another segment - init.
 195          */
 196         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 197 #endif
 198
 199         INIT_TEXT_SECTION(PAGE_SIZE)
 200 #ifdef CONFIG_X86_64
 201         :init
 202 #endif
 203
 204         INIT_DATA_SECTION(16)
 205
 206         /*
 207          * Code and data for a variety of lowlevel trampolines, to be
 208          * copied into base memory (< 1 MiB) during initialization.
 209          * Since it is copied early, the main copy can be discarded
 210          * afterwards.
 211          */
 212          .x86_trampoline : AT(ADDR(.x86_trampoline) - LOAD_OFFSET) {
 213                 x86_trampoline_start = .;
 214                 *(.x86_trampoline)
 215                 x86_trampoline_end = .;
 216         }
 217
 218         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 219                 __x86_cpu_dev_start = .;
 220                 *(.x86_cpu_dev.init)
 221                 __x86_cpu_dev_end = .;
 222         }
 223
 224         /*
 225          * start address and size of operations which during runtime
 226          * can be patched with virtualization friendly instructions or
 227          * baremetal native ones. Think page table operations.
 228          * Details in paravirt_types.h
 229          */
 230         . = ALIGN(8);
 231         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 232                 __parainstructions = .;
 233                 *(.parainstructions)
 234                 __parainstructions_end = .;
 235         }
 236
 237         /*
 238          * struct alt_inst entries. From the header (alternative.h):
 239          * "Alternative instructions for different CPU types or capabilities"
 240          * Think locking instructions on spinlocks.
 241          */
 242         . = ALIGN(8);
 243         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 244                 __alt_instructions = .;
 245                 *(.altinstructions)
 246                 __alt_instructions_end = .;
 247         }
 248
 249         /*
 250          * And here are the replacement instructions. The linker sticks
 251          * them as binary blobs. The .altinstructions has enough data to
 252          * get the address and the length of them to patch the kernel safely.
 253          */
 254         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 255                 *(.altinstr_replacement)
 256         }
 257
 258         /*
 259          * struct iommu_table_entry entries are injected in this section.
 260          * It is an array of IOMMUs which during run time gets sorted depending
 261          * on its dependency order. After rootfs_initcall is complete
 262          * this section can be safely removed.
 263          */
 264         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 265                 __iommu_table = .;
 266                 *(.iommu_table)
 267                 __iommu_table_end = .;
 268         }
 269
 270         . = ALIGN(8);
 271         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 272                 __apicdrivers = .;
 273                 *(.apicdrivers);
 274                 __apicdrivers_end = .;
 275         }
 276
 277         . = ALIGN(8);
 278         /*
 279          * .exit.text is discard at runtime, not link time, to deal with
 280          *  references from .altinstructions and .eh_frame
 281          */
 282         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 283                 EXIT_TEXT
 284         }
 285
 286         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 287                 EXIT_DATA
 288         }
 289
 290 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 291         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 292 #endif
 293
 294         . = ALIGN(PAGE_SIZE);
 295
 296         /* freed after init ends here */
 297         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 298                 __init_end = .;
 299         }
 300
 301         /*
 302          * smp_locks might be freed after init
 303          * start/end must be page aligned
 304          */
 305         . = ALIGN(PAGE_SIZE);
 306         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 307                 __smp_locks = .;
 308                 *(.smp_locks)
 309                 . = ALIGN(PAGE_SIZE);
 310                 __smp_locks_end = .;
 311         }
 312
 313 #ifdef CONFIG_X86_64
 314         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 315                 NOSAVE_DATA
 316         }
 317 #endif
 318
 319         /* BSS */
 320         . = ALIGN(PAGE_SIZE);
 321         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 322                 __bss_start = .;
 323                 *(.bss..page_aligned)
 324                 *(.bss)
 325                 . = ALIGN(PAGE_SIZE);
 326                 __bss_stop = .;
 327         }
 328
 329         . = ALIGN(PAGE_SIZE);
 330         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 331                 __brk_base = .;
 332                 . += 64 * 1024;         /* 64k alignment slop space */
 333                 *(.brk_reservation)     /* areas brk users have reserved */
 334                 __brk_limit = .;
 335         }
 336
 337         _end = .;
 338
 339         STABS_DEBUG
 340         DWARF_DEBUG
 341
 342         /* Sections to be discarded */
 343         DISCARDS
 344         /DISCARD/ : { *(.eh_frame) }
 345 }
 346
 347
 348 #ifdef CONFIG_X86_32
 349 /*
 350  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 351  */
 352 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 353            "kernel image bigger than KERNEL_IMAGE_SIZE");
 354 #else
 355 /*
 356  * Per-cpu symbols which need to be offset from __per_cpu_load
 357  * for the boot processor.
 358  */
 359 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 360 INIT_PER_CPU(gdt_page);
 361 INIT_PER_CPU(irq_stack_union);
 362
 363 /*
 364  * Build-time check on the image size:
 365  */
 366 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 367            "kernel image bigger than KERNEL_IMAGE_SIZE");
 368
 369 #ifdef CONFIG_SMP
 370 . = ASSERT((irq_stack_union == 0),
 371            "irq_stack_union is not at start of per-cpu area");
 372 #endif
 373
 374 #endif /* CONFIG_X86_32 */
 375
 376 #ifdef CONFIG_KEXEC
 377 #include <asm/kexec.h>
 378
 379 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 380            "kexec control code size is too big");
 381 #endif
 382