arch/microblaze/kernel/head.S

   1 /*
   2  * Copyright (C) 2007-2009 Michal Simek <monstr@monstr.eu>
   3  * Copyright (C) 2007-2009 PetaLogix
   4  * Copyright (C) 2006 Atmark Techno, Inc.
   5  *
   6  * MMU code derived from arch/ppc/kernel/head_4xx.S:
   7  *    Copyright (c) 1995-1996 Gary Thomas <gdt@linuxppc.org>
   8  *      Initial PowerPC version.
   9  *    Copyright (c) 1996 Cort Dougan <cort@cs.nmt.edu>
  10  *      Rewritten for PReP
  11  *    Copyright (c) 1996 Paul Mackerras <paulus@cs.anu.edu.au>
  12  *      Low-level exception handers, MMU support, and rewrite.
  13  *    Copyright (c) 1997 Dan Malek <dmalek@jlc.net>
  14  *      PowerPC 8xx modifications.
  15  *    Copyright (c) 1998-1999 TiVo, Inc.
  16  *      PowerPC 403GCX modifications.
  17  *    Copyright (c) 1999 Grant Erickson <grant@lcse.umn.edu>
  18  *      PowerPC 403GCX/405GP modifications.
  19  *    Copyright 2000 MontaVista Software Inc.
  20  *      PPC405 modifications
  21  *      PowerPC 403GCX/405GP modifications.
  22  *      Author: MontaVista Software, Inc.
  23  *              frank_rowand@mvista.com or source@mvista.com
  24  *              debbie_chu@mvista.com
  25  *
  26  * This file is subject to the terms and conditions of the GNU General Public
  27  * License. See the file "COPYING" in the main directory of this archive
  28  * for more details.
  29  */
  30
  31 #include <linux/linkage.h>
  32 #include <asm/thread_info.h>
  33 #include <asm/page.h>
  34 #include <linux/of_fdt.h>               /* for OF_DT_HEADER */
  35
  36 #ifdef CONFIG_MMU
  37 #include <asm/setup.h> /* COMMAND_LINE_SIZE */
  38 #include <asm/mmu.h>
  39 #include <asm/processor.h>
  40
  41 .data
  42 .global empty_zero_page
  43 .align 12
  44 empty_zero_page:
  45         .space  4096
  46 .global swapper_pg_dir
  47 swapper_pg_dir:
  48         .space  4096
  49
  50 #endif /* CONFIG_MMU */
  51
  52         .text
  53 ENTRY(_start)
  54         mfs     r1, rmsr
  55         andi    r1, r1, ~2
  56         mts     rmsr, r1
  57 /*
  58  * Here is checking mechanism which check if Microblaze has msr instructions
  59  * We load msr and compare it with previous r1 value - if is the same,
  60  * msr instructions works if not - cpu don't have them.
  61  */
  62         /* r8=0 - I have msr instr, 1 - I don't have them */
  63         rsubi   r0, r0, 1       /* set the carry bit */
  64         msrclr  r0, 0x4         /* try to clear it */
  65         /* read the carry bit, r8 will be '0' if msrclr exists */
  66         addik   r8, r0, 0
  67
  68 /* r7 may point to an FDT, or there may be one linked in.
  69    if it's in r7, we've got to save it away ASAP.
  70    We ensure r7 points to a valid FDT, just in case the bootloader
  71    is broken or non-existent */
  72         beqi    r7, no_fdt_arg                  /* NULL pointer?  don't copy */
  73         lw      r11, r0, r7                     /* Does r7 point to a */
  74         rsubi   r11, r11, OF_DT_HEADER          /* valid FDT? */
  75         beqi    r11, _prepare_copy_fdt
  76         or      r7, r0, r0              /* clear R7 when not valid DTB */
  77         bnei    r11, no_fdt_arg                 /* No - get out of here */
  78 _prepare_copy_fdt:
  79         or      r11, r0, r0 /* incremment */
  80         ori     r4, r0, TOPHYS(_fdt_start)
  81         ori     r3, r0, (0x4000 - 4)
  82 _copy_fdt:
  83         lw      r12, r7, r11 /* r12 = r7 + r11 */
  84         sw      r12, r4, r11 /* addr[r4 + r11] = r12 */
  85         addik   r11, r11, 4 /* increment counting */
  86         bgtid   r3, _copy_fdt /* loop for all entries */
  87         addik   r3, r3, -4 /* descrement loop */
  88 no_fdt_arg:
  89
  90 #ifdef CONFIG_MMU
  91
  92 #ifndef CONFIG_CMDLINE_BOOL
  93 /*
  94  * handling command line
  95  * copy command line to __init_end. There is space for storing command line.
  96  */
  97         or      r6, r0, r0              /* incremment */
  98         ori     r4, r0, __init_end      /* load address of command line */
  99         tophys(r4,r4)                   /* convert to phys address */
 100         ori     r3, r0, COMMAND_LINE_SIZE - 1 /* number of loops */
 101 _copy_command_line:
 102         lbu     r2, r5, r6 /* r7=r5+r6 - r5 contain pointer to command line */
 103         sb      r2, r4, r6              /* addr[r4+r6]= r7*/
 104         addik   r6, r6, 1               /* increment counting */
 105         bgtid   r3, _copy_command_line  /* loop for all entries       */
 106         addik   r3, r3, -1              /* descrement loop */
 107         addik   r5, r4, 0               /* add new space for command line */
 108         tovirt(r5,r5)
 109 #endif /* CONFIG_CMDLINE_BOOL */
 110
 111 #ifdef NOT_COMPILE
 112 /* save bram context */
 113         or      r6, r0, r0                              /* incremment */
 114         ori     r4, r0, TOPHYS(_bram_load_start)        /* save bram context */
 115         ori     r3, r0, (LMB_SIZE - 4)
 116 _copy_bram:
 117         lw      r7, r0, r6              /* r7 = r0 + r6 */
 118         sw      r7, r4, r6              /* addr[r4 + r6] = r7*/
 119         addik   r6, r6, 4               /* increment counting */
 120         bgtid   r3, _copy_bram          /* loop for all entries */
 121         addik   r3, r3, -4              /* descrement loop */
 122 #endif
 123         /* We have to turn on the MMU right away. */
 124
 125         /*
 126          * Set up the initial MMU state so we can do the first level of
 127          * kernel initialization.  This maps the first 16 MBytes of memory 1:1
 128          * virtual to physical.
 129          */
 130         nop
 131         addik   r3, r0, 63              /* Invalidate all TLB entries */
 132 _invalidate:
 133         mts     rtlbx, r3
 134         mts     rtlbhi, r0                      /* flush: ensure V is clear   */
 135         bgtid   r3, _invalidate         /* loop for all entries       */
 136         addik   r3, r3, -1
 137         /* sync */
 138
 139         /* Setup the kernel PID */
 140         mts     rpid,r0                 /* Load the kernel PID */
 141         nop
 142         bri     4
 143
 144         /*
 145          * We should still be executing code at physical address area
 146          * RAM_BASEADDR at this point. However, kernel code is at
 147          * a virtual address. So, set up a TLB mapping to cover this once
 148          * translation is enabled.
 149          */
 150
 151         addik   r3,r0, CONFIG_KERNEL_START /* Load the kernel virtual address */
 152         tophys(r4,r3)                   /* Load the kernel physical address */
 153
 154         /*
 155          * Configure and load two entries into TLB slots 0 and 1.
 156          * In case we are pinning TLBs, these are reserved in by the
 157          * other TLB functions.  If not reserving, then it doesn't
 158          * matter where they are loaded.
 159          */
 160         andi    r4,r4,0xfffffc00        /* Mask off the real page number */
 161         ori     r4,r4,(TLB_WR | TLB_EX) /* Set the write and execute bits */
 162
 163         andi    r3,r3,0xfffffc00        /* Mask off the effective page number */
 164         ori     r3,r3,(TLB_VALID | TLB_PAGESZ(PAGESZ_16M))
 165
 166         mts     rtlbx,r0                /* TLB slow 0 */
 167
 168         mts     rtlblo,r4               /* Load the data portion of the entry */
 169         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 170
 171         addik   r4, r4, 0x01000000      /* Map next 16 M entries */
 172         addik   r3, r3, 0x01000000
 173
 174         ori     r6,r0,1                 /* TLB slot 1 */
 175         mts     rtlbx,r6
 176
 177         mts     rtlblo,r4               /* Load the data portion of the entry */
 178         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 179
 180         /*
 181          * Load a TLB entry for LMB, since we need access to
 182          * the exception vectors, using a 4k real==virtual mapping.
 183          */
 184         ori     r6,r0,3                 /* TLB slot 3 */
 185         mts     rtlbx,r6
 186
 187         ori     r4,r0,(TLB_WR | TLB_EX)
 188         ori     r3,r0,(TLB_VALID | TLB_PAGESZ(PAGESZ_4K))
 189
 190         mts     rtlblo,r4               /* Load the data portion of the entry */
 191         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 192
 193         /*
 194          * We now have the lower 16 Meg of RAM mapped into TLB entries, and the
 195          * caches ready to work.
 196          */
 197 turn_on_mmu:
 198         ori     r15,r0,start_here
 199         ori     r4,r0,MSR_KERNEL_VMS
 200         mts     rmsr,r4
 201         nop
 202         rted    r15,0                   /* enables MMU */
 203         nop
 204
 205 start_here:
 206 #endif /* CONFIG_MMU */
 207
 208         /* Initialize small data anchors */
 209         la      r13, r0, _KERNEL_SDA_BASE_
 210         la      r2, r0, _KERNEL_SDA2_BASE_
 211
 212         /* Initialize stack pointer */
 213         la      r1, r0, init_thread_union + THREAD_SIZE - 4
 214
 215         /* Initialize r31 with current task address */
 216         la      r31, r0, init_task
 217
 218         /*
 219          * Call platform dependent initialize function.
 220          * Please see $(ARCH)/mach-$(SUBARCH)/setup.c for
 221          * the function.
 222          */
 223         la      r9, r0, machine_early_init
 224         brald   r15, r9
 225         nop
 226
 227 #ifndef CONFIG_MMU
 228         la      r15, r0, machine_halt
 229         braid   start_kernel
 230         nop
 231 #else
 232         /*
 233          * Initialize the MMU.
 234          */
 235         bralid  r15, mmu_init
 236         nop
 237
 238         /* Go back to running unmapped so we can load up new values
 239          * and change to using our exception vectors.
 240          * On the MicroBlaze, all we invalidate the used TLB entries to clear
 241          * the old 16M byte TLB mappings.
 242          */
 243         ori     r15,r0,TOPHYS(kernel_load_context)
 244         ori     r4,r0,MSR_KERNEL
 245         mts     rmsr,r4
 246         nop
 247         bri     4
 248         rted    r15,0
 249         nop
 250
 251         /* Load up the kernel context */
 252 kernel_load_context:
 253         # Keep entry 0 and 1 valid. Entry 3 mapped to LMB can go away.
 254         ori     r5,r0,3
 255         mts     rtlbx,r5
 256         nop
 257         mts     rtlbhi,r0
 258         nop
 259         addi    r15, r0, machine_halt
 260         ori     r17, r0, start_kernel
 261         ori     r4, r0, MSR_KERNEL_VMS
 262         mts     rmsr, r4
 263         nop
 264         rted    r17, 0          /* enable MMU and jump to start_kernel */
 265         nop
 266 #endif /* CONFIG_MMU */