arch/s390/kernel/relocate_kernel.S

   1 /*
   2  * arch/s390/kernel/relocate_kernel.S
   3  *
   4  * (C) Copyright IBM Corp. 2005
   5  *
   6  * Author(s): Rolf Adelsberger,
   7  *            Heiko Carstens <heiko.carstens@de.ibm.com>
   8  *
   9  */
  10
  11 #include <linux/linkage.h>
  12 #include <asm/sigp.h>
  13
  14 /*
  15  * moves the new kernel to its destination...
  16  * %r2 = pointer to first kimage_entry_t
  17  * %r3 = start address - where to jump to after the job is done...
  18  *
  19  * %r5 will be used as temp. storage
  20  * %r6 holds the destination address
  21  * %r7 = PAGE_SIZE
  22  * %r8 holds the source address
  23  * %r9 = PAGE_SIZE
  24  * %r10 is a page mask
  25  */
  26
  27         .text
  28 ENTRY(relocate_kernel)
  29                 basr    %r13,0          # base address
  30         .base:
  31                 stnsm   sys_msk-.base(%r13),0xfb        # disable DAT
  32                 stctl   %c0,%c15,ctlregs-.base(%r13)
  33                 stm     %r0,%r15,gprregs-.base(%r13)
  34                 la      %r1,load_psw-.base(%r13)
  35                 mvc     0(8,%r0),0(%r1)
  36                 la      %r0,.back-.base(%r13)
  37                 st      %r0,4(%r0)
  38                 oi      4(%r0),0x80
  39                 mvc     0x68(8,%r0),0(%r1)
  40                 la      %r0,.back_pgm-.base(%r13)
  41                 st      %r0,0x6c(%r0)
  42                 oi      0x6c(%r0),0x80
  43                 lhi     %r0,0
  44                 diag    %r0,%r0,0x308
  45         .back:
  46                 basr    %r13,0
  47         .back_base:
  48                 oi      have_diag308-.back_base(%r13),0x01
  49                 lctl    %c0,%c15,ctlregs-.back_base(%r13)
  50                 lm      %r0,%r15,gprregs-.back_base(%r13)
  51                 j       .start_reloc
  52         .back_pgm:
  53                 lm      %r0,%r15,gprregs-.base(%r13)
  54         .start_reloc:
  55                 lhi     %r10,-1         # preparing the mask
  56                 sll     %r10,12         # shift it such that it becomes 0xf000
  57         .top:
  58                 lhi     %r7,4096        # load PAGE_SIZE in r7
  59                 lhi     %r9,4096        # load PAGE_SIZE in r9
  60                 l       %r5,0(%r2)      # read another word for indirection page
  61                 ahi     %r2,4           # increment pointer
  62                 tml     %r5,0x1         # is it a destination page?
  63                 je      .indir_check    # NO, goto "indir_check"
  64                 lr      %r6,%r5         # r6 = r5
  65                 nr      %r6,%r10        # mask it out and...
  66                 j       .top            # ...next iteration
  67         .indir_check:
  68                 tml     %r5,0x2         # is it a indirection page?
  69                 je      .done_test      # NO, goto "done_test"
  70                 nr      %r5,%r10        # YES, mask out,
  71                 lr      %r2,%r5         # move it into the right register,
  72                 j       .top            # and read next...
  73         .done_test:
  74                 tml     %r5,0x4         # is it the done indicator?
  75                 je      .source_test    # NO! Well, then it should be the source indicator...
  76                 j       .done           # ok, lets finish it here...
  77         .source_test:
  78                 tml     %r5,0x8         # it should be a source indicator...
  79                 je      .top            # NO, ignore it...
  80                 lr      %r8,%r5         # r8 = r5
  81                 nr      %r8,%r10        # masking
  82         0:      mvcle   %r6,%r8,0x0     # copy PAGE_SIZE bytes from r8 to r6 - pad with 0
  83                 jo      0b
  84                 j       .top
  85         .done:
  86                 sr      %r0,%r0         # clear register r0
  87                 la      %r4,load_psw-.base(%r13)        # load psw-address into the register
  88                 o       %r3,4(%r4)      # or load address into psw
  89                 st      %r3,4(%r4)
  90                 mvc     0(8,%r0),0(%r4) # copy psw to absolute address 0
  91                 tm      have_diag308-.base(%r13),0x01
  92                 jno     .no_diag308
  93                 diag    %r0,%r0,0x308
  94         .no_diag308:
  95                 sr      %r1,%r1         # clear %r1
  96                 sr      %r2,%r2         # clear %r2
  97                 sigp    %r1,%r2,SIGP_SET_ARCHITECTURE # set cpuid to zero
  98                 lpsw    0               # hopefully start new kernel...
  99
 100                 .align  8
 101         load_psw:
 102                 .long   0x00080000,0x80000000
 103         sys_msk:
 104                 .quad   0
 105         ctlregs:
 106                 .rept   16
 107                 .long   0
 108                 .endr
 109         gprregs:
 110                 .rept   16
 111                 .long   0
 112                 .endr
 113         have_diag308:
 114                 .byte   0
 115                 .align  8
 116         relocate_kernel_end:
 117         .align 8
 118         .globl  relocate_kernel_len
 119         relocate_kernel_len:
 120                 .quad   relocate_kernel_end - relocate_kernel