arch/powerpc/kvm/bookehv_interrupts.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * You should have received a copy of the GNU General Public License
  12  * along with this program; if not, write to the Free Software
  13  * Foundation, 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  14  *
  15  * Copyright (C) 2010-2011 Freescale Semiconductor, Inc.
  16  *
  17  * Author: Varun Sethi <varun.sethi@freescale.com>
  18  * Author: Scott Wood <scotwood@freescale.com>
  19  *
  20  * This file is derived from arch/powerpc/kvm/booke_interrupts.S
  21  */
  22
  23 #include <asm/ppc_asm.h>
  24 #include <asm/kvm_asm.h>
  25 #include <asm/reg.h>
  26 #include <asm/mmu-44x.h>
  27 #include <asm/page.h>
  28 #include <asm/asm-compat.h>
  29 #include <asm/asm-offsets.h>
  30 #include <asm/bitsperlong.h>
  31 #include <asm/thread_info.h>
  32
  33 #include "../kernel/head_booke.h" /* for THREAD_NORMSAVE() */
  34
  35 #define GET_VCPU(vcpu, thread)  \
  36         PPC_LL  vcpu, THREAD_KVM_VCPU(thread)
  37
  38 #define LONGBYTES               (BITS_PER_LONG / 8)
  39
  40 #define VCPU_GUEST_SPRG(n)      (VCPU_GUEST_SPRGS + (n * LONGBYTES))
  41
  42 /* The host stack layout: */
  43 #define HOST_R1         (0 * LONGBYTES) /* Implied by stwu. */
  44 #define HOST_CALLEE_LR  (1 * LONGBYTES)
  45 #define HOST_RUN        (2 * LONGBYTES) /* struct kvm_run */
  46 /*
  47  * r2 is special: it holds 'current', and it made nonvolatile in the
  48  * kernel with the -ffixed-r2 gcc option.
  49  */
  50 #define HOST_R2         (3 * LONGBYTES)
  51 #define HOST_CR         (4 * LONGBYTES)
  52 #define HOST_NV_GPRS    (5 * LONGBYTES)
  53 #define HOST_NV_GPR(n)  (HOST_NV_GPRS + ((n - 14) * LONGBYTES))
  54 #define HOST_MIN_STACK_SIZE (HOST_NV_GPR(31) + LONGBYTES)
  55 #define HOST_STACK_SIZE ((HOST_MIN_STACK_SIZE + 15) & ~15) /* Align. */
  56 #define HOST_STACK_LR   (HOST_STACK_SIZE + LONGBYTES) /* In caller stack frame. */
  57
  58 #define NEED_EMU                0x00000001 /* emulation -- save nv regs */
  59 #define NEED_DEAR               0x00000002 /* save faulting DEAR */
  60 #define NEED_ESR                0x00000004 /* save faulting ESR */
  61
  62 /*
  63  * On entry:
  64  * r4 = vcpu, r5 = srr0, r6 = srr1
  65  * saved in vcpu: cr, ctr, r3-r13
  66  */
  67 .macro kvm_handler_common intno, srr0, flags
  68         /* Restore host stack pointer */
  69         PPC_STL r1, VCPU_GPR(R1)(r4)
  70         PPC_STL r2, VCPU_GPR(R2)(r4)
  71         PPC_LL  r1, VCPU_HOST_STACK(r4)
  72         PPC_LL  r2, HOST_R2(r1)
  73
  74         mfspr   r10, SPRN_PID
  75         lwz     r8, VCPU_HOST_PID(r4)
  76         PPC_LL  r11, VCPU_SHARED(r4)
  77         PPC_STL r14, VCPU_GPR(R14)(r4) /* We need a non-volatile GPR. */
  78         li      r14, \intno
  79
  80         stw     r10, VCPU_GUEST_PID(r4)
  81         mtspr   SPRN_PID, r8
  82
  83 #ifdef CONFIG_KVM_EXIT_TIMING
  84         /* save exit time */
  85 1:      mfspr   r7, SPRN_TBRU
  86         mfspr   r8, SPRN_TBRL
  87         mfspr   r9, SPRN_TBRU
  88         cmpw    r9, r7
  89         stw     r8, VCPU_TIMING_EXIT_TBL(r4)
  90         bne-    1b
  91         stw     r9, VCPU_TIMING_EXIT_TBU(r4)
  92 #endif
  93
  94         oris    r8, r6, MSR_CE@h
  95         PPC_STD(r6, VCPU_SHARED_MSR, r11)
  96         ori     r8, r8, MSR_ME | MSR_RI
  97         PPC_STL r5, VCPU_PC(r4)
  98
  99         /*
 100          * Make sure CE/ME/RI are set (if appropriate for exception type)
 101          * whether or not the guest had it set.  Since mfmsr/mtmsr are
 102          * somewhat expensive, skip in the common case where the guest
 103          * had all these bits set (and thus they're still set if
 104          * appropriate for the exception type).
 105          */
 106         cmpw    r6, r8
 107         beq     1f
 108         mfmsr   r7
 109         .if     \srr0 != SPRN_MCSRR0 && \srr0 != SPRN_CSRR0
 110         oris    r7, r7, MSR_CE@h
 111         .endif
 112         .if     \srr0 != SPRN_MCSRR0
 113         ori     r7, r7, MSR_ME | MSR_RI
 114         .endif
 115         mtmsr   r7
 116 1:
 117
 118         .if     \flags & NEED_EMU
 119         /*
 120          * This assumes you have external PID support.
 121          * To support a bookehv CPU without external PID, you'll
 122          * need to look up the TLB entry and create a temporary mapping.
 123          *
 124          * FIXME: we don't currently handle if the lwepx faults.  PR-mode
 125          * booke doesn't handle it either.  Since Linux doesn't use
 126          * broadcast tlbivax anymore, the only way this should happen is
 127          * if the guest maps its memory execute-but-not-read, or if we
 128          * somehow take a TLB miss in the middle of this entry code and
 129          * evict the relevant entry.  On e500mc, all kernel lowmem is
 130          * bolted into TLB1 large page mappings, and we don't use
 131          * broadcast invalidates, so we should not take a TLB miss here.
 132          *
 133          * Later we'll need to deal with faults here.  Disallowing guest
 134          * mappings that are execute-but-not-read could be an option on
 135          * e500mc, but not on chips with an LRAT if it is used.
 136          */
 137
 138         mfspr   r3, SPRN_EPLC   /* will already have correct ELPID and EGS */
 139         PPC_STL r15, VCPU_GPR(R15)(r4)
 140         PPC_STL r16, VCPU_GPR(R16)(r4)
 141         PPC_STL r17, VCPU_GPR(R17)(r4)
 142         PPC_STL r18, VCPU_GPR(R18)(r4)
 143         PPC_STL r19, VCPU_GPR(R19)(r4)
 144         mr      r8, r3
 145         PPC_STL r20, VCPU_GPR(R20)(r4)
 146         rlwimi  r8, r6, EPC_EAS_SHIFT - MSR_IR_LG, EPC_EAS
 147         PPC_STL r21, VCPU_GPR(R21)(r4)
 148         rlwimi  r8, r6, EPC_EPR_SHIFT - MSR_PR_LG, EPC_EPR
 149         PPC_STL r22, VCPU_GPR(R22)(r4)
 150         rlwimi  r8, r10, EPC_EPID_SHIFT, EPC_EPID
 151         PPC_STL r23, VCPU_GPR(R23)(r4)
 152         PPC_STL r24, VCPU_GPR(R24)(r4)
 153         PPC_STL r25, VCPU_GPR(R25)(r4)
 154         PPC_STL r26, VCPU_GPR(R26)(r4)
 155         PPC_STL r27, VCPU_GPR(R27)(r4)
 156         PPC_STL r28, VCPU_GPR(R28)(r4)
 157         PPC_STL r29, VCPU_GPR(R29)(r4)
 158         PPC_STL r30, VCPU_GPR(R30)(r4)
 159         PPC_STL r31, VCPU_GPR(R31)(r4)
 160         mtspr   SPRN_EPLC, r8
 161
 162         /* disable preemption, so we are sure we hit the fixup handler */
 163 #ifdef CONFIG_PPC64
 164         clrrdi  r8,r1,THREAD_SHIFT
 165 #else
 166         rlwinm  r8,r1,0,0,31-THREAD_SHIFT       /* current thread_info */
 167 #endif
 168         li      r7, 1
 169         stw     r7, TI_PREEMPT(r8)
 170
 171         isync
 172
 173         /*
 174          * In case the read goes wrong, we catch it and write an invalid value
 175          * in LAST_INST instead.
 176          */
 177 1:      lwepx   r9, 0, r5
 178 2:
 179 .section .fixup, "ax"
 180 3:      li      r9, KVM_INST_FETCH_FAILED
 181         b       2b
 182 .previous
 183 .section __ex_table,"a"
 184         PPC_LONG_ALIGN
 185         PPC_LONG 1b,3b
 186 .previous
 187
 188         mtspr   SPRN_EPLC, r3
 189         li      r7, 0
 190         stw     r7, TI_PREEMPT(r8)
 191         stw     r9, VCPU_LAST_INST(r4)
 192         .endif
 193
 194         .if     \flags & NEED_ESR
 195         mfspr   r8, SPRN_ESR
 196         PPC_STL r8, VCPU_FAULT_ESR(r4)
 197         .endif
 198
 199         .if     \flags & NEED_DEAR
 200         mfspr   r9, SPRN_DEAR
 201         PPC_STL r9, VCPU_FAULT_DEAR(r4)
 202         .endif
 203
 204         b       kvmppc_resume_host
 205 .endm
 206
 207 /*
 208  * For input register values, see arch/powerpc/include/asm/kvm_booke_hv_asm.h
 209  */
 210 .macro kvm_handler intno srr0, srr1, flags
 211 _GLOBAL(kvmppc_handler_\intno\()_\srr1)
 212         GET_VCPU(r11, r10)
 213         PPC_STL r3, VCPU_GPR(R3)(r11)
 214         mfspr   r3, SPRN_SPRG_RSCRATCH0
 215         PPC_STL r4, VCPU_GPR(R4)(r11)
 216         PPC_LL  r4, THREAD_NORMSAVE(0)(r10)
 217         PPC_STL r5, VCPU_GPR(R5)(r11)
 218         stw     r13, VCPU_CR(r11)
 219         mfspr   r5, \srr0
 220         PPC_STL r3, VCPU_GPR(R10)(r11)
 221         PPC_LL  r3, THREAD_NORMSAVE(2)(r10)
 222         PPC_STL r6, VCPU_GPR(R6)(r11)
 223         PPC_STL r4, VCPU_GPR(R11)(r11)
 224         mfspr   r6, \srr1
 225         PPC_STL r7, VCPU_GPR(R7)(r11)
 226         PPC_STL r8, VCPU_GPR(R8)(r11)
 227         PPC_STL r9, VCPU_GPR(R9)(r11)
 228         PPC_STL r3, VCPU_GPR(R13)(r11)
 229         mfctr   r7
 230         PPC_STL r12, VCPU_GPR(R12)(r11)
 231         PPC_STL r7, VCPU_CTR(r11)
 232         mr      r4, r11
 233         kvm_handler_common \intno, \srr0, \flags
 234 .endm
 235
 236 .macro kvm_lvl_handler intno scratch srr0, srr1, flags
 237 _GLOBAL(kvmppc_handler_\intno\()_\srr1)
 238         mfspr   r10, SPRN_SPRG_THREAD
 239         GET_VCPU(r11, r10)
 240         PPC_STL r3, VCPU_GPR(R3)(r11)
 241         mfspr   r3, \scratch
 242         PPC_STL r4, VCPU_GPR(R4)(r11)
 243         PPC_LL  r4, GPR9(r8)
 244         PPC_STL r5, VCPU_GPR(R5)(r11)
 245         stw     r9, VCPU_CR(r11)
 246         mfspr   r5, \srr0
 247         PPC_STL r3, VCPU_GPR(R8)(r11)
 248         PPC_LL  r3, GPR10(r8)
 249         PPC_STL r6, VCPU_GPR(R6)(r11)
 250         PPC_STL r4, VCPU_GPR(R9)(r11)
 251         mfspr   r6, \srr1
 252         PPC_LL  r4, GPR11(r8)
 253         PPC_STL r7, VCPU_GPR(R7)(r11)
 254         PPC_STL r3, VCPU_GPR(R10)(r11)
 255         mfctr   r7
 256         PPC_STL r12, VCPU_GPR(R12)(r11)
 257         PPC_STL r13, VCPU_GPR(R13)(r11)
 258         PPC_STL r4, VCPU_GPR(R11)(r11)
 259         PPC_STL r7, VCPU_CTR(r11)
 260         mr      r4, r11
 261         kvm_handler_common \intno, \srr0, \flags
 262 .endm
 263
 264 kvm_lvl_handler BOOKE_INTERRUPT_CRITICAL, \
 265         SPRN_SPRG_RSCRATCH_CRIT, SPRN_CSRR0, SPRN_CSRR1, 0
 266 kvm_lvl_handler BOOKE_INTERRUPT_MACHINE_CHECK, \
 267         SPRN_SPRG_RSCRATCH_MC, SPRN_MCSRR0, SPRN_MCSRR1, 0
 268 kvm_handler BOOKE_INTERRUPT_DATA_STORAGE, \
 269         SPRN_SRR0, SPRN_SRR1, (NEED_EMU | NEED_DEAR)
 270 kvm_handler BOOKE_INTERRUPT_INST_STORAGE, SPRN_SRR0, SPRN_SRR1, NEED_ESR
 271 kvm_handler BOOKE_INTERRUPT_EXTERNAL, SPRN_SRR0, SPRN_SRR1, 0
 272 kvm_handler BOOKE_INTERRUPT_ALIGNMENT, \
 273         SPRN_SRR0, SPRN_SRR1, (NEED_DEAR | NEED_ESR)
 274 kvm_handler BOOKE_INTERRUPT_PROGRAM, SPRN_SRR0, SPRN_SRR1, NEED_ESR
 275 kvm_handler BOOKE_INTERRUPT_FP_UNAVAIL, SPRN_SRR0, SPRN_SRR1, 0
 276 kvm_handler BOOKE_INTERRUPT_SYSCALL, SPRN_SRR0, SPRN_SRR1, 0
 277 kvm_handler BOOKE_INTERRUPT_AP_UNAVAIL, SPRN_SRR0, SPRN_SRR1, 0
 278 kvm_handler BOOKE_INTERRUPT_DECREMENTER, SPRN_SRR0, SPRN_SRR1, 0
 279 kvm_handler BOOKE_INTERRUPT_FIT, SPRN_SRR0, SPRN_SRR1, 0
 280 kvm_lvl_handler BOOKE_INTERRUPT_WATCHDOG, \
 281         SPRN_SPRG_RSCRATCH_CRIT, SPRN_CSRR0, SPRN_CSRR1, 0
 282 kvm_handler BOOKE_INTERRUPT_DTLB_MISS, \
 283         SPRN_SRR0, SPRN_SRR1, (NEED_EMU | NEED_DEAR | NEED_ESR)
 284 kvm_handler BOOKE_INTERRUPT_ITLB_MISS, SPRN_SRR0, SPRN_SRR1, 0
 285 kvm_handler BOOKE_INTERRUPT_SPE_UNAVAIL, SPRN_SRR0, SPRN_SRR1, 0
 286 kvm_handler BOOKE_INTERRUPT_SPE_FP_DATA, SPRN_SRR0, SPRN_SRR1, 0
 287 kvm_handler BOOKE_INTERRUPT_SPE_FP_ROUND, SPRN_SRR0, SPRN_SRR1, 0
 288 kvm_handler BOOKE_INTERRUPT_PERFORMANCE_MONITOR, SPRN_SRR0, SPRN_SRR1, 0
 289 kvm_handler BOOKE_INTERRUPT_DOORBELL, SPRN_SRR0, SPRN_SRR1, 0
 290 kvm_lvl_handler BOOKE_INTERRUPT_DOORBELL_CRITICAL, \
 291         SPRN_SPRG_RSCRATCH_CRIT, SPRN_CSRR0, SPRN_CSRR1, 0
 292 kvm_handler BOOKE_INTERRUPT_HV_PRIV, SPRN_SRR0, SPRN_SRR1, NEED_EMU
 293 kvm_handler BOOKE_INTERRUPT_HV_SYSCALL, SPRN_SRR0, SPRN_SRR1, 0
 294 kvm_handler BOOKE_INTERRUPT_GUEST_DBELL, SPRN_GSRR0, SPRN_GSRR1, 0
 295 kvm_lvl_handler BOOKE_INTERRUPT_GUEST_DBELL_CRIT, \
 296         SPRN_SPRG_RSCRATCH_CRIT, SPRN_CSRR0, SPRN_CSRR1, 0
 297 kvm_lvl_handler BOOKE_INTERRUPT_DEBUG, \
 298         SPRN_SPRG_RSCRATCH_CRIT, SPRN_CSRR0, SPRN_CSRR1, 0
 299 kvm_lvl_handler BOOKE_INTERRUPT_DEBUG, \
 300         SPRN_SPRG_RSCRATCH_DBG, SPRN_DSRR0, SPRN_DSRR1, 0
 301
 302
 303 /* Registers:
 304  *  SPRG_SCRATCH0: guest r10
 305  *  r4: vcpu pointer
 306  *  r11: vcpu->arch.shared
 307  *  r14: KVM exit number
 308  */
 309 _GLOBAL(kvmppc_resume_host)
 310         /* Save remaining volatile guest register state to vcpu. */
 311         mfspr   r3, SPRN_VRSAVE
 312         PPC_STL r0, VCPU_GPR(R0)(r4)
 313         mflr    r5
 314         mfspr   r6, SPRN_SPRG4
 315         PPC_STL r5, VCPU_LR(r4)
 316         mfspr   r7, SPRN_SPRG5
 317         stw     r3, VCPU_VRSAVE(r4)
 318         PPC_STD(r6, VCPU_SHARED_SPRG4, r11)
 319         mfspr   r8, SPRN_SPRG6
 320         PPC_STD(r7, VCPU_SHARED_SPRG5, r11)
 321         mfspr   r9, SPRN_SPRG7
 322         PPC_STD(r8, VCPU_SHARED_SPRG6, r11)
 323         mfxer   r3
 324         PPC_STD(r9, VCPU_SHARED_SPRG7, r11)
 325
 326         /* save guest MAS registers and restore host mas4 & mas6 */
 327         mfspr   r5, SPRN_MAS0
 328         PPC_STL r3, VCPU_XER(r4)
 329         mfspr   r6, SPRN_MAS1
 330         stw     r5, VCPU_SHARED_MAS0(r11)
 331         mfspr   r7, SPRN_MAS2
 332         stw     r6, VCPU_SHARED_MAS1(r11)
 333         PPC_STD(r7, VCPU_SHARED_MAS2, r11)
 334         mfspr   r5, SPRN_MAS3
 335         mfspr   r6, SPRN_MAS4
 336         stw     r5, VCPU_SHARED_MAS7_3+4(r11)
 337         mfspr   r7, SPRN_MAS6
 338         stw     r6, VCPU_SHARED_MAS4(r11)
 339         mfspr   r5, SPRN_MAS7
 340         lwz     r6, VCPU_HOST_MAS4(r4)
 341         stw     r7, VCPU_SHARED_MAS6(r11)
 342         lwz     r8, VCPU_HOST_MAS6(r4)
 343         mtspr   SPRN_MAS4, r6
 344         stw     r5, VCPU_SHARED_MAS7_3+0(r11)
 345         mtspr   SPRN_MAS6, r8
 346         /* Enable MAS register updates via exception */
 347         mfspr   r3, SPRN_EPCR
 348         rlwinm  r3, r3, 0, ~SPRN_EPCR_DMIUH
 349         mtspr   SPRN_EPCR, r3
 350         isync
 351
 352         /* Switch to kernel stack and jump to handler. */
 353         PPC_LL  r3, HOST_RUN(r1)
 354         mr      r5, r14 /* intno */
 355         mr      r14, r4 /* Save vcpu pointer. */
 356         bl      kvmppc_handle_exit
 357
 358         /* Restore vcpu pointer and the nonvolatiles we used. */
 359         mr      r4, r14
 360         PPC_LL  r14, VCPU_GPR(R14)(r4)
 361
 362         andi.   r5, r3, RESUME_FLAG_NV
 363         beq     skip_nv_load
 364         PPC_LL  r15, VCPU_GPR(R15)(r4)
 365         PPC_LL  r16, VCPU_GPR(R16)(r4)
 366         PPC_LL  r17, VCPU_GPR(R17)(r4)
 367         PPC_LL  r18, VCPU_GPR(R18)(r4)
 368         PPC_LL  r19, VCPU_GPR(R19)(r4)
 369         PPC_LL  r20, VCPU_GPR(R20)(r4)
 370         PPC_LL  r21, VCPU_GPR(R21)(r4)
 371         PPC_LL  r22, VCPU_GPR(R22)(r4)
 372         PPC_LL  r23, VCPU_GPR(R23)(r4)
 373         PPC_LL  r24, VCPU_GPR(R24)(r4)
 374         PPC_LL  r25, VCPU_GPR(R25)(r4)
 375         PPC_LL  r26, VCPU_GPR(R26)(r4)
 376         PPC_LL  r27, VCPU_GPR(R27)(r4)
 377         PPC_LL  r28, VCPU_GPR(R28)(r4)
 378         PPC_LL  r29, VCPU_GPR(R29)(r4)
 379         PPC_LL  r30, VCPU_GPR(R30)(r4)
 380         PPC_LL  r31, VCPU_GPR(R31)(r4)
 381 skip_nv_load:
 382         /* Should we return to the guest? */
 383         andi.   r5, r3, RESUME_FLAG_HOST
 384         beq     lightweight_exit
 385
 386         srawi   r3, r3, 2 /* Shift -ERR back down. */
 387
 388 heavyweight_exit:
 389         /* Not returning to guest. */
 390         PPC_LL  r5, HOST_STACK_LR(r1)
 391         lwz     r6, HOST_CR(r1)
 392
 393         /*
 394          * We already saved guest volatile register state; now save the
 395          * non-volatiles.
 396          */
 397
 398         PPC_STL r15, VCPU_GPR(R15)(r4)
 399         PPC_STL r16, VCPU_GPR(R16)(r4)
 400         PPC_STL r17, VCPU_GPR(R17)(r4)
 401         PPC_STL r18, VCPU_GPR(R18)(r4)
 402         PPC_STL r19, VCPU_GPR(R19)(r4)
 403         PPC_STL r20, VCPU_GPR(R20)(r4)
 404         PPC_STL r21, VCPU_GPR(R21)(r4)
 405         PPC_STL r22, VCPU_GPR(R22)(r4)
 406         PPC_STL r23, VCPU_GPR(R23)(r4)
 407         PPC_STL r24, VCPU_GPR(R24)(r4)
 408         PPC_STL r25, VCPU_GPR(R25)(r4)
 409         PPC_STL r26, VCPU_GPR(R26)(r4)
 410         PPC_STL r27, VCPU_GPR(R27)(r4)
 411         PPC_STL r28, VCPU_GPR(R28)(r4)
 412         PPC_STL r29, VCPU_GPR(R29)(r4)
 413         PPC_STL r30, VCPU_GPR(R30)(r4)
 414         PPC_STL r31, VCPU_GPR(R31)(r4)
 415
 416         /* Load host non-volatile register state from host stack. */
 417         PPC_LL  r14, HOST_NV_GPR(r14)(r1)
 418         PPC_LL  r15, HOST_NV_GPR(r15)(r1)
 419         PPC_LL  r16, HOST_NV_GPR(r16)(r1)
 420         PPC_LL  r17, HOST_NV_GPR(r17)(r1)
 421         PPC_LL  r18, HOST_NV_GPR(r18)(r1)
 422         PPC_LL  r19, HOST_NV_GPR(r19)(r1)
 423         PPC_LL  r20, HOST_NV_GPR(r20)(r1)
 424         PPC_LL  r21, HOST_NV_GPR(r21)(r1)
 425         PPC_LL  r22, HOST_NV_GPR(r22)(r1)
 426         PPC_LL  r23, HOST_NV_GPR(r23)(r1)
 427         PPC_LL  r24, HOST_NV_GPR(r24)(r1)
 428         PPC_LL  r25, HOST_NV_GPR(r25)(r1)
 429         PPC_LL  r26, HOST_NV_GPR(r26)(r1)
 430         PPC_LL  r27, HOST_NV_GPR(r27)(r1)
 431         PPC_LL  r28, HOST_NV_GPR(r28)(r1)
 432         PPC_LL  r29, HOST_NV_GPR(r29)(r1)
 433         PPC_LL  r30, HOST_NV_GPR(r30)(r1)
 434         PPC_LL  r31, HOST_NV_GPR(r31)(r1)
 435
 436         /* Return to kvm_vcpu_run(). */
 437         mtlr    r5
 438         mtcr    r6
 439         addi    r1, r1, HOST_STACK_SIZE
 440         /* r3 still contains the return code from kvmppc_handle_exit(). */
 441         blr
 442
 443 /* Registers:
 444  *  r3: kvm_run pointer
 445  *  r4: vcpu pointer
 446  */
 447 _GLOBAL(__kvmppc_vcpu_run)
 448         stwu    r1, -HOST_STACK_SIZE(r1)
 449         PPC_STL r1, VCPU_HOST_STACK(r4) /* Save stack pointer to vcpu. */
 450
 451         /* Save host state to stack. */
 452         PPC_STL r3, HOST_RUN(r1)
 453         mflr    r3
 454         mfcr    r5
 455         PPC_STL r3, HOST_STACK_LR(r1)
 456
 457         stw     r5, HOST_CR(r1)
 458
 459         /* Save host non-volatile register state to stack. */
 460         PPC_STL r14, HOST_NV_GPR(r14)(r1)
 461         PPC_STL r15, HOST_NV_GPR(r15)(r1)
 462         PPC_STL r16, HOST_NV_GPR(r16)(r1)
 463         PPC_STL r17, HOST_NV_GPR(r17)(r1)
 464         PPC_STL r18, HOST_NV_GPR(r18)(r1)
 465         PPC_STL r19, HOST_NV_GPR(r19)(r1)
 466         PPC_STL r20, HOST_NV_GPR(r20)(r1)
 467         PPC_STL r21, HOST_NV_GPR(r21)(r1)
 468         PPC_STL r22, HOST_NV_GPR(r22)(r1)
 469         PPC_STL r23, HOST_NV_GPR(r23)(r1)
 470         PPC_STL r24, HOST_NV_GPR(r24)(r1)
 471         PPC_STL r25, HOST_NV_GPR(r25)(r1)
 472         PPC_STL r26, HOST_NV_GPR(r26)(r1)
 473         PPC_STL r27, HOST_NV_GPR(r27)(r1)
 474         PPC_STL r28, HOST_NV_GPR(r28)(r1)
 475         PPC_STL r29, HOST_NV_GPR(r29)(r1)
 476         PPC_STL r30, HOST_NV_GPR(r30)(r1)
 477         PPC_STL r31, HOST_NV_GPR(r31)(r1)
 478
 479         /* Load guest non-volatiles. */
 480         PPC_LL  r14, VCPU_GPR(R14)(r4)
 481         PPC_LL  r15, VCPU_GPR(R15)(r4)
 482         PPC_LL  r16, VCPU_GPR(R16)(r4)
 483         PPC_LL  r17, VCPU_GPR(R17)(r4)
 484         PPC_LL  r18, VCPU_GPR(R18)(r4)
 485         PPC_LL  r19, VCPU_GPR(R19)(r4)
 486         PPC_LL  r20, VCPU_GPR(R20)(r4)
 487         PPC_LL  r21, VCPU_GPR(R21)(r4)
 488         PPC_LL  r22, VCPU_GPR(R22)(r4)
 489         PPC_LL  r23, VCPU_GPR(R23)(r4)
 490         PPC_LL  r24, VCPU_GPR(R24)(r4)
 491         PPC_LL  r25, VCPU_GPR(R25)(r4)
 492         PPC_LL  r26, VCPU_GPR(R26)(r4)
 493         PPC_LL  r27, VCPU_GPR(R27)(r4)
 494         PPC_LL  r28, VCPU_GPR(R28)(r4)
 495         PPC_LL  r29, VCPU_GPR(R29)(r4)
 496         PPC_LL  r30, VCPU_GPR(R30)(r4)
 497         PPC_LL  r31, VCPU_GPR(R31)(r4)
 498
 499
 500 lightweight_exit:
 501         PPC_STL r2, HOST_R2(r1)
 502
 503         mfspr   r3, SPRN_PID
 504         stw     r3, VCPU_HOST_PID(r4)
 505         lwz     r3, VCPU_GUEST_PID(r4)
 506         mtspr   SPRN_PID, r3
 507
 508         PPC_LL  r11, VCPU_SHARED(r4)
 509         /* Disable MAS register updates via exception */
 510         mfspr   r3, SPRN_EPCR
 511         oris    r3, r3, SPRN_EPCR_DMIUH@h
 512         mtspr   SPRN_EPCR, r3
 513         isync
 514         /* Save host mas4 and mas6 and load guest MAS registers */
 515         mfspr   r3, SPRN_MAS4
 516         stw     r3, VCPU_HOST_MAS4(r4)
 517         mfspr   r3, SPRN_MAS6
 518         stw     r3, VCPU_HOST_MAS6(r4)
 519         lwz     r3, VCPU_SHARED_MAS0(r11)
 520         lwz     r5, VCPU_SHARED_MAS1(r11)
 521         PPC_LD(r6, VCPU_SHARED_MAS2, r11)
 522         lwz     r7, VCPU_SHARED_MAS7_3+4(r11)
 523         lwz     r8, VCPU_SHARED_MAS4(r11)
 524         mtspr   SPRN_MAS0, r3
 525         mtspr   SPRN_MAS1, r5
 526         mtspr   SPRN_MAS2, r6
 527         mtspr   SPRN_MAS3, r7
 528         mtspr   SPRN_MAS4, r8
 529         lwz     r3, VCPU_SHARED_MAS6(r11)
 530         lwz     r5, VCPU_SHARED_MAS7_3+0(r11)
 531         mtspr   SPRN_MAS6, r3
 532         mtspr   SPRN_MAS7, r5
 533
 534         /*
 535          * Host interrupt handlers may have clobbered these guest-readable
 536          * SPRGs, so we need to reload them here with the guest's values.
 537          */
 538         lwz     r3, VCPU_VRSAVE(r4)
 539         PPC_LD(r5, VCPU_SHARED_SPRG4, r11)
 540         mtspr   SPRN_VRSAVE, r3
 541         PPC_LD(r6, VCPU_SHARED_SPRG5, r11)
 542         mtspr   SPRN_SPRG4W, r5
 543         PPC_LD(r7, VCPU_SHARED_SPRG6, r11)
 544         mtspr   SPRN_SPRG5W, r6
 545         PPC_LD(r8, VCPU_SHARED_SPRG7, r11)
 546         mtspr   SPRN_SPRG6W, r7
 547         mtspr   SPRN_SPRG7W, r8
 548
 549         /* Load some guest volatiles. */
 550         PPC_LL  r3, VCPU_LR(r4)
 551         PPC_LL  r5, VCPU_XER(r4)
 552         PPC_LL  r6, VCPU_CTR(r4)
 553         lwz     r7, VCPU_CR(r4)
 554         PPC_LL  r8, VCPU_PC(r4)
 555         PPC_LD(r9, VCPU_SHARED_MSR, r11)
 556         PPC_LL  r0, VCPU_GPR(R0)(r4)
 557         PPC_LL  r1, VCPU_GPR(R1)(r4)
 558         PPC_LL  r2, VCPU_GPR(R2)(r4)
 559         PPC_LL  r10, VCPU_GPR(R10)(r4)
 560         PPC_LL  r11, VCPU_GPR(R11)(r4)
 561         PPC_LL  r12, VCPU_GPR(R12)(r4)
 562         PPC_LL  r13, VCPU_GPR(R13)(r4)
 563         mtlr    r3
 564         mtxer   r5
 565         mtctr   r6
 566         mtsrr0  r8
 567         mtsrr1  r9
 568
 569 #ifdef CONFIG_KVM_EXIT_TIMING
 570         /* save enter time */
 571 1:
 572         mfspr   r6, SPRN_TBRU
 573         mfspr   r9, SPRN_TBRL
 574         mfspr   r8, SPRN_TBRU
 575         cmpw    r8, r6
 576         stw     r9, VCPU_TIMING_LAST_ENTER_TBL(r4)
 577         bne     1b
 578         stw     r8, VCPU_TIMING_LAST_ENTER_TBU(r4)
 579 #endif
 580
 581         /*
 582          * Don't execute any instruction which can change CR after
 583          * below instruction.
 584          */
 585         mtcr    r7
 586
 587         /* Finish loading guest volatiles and jump to guest. */
 588         PPC_LL  r5, VCPU_GPR(R5)(r4)
 589         PPC_LL  r6, VCPU_GPR(R6)(r4)
 590         PPC_LL  r7, VCPU_GPR(R7)(r4)
 591         PPC_LL  r8, VCPU_GPR(R8)(r4)
 592         PPC_LL  r9, VCPU_GPR(R9)(r4)
 593
 594         PPC_LL  r3, VCPU_GPR(R3)(r4)
 595         PPC_LL  r4, VCPU_GPR(R4)(r4)
 596         rfi