arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .text.head : {
  27                 _stext = .;
  28                 _sinittext = .;
  29                 *(.text.head)
  30         }
  31
  32         .init : {                       /* Init code and data           */
  33                         INIT_TEXT
  34                 _einittext = .;
  35                 __proc_info_begin = .;
  36                         *(.proc.info.init)
  37                 __proc_info_end = .;
  38                 __arch_info_begin = .;
  39                         *(.arch.info.init)
  40                 __arch_info_end = .;
  41                 __tagtable_begin = .;
  42                         *(.taglist.init)
  43                 __tagtable_end = .;
  44                 . = ALIGN(16);
  45                 __setup_start = .;
  46                         *(.init.setup)
  47                 __setup_end = .;
  48                 __early_begin = .;
  49                         *(.early_param.init)
  50                 __early_end = .;
  51                 __initcall_start = .;
  52                         INITCALLS
  53                 __initcall_end = .;
  54                 __con_initcall_start = .;
  55                         *(.con_initcall.init)
  56                 __con_initcall_end = .;
  57                 __security_initcall_start = .;
  58                         *(.security_initcall.init)
  59                 __security_initcall_end = .;
  60 #ifdef CONFIG_BLK_DEV_INITRD
  61                 . = ALIGN(32);
  62                 __initramfs_start = .;
  63                         usr/built-in.o(.init.ramfs)
  64                 __initramfs_end = .;
  65 #endif
  66                 . = ALIGN(4096);
  67                 __per_cpu_load = .;
  68                 __per_cpu_start = .;
  69                         *(.data.percpu.page_aligned)
  70                         *(.data.percpu)
  71                         *(.data.percpu.shared_aligned)
  72                 __per_cpu_end = .;
  73 #ifndef CONFIG_XIP_KERNEL
  74                 __init_begin = _stext;
  75                 INIT_DATA
  76                 . = ALIGN(4096);
  77                 __init_end = .;
  78 #endif
  79         }
  80
  81         /DISCARD/ : {                   /* Exit code and data           */
  82                 EXIT_TEXT
  83                 EXIT_DATA
  84                 *(.exitcall.exit)
  85                 *(.ARM.exidx.exit.text)
  86                 *(.ARM.extab.exit.text)
  87 #ifndef CONFIG_HOTPLUG_CPU
  88                 *(.ARM.exidx.cpuexit.text)
  89                 *(.ARM.extab.cpuexit.text)
  90 #endif
  91 #ifndef CONFIG_HOTPLUG
  92                 *(.ARM.exidx.devexit.text)
  93                 *(.ARM.extab.devexit.text)
  94 #endif
  95 #ifndef CONFIG_MMU
  96                 *(.fixup)
  97                 *(__ex_table)
  98 #endif
  99         }
 100
 101         .text : {                       /* Real text segment            */
 102                 _text = .;              /* Text and read-only data      */
 103                         __exception_text_start = .;
 104                         *(.exception.text)
 105                         __exception_text_end = .;
 106                         TEXT_TEXT
 107                         SCHED_TEXT
 108                         LOCK_TEXT
 109                         KPROBES_TEXT
 110 #ifdef CONFIG_MMU
 111                         *(.fixup)
 112 #endif
 113                         *(.gnu.warning)
 114                         *(.rodata)
 115                         *(.rodata.*)
 116                         *(.glue_7)
 117                         *(.glue_7t)
 118                 *(.got)                 /* Global offset table          */
 119         }
 120
 121         RODATA
 122
 123         _etext = .;                     /* End of text and rodata section */
 124
 125 #ifdef CONFIG_ARM_UNWIND
 126         /*
 127          * Stack unwinding tables
 128          */
 129         . = ALIGN(8);
 130         .ARM.unwind_idx : {
 131                 __start_unwind_idx = .;
 132                 *(.ARM.exidx*)
 133                 __stop_unwind_idx = .;
 134         }
 135         .ARM.unwind_tab : {
 136                 __start_unwind_tab = .;
 137                 *(.ARM.extab*)
 138                 __stop_unwind_tab = .;
 139         }
 140 #endif
 141
 142 #ifdef CONFIG_XIP_KERNEL
 143         __data_loc = ALIGN(4);          /* location in binary */
 144         . = PAGE_OFFSET + TEXT_OFFSET;
 145 #else
 146         . = ALIGN(THREAD_SIZE);
 147         __data_loc = .;
 148 #endif
 149
 150         .data : AT(__data_loc) {
 151                 _data = .;              /* address in memory */
 152                 _sdata = .;
 153
 154                 /*
 155                  * first, the init task union, aligned
 156                  * to an 8192 byte boundary.
 157                  */
 158                 *(.data.init_task)
 159
 160 #ifdef CONFIG_XIP_KERNEL
 161                 . = ALIGN(4096);
 162                 __init_begin = .;
 163                 INIT_DATA
 164                 . = ALIGN(4096);
 165                 __init_end = .;
 166 #endif
 167
 168                 . = ALIGN(4096);
 169                 __nosave_begin = .;
 170                 *(.data.nosave)
 171                 . = ALIGN(4096);
 172                 __nosave_end = .;
 173
 174                 /*
 175                  * then the cacheline aligned data
 176                  */
 177                 . = ALIGN(32);
 178                 *(.data.cacheline_aligned)
 179
 180                 /*
 181                  * The exception fixup table (might need resorting at runtime)
 182                  */
 183                 . = ALIGN(32);
 184                 __start___ex_table = .;
 185 #ifdef CONFIG_MMU
 186                 *(__ex_table)
 187 #endif
 188                 __stop___ex_table = .;
 189
 190                 /*
 191                  * and the usual data section
 192                  */
 193                 DATA_DATA
 194                 CONSTRUCTORS
 195
 196                 _edata = .;
 197         }
 198         _edata_loc = __data_loc + SIZEOF(.data);
 199
 200         .bss : {
 201                 __bss_start = .;        /* BSS                          */
 202                 *(.bss)
 203                 *(COMMON)
 204                 __bss_stop = .;
 205                 _end = .;
 206         }
 207                                         /* Stabs debugging sections.    */
 208         .stab 0 : { *(.stab) }
 209         .stabstr 0 : { *(.stabstr) }
 210         .stab.excl 0 : { *(.stab.excl) }
 211         .stab.exclstr 0 : { *(.stab.exclstr) }
 212         .stab.index 0 : { *(.stab.index) }
 213         .stab.indexstr 0 : { *(.stab.indexstr) }
 214         .comment 0 : { *(.comment) }
 215 }
 216
 217 /*
 218  * These must never be empty
 219  * If you have to comment these two assert statements out, your
 220  * binutils is too old (for other reasons as well)
 221  */
 222 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 223 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")