scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".sched.text" => 1,
 134      ".spinlock.text" => 1,
 135      ".irqentry.text" => 1,
 136      ".text.unlikely" => 1,
 137 );
 138
 139 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 140 $objdump = 'objdump' if (!$objdump);
 141 $objcopy = 'objcopy' if (!$objcopy);
 142 $cc = 'gcc' if (!$cc);
 143 $ld = 'ld' if (!$ld);
 144 $nm = 'nm' if (!$nm);
 145 $rm = 'rm' if (!$rm);
 146 $mv = 'mv' if (!$mv);
 147
 148 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 149 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 150
 151 my %locals;             # List of local (static) functions
 152 my %weak;               # List of weak functions
 153 my %convert;            # List of local functions used that needs conversion
 154
 155 my $type;
 156 my $local_regex;        # Match a local function (return function)
 157 my $weak_regex;         # Match a weak function (return function)
 158 my $section_regex;      # Find the start of a section
 159 my $function_regex;     # Find the name of a function
 160                         #    (return offset and func name)
 161 my $mcount_regex;       # Find the call site to mcount (return offset)
 162 my $mcount_adjust;      # Address adjustment to mcount offset
 163 my $alignment;          # The .align value to use for $mcount_section
 164 my $section_type;       # Section header plus possible alignment command
 165 my $can_use_local = 0;  # If we can use local function references
 166
 167 # Shut up recordmcount if user has older objcopy
 168 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 169 my $print_warning = 1;
 170 $print_warning = 0 if ( -f $quiet_recordmcount);
 171
 172 ##
 173 # check_objcopy - whether objcopy supports --globalize-symbols
 174 #
 175 #  --globalize-symbols came out in 2.17, we must test the version
 176 #  of objcopy, and if it is less than 2.17, then we can not
 177 #  record local functions.
 178 sub check_objcopy
 179 {
 180     open (IN, "$objcopy --version |") or die "error running $objcopy";
 181     while (<IN>) {
 182         if (/objcopy.*\s(\d+)\.(\d+)/) {
 183             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 184             last;
 185         }
 186     }
 187     close (IN);
 188
 189     if (!$can_use_local && $print_warning) {
 190         print STDERR "WARNING: could not find objcopy version or version " .
 191             "is less than 2.17.\n" .
 192             "\tLocal function references are disabled.\n";
 193         open (QUIET, ">$quiet_recordmcount");
 194         printf QUIET "Disables the warning from recordmcount.pl\n";
 195         close QUIET;
 196     }
 197 }
 198
 199 if ($arch =~ /(x86(_64)?)|(i386)/) {
 200     if ($bits == 64) {
 201         $arch = "x86_64";
 202     } else {
 203         $arch = "i386";
 204     }
 205 }
 206
 207 #
 208 # We base the defaults off of i386, the other archs may
 209 # feel free to change them in the below if statements.
 210 #
 211 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 212 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 213 $section_regex = "Disassembly of section\\s+(\\S+):";
 214 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 215 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 216 $section_type = '@progbits';
 217 $mcount_adjust = 0;
 218 $type = ".long";
 219
 220 if ($arch eq "x86_64") {
 221     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 222     $type = ".quad";
 223     $alignment = 8;
 224
 225     # force flags for this arch
 226     $ld .= " -m elf_x86_64";
 227     $objdump .= " -M x86-64";
 228     $objcopy .= " -O elf64-x86-64";
 229     $cc .= " -m64";
 230
 231 } elsif ($arch eq "i386") {
 232     $alignment = 4;
 233
 234     # force flags for this arch
 235     $ld .= " -m elf_i386";
 236     $objdump .= " -M i386";
 237     $objcopy .= " -O elf32-i386";
 238     $cc .= " -m32";
 239
 240 } elsif ($arch eq "s390" && $bits == 32) {
 241     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
 242     $alignment = 4;
 243     $ld .= " -m elf_s390";
 244     $cc .= " -m31";
 245
 246 } elsif ($arch eq "s390" && $bits == 64) {
 247     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 248     $alignment = 8;
 249     $type = ".quad";
 250     $ld .= " -m elf64_s390";
 251     $cc .= " -m64";
 252
 253 } elsif ($arch eq "sh") {
 254     $alignment = 2;
 255
 256     # force flags for this arch
 257     $ld .= " -m shlelf_linux";
 258     $objcopy .= " -O elf32-sh-linux";
 259     $cc .= " -m32";
 260
 261 } elsif ($arch eq "powerpc") {
 262     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 263     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 264     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 265
 266     if ($bits == 64) {
 267         $type = ".quad";
 268     }
 269
 270 } elsif ($arch eq "arm") {
 271     $alignment = 2;
 272     $section_type = '%progbits';
 273
 274 } elsif ($arch eq "ia64") {
 275     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 276     $type = "data8";
 277
 278     if ($is_module eq "0") {
 279         $cc .= " -mconstant-gp";
 280     }
 281 } elsif ($arch eq "sparc64") {
 282     # In the objdump output there are giblets like:
 283     # 0000000000000000 <igmp_net_exit-0x18>:
 284     # As there's some data blobs that get emitted into the
 285     # text section before the first instructions and the first
 286     # real symbols.  We don't want to match that, so to combat
 287     # this we use '\w' so we'll match just plain symbol names,
 288     # and not those that also include hex offsets inside of the
 289     # '<>' brackets.  Actually the generic function_regex setting
 290     # could safely use this too.
 291     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 292
 293     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 294     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 295
 296     $alignment = 8;
 297     $type = ".xword";
 298     $ld .= " -m elf64_sparc";
 299     $cc .= " -m64";
 300     $objcopy .= " -O elf64-sparc";
 301 } elsif ($arch eq "mips") {
 302     # To enable module support, we need to enable the -mlong-calls option
 303     # of gcc for module, after using this option, we can not get the real
 304     # offset of the calling to _mcount, but the offset of the lui
 305     # instruction or the addiu one. herein, we record the address of the
 306     # first one, and then we can replace this instruction by a branch
 307     # instruction to jump over the profiling function to filter the
 308     # indicated functions, or swith back to the lui instruction to trace
 309     # them, which means dynamic tracing.
 310     #
 311     #       c:  3c030000        lui     v1,0x0
 312     #                   c: R_MIPS_HI16  _mcount
 313     #                   c: R_MIPS_NONE  *ABS*
 314     #                   c: R_MIPS_NONE  *ABS*
 315     #      10:  64630000        daddiu  v1,v1,0
 316     #                   10: R_MIPS_LO16 _mcount
 317     #                   10: R_MIPS_NONE *ABS*
 318     #                   10: R_MIPS_NONE *ABS*
 319     #      14:  03e0082d        move    at,ra
 320     #      18:  0060f809        jalr    v1
 321     #
 322     # for the kernel:
 323     #
 324     #     10:   03e0082d        move    at,ra
 325     #     14:   0c000000        jal     0 <loongson_halt>
 326     #                    14: R_MIPS_26   _mcount
 327     #                    14: R_MIPS_NONE *ABS*
 328     #                    14: R_MIPS_NONE *ABS*
 329     #    18:   00020021        nop
 330     if ($is_module eq "0") {
 331             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 332     } else {
 333             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 334     }
 335     $objdump .= " -Melf-trad".$endian."mips ";
 336
 337     if ($endian eq "big") {
 338             $endian = " -EB ";
 339             $ld .= " -melf".$bits."btsmip";
 340     } else {
 341             $endian = " -EL ";
 342             $ld .= " -melf".$bits."ltsmip";
 343     }
 344
 345     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 346     $ld .= $endian;
 347
 348     if ($bits == 64) {
 349             $function_regex =
 350                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 351             $type = ".dword";
 352     }
 353 } elsif ($arch eq "microblaze") {
 354     # Microblaze calls '_mcount' instead of plain 'mcount'.
 355     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 356 } elsif ($arch eq "blackfin") {
 357     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 358     $mcount_adjust = -4;
 359 } else {
 360     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 361 }
 362
 363 my $text_found = 0;
 364 my $read_function = 0;
 365 my $opened = 0;
 366 my $mcount_section = "__mcount_loc";
 367
 368 my $dirname;
 369 my $filename;
 370 my $prefix;
 371 my $ext;
 372
 373 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 374     $dirname = $1;
 375     $filename = $2;
 376 } else {
 377     $dirname = ".";
 378     $filename = $inputfile;
 379 }
 380
 381 if ($filename =~ m,^(.*)(\.\S),) {
 382     $prefix = $1;
 383     $ext = $2;
 384 } else {
 385     $prefix = $filename;
 386     $ext = "";
 387 }
 388
 389 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 390 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 391
 392 check_objcopy();
 393
 394 #
 395 # Step 1: find all the local (static functions) and weak symbols.
 396 #         't' is local, 'w/W' is weak
 397 #
 398 open (IN, "$nm $inputfile|") || die "error running $nm";
 399 while (<IN>) {
 400     if (/$local_regex/) {
 401         $locals{$1} = 1;
 402     } elsif (/$weak_regex/) {
 403         $weak{$2} = $1;
 404     }
 405 }
 406 close(IN);
 407
 408 my @offsets;            # Array of offsets of mcount callers
 409 my $ref_func;           # reference function to use for offsets
 410 my $offset = 0;         # offset of ref_func to section beginning
 411
 412 ##
 413 # update_funcs - print out the current mcount callers
 414 #
 415 #  Go through the list of offsets to callers and write them to
 416 #  the output file in a format that can be read by an assembler.
 417 #
 418 sub update_funcs
 419 {
 420     return unless ($ref_func and @offsets);
 421
 422     # Sanity check on weak function. A weak function may be overwritten by
 423     # another function of the same name, making all these offsets incorrect.
 424     if (defined $weak{$ref_func}) {
 425         die "$inputfile: ERROR: referencing weak function" .
 426             " $ref_func for mcount\n";
 427     }
 428
 429     # is this function static? If so, note this fact.
 430     if (defined $locals{$ref_func}) {
 431
 432         # only use locals if objcopy supports globalize-symbols
 433         if (!$can_use_local) {
 434             return;
 435         }
 436         $convert{$ref_func} = 1;
 437     }
 438
 439     # Loop through all the mcount caller offsets and print a reference
 440     # to the caller based from the ref_func.
 441     if (!$opened) {
 442         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 443         $opened = 1;
 444         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 445         print FILE "\t.align $alignment\n" if (defined($alignment));
 446     }
 447     foreach my $cur_offset (@offsets) {
 448         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 449     }
 450 }
 451
 452 #
 453 # Step 2: find the sections and mcount call sites
 454 #
 455 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 456
 457 my $text;
 458
 459
 460 # read headers first
 461 my $read_headers = 1;
 462
 463 while (<IN>) {
 464
 465     if ($read_headers && /$mcount_section/) {
 466         #
 467         # Somehow the make process can execute this script on an
 468         # object twice. If it does, we would duplicate the mcount
 469         # section and it will cause the function tracer self test
 470         # to fail. Check if the mcount section exists, and if it does,
 471         # warn and exit.
 472         #
 473         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 474             "\tThis may be an indication that your build is corrupted.\n" .
 475             "\tDelete $inputfile and try again. If the same object file\n" .
 476             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 477         exit(-1);
 478     }
 479
 480     # is it a section?
 481     if (/$section_regex/) {
 482         $read_headers = 0;
 483
 484         # Only record text sections that we know are safe
 485         $read_function = defined($text_sections{$1});
 486         # print out any recorded offsets
 487         update_funcs();
 488
 489         # reset all markers and arrays
 490         $text_found = 0;
 491         undef($ref_func);
 492         undef(@offsets);
 493
 494     # section found, now is this a start of a function?
 495     } elsif ($read_function && /$function_regex/) {
 496         $text_found = 1;
 497         $text = $2;
 498
 499         # if this is either a local function or a weak function
 500         # keep looking for functions that are global that
 501         # we can use safely.
 502         if (!defined($locals{$text}) && !defined($weak{$text})) {
 503             $ref_func = $text;
 504             $read_function = 0;
 505             $offset = hex $1;
 506         } else {
 507             # if we already have a function, and this is weak, skip it
 508             if (!defined($ref_func) && !defined($weak{$text}) &&
 509                  # PPC64 can have symbols that start with .L and
 510                  # gcc considers these special. Don't use them!
 511                  $text !~ /^\.L/) {
 512                 $ref_func = $text;
 513                 $offset = hex $1;
 514             }
 515         }
 516     }
 517     # is this a call site to mcount? If so, record it to print later
 518     if ($text_found && /$mcount_regex/) {
 519         push(@offsets, (hex $1) + $mcount_adjust);
 520     }
 521 }
 522
 523 # dump out anymore offsets that may have been found
 524 update_funcs();
 525
 526 # If we did not find any mcount callers, we are done (do nothing).
 527 if (!$opened) {
 528     exit(0);
 529 }
 530
 531 close(FILE);
 532
 533 #
 534 # Step 3: Compile the file that holds the list of call sites to mcount.
 535 #
 536 `$cc -o $mcount_o -c $mcount_s`;
 537
 538 my @converts = keys %convert;
 539
 540 #
 541 # Step 4: Do we have sections that started with local functions?
 542 #
 543 if ($#converts >= 0) {
 544     my $globallist = "";
 545     my $locallist = "";
 546
 547     foreach my $con (@converts) {
 548         $globallist .= " --globalize-symbol $con";
 549         $locallist .= " --localize-symbol $con";
 550     }
 551
 552     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 553     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 554
 555     #
 556     # Step 5: set up each local function as a global
 557     #
 558     `$objcopy $globallist $inputfile $globalobj`;
 559
 560     #
 561     # Step 6: Link the global version to our list.
 562     #
 563     `$ld -r $globalobj $mcount_o -o $globalmix`;
 564
 565     #
 566     # Step 7: Convert the local functions back into local symbols
 567     #
 568     `$objcopy $locallist $globalmix $inputfile`;
 569
 570     # Remove the temp files
 571     `$rm $globalobj $globalmix`;
 572
 573 } else {
 574
 575     my $mix = $dirname . "/.tmp_mx_" . $filename;
 576
 577     #
 578     # Step 8: Link the object with our list of call sites object.
 579     #
 580     `$ld -r $inputfile $mcount_o -o $mix`;
 581
 582     #
 583     # Step 9: Move the result back to the original object.
 584     #
 585     `$mv $mix $inputfile`;
 586 }
 587
 588 # Clean up the temp files
 589 `$rm $mcount_o $mcount_s`;
 590
 591 exit(0);