arch/microblaze/kernel/head.S

   1 /*
   2  * Copyright (C) 2007-2009 Michal Simek <monstr@monstr.eu>
   3  * Copyright (C) 2007-2009 PetaLogix
   4  * Copyright (C) 2006 Atmark Techno, Inc.
   5  *
   6  * MMU code derived from arch/ppc/kernel/head_4xx.S:
   7  *    Copyright (c) 1995-1996 Gary Thomas <gdt@linuxppc.org>
   8  *      Initial PowerPC version.
   9  *    Copyright (c) 1996 Cort Dougan <cort@cs.nmt.edu>
  10  *      Rewritten for PReP
  11  *    Copyright (c) 1996 Paul Mackerras <paulus@cs.anu.edu.au>
  12  *      Low-level exception handers, MMU support, and rewrite.
  13  *    Copyright (c) 1997 Dan Malek <dmalek@jlc.net>
  14  *      PowerPC 8xx modifications.
  15  *    Copyright (c) 1998-1999 TiVo, Inc.
  16  *      PowerPC 403GCX modifications.
  17  *    Copyright (c) 1999 Grant Erickson <grant@lcse.umn.edu>
  18  *      PowerPC 403GCX/405GP modifications.
  19  *    Copyright 2000 MontaVista Software Inc.
  20  *      PPC405 modifications
  21  *      PowerPC 403GCX/405GP modifications.
  22  *      Author: MontaVista Software, Inc.
  23  *              frank_rowand@mvista.com or source@mvista.com
  24  *              debbie_chu@mvista.com
  25  *
  26  * This file is subject to the terms and conditions of the GNU General Public
  27  * License. See the file "COPYING" in the main directory of this archive
  28  * for more details.
  29  */
  30
  31 #include <linux/init.h>
  32 #include <linux/linkage.h>
  33 #include <asm/thread_info.h>
  34 #include <asm/page.h>
  35 #include <linux/of_fdt.h>               /* for OF_DT_HEADER */
  36
  37 #ifdef CONFIG_MMU
  38 #include <asm/setup.h> /* COMMAND_LINE_SIZE */
  39 #include <asm/mmu.h>
  40 #include <asm/processor.h>
  41
  42 .data
  43 .global empty_zero_page
  44 .align 12
  45 empty_zero_page:
  46         .space  PAGE_SIZE
  47 .global swapper_pg_dir
  48 swapper_pg_dir:
  49         .space  PAGE_SIZE
  50
  51 #endif /* CONFIG_MMU */
  52
  53         __HEAD
  54 ENTRY(_start)
  55 #if CONFIG_KERNEL_BASE_ADDR == 0
  56         brai    TOPHYS(real_start)
  57         .org    0x100
  58 real_start:
  59 #endif
  60
  61         mfs     r1, rmsr
  62         andi    r1, r1, ~2
  63         mts     rmsr, r1
  64 /*
  65  * Here is checking mechanism which check if Microblaze has msr instructions
  66  * We load msr and compare it with previous r1 value - if is the same,
  67  * msr instructions works if not - cpu don't have them.
  68  */
  69         /* r8=0 - I have msr instr, 1 - I don't have them */
  70         rsubi   r0, r0, 1       /* set the carry bit */
  71         msrclr  r0, 0x4         /* try to clear it */
  72         /* read the carry bit, r8 will be '0' if msrclr exists */
  73         addik   r8, r0, 0
  74
  75 /* r7 may point to an FDT, or there may be one linked in.
  76    if it's in r7, we've got to save it away ASAP.
  77    We ensure r7 points to a valid FDT, just in case the bootloader
  78    is broken or non-existent */
  79         beqi    r7, no_fdt_arg                  /* NULL pointer?  don't copy */
  80 /* Does r7 point to a valid FDT? Load HEADER magic number */
  81         /* Run time Big/Little endian platform */
  82         /* Save 1 as word and load byte - 0 - BIG, 1 - LITTLE */
  83         addik   r11, r0, 0x1 /* BIG/LITTLE checking value */
  84         /* __bss_start will be zeroed later - it is just temp location */
  85         swi     r11, r0, TOPHYS(__bss_start)
  86         lbui    r11, r0, TOPHYS(__bss_start)
  87         beqid   r11, big_endian /* DO NOT break delay stop dependency */
  88         lw      r11, r0, r7 /* Big endian load in delay slot */
  89         lwr     r11, r0, r7 /* Little endian load */
  90 big_endian:
  91         rsubi   r11, r11, OF_DT_HEADER  /* Check FDT header */
  92         beqi    r11, _prepare_copy_fdt
  93         or      r7, r0, r0              /* clear R7 when not valid DTB */
  94         bnei    r11, no_fdt_arg                 /* No - get out of here */
  95 _prepare_copy_fdt:
  96         or      r11, r0, r0 /* incremment */
  97         ori     r4, r0, TOPHYS(_fdt_start)
  98         ori     r3, r0, (0x4000 - 4)
  99 _copy_fdt:
 100         lw      r12, r7, r11 /* r12 = r7 + r11 */
 101         sw      r12, r4, r11 /* addr[r4 + r11] = r12 */
 102         addik   r11, r11, 4 /* increment counting */
 103         bgtid   r3, _copy_fdt /* loop for all entries */
 104         addik   r3, r3, -4 /* descrement loop */
 105 no_fdt_arg:
 106
 107 #ifdef CONFIG_MMU
 108
 109 #ifndef CONFIG_CMDLINE_BOOL
 110 /*
 111  * handling command line
 112  * copy command line to __init_end. There is space for storing command line.
 113  */
 114         or      r6, r0, r0              /* incremment */
 115         ori     r4, r0, __init_end      /* load address of command line */
 116         tophys(r4,r4)                   /* convert to phys address */
 117         ori     r3, r0, COMMAND_LINE_SIZE - 1 /* number of loops */
 118 _copy_command_line:
 119         lbu     r2, r5, r6 /* r2=r5+r6 - r5 contain pointer to command line */
 120         sb      r2, r4, r6              /* addr[r4+r6]= r2*/
 121         addik   r6, r6, 1               /* increment counting */
 122         bgtid   r3, _copy_command_line  /* loop for all entries       */
 123         addik   r3, r3, -1              /* descrement loop */
 124         addik   r5, r4, 0               /* add new space for command line */
 125         tovirt(r5,r5)
 126 #endif /* CONFIG_CMDLINE_BOOL */
 127
 128 #ifdef NOT_COMPILE
 129 /* save bram context */
 130         or      r6, r0, r0                              /* incremment */
 131         ori     r4, r0, TOPHYS(_bram_load_start)        /* save bram context */
 132         ori     r3, r0, (LMB_SIZE - 4)
 133 _copy_bram:
 134         lw      r7, r0, r6              /* r7 = r0 + r6 */
 135         sw      r7, r4, r6              /* addr[r4 + r6] = r7*/
 136         addik   r6, r6, 4               /* increment counting */
 137         bgtid   r3, _copy_bram          /* loop for all entries */
 138         addik   r3, r3, -4              /* descrement loop */
 139 #endif
 140         /* We have to turn on the MMU right away. */
 141
 142         /*
 143          * Set up the initial MMU state so we can do the first level of
 144          * kernel initialization.  This maps the first 16 MBytes of memory 1:1
 145          * virtual to physical.
 146          */
 147         nop
 148         addik   r3, r0, MICROBLAZE_TLB_SIZE -1  /* Invalidate all TLB entries */
 149 _invalidate:
 150         mts     rtlbx, r3
 151         mts     rtlbhi, r0                      /* flush: ensure V is clear   */
 152         bgtid   r3, _invalidate         /* loop for all entries       */
 153         addik   r3, r3, -1
 154         /* sync */
 155
 156         /* Setup the kernel PID */
 157         mts     rpid,r0                 /* Load the kernel PID */
 158         nop
 159         bri     4
 160
 161         /*
 162          * We should still be executing code at physical address area
 163          * RAM_BASEADDR at this point. However, kernel code is at
 164          * a virtual address. So, set up a TLB mapping to cover this once
 165          * translation is enabled.
 166          */
 167
 168         addik   r3,r0, CONFIG_KERNEL_START /* Load the kernel virtual address */
 169         tophys(r4,r3)                   /* Load the kernel physical address */
 170
 171         /*
 172          * Configure and load two entries into TLB slots 0 and 1.
 173          * In case we are pinning TLBs, these are reserved in by the
 174          * other TLB functions.  If not reserving, then it doesn't
 175          * matter where they are loaded.
 176          */
 177         andi    r4,r4,0xfffffc00        /* Mask off the real page number */
 178         ori     r4,r4,(TLB_WR | TLB_EX) /* Set the write and execute bits */
 179
 180         andi    r3,r3,0xfffffc00        /* Mask off the effective page number */
 181         ori     r3,r3,(TLB_VALID | TLB_PAGESZ(PAGESZ_16M))
 182
 183         mts     rtlbx,r0                /* TLB slow 0 */
 184
 185         mts     rtlblo,r4               /* Load the data portion of the entry */
 186         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 187
 188         addik   r4, r4, 0x01000000      /* Map next 16 M entries */
 189         addik   r3, r3, 0x01000000
 190
 191         ori     r6,r0,1                 /* TLB slot 1 */
 192         mts     rtlbx,r6
 193
 194         mts     rtlblo,r4               /* Load the data portion of the entry */
 195         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 196
 197         /*
 198          * Load a TLB entry for LMB, since we need access to
 199          * the exception vectors, using a 4k real==virtual mapping.
 200          */
 201         ori     r6,r0,3                 /* TLB slot 3 */
 202         mts     rtlbx,r6
 203
 204         ori     r4,r0,(TLB_WR | TLB_EX)
 205         ori     r3,r0,(TLB_VALID | TLB_PAGESZ(PAGESZ_4K))
 206
 207         mts     rtlblo,r4               /* Load the data portion of the entry */
 208         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 209
 210         /*
 211          * We now have the lower 16 Meg of RAM mapped into TLB entries, and the
 212          * caches ready to work.
 213          */
 214 turn_on_mmu:
 215         ori     r15,r0,start_here
 216         ori     r4,r0,MSR_KERNEL_VMS
 217         mts     rmsr,r4
 218         nop
 219         rted    r15,0                   /* enables MMU */
 220         nop
 221
 222 start_here:
 223 #endif /* CONFIG_MMU */
 224
 225         /* Initialize small data anchors */
 226         la      r13, r0, _KERNEL_SDA_BASE_
 227         la      r2, r0, _KERNEL_SDA2_BASE_
 228
 229         /* Initialize stack pointer */
 230         la      r1, r0, init_thread_union + THREAD_SIZE - 4
 231
 232         /* Initialize r31 with current task address */
 233         la      r31, r0, init_task
 234
 235         /*
 236          * Call platform dependent initialize function.
 237          * Please see $(ARCH)/mach-$(SUBARCH)/setup.c for
 238          * the function.
 239          */
 240         la      r9, r0, machine_early_init
 241         brald   r15, r9
 242         nop
 243
 244 #ifndef CONFIG_MMU
 245         la      r15, r0, machine_halt
 246         braid   start_kernel
 247         nop
 248 #else
 249         /*
 250          * Initialize the MMU.
 251          */
 252         bralid  r15, mmu_init
 253         nop
 254
 255         /* Go back to running unmapped so we can load up new values
 256          * and change to using our exception vectors.
 257          * On the MicroBlaze, all we invalidate the used TLB entries to clear
 258          * the old 16M byte TLB mappings.
 259          */
 260         ori     r15,r0,TOPHYS(kernel_load_context)
 261         ori     r4,r0,MSR_KERNEL
 262         mts     rmsr,r4
 263         nop
 264         bri     4
 265         rted    r15,0
 266         nop
 267
 268         /* Load up the kernel context */
 269 kernel_load_context:
 270         # Keep entry 0 and 1 valid. Entry 3 mapped to LMB can go away.
 271         ori     r5,r0,3
 272         mts     rtlbx,r5
 273         nop
 274         mts     rtlbhi,r0
 275         nop
 276         addi    r15, r0, machine_halt
 277         ori     r17, r0, start_kernel
 278         ori     r4, r0, MSR_KERNEL_VMS
 279         mts     rmsr, r4
 280         nop
 281         rted    r17, 0          /* enable MMU and jump to start_kernel */
 282         nop
 283 #endif /* CONFIG_MMU */