arch/x86/boot/header.S

   1 /*
   2  *      header.S
   3  *
   4  *      Copyright (C) 1991, 1992 Linus Torvalds
   5  *
   6  *      Based on bootsect.S and setup.S
   7  *      modified by more people than can be counted
   8  *
   9  *      Rewritten as a common file by H. Peter Anvin (Apr 2007)
  10  *
  11  * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
  12  * addresses must be multiplied by 16 to obtain their respective linear
  13  * addresses. To avoid confusion, linear addresses are written using leading
  14  * hex while segment addresses are written as segment:offset.
  15  *
  16  */
  17
  18 #include <asm/segment.h>
  19 #include <generated/utsrelease.h>
  20 #include <asm/boot.h>
  21 #include <asm/e820.h>
  22 #include <asm/page_types.h>
  23 #include <asm/setup.h>
  24 #include "boot.h"
  25 #include "voffset.h"
  26 #include "zoffset.h"
  27
  28 BOOTSEG         = 0x07C0                /* original address of boot-sector */
  29 SYSSEG          = 0x1000                /* historical load address >> 4 */
  30
  31 #ifndef SVGA_MODE
  32 #define SVGA_MODE ASK_VGA
  33 #endif
  34
  35 #ifndef RAMDISK
  36 #define RAMDISK 0
  37 #endif
  38
  39 #ifndef ROOT_RDONLY
  40 #define ROOT_RDONLY 1
  41 #endif
  42
  43         .code16
  44         .section ".bstext", "ax"
  45
  46         .global bootsect_start
  47 bootsect_start:
  48 #ifdef CONFIG_EFI_STUB
  49         # "MZ", MS-DOS header
  50         .byte 0x4d
  51         .byte 0x5a
  52 #endif
  53
  54         # Normalize the start address
  55         ljmp    $BOOTSEG, $start2
  56
  57 start2:
  58         movw    %cs, %ax
  59         movw    %ax, %ds
  60         movw    %ax, %es
  61         movw    %ax, %ss
  62         xorw    %sp, %sp
  63         sti
  64         cld
  65
  66         movw    $bugger_off_msg, %si
  67
  68 msg_loop:
  69         lodsb
  70         andb    %al, %al
  71         jz      bs_die
  72         movb    $0xe, %ah
  73         movw    $7, %bx
  74         int     $0x10
  75         jmp     msg_loop
  76
  77 bs_die:
  78         # Allow the user to press a key, then reboot
  79         xorw    %ax, %ax
  80         int     $0x16
  81         int     $0x19
  82
  83         # int 0x19 should never return.  In case it does anyway,
  84         # invoke the BIOS reset code...
  85         ljmp    $0xf000,$0xfff0
  86
  87 #ifdef CONFIG_EFI_STUB
  88         .org    0x3c
  89         #
  90         # Offset to the PE header.
  91         #
  92         .long   pe_header
  93 #endif /* CONFIG_EFI_STUB */
  94
  95         .section ".bsdata", "a"
  96 bugger_off_msg:
  97         .ascii  "Direct booting from floppy is no longer supported.\r\n"
  98         .ascii  "Please use a boot loader program instead.\r\n"
  99         .ascii  "\n"
 100         .ascii  "Remove disk and press any key to reboot . . .\r\n"
 101         .byte   0
 102
 103 #ifdef CONFIG_EFI_STUB
 104 pe_header:
 105         .ascii  "PE"
 106         .word   0
 107
 108 coff_header:
 109 #ifdef CONFIG_X86_32
 110         .word   0x14c                           # i386
 111 #else
 112         .word   0x8664                          # x86-64
 113 #endif
 114         .word   2                               # nr_sections
 115         .long   0                               # TimeDateStamp
 116         .long   0                               # PointerToSymbolTable
 117         .long   1                               # NumberOfSymbols
 118         .word   section_table - optional_header # SizeOfOptionalHeader
 119 #ifdef CONFIG_X86_32
 120         .word   0x306                           # Characteristics.
 121                                                 # IMAGE_FILE_32BIT_MACHINE |
 122                                                 # IMAGE_FILE_DEBUG_STRIPPED |
 123                                                 # IMAGE_FILE_EXECUTABLE_IMAGE |
 124                                                 # IMAGE_FILE_LINE_NUMS_STRIPPED
 125 #else
 126         .word   0x206                           # Characteristics
 127                                                 # IMAGE_FILE_DEBUG_STRIPPED |
 128                                                 # IMAGE_FILE_EXECUTABLE_IMAGE |
 129                                                 # IMAGE_FILE_LINE_NUMS_STRIPPED
 130 #endif
 131
 132 optional_header:
 133 #ifdef CONFIG_X86_32
 134         .word   0x10b                           # PE32 format
 135 #else
 136         .word   0x20b                           # PE32+ format
 137 #endif
 138         .byte   0x02                            # MajorLinkerVersion
 139         .byte   0x14                            # MinorLinkerVersion
 140
 141         # Filled in by build.c
 142         .long   0                               # SizeOfCode
 143
 144         .long   0                               # SizeOfInitializedData
 145         .long   0                               # SizeOfUninitializedData
 146
 147         # Filled in by build.c
 148         .long   0x0000                          # AddressOfEntryPoint
 149
 150         .long   0x0200                          # BaseOfCode
 151 #ifdef CONFIG_X86_32
 152         .long   0                               # data
 153 #endif
 154
 155 extra_header_fields:
 156 #ifdef CONFIG_X86_32
 157         .long   0                               # ImageBase
 158 #else
 159         .quad   0                               # ImageBase
 160 #endif
 161         .long   0x1000                          # SectionAlignment
 162         .long   0x200                           # FileAlignment
 163         .word   0                               # MajorOperatingSystemVersion
 164         .word   0                               # MinorOperatingSystemVersion
 165         .word   0                               # MajorImageVersion
 166         .word   0                               # MinorImageVersion
 167         .word   0                               # MajorSubsystemVersion
 168         .word   0                               # MinorSubsystemVersion
 169         .long   0                               # Win32VersionValue
 170
 171         #
 172         # The size of the bzImage is written in tools/build.c
 173         #
 174         .long   0                               # SizeOfImage
 175
 176         .long   0x200                           # SizeOfHeaders
 177         .long   0                               # CheckSum
 178         .word   0xa                             # Subsystem (EFI application)
 179         .word   0                               # DllCharacteristics
 180 #ifdef CONFIG_X86_32
 181         .long   0                               # SizeOfStackReserve
 182         .long   0                               # SizeOfStackCommit
 183         .long   0                               # SizeOfHeapReserve
 184         .long   0                               # SizeOfHeapCommit
 185 #else
 186         .quad   0                               # SizeOfStackReserve
 187         .quad   0                               # SizeOfStackCommit
 188         .quad   0                               # SizeOfHeapReserve
 189         .quad   0                               # SizeOfHeapCommit
 190 #endif
 191         .long   0                               # LoaderFlags
 192         .long   0x6                             # NumberOfRvaAndSizes
 193
 194         .quad   0                               # ExportTable
 195         .quad   0                               # ImportTable
 196         .quad   0                               # ResourceTable
 197         .quad   0                               # ExceptionTable
 198         .quad   0                               # CertificationTable
 199         .quad   0                               # BaseRelocationTable
 200
 201         # Section table
 202 section_table:
 203         .ascii  ".text"
 204         .byte   0
 205         .byte   0
 206         .byte   0
 207         .long   0
 208         .long   0x0                             # startup_{32,64}
 209         .long   0                               # Size of initialized data
 210                                                 # on disk
 211         .long   0x0                             # startup_{32,64}
 212         .long   0                               # PointerToRelocations
 213         .long   0                               # PointerToLineNumbers
 214         .word   0                               # NumberOfRelocations
 215         .word   0                               # NumberOfLineNumbers
 216         .long   0x60500020                      # Characteristics (section flags)
 217
 218         #
 219         # The EFI application loader requires a relocation section
 220         # because EFI applications must be relocatable. But since
 221         # we don't need the loader to fixup any relocs for us, we
 222         # just create an empty (zero-length) .reloc section header.
 223         #
 224         .ascii  ".reloc"
 225         .byte   0
 226         .byte   0
 227         .long   0
 228         .long   0
 229         .long   0                               # SizeOfRawData
 230         .long   0                               # PointerToRawData
 231         .long   0                               # PointerToRelocations
 232         .long   0                               # PointerToLineNumbers
 233         .word   0                               # NumberOfRelocations
 234         .word   0                               # NumberOfLineNumbers
 235         .long   0x42100040                      # Characteristics (section flags)
 236 #endif /* CONFIG_EFI_STUB */
 237
 238         # Kernel attributes; used by setup.  This is part 1 of the
 239         # header, from the old boot sector.
 240
 241         .section ".header", "a"
 242         .globl  hdr
 243 hdr:
 244 setup_sects:    .byte 0                 /* Filled in by build.c */
 245 root_flags:     .word ROOT_RDONLY
 246 syssize:        .long 0                 /* Filled in by build.c */
 247 ram_size:       .word 0                 /* Obsolete */
 248 vid_mode:       .word SVGA_MODE
 249 root_dev:       .word 0                 /* Filled in by build.c */
 250 boot_flag:      .word 0xAA55
 251
 252         # offset 512, entry point
 253
 254         .globl  _start
 255 _start:
 256                 # Explicitly enter this as bytes, or the assembler
 257                 # tries to generate a 3-byte jump here, which causes
 258                 # everything else to push off to the wrong offset.
 259                 .byte   0xeb            # short (2-byte) jump
 260                 .byte   start_of_setup-1f
 261 1:
 262
 263         # Part 2 of the header, from the old setup.S
 264
 265                 .ascii  "HdrS"          # header signature
 266                 .word   0x020a          # header version number (>= 0x0105)
 267                                         # or else old loadlin-1.5 will fail)
 268                 .globl realmode_swtch
 269 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
 270 start_sys_seg:  .word   SYSSEG          # obsolete and meaningless, but just
 271                                         # in case something decided to "use" it
 272                 .word   kernel_version-512 # pointing to kernel version string
 273                                         # above section of header is compatible
 274                                         # with loadlin-1.5 (header v1.5). Don't
 275                                         # change it.
 276
 277 type_of_loader: .byte   0               # 0 means ancient bootloader, newer
 278                                         # bootloaders know to change this.
 279                                         # See Documentation/x86/boot.txt for
 280                                         # assigned ids
 281
 282 # flags, unused bits must be zero (RFU) bit within loadflags
 283 loadflags:
 284 LOADED_HIGH     = 1                     # If set, the kernel is loaded high
 285 CAN_USE_HEAP    = 0x80                  # If set, the loader also has set
 286                                         # heap_end_ptr to tell how much
 287                                         # space behind setup.S can be used for
 288                                         # heap purposes.
 289                                         # Only the loader knows what is free
 290                 .byte   LOADED_HIGH
 291
 292 setup_move_size: .word  0x8000          # size to move, when setup is not
 293                                         # loaded at 0x90000. We will move setup
 294                                         # to 0x90000 then just before jumping
 295                                         # into the kernel. However, only the
 296                                         # loader knows how much data behind
 297                                         # us also needs to be loaded.
 298
 299 code32_start:                           # here loaders can put a different
 300                                         # start address for 32-bit code.
 301                 .long   0x100000        # 0x100000 = default for big kernel
 302
 303 ramdisk_image:  .long   0               # address of loaded ramdisk image
 304                                         # Here the loader puts the 32-bit
 305                                         # address where it loaded the image.
 306                                         # This only will be read by the kernel.
 307
 308 ramdisk_size:   .long   0               # its size in bytes
 309
 310 bootsect_kludge:
 311                 .long   0               # obsolete
 312
 313 heap_end_ptr:   .word   _end+STACK_SIZE-512
 314                                         # (Header version 0x0201 or later)
 315                                         # space from here (exclusive) down to
 316                                         # end of setup code can be used by setup
 317                                         # for local heap purposes.
 318
 319 ext_loader_ver:
 320                 .byte   0               # Extended boot loader version
 321 ext_loader_type:
 322                 .byte   0               # Extended boot loader type
 323
 324 cmd_line_ptr:   .long   0               # (Header version 0x0202 or later)
 325                                         # If nonzero, a 32-bit pointer
 326                                         # to the kernel command line.
 327                                         # The command line should be
 328                                         # located between the start of
 329                                         # setup and the end of low
 330                                         # memory (0xa0000), or it may
 331                                         # get overwritten before it
 332                                         # gets read.  If this field is
 333                                         # used, there is no longer
 334                                         # anything magical about the
 335                                         # 0x90000 segment; the setup
 336                                         # can be located anywhere in
 337                                         # low memory 0x10000 or higher.
 338
 339 ramdisk_max:    .long 0x7fffffff
 340                                         # (Header version 0x0203 or later)
 341                                         # The highest safe address for
 342                                         # the contents of an initrd
 343                                         # The current kernel allows up to 4 GB,
 344                                         # but leave it at 2 GB to avoid
 345                                         # possible bootloader bugs.
 346
 347 kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN  #physical addr alignment
 348                                                 #required for protected mode
 349                                                 #kernel
 350 #ifdef CONFIG_RELOCATABLE
 351 relocatable_kernel:    .byte 1
 352 #else
 353 relocatable_kernel:    .byte 0
 354 #endif
 355 min_alignment:          .byte MIN_KERNEL_ALIGN_LG2      # minimum alignment
 356 pad3:                   .word 0
 357
 358 cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
 359                                                 #added with boot protocol
 360                                                 #version 2.06
 361
 362 hardware_subarch:       .long 0                 # subarchitecture, added with 2.07
 363                                                 # default to 0 for normal x86 PC
 364
 365 hardware_subarch_data:  .quad 0
 366
 367 payload_offset:         .long ZO_input_data
 368 payload_length:         .long ZO_z_input_len
 369
 370 setup_data:             .quad 0                 # 64-bit physical pointer to
 371                                                 # single linked list of
 372                                                 # struct setup_data
 373
 374 pref_address:           .quad LOAD_PHYSICAL_ADDR        # preferred load addr
 375
 376 #define ZO_INIT_SIZE    (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
 377 #define VO_INIT_SIZE    (VO__end - VO__text)
 378 #if ZO_INIT_SIZE > VO_INIT_SIZE
 379 #define INIT_SIZE ZO_INIT_SIZE
 380 #else
 381 #define INIT_SIZE VO_INIT_SIZE
 382 #endif
 383 init_size:              .long INIT_SIZE         # kernel initialization size
 384
 385 # End of setup header #####################################################
 386
 387         .section ".entrytext", "ax"
 388 start_of_setup:
 389 #ifdef SAFE_RESET_DISK_CONTROLLER
 390 # Reset the disk controller.
 391         movw    $0x0000, %ax            # Reset disk controller
 392         movb    $0x80, %dl              # All disks
 393         int     $0x13
 394 #endif
 395
 396 # Force %es = %ds
 397         movw    %ds, %ax
 398         movw    %ax, %es
 399         cld
 400
 401 # Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
 402 # which happened to work by accident for the old code.  Recalculate the stack
 403 # pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
 404 # stack behind its own code, so we can't blindly put it directly past the heap.
 405
 406         movw    %ss, %dx
 407         cmpw    %ax, %dx        # %ds == %ss?
 408         movw    %sp, %dx
 409         je      2f              # -> assume %sp is reasonably set
 410
 411         # Invalid %ss, make up a new stack
 412         movw    $_end, %dx
 413         testb   $CAN_USE_HEAP, loadflags
 414         jz      1f
 415         movw    heap_end_ptr, %dx
 416 1:      addw    $STACK_SIZE, %dx
 417         jnc     2f
 418         xorw    %dx, %dx        # Prevent wraparound
 419
 420 2:      # Now %dx should point to the end of our stack space
 421         andw    $~3, %dx        # dword align (might as well...)
 422         jnz     3f
 423         movw    $0xfffc, %dx    # Make sure we're not zero
 424 3:      movw    %ax, %ss
 425         movzwl  %dx, %esp       # Clear upper half of %esp
 426         sti                     # Now we should have a working stack
 427
 428 # We will have entered with %cs = %ds+0x20, normalize %cs so
 429 # it is on par with the other segments.
 430         pushw   %ds
 431         pushw   $6f
 432         lretw
 433 6:
 434
 435 # Check signature at end of setup
 436         cmpl    $0x5a5aaa55, setup_sig
 437         jne     setup_bad
 438
 439 # Zero the bss
 440         movw    $__bss_start, %di
 441         movw    $_end+3, %cx
 442         xorl    %eax, %eax
 443         subw    %di, %cx
 444         shrw    $2, %cx
 445         rep; stosl
 446
 447 # Jump to C code (should not return)
 448         calll   main
 449
 450 # Setup corrupt somehow...
 451 setup_bad:
 452         movl    $setup_corrupt, %eax
 453         calll   puts
 454         # Fall through...
 455
 456         .globl  die
 457         .type   die, @function
 458 die:
 459         hlt
 460         jmp     die
 461
 462         .size   die, .-die
 463
 464         .section ".initdata", "a"
 465 setup_corrupt:
 466         .byte   7
 467         .string "No setup signature found...\n"
 468
 469         .data
 470 dummy:  .long   0