recipes/qt4/qt4-tools-sdk.inc

   1 DESCRIPTION = "SDK tools for Qt/[X11|Mac|Embedded] version 4.x"
   2 DEPENDS = "zlib-native dbus-native"
   3 SECTION = "libs"
   4 HOMEPAGE = "http://www.trolltech.com"
   5 PRIORITY = "optional"
   6 LICENSE = "LGPLv2.1 GPLv3"
   7
   8 INC_PR = "r3"
   9
  10 FILESPATHPKG =. "qt-${PV}:"
  11 inherit sdk
  12
  13 SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-everywhere-opensource-src-${PV}.tar.gz \
  14            file://configure-lflags.patch \
  15            file://compile.test-lflags.patch \
  16            file://qt-config.patch \
  17            file://g++.conf \
  18            file://linux.conf"
  19
  20 S = "${WORKDIR}/qt-everywhere-opensource-src-${PV}"
  21
  22
  23 # FIXME: make it work with "${STAGING_BINDIR_NATIVE}/pkg-config --cflags dbus-1"
  24 EXTRA_OECONF = "-prefix ${prefix} \
  25                 -qt-libjpeg -qt-gif -system-zlib \
  26                 -no-libjpeg -no-libpng -no-libmng -no-libtiff \
  27                 -no-accessibility \
  28                 -no-cups \
  29                 -no-exceptions  \
  30                 -no-nas-sound \
  31                 -no-nis -no-openssl \
  32                 -verbose -release -fast -static \
  33                 -embedded -no-freetype -no-glib -no-iconv \
  34                 -qt3support \
  35                 -I${STAGING_DIR}/${HOST_SYS}${target_includedir} \
  36                 -I${STAGING_DIR}/${HOST_SYS}${target_includedir}/dbus-1.0 \
  37                 -I${STAGING_DIR}/${HOST_SYS}${target_libdir}/dbus-1.0/include"
  38
  39 # yank default -e, otherwise we get the following error:
  40 # moc_qbuffer.cpp: No such file or directory
  41 EXTRA_OEMAKE = " "
  42
  43 do_configure() {
  44    (echo o; echo yes) | ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
  45 }
  46
  47 TOBUILD = "\
  48   src/tools/bootstrap \
  49   src/tools/moc \
  50   src/corelib \
  51   src/sql \
  52   src/dbus \
  53   src/qt3support \
  54   src/xml \
  55   src/tools/uic \
  56   src/tools/rcc \
  57   src/network \
  58   src/gui \
  59   src/tools/uic3 \
  60   tools/linguist/lrelease \
  61   tools/linguist/lupdate \
  62   tools/qdbus \
  63 "
  64
  65 do_compile() {
  66     for i in ${TOBUILD}; do
  67         cd ${S}/$i && oe_runmake CC="${CC}" CXX="${CXX}"
  68     done
  69 }
  70
  71 do_install() {
  72     install -d ${D}${bindir}
  73     install -m 0755 bin/qmake ${D}${bindir}/qmake2
  74     for i in moc uic uic3 rcc lrelease lupdate qdbuscpp2xml qdbusxml2cpp; do
  75         install -m 0755 bin/${i} ${D}${bindir}/${i}4
  76     done
  77
  78         (cd ${D}${bindir}; \
  79         ln -s qmake2 qmake; \
  80         for i in moc uic uic3 rcc lrelease lupdate qdbuscpp2xml qdbusxml2cpp; do \
  81                 ln -s ${i}4 ${i}; \
  82         done)
  83
  84         # make a symbolic link to mkspecs for compatibility with Nokia's SDK
  85         # and QTCreator
  86         (cd ${D}${bindir}/..; ln -s ${TARGET_SYS}/usr/share/qtopia/mkspecs mkspecs;)
  87 }
  88