arch/s390/kernel/entry.S

   1 /*
   2  *  arch/s390/kernel/entry.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2012
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/init.h>
  13 #include <linux/linkage.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21 #include <asm/sigp.h>
  22
  23 __PT_R0      =  __PT_GPRS
  24 __PT_R1      =  __PT_GPRS + 4
  25 __PT_R2      =  __PT_GPRS + 8
  26 __PT_R3      =  __PT_GPRS + 12
  27 __PT_R4      =  __PT_GPRS + 16
  28 __PT_R5      =  __PT_GPRS + 20
  29 __PT_R6      =  __PT_GPRS + 24
  30 __PT_R7      =  __PT_GPRS + 28
  31 __PT_R8      =  __PT_GPRS + 32
  32 __PT_R9      =  __PT_GPRS + 36
  33 __PT_R10     =  __PT_GPRS + 40
  34 __PT_R11     =  __PT_GPRS + 44
  35 __PT_R12     =  __PT_GPRS + 48
  36 __PT_R13     =  __PT_GPRS + 524
  37 __PT_R14     =  __PT_GPRS + 56
  38 __PT_R15     =  __PT_GPRS + 60
  39
  40 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  41                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
  42 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  43                  _TIF_MCCK_PENDING)
  44 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  45                  _TIF_SYSCALL_TRACEPOINT)
  46
  47 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  48 STACK_SIZE  = 1 << STACK_SHIFT
  49
  50 #define BASED(name) name-system_call(%r13)
  51
  52         .macro  TRACE_IRQS_ON
  53 #ifdef CONFIG_TRACE_IRQFLAGS
  54         basr    %r2,%r0
  55         l       %r1,BASED(.Lhardirqs_on)
  56         basr    %r14,%r1                # call trace_hardirqs_on_caller
  57 #endif
  58         .endm
  59
  60         .macro  TRACE_IRQS_OFF
  61 #ifdef CONFIG_TRACE_IRQFLAGS
  62         basr    %r2,%r0
  63         l       %r1,BASED(.Lhardirqs_off)
  64         basr    %r14,%r1                # call trace_hardirqs_off_caller
  65 #endif
  66         .endm
  67
  68         .macro  LOCKDEP_SYS_EXIT
  69 #ifdef CONFIG_LOCKDEP
  70         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  71         jz      .+10
  72         l       %r1,BASED(.Llockdep_sys_exit)
  73         basr    %r14,%r1                # call lockdep_sys_exit
  74 #endif
  75         .endm
  76
  77         .macro  CHECK_STACK stacksize,savearea
  78 #ifdef CONFIG_CHECK_STACK
  79         tml     %r15,\stacksize - CONFIG_STACK_GUARD
  80         la      %r14,\savearea
  81         jz      stack_overflow
  82 #endif
  83         .endm
  84
  85         .macro  SWITCH_ASYNC savearea,stack,shift
  86         tmh     %r8,0x0001              # interrupting from user ?
  87         jnz     1f
  88         lr      %r14,%r9
  89         sl      %r14,BASED(.Lcritical_start)
  90         cl      %r14,BASED(.Lcritical_length)
  91         jhe     0f
  92         la      %r11,\savearea          # inside critical section, do cleanup
  93         bras    %r14,cleanup_critical
  94         tmh     %r8,0x0001              # retest problem state after cleanup
  95         jnz     1f
  96 0:      l       %r14,\stack             # are we already on the target stack?
  97         slr     %r14,%r15
  98         sra     %r14,\shift
  99         jnz     1f
 100         CHECK_STACK 1<<\shift,\savearea
 101         j       2f
 102 1:      l       %r15,\stack             # load target stack
 103 2:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 104         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 105         .endm
 106
 107         .macro  ADD64 high,low,timer
 108         al      \high,\timer
 109         al      \low,4+\timer
 110         brc     12,.+8
 111         ahi     \high,1
 112         .endm
 113
 114         .macro  SUB64 high,low,timer
 115         sl      \high,\timer
 116         sl      \low,4+\timer
 117         brc     3,.+8
 118         ahi     \high,-1
 119         .endm
 120
 121         .macro  UPDATE_VTIME high,low,enter_timer
 122         lm      \high,\low,__LC_EXIT_TIMER
 123         SUB64   \high,\low,\enter_timer
 124         ADD64   \high,\low,__LC_USER_TIMER
 125         stm     \high,\low,__LC_USER_TIMER
 126         lm      \high,\low,__LC_LAST_UPDATE_TIMER
 127         SUB64   \high,\low,__LC_EXIT_TIMER
 128         ADD64   \high,\low,__LC_SYSTEM_TIMER
 129         stm     \high,\low,__LC_SYSTEM_TIMER
 130         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 131         .endm
 132
 133         .macro REENABLE_IRQS
 134         st      %r8,__LC_RETURN_PSW
 135         ni      __LC_RETURN_PSW,0xbf
 136         ssm     __LC_RETURN_PSW
 137         .endm
 138
 139         .section .kprobes.text, "ax"
 140
 141 /*
 142  * Scheduler resume function, called by switch_to
 143  *  gpr2 = (task_struct *) prev
 144  *  gpr3 = (task_struct *) next
 145  * Returns:
 146  *  gpr2 = prev
 147  */
 148 ENTRY(__switch_to)
 149         stm     %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 150         st      %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 151         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
 152         l       %r5,__THREAD_info(%r3)          # get thread_info of next
 153         lr      %r15,%r5
 154         ahi     %r15,STACK_SIZE                 # end of kernel stack of next
 155         st      %r3,__LC_CURRENT                # store task struct of next
 156         st      %r5,__LC_THREAD_INFO            # store thread info of next
 157         st      %r15,__LC_KERNEL_STACK          # store end of kernel stack
 158         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 159         mvc     __LC_CURRENT_PID(4,%r0),__TASK_pid(%r3) # store pid of next
 160         l       %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 161         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
 162         jz      0f
 163         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 164         oi      __TI_flags+3(%r5),_TIF_MCCK_PENDING     # set it in next
 165 0:      lm      %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 166         br      %r14
 167
 168 __critical_start:
 169 /*
 170  * SVC interrupt handler routine. System calls are synchronous events and
 171  * are executed with interrupts enabled.
 172  */
 173
 174 ENTRY(system_call)
 175         stpt    __LC_SYNC_ENTER_TIMER
 176 sysc_stm:
 177         stm     %r8,%r15,__LC_SAVE_AREA_SYNC
 178         l       %r12,__LC_THREAD_INFO
 179         l       %r13,__LC_SVC_NEW_PSW+4
 180 sysc_per:
 181         l       %r15,__LC_KERNEL_STACK
 182         ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 183         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 184 sysc_vtime:
 185         UPDATE_VTIME %r8,%r9,__LC_SYNC_ENTER_TIMER
 186         stm     %r0,%r7,__PT_R0(%r11)
 187         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_SYNC
 188         mvc     __PT_PSW(8,%r11),__LC_SVC_OLD_PSW
 189         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 190 sysc_do_svc:
 191         oi      __TI_flags+3(%r12),_TIF_SYSCALL
 192         lh      %r8,__PT_INT_CODE+2(%r11)
 193         sla     %r8,2                           # shift and test for svc0
 194         jnz     sysc_nr_ok
 195         # svc 0: system call number in %r1
 196         cl      %r1,BASED(.Lnr_syscalls)
 197         jnl     sysc_nr_ok
 198         sth     %r1,__PT_INT_CODE+2(%r11)
 199         lr      %r8,%r1
 200         sla     %r8,2
 201 sysc_nr_ok:
 202         l       %r10,BASED(.Lsys_call_table)    # 31 bit system call table
 203         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 204         st      %r2,__PT_ORIG_GPR2(%r11)
 205         st      %r7,STACK_FRAME_OVERHEAD(%r15)
 206         l       %r9,0(%r8,%r10)                 # get system call addr.
 207         tm      __TI_flags+2(%r12),_TIF_TRACE >> 8
 208         jnz     sysc_tracesys
 209         basr    %r14,%r9                        # call sys_xxxx
 210         st      %r2,__PT_R2(%r11)               # store return value
 211
 212 sysc_return:
 213         LOCKDEP_SYS_EXIT
 214 sysc_tif:
 215         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
 216         jno     sysc_restore
 217         tm      __TI_flags+3(%r12),_TIF_WORK_SVC
 218         jnz     sysc_work                       # check for work
 219         ni      __TI_flags+3(%r12),255-_TIF_SYSCALL
 220 sysc_restore:
 221         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r11)
 222         stpt    __LC_EXIT_TIMER
 223         lm      %r0,%r15,__PT_R0(%r11)
 224         lpsw    __LC_RETURN_PSW
 225 sysc_done:
 226
 227 #
 228 # One of the work bits is on. Find out which one.
 229 #
 230 sysc_work:
 231         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 232         jo      sysc_mcck_pending
 233         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 234         jo      sysc_reschedule
 235         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
 236         jo      sysc_sigpending
 237         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
 238         jo      sysc_notify_resume
 239         tm      __TI_flags+3(%r12),_TIF_PER_TRAP
 240         jo      sysc_singlestep
 241         j       sysc_return             # beware of critical section cleanup
 242
 243 #
 244 # _TIF_NEED_RESCHED is set, call schedule
 245 #
 246 sysc_reschedule:
 247         l       %r1,BASED(.Lschedule)
 248         la      %r14,BASED(sysc_return)
 249         br      %r1                     # call schedule
 250
 251 #
 252 # _TIF_MCCK_PENDING is set, call handler
 253 #
 254 sysc_mcck_pending:
 255         l       %r1,BASED(.Lhandle_mcck)
 256         la      %r14,BASED(sysc_return)
 257         br      %r1                     # TIF bit will be cleared by handler
 258
 259 #
 260 # _TIF_SIGPENDING is set, call do_signal
 261 #
 262 sysc_sigpending:
 263         ni      __TI_flags+3(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
 264         lr      %r2,%r11                # pass pointer to pt_regs
 265         l       %r1,BASED(.Ldo_signal)
 266         basr    %r14,%r1                # call do_signal
 267         tm      __TI_flags+3(%r12),_TIF_SYSCALL
 268         jno     sysc_return
 269         lm      %r2,%r7,__PT_R2(%r11)   # load svc arguments
 270         xr      %r8,%r8                 # svc 0 returns -ENOSYS
 271         clc     __PT_INT_CODE+2(2,%r11),BASED(.Lnr_syscalls+2)
 272         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 273         lh      %r8,__PT_INT_CODE+2(%r11)       # load new svc number
 274         sla     %r8,2
 275         j       sysc_nr_ok              # restart svc
 276
 277 #
 278 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 279 #
 280 sysc_notify_resume:
 281         lr      %r2,%r11                # pass pointer to pt_regs
 282         l       %r1,BASED(.Ldo_notify_resume)
 283         la      %r14,BASED(sysc_return)
 284         br      %r1                     # call do_notify_resume
 285
 286 #
 287 # _TIF_PER_TRAP is set, call do_per_trap
 288 #
 289 sysc_singlestep:
 290         ni      __TI_flags+3(%r12),255-(_TIF_SYSCALL | _TIF_PER_TRAP)
 291         lr      %r2,%r11                # pass pointer to pt_regs
 292         l       %r1,BASED(.Ldo_per_trap)
 293         la      %r14,BASED(sysc_return)
 294         br      %r1                     # call do_per_trap
 295
 296 #
 297 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 298 # and after the system call
 299 #
 300 sysc_tracesys:
 301         l       %r1,BASED(.Ltrace_enter)
 302         lr      %r2,%r11                # pass pointer to pt_regs
 303         la      %r3,0
 304         xr      %r0,%r0
 305         icm     %r0,3,__PT_INT_CODE+2(%r11)
 306         st      %r0,__PT_R2(%r11)
 307         basr    %r14,%r1                # call do_syscall_trace_enter
 308         cl      %r2,BASED(.Lnr_syscalls)
 309         jnl     sysc_tracenogo
 310         lr      %r8,%r2
 311         sll     %r8,2
 312         l       %r9,0(%r8,%r10)
 313 sysc_tracego:
 314         lm      %r3,%r7,__PT_R3(%r11)
 315         st      %r7,STACK_FRAME_OVERHEAD(%r15)
 316         l       %r2,__PT_ORIG_GPR2(%r11)
 317         basr    %r14,%r9                # call sys_xxx
 318         st      %r2,__PT_R2(%r11)       # store return value
 319 sysc_tracenogo:
 320         tm      __TI_flags+2(%r12),_TIF_TRACE >> 8
 321         jz      sysc_return
 322         l       %r1,BASED(.Ltrace_exit)
 323         lr      %r2,%r11                # pass pointer to pt_regs
 324         la      %r14,BASED(sysc_return)
 325         br      %r1                     # call do_syscall_trace_exit
 326
 327 #
 328 # a new process exits the kernel with ret_from_fork
 329 #
 330 ENTRY(ret_from_fork)
 331         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 332         l       %r12,__LC_THREAD_INFO
 333         l       %r13,__LC_SVC_NEW_PSW+4
 334         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 335         jo      0f
 336         st      %r15,__PT_R15(%r11)     # store stack pointer for new kthread
 337 0:      l       %r1,BASED(.Lschedule_tail)
 338         basr    %r14,%r1                # call schedule_tail
 339         TRACE_IRQS_ON
 340         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 341         j       sysc_tracenogo
 342
 343 #
 344 # kernel_execve function needs to deal with pt_regs that is not
 345 # at the usual place
 346 #
 347 ENTRY(kernel_execve)
 348         stm     %r12,%r15,48(%r15)
 349         lr      %r14,%r15
 350         l       %r13,__LC_SVC_NEW_PSW+4
 351         ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 352         st      %r14,__SF_BACKCHAIN(%r15)
 353         la      %r12,STACK_FRAME_OVERHEAD(%r15)
 354         xc      0(__PT_SIZE,%r12),0(%r12)
 355         l       %r1,BASED(.Ldo_execve)
 356         lr      %r5,%r12
 357         basr    %r14,%r1                # call do_execve
 358         ltr     %r2,%r2
 359         je      0f
 360         ahi     %r15,(STACK_FRAME_OVERHEAD + __PT_SIZE)
 361         lm      %r12,%r15,48(%r15)
 362         br      %r14
 363         # execve succeeded.
 364 0:      ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 365         l       %r15,__LC_KERNEL_STACK  # load ksp
 366         ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 367         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 368         mvc     0(__PT_SIZE,%r11),0(%r12)       # copy pt_regs
 369         l       %r12,__LC_THREAD_INFO
 370         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 371         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 372         l       %r1,BASED(.Lexecve_tail)
 373         basr    %r14,%r1                # call execve_tail
 374         j       sysc_return
 375
 376 /*
 377  * Program check handler routine
 378  */
 379
 380 ENTRY(pgm_check_handler)
 381         stpt    __LC_SYNC_ENTER_TIMER
 382         stm     %r8,%r15,__LC_SAVE_AREA_SYNC
 383         l       %r12,__LC_THREAD_INFO
 384         l       %r13,__LC_SVC_NEW_PSW+4
 385         lm      %r8,%r9,__LC_PGM_OLD_PSW
 386         tmh     %r8,0x0001              # test problem state bit
 387         jnz     1f                      # -> fault in user space
 388         tmh     %r8,0x4000              # PER bit set in old PSW ?
 389         jnz     0f                      # -> enabled, can't be a double fault
 390         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 391         jnz     pgm_svcper              # -> single stepped svc
 392 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 393         j       2f
 394 1:      UPDATE_VTIME %r14,%r15,__LC_SYNC_ENTER_TIMER
 395         l       %r15,__LC_KERNEL_STACK
 396 2:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 397         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 398         stm     %r0,%r7,__PT_R0(%r11)
 399         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_SYNC
 400         stm     %r8,%r9,__PT_PSW(%r11)
 401         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 402         mvc     __PT_INT_PARM_LONG(4,%r11),__LC_TRANS_EXC_CODE
 403         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 404         jz      0f
 405         l       %r1,__TI_task(%r12)
 406         tmh     %r8,0x0001              # kernel per event ?
 407         jz      pgm_kprobe
 408         oi      __TI_flags+3(%r12),_TIF_PER_TRAP
 409         mvc     __THREAD_per_address(4,%r1),__LC_PER_ADDRESS
 410         mvc     __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
 411         mvc     __THREAD_per_paid(1,%r1),__LC_PER_PAID
 412 0:      REENABLE_IRQS
 413         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 414         l       %r1,BASED(.Ljump_table)
 415         la      %r10,0x7f
 416         n       %r10,__PT_INT_CODE(%r11)
 417         je      sysc_return
 418         sll     %r10,2
 419         l       %r1,0(%r10,%r1)         # load address of handler routine
 420         lr      %r2,%r11                # pass pointer to pt_regs
 421         basr    %r14,%r1                # branch to interrupt-handler
 422         j       sysc_return
 423
 424 #
 425 # PER event in supervisor state, must be kprobes
 426 #
 427 pgm_kprobe:
 428         REENABLE_IRQS
 429         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 430         l       %r1,BASED(.Ldo_per_trap)
 431         lr      %r2,%r11                # pass pointer to pt_regs
 432         basr    %r14,%r1                # call do_per_trap
 433         j       sysc_return
 434
 435 #
 436 # single stepped system call
 437 #
 438 pgm_svcper:
 439         oi      __TI_flags+3(%r12),_TIF_PER_TRAP
 440         mvc     __LC_RETURN_PSW(4),__LC_SVC_NEW_PSW
 441         mvc     __LC_RETURN_PSW+4(4),BASED(.Lsysc_per)
 442         lpsw    __LC_RETURN_PSW         # branch to sysc_per and enable irqs
 443
 444 /*
 445  * IO interrupt handler routine
 446  */
 447
 448 ENTRY(io_int_handler)
 449         stck    __LC_INT_CLOCK
 450         stpt    __LC_ASYNC_ENTER_TIMER
 451         stm     %r8,%r15,__LC_SAVE_AREA_ASYNC
 452         l       %r12,__LC_THREAD_INFO
 453         l       %r13,__LC_SVC_NEW_PSW+4
 454         lm      %r8,%r9,__LC_IO_OLD_PSW
 455         tmh     %r8,0x0001              # interrupting from user ?
 456         jz      io_skip
 457         UPDATE_VTIME %r14,%r15,__LC_ASYNC_ENTER_TIMER
 458 io_skip:
 459         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 460         stm     %r0,%r7,__PT_R0(%r11)
 461         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_ASYNC
 462         stm     %r8,%r9,__PT_PSW(%r11)
 463         TRACE_IRQS_OFF
 464         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 465         l       %r1,BASED(.Ldo_IRQ)
 466         lr      %r2,%r11                # pass pointer to pt_regs
 467         basr    %r14,%r1                # call do_IRQ
 468 io_return:
 469         LOCKDEP_SYS_EXIT
 470         TRACE_IRQS_ON
 471 io_tif:
 472         tm      __TI_flags+3(%r12),_TIF_WORK_INT
 473         jnz     io_work                 # there is work to do (signals etc.)
 474 io_restore:
 475         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r11)
 476         stpt    __LC_EXIT_TIMER
 477         lm      %r0,%r15,__PT_R0(%r11)
 478         lpsw    __LC_RETURN_PSW
 479 io_done:
 480
 481 #
 482 # There is work todo, find out in which context we have been interrupted:
 483 # 1) if we return to user space we can do all _TIF_WORK_INT work
 484 # 2) if we return to kernel code and preemptive scheduling is enabled check
 485 #    the preemption counter and if it is zero call preempt_schedule_irq
 486 # Before any work can be done, a switch to the kernel stack is required.
 487 #
 488 io_work:
 489         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 490         jo      io_work_user            # yes -> do resched & signal
 491 #ifdef CONFIG_PREEMPT
 492         # check for preemptive scheduling
 493         icm     %r0,15,__TI_precount(%r12)
 494         jnz     io_restore              # preemption disabled
 495         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 496         jno     io_restore
 497         # switch to kernel stack
 498         l       %r1,__PT_R15(%r11)
 499         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 500         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 501         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
 502         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 503         lr      %r15,%r1
 504         # TRACE_IRQS_ON already done at io_return, call
 505         # TRACE_IRQS_OFF to keep things symmetrical
 506         TRACE_IRQS_OFF
 507         l       %r1,BASED(.Lpreempt_irq)
 508         basr    %r14,%r1                # call preempt_schedule_irq
 509         j       io_return
 510 #else
 511         j       io_restore
 512 #endif
 513
 514 #
 515 # Need to do work before returning to userspace, switch to kernel stack
 516 #
 517 io_work_user:
 518         l       %r1,__LC_KERNEL_STACK
 519         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 520         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 521         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
 522         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 523         lr      %r15,%r1
 524
 525 #
 526 # One of the work bits is on. Find out which one.
 527 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 528 #               and _TIF_MCCK_PENDING
 529 #
 530 io_work_tif:
 531         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 532         jo      io_mcck_pending
 533         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 534         jo      io_reschedule
 535         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
 536         jo      io_sigpending
 537         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
 538         jo      io_notify_resume
 539         j       io_return               # beware of critical section cleanup
 540
 541 #
 542 # _TIF_MCCK_PENDING is set, call handler
 543 #
 544 io_mcck_pending:
 545         # TRACE_IRQS_ON already done at io_return
 546         l       %r1,BASED(.Lhandle_mcck)
 547         basr    %r14,%r1                # TIF bit will be cleared by handler
 548         TRACE_IRQS_OFF
 549         j       io_return
 550
 551 #
 552 # _TIF_NEED_RESCHED is set, call schedule
 553 #
 554 io_reschedule:
 555         # TRACE_IRQS_ON already done at io_return
 556         l       %r1,BASED(.Lschedule)
 557         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 558         basr    %r14,%r1                # call scheduler
 559         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 560         TRACE_IRQS_OFF
 561         j       io_return
 562
 563 #
 564 # _TIF_SIGPENDING is set, call do_signal
 565 #
 566 io_sigpending:
 567         # TRACE_IRQS_ON already done at io_return
 568         l       %r1,BASED(.Ldo_signal)
 569         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 570         lr      %r2,%r11                # pass pointer to pt_regs
 571         basr    %r14,%r1                # call do_signal
 572         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 573         TRACE_IRQS_OFF
 574         j       io_return
 575
 576 #
 577 # _TIF_SIGPENDING is set, call do_signal
 578 #
 579 io_notify_resume:
 580         # TRACE_IRQS_ON already done at io_return
 581         l       %r1,BASED(.Ldo_notify_resume)
 582         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 583         lr      %r2,%r11                # pass pointer to pt_regs
 584         basr    %r14,%r1                # call do_notify_resume
 585         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 586         TRACE_IRQS_OFF
 587         j       io_return
 588
 589 /*
 590  * External interrupt handler routine
 591  */
 592
 593 ENTRY(ext_int_handler)
 594         stck    __LC_INT_CLOCK
 595         stpt    __LC_ASYNC_ENTER_TIMER
 596         stm     %r8,%r15,__LC_SAVE_AREA_ASYNC
 597         l       %r12,__LC_THREAD_INFO
 598         l       %r13,__LC_SVC_NEW_PSW+4
 599         lm      %r8,%r9,__LC_EXT_OLD_PSW
 600         tmh     %r8,0x0001              # interrupting from user ?
 601         jz      ext_skip
 602         UPDATE_VTIME %r14,%r15,__LC_ASYNC_ENTER_TIMER
 603 ext_skip:
 604         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 605         stm     %r0,%r7,__PT_R0(%r11)
 606         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_ASYNC
 607         stm     %r8,%r9,__PT_PSW(%r11)
 608         TRACE_IRQS_OFF
 609         lr      %r2,%r11                # pass pointer to pt_regs
 610         l       %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
 611         l       %r4,__LC_EXT_PARAMS     # get external parameters
 612         l       %r1,BASED(.Ldo_extint)
 613         basr    %r14,%r1                # call do_extint
 614         j       io_return
 615
 616 /*
 617  * Load idle PSW. The second "half" of this function is in cleanup_idle.
 618  */
 619 ENTRY(psw_idle)
 620         st      %r4,__SF_EMPTY(%r15)
 621         basr    %r1,0
 622         la      %r1,psw_idle_lpsw+4-.(%r1)
 623         st      %r1,__SF_EMPTY+4(%r15)
 624         oi      __SF_EMPTY+4(%r15),0x80
 625         la      %r1,.Lvtimer_max-psw_idle_lpsw-4(%r1)
 626         stck    __IDLE_ENTER(%r2)
 627         ltr     %r5,%r5
 628         stpt    __VQ_IDLE_ENTER(%r3)
 629         jz      psw_idle_lpsw
 630         spt     0(%r1)
 631 psw_idle_lpsw:
 632         lpsw    __SF_EMPTY(%r15)
 633         br      %r14
 634 psw_idle_end:
 635
 636 __critical_end:
 637
 638 /*
 639  * Machine check handler routines
 640  */
 641
 642 ENTRY(mcck_int_handler)
 643         stck    __LC_MCCK_CLOCK
 644         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
 645         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
 646         l       %r12,__LC_THREAD_INFO
 647         l       %r13,__LC_SVC_NEW_PSW+4
 648         lm      %r8,%r9,__LC_MCK_OLD_PSW
 649         tm      __LC_MCCK_CODE,0x80     # system damage?
 650         jo      mcck_panic              # yes -> rest of mcck code invalid
 651         la      %r14,__LC_CPU_TIMER_SAVE_AREA
 652         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 653         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 654         jo      3f
 655         la      %r14,__LC_SYNC_ENTER_TIMER
 656         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 657         jl      0f
 658         la      %r14,__LC_ASYNC_ENTER_TIMER
 659 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 660         jl      1f
 661         la      %r14,__LC_EXIT_TIMER
 662 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 663         jl      2f
 664         la      %r14,__LC_LAST_UPDATE_TIMER
 665 2:      spt     0(%r14)
 666         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 667 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 668         jno     mcck_panic              # no -> skip cleanup critical
 669         tm      %r8,0x0001              # interrupting from user ?
 670         jz      mcck_skip
 671         UPDATE_VTIME %r14,%r15,__LC_MCCK_ENTER_TIMER
 672 mcck_skip:
 673         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+32,__LC_PANIC_STACK,PAGE_SHIFT
 674         mvc     __PT_R0(64,%r11),__LC_GPREGS_SAVE_AREA
 675         stm     %r8,%r9,__PT_PSW(%r11)
 676         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 677         l       %r1,BASED(.Ldo_machine_check)
 678         lr      %r2,%r11                # pass pointer to pt_regs
 679         basr    %r14,%r1                # call s390_do_machine_check
 680         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 681         jno     mcck_return
 682         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
 683         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 684         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 685         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
 686         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 687         lr      %r15,%r1
 688         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
 689         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 690         jno     mcck_return
 691         TRACE_IRQS_OFF
 692         l       %r1,BASED(.Lhandle_mcck)
 693         basr    %r14,%r1                # call s390_handle_mcck
 694         TRACE_IRQS_ON
 695 mcck_return:
 696         mvc     __LC_RETURN_MCCK_PSW(8),__PT_PSW(%r11) # move return PSW
 697         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 698         jno     0f
 699         lm      %r0,%r15,__PT_R0(%r11)
 700         stpt    __LC_EXIT_TIMER
 701         lpsw    __LC_RETURN_MCCK_PSW
 702 0:      lm      %r0,%r15,__PT_R0(%r11)
 703         lpsw    __LC_RETURN_MCCK_PSW
 704
 705 mcck_panic:
 706         l       %r14,__LC_PANIC_STACK
 707         slr     %r14,%r15
 708         sra     %r14,PAGE_SHIFT
 709         jz      0f
 710         l       %r15,__LC_PANIC_STACK
 711 0:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 712         j       mcck_skip
 713
 714 #
 715 # PSW restart interrupt handler
 716 #
 717 ENTRY(restart_int_handler)
 718         st      %r15,__LC_SAVE_AREA_RESTART
 719         l       %r15,__LC_RESTART_STACK
 720         ahi     %r15,-__PT_SIZE                 # create pt_regs on stack
 721         xc      0(__PT_SIZE,%r15),0(%r15)
 722         stm     %r0,%r14,__PT_R0(%r15)
 723         mvc     __PT_R15(4,%r15),__LC_SAVE_AREA_RESTART
 724         mvc     __PT_PSW(8,%r15),__LC_RST_OLD_PSW # store restart old psw
 725         ahi     %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
 726         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
 727         l       %r1,__LC_RESTART_FN             # load fn, parm & source cpu
 728         l       %r2,__LC_RESTART_DATA
 729         l       %r3,__LC_RESTART_SOURCE
 730         ltr     %r3,%r3                         # test source cpu address
 731         jm      1f                              # negative -> skip source stop
 732 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
 733         brc     10,0b                           # wait for status stored
 734 1:      basr    %r14,%r1                        # call function
 735         stap    __SF_EMPTY(%r15)                # store cpu address
 736         lh      %r3,__SF_EMPTY(%r15)
 737 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
 738         brc     2,2b
 739 3:      j       3b
 740
 741         .section .kprobes.text, "ax"
 742
 743 #ifdef CONFIG_CHECK_STACK
 744 /*
 745  * The synchronous or the asynchronous stack overflowed. We are dead.
 746  * No need to properly save the registers, we are going to panic anyway.
 747  * Setup a pt_regs so that show_trace can provide a good call trace.
 748  */
 749 stack_overflow:
 750         l       %r15,__LC_PANIC_STACK   # change to panic stack
 751         ahi     %r15,-__PT_SIZE         # create pt_regs
 752         stm     %r0,%r7,__PT_R0(%r15)
 753         stm     %r8,%r9,__PT_PSW(%r15)
 754         mvc     __PT_R8(32,%r11),0(%r14)
 755         lr      %r15,%r11
 756         ahi     %r15,-STACK_FRAME_OVERHEAD
 757         l       %r1,BASED(1f)
 758         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 759         lr      %r2,%r11                # pass pointer to pt_regs
 760         br      %r1                     # branch to kernel_stack_overflow
 761 1:      .long   kernel_stack_overflow
 762 #endif
 763
 764 cleanup_table:
 765         .long   system_call + 0x80000000
 766         .long   sysc_do_svc + 0x80000000
 767         .long   sysc_tif + 0x80000000
 768         .long   sysc_restore + 0x80000000
 769         .long   sysc_done + 0x80000000
 770         .long   io_tif + 0x80000000
 771         .long   io_restore + 0x80000000
 772         .long   io_done + 0x80000000
 773         .long   psw_idle + 0x80000000
 774         .long   psw_idle_end + 0x80000000
 775
 776 cleanup_critical:
 777         cl      %r9,BASED(cleanup_table)        # system_call
 778         jl      0f
 779         cl      %r9,BASED(cleanup_table+4)      # sysc_do_svc
 780         jl      cleanup_system_call
 781         cl      %r9,BASED(cleanup_table+8)      # sysc_tif
 782         jl      0f
 783         cl      %r9,BASED(cleanup_table+12)     # sysc_restore
 784         jl      cleanup_sysc_tif
 785         cl      %r9,BASED(cleanup_table+16)     # sysc_done
 786         jl      cleanup_sysc_restore
 787         cl      %r9,BASED(cleanup_table+20)     # io_tif
 788         jl      0f
 789         cl      %r9,BASED(cleanup_table+24)     # io_restore
 790         jl      cleanup_io_tif
 791         cl      %r9,BASED(cleanup_table+28)     # io_done
 792         jl      cleanup_io_restore
 793         cl      %r9,BASED(cleanup_table+32)     # psw_idle
 794         jl      0f
 795         cl      %r9,BASED(cleanup_table+36)     # psw_idle_end
 796         jl      cleanup_idle
 797 0:      br      %r14
 798
 799 cleanup_system_call:
 800         # check if stpt has been executed
 801         cl      %r9,BASED(cleanup_system_call_insn)
 802         jh      0f
 803         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 804         chi     %r11,__LC_SAVE_AREA_ASYNC
 805         je      0f
 806         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 807 0:      # check if stm has been executed
 808         cl      %r9,BASED(cleanup_system_call_insn+4)
 809         jh      0f
 810         mvc     __LC_SAVE_AREA_SYNC(32),0(%r11)
 811 0:      # set up saved registers r12, and r13
 812         st      %r12,16(%r11)           # r12 thread-info pointer
 813         st      %r13,20(%r11)           # r13 literal-pool pointer
 814         # check if the user time calculation has been done
 815         cl      %r9,BASED(cleanup_system_call_insn+8)
 816         jh      0f
 817         l       %r10,__LC_EXIT_TIMER
 818         l       %r15,__LC_EXIT_TIMER+4
 819         SUB64   %r10,%r15,__LC_SYNC_ENTER_TIMER
 820         ADD64   %r10,%r15,__LC_USER_TIMER
 821         st      %r10,__LC_USER_TIMER
 822         st      %r15,__LC_USER_TIMER+4
 823 0:      # check if the system time calculation has been done
 824         cl      %r9,BASED(cleanup_system_call_insn+12)
 825         jh      0f
 826         l       %r10,__LC_LAST_UPDATE_TIMER
 827         l       %r15,__LC_LAST_UPDATE_TIMER+4
 828         SUB64   %r10,%r15,__LC_EXIT_TIMER
 829         ADD64   %r10,%r15,__LC_SYSTEM_TIMER
 830         st      %r10,__LC_SYSTEM_TIMER
 831         st      %r15,__LC_SYSTEM_TIMER+4
 832 0:      # update accounting time stamp
 833         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 834         # set up saved register 11
 835         l       %r15,__LC_KERNEL_STACK
 836         ahi     %r15,-__PT_SIZE
 837         st      %r15,12(%r11)           # r11 pt_regs pointer
 838         # fill pt_regs
 839         mvc     __PT_R8(32,%r15),__LC_SAVE_AREA_SYNC
 840         stm     %r0,%r7,__PT_R0(%r15)
 841         mvc     __PT_PSW(8,%r15),__LC_SVC_OLD_PSW
 842         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
 843         # setup saved register 15
 844         ahi     %r15,-STACK_FRAME_OVERHEAD
 845         st      %r15,28(%r11)           # r15 stack pointer
 846         # set new psw address and exit
 847         l       %r9,BASED(cleanup_table+4)      # sysc_do_svc + 0x80000000
 848         br      %r14
 849 cleanup_system_call_insn:
 850         .long   system_call + 0x80000000
 851         .long   sysc_stm + 0x80000000
 852         .long   sysc_vtime + 0x80000000 + 36
 853         .long   sysc_vtime + 0x80000000 + 76
 854
 855 cleanup_sysc_tif:
 856         l       %r9,BASED(cleanup_table+8)      # sysc_tif + 0x80000000
 857         br      %r14
 858
 859 cleanup_sysc_restore:
 860         cl      %r9,BASED(cleanup_sysc_restore_insn)
 861         jhe     0f
 862         l       %r9,12(%r11)            # get saved pointer to pt_regs
 863         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r9)
 864         mvc     0(32,%r11),__PT_R8(%r9)
 865         lm      %r0,%r7,__PT_R0(%r9)
 866 0:      lm      %r8,%r9,__LC_RETURN_PSW
 867         br      %r14
 868 cleanup_sysc_restore_insn:
 869         .long   sysc_done - 4 + 0x80000000
 870
 871 cleanup_io_tif:
 872         l       %r9,BASED(cleanup_table+20)     # io_tif + 0x80000000
 873         br      %r14
 874
 875 cleanup_io_restore:
 876         cl      %r9,BASED(cleanup_io_restore_insn)
 877         jhe     0f
 878         l       %r9,12(%r11)            # get saved r11 pointer to pt_regs
 879         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r9)
 880         mvc     0(32,%r11),__PT_R8(%r9)
 881         lm      %r0,%r7,__PT_R0(%r9)
 882 0:      lm      %r8,%r9,__LC_RETURN_PSW
 883         br      %r14
 884 cleanup_io_restore_insn:
 885         .long   io_done - 4 + 0x80000000
 886
 887 cleanup_idle:
 888         # copy interrupt clock & cpu timer
 889         mvc     __IDLE_EXIT(8,%r2),__LC_INT_CLOCK
 890         mvc     __VQ_IDLE_EXIT(8,%r3),__LC_ASYNC_ENTER_TIMER
 891         chi     %r11,__LC_SAVE_AREA_ASYNC
 892         je      0f
 893         mvc     __IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
 894         mvc     __VQ_IDLE_EXIT(8,%r3),__LC_MCCK_ENTER_TIMER
 895 0:      # check if stck has been executed
 896         cl      %r9,BASED(cleanup_idle_insn)
 897         jhe     1f
 898         mvc     __IDLE_ENTER(8,%r2),__IDLE_EXIT(%r2)
 899         mvc     __VQ_IDLE_ENTER(8,%r3),__VQ_IDLE_EXIT(%r3)
 900         j       2f
 901 1:      # check if the cpu timer has been reprogrammed
 902         ltr     %r5,%r5
 903         jz      2f
 904         spt     __VQ_IDLE_ENTER(%r3)
 905 2:      # account system time going idle
 906         lm      %r9,%r10,__LC_STEAL_TIMER
 907         ADD64   %r9,%r10,__IDLE_ENTER(%r2)
 908         SUB64   %r9,%r10,__LC_LAST_UPDATE_CLOCK
 909         stm     %r9,%r10,__LC_STEAL_TIMER
 910         mvc     __LC_LAST_UPDATE_CLOCK(8),__IDLE_EXIT(%r2)
 911         lm      %r9,%r10,__LC_SYSTEM_TIMER
 912         ADD64   %r9,%r10,__LC_LAST_UPDATE_TIMER
 913         SUB64   %r9,%r10,__VQ_IDLE_ENTER(%r3)
 914         stm     %r9,%r10,__LC_SYSTEM_TIMER
 915         mvc     __LC_LAST_UPDATE_TIMER(8),__VQ_IDLE_EXIT(%r3)
 916         # prepare return psw
 917         n       %r8,BASED(cleanup_idle_wait)    # clear wait state bit
 918         l       %r9,24(%r11)                    # return from psw_idle
 919         br      %r14
 920 cleanup_idle_insn:
 921         .long   psw_idle_lpsw + 0x80000000
 922 cleanup_idle_wait:
 923         .long   0xfffdffff
 924
 925 /*
 926  * Integer constants
 927  */
 928         .align  4
 929 .Lnr_syscalls:
 930         .long   NR_syscalls
 931 .Lvtimer_max:
 932         .quad   0x7fffffffffffffff
 933
 934 /*
 935  * Symbol constants
 936  */
 937 .Ldo_machine_check:     .long   s390_do_machine_check
 938 .Lhandle_mcck:          .long   s390_handle_mcck
 939 .Ldo_IRQ:               .long   do_IRQ
 940 .Ldo_extint:            .long   do_extint
 941 .Ldo_signal:            .long   do_signal
 942 .Ldo_notify_resume:     .long   do_notify_resume
 943 .Ldo_per_trap:          .long   do_per_trap
 944 .Ldo_execve:            .long   do_execve
 945 .Lexecve_tail:          .long   execve_tail
 946 .Ljump_table:           .long   pgm_check_table
 947 .Lschedule:             .long   schedule
 948 #ifdef CONFIG_PREEMPT
 949 .Lpreempt_irq:          .long   preempt_schedule_irq
 950 #endif
 951 .Ltrace_enter:          .long   do_syscall_trace_enter
 952 .Ltrace_exit:           .long   do_syscall_trace_exit
 953 .Lschedule_tail:        .long   schedule_tail
 954 .Lsys_call_table:       .long   sys_call_table
 955 .Lsysc_per:             .long   sysc_per + 0x80000000
 956 #ifdef CONFIG_TRACE_IRQFLAGS
 957 .Lhardirqs_on:          .long   trace_hardirqs_on_caller
 958 .Lhardirqs_off:         .long   trace_hardirqs_off_caller
 959 #endif
 960 #ifdef CONFIG_LOCKDEP
 961 .Llockdep_sys_exit:     .long   lockdep_sys_exit
 962 #endif
 963 .Lcritical_start:       .long   __critical_start + 0x80000000
 964 .Lcritical_length:      .long   __critical_end - __critical_start
 965
 966                 .section .rodata, "a"
 967 #define SYSCALL(esa,esame,emu)  .long esa
 968         .globl  sys_call_table
 969 sys_call_table:
 970 #include "syscalls.S"
 971 #undef SYSCALL