scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".ref.text" => 1,
 134      ".sched.text" => 1,
 135      ".spinlock.text" => 1,
 136      ".irqentry.text" => 1,
 137      ".kprobes.text" => 1,
 138      ".text.unlikely" => 1,
 139 );
 140
 141 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 142 $objdump = 'objdump' if (!$objdump);
 143 $objcopy = 'objcopy' if (!$objcopy);
 144 $cc = 'gcc' if (!$cc);
 145 $ld = 'ld' if (!$ld);
 146 $nm = 'nm' if (!$nm);
 147 $rm = 'rm' if (!$rm);
 148 $mv = 'mv' if (!$mv);
 149
 150 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 151 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 152
 153 my %locals;             # List of local (static) functions
 154 my %weak;               # List of weak functions
 155 my %convert;            # List of local functions used that needs conversion
 156
 157 my $type;
 158 my $local_regex;        # Match a local function (return function)
 159 my $weak_regex;         # Match a weak function (return function)
 160 my $section_regex;      # Find the start of a section
 161 my $function_regex;     # Find the name of a function
 162                         #    (return offset and func name)
 163 my $mcount_regex;       # Find the call site to mcount (return offset)
 164 my $mcount_adjust;      # Address adjustment to mcount offset
 165 my $alignment;          # The .align value to use for $mcount_section
 166 my $section_type;       # Section header plus possible alignment command
 167 my $can_use_local = 0;  # If we can use local function references
 168
 169 # Shut up recordmcount if user has older objcopy
 170 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 171 my $print_warning = 1;
 172 $print_warning = 0 if ( -f $quiet_recordmcount);
 173
 174 ##
 175 # check_objcopy - whether objcopy supports --globalize-symbols
 176 #
 177 #  --globalize-symbols came out in 2.17, we must test the version
 178 #  of objcopy, and if it is less than 2.17, then we can not
 179 #  record local functions.
 180 sub check_objcopy
 181 {
 182     open (IN, "$objcopy --version |") or die "error running $objcopy";
 183     while (<IN>) {
 184         if (/objcopy.*\s(\d+)\.(\d+)/) {
 185             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 186             last;
 187         }
 188     }
 189     close (IN);
 190
 191     if (!$can_use_local && $print_warning) {
 192         print STDERR "WARNING: could not find objcopy version or version " .
 193             "is less than 2.17.\n" .
 194             "\tLocal function references are disabled.\n";
 195         open (QUIET, ">$quiet_recordmcount");
 196         printf QUIET "Disables the warning from recordmcount.pl\n";
 197         close QUIET;
 198     }
 199 }
 200
 201 if ($arch =~ /(x86(_64)?)|(i386)/) {
 202     if ($bits == 64) {
 203         $arch = "x86_64";
 204     } else {
 205         $arch = "i386";
 206     }
 207 }
 208
 209 #
 210 # We base the defaults off of i386, the other archs may
 211 # feel free to change them in the below if statements.
 212 #
 213 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 214 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 215 $section_regex = "Disassembly of section\\s+(\\S+):";
 216 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 217 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 218 $section_type = '@progbits';
 219 $mcount_adjust = 0;
 220 $type = ".long";
 221
 222 if ($arch eq "x86_64") {
 223     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 224     $type = ".quad";
 225     $alignment = 8;
 226     $mcount_adjust = -1;
 227
 228     # force flags for this arch
 229     $ld .= " -m elf_x86_64";
 230     $objdump .= " -M x86-64";
 231     $objcopy .= " -O elf64-x86-64";
 232     $cc .= " -m64";
 233
 234 } elsif ($arch eq "i386") {
 235     $alignment = 4;
 236     $mcount_adjust = -1;
 237
 238     # force flags for this arch
 239     $ld .= " -m elf_i386";
 240     $objdump .= " -M i386";
 241     $objcopy .= " -O elf32-i386";
 242     $cc .= " -m32";
 243
 244 } elsif ($arch eq "s390" && $bits == 32) {
 245     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
 246     $mcount_adjust = -4;
 247     $alignment = 4;
 248     $ld .= " -m elf_s390";
 249     $cc .= " -m31";
 250
 251 } elsif ($arch eq "s390" && $bits == 64) {
 252     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 253     $mcount_adjust = -8;
 254     $alignment = 8;
 255     $type = ".quad";
 256     $ld .= " -m elf64_s390";
 257     $cc .= " -m64";
 258
 259 } elsif ($arch eq "sh") {
 260     $alignment = 2;
 261
 262     # force flags for this arch
 263     $ld .= " -m shlelf_linux";
 264     $objcopy .= " -O elf32-sh-linux";
 265
 266 } elsif ($arch eq "powerpc") {
 267     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 268     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 269     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 270
 271     if ($bits == 64) {
 272         $type = ".quad";
 273     }
 274
 275 } elsif ($arch eq "arm") {
 276     $alignment = 2;
 277     $section_type = '%progbits';
 278     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 279                         "\\s+(__gnu_mcount_nc|mcount)\$";
 280
 281 } elsif ($arch eq "ia64") {
 282     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 283     $type = "data8";
 284
 285     if ($is_module eq "0") {
 286         $cc .= " -mconstant-gp";
 287     }
 288 } elsif ($arch eq "sparc64") {
 289     # In the objdump output there are giblets like:
 290     # 0000000000000000 <igmp_net_exit-0x18>:
 291     # As there's some data blobs that get emitted into the
 292     # text section before the first instructions and the first
 293     # real symbols.  We don't want to match that, so to combat
 294     # this we use '\w' so we'll match just plain symbol names,
 295     # and not those that also include hex offsets inside of the
 296     # '<>' brackets.  Actually the generic function_regex setting
 297     # could safely use this too.
 298     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 299
 300     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 301     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 302
 303     $alignment = 8;
 304     $type = ".xword";
 305     $ld .= " -m elf64_sparc";
 306     $cc .= " -m64";
 307     $objcopy .= " -O elf64-sparc";
 308 } elsif ($arch eq "mips") {
 309     # To enable module support, we need to enable the -mlong-calls option
 310     # of gcc for module, after using this option, we can not get the real
 311     # offset of the calling to _mcount, but the offset of the lui
 312     # instruction or the addiu one. herein, we record the address of the
 313     # first one, and then we can replace this instruction by a branch
 314     # instruction to jump over the profiling function to filter the
 315     # indicated functions, or swith back to the lui instruction to trace
 316     # them, which means dynamic tracing.
 317     #
 318     #       c:  3c030000        lui     v1,0x0
 319     #                   c: R_MIPS_HI16  _mcount
 320     #                   c: R_MIPS_NONE  *ABS*
 321     #                   c: R_MIPS_NONE  *ABS*
 322     #      10:  64630000        daddiu  v1,v1,0
 323     #                   10: R_MIPS_LO16 _mcount
 324     #                   10: R_MIPS_NONE *ABS*
 325     #                   10: R_MIPS_NONE *ABS*
 326     #      14:  03e0082d        move    at,ra
 327     #      18:  0060f809        jalr    v1
 328     #
 329     # for the kernel:
 330     #
 331     #     10:   03e0082d        move    at,ra
 332     #     14:   0c000000        jal     0 <loongson_halt>
 333     #                    14: R_MIPS_26   _mcount
 334     #                    14: R_MIPS_NONE *ABS*
 335     #                    14: R_MIPS_NONE *ABS*
 336     #    18:   00020021        nop
 337     if ($is_module eq "0") {
 338             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 339     } else {
 340             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 341     }
 342     $objdump .= " -Melf-trad".$endian."mips ";
 343
 344     if ($endian eq "big") {
 345             $endian = " -EB ";
 346             $ld .= " -melf".$bits."btsmip";
 347     } else {
 348             $endian = " -EL ";
 349             $ld .= " -melf".$bits."ltsmip";
 350     }
 351
 352     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 353     $ld .= $endian;
 354
 355     if ($bits == 64) {
 356             $function_regex =
 357                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 358             $type = ".dword";
 359     }
 360 } elsif ($arch eq "microblaze") {
 361     # Microblaze calls '_mcount' instead of plain 'mcount'.
 362     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 363 } elsif ($arch eq "blackfin") {
 364     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 365     $mcount_adjust = -4;
 366 } else {
 367     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 368 }
 369
 370 my $text_found = 0;
 371 my $read_function = 0;
 372 my $opened = 0;
 373 my $mcount_section = "__mcount_loc";
 374
 375 my $dirname;
 376 my $filename;
 377 my $prefix;
 378 my $ext;
 379
 380 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 381     $dirname = $1;
 382     $filename = $2;
 383 } else {
 384     $dirname = ".";
 385     $filename = $inputfile;
 386 }
 387
 388 if ($filename =~ m,^(.*)(\.\S),) {
 389     $prefix = $1;
 390     $ext = $2;
 391 } else {
 392     $prefix = $filename;
 393     $ext = "";
 394 }
 395
 396 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 397 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 398
 399 check_objcopy();
 400
 401 #
 402 # Step 1: find all the local (static functions) and weak symbols.
 403 #         't' is local, 'w/W' is weak
 404 #
 405 open (IN, "$nm $inputfile|") || die "error running $nm";
 406 while (<IN>) {
 407     if (/$local_regex/) {
 408         $locals{$1} = 1;
 409     } elsif (/$weak_regex/) {
 410         $weak{$2} = $1;
 411     }
 412 }
 413 close(IN);
 414
 415 my @offsets;            # Array of offsets of mcount callers
 416 my $ref_func;           # reference function to use for offsets
 417 my $offset = 0;         # offset of ref_func to section beginning
 418
 419 ##
 420 # update_funcs - print out the current mcount callers
 421 #
 422 #  Go through the list of offsets to callers and write them to
 423 #  the output file in a format that can be read by an assembler.
 424 #
 425 sub update_funcs
 426 {
 427     return unless ($ref_func and @offsets);
 428
 429     # Sanity check on weak function. A weak function may be overwritten by
 430     # another function of the same name, making all these offsets incorrect.
 431     if (defined $weak{$ref_func}) {
 432         die "$inputfile: ERROR: referencing weak function" .
 433             " $ref_func for mcount\n";
 434     }
 435
 436     # is this function static? If so, note this fact.
 437     if (defined $locals{$ref_func}) {
 438
 439         # only use locals if objcopy supports globalize-symbols
 440         if (!$can_use_local) {
 441             return;
 442         }
 443         $convert{$ref_func} = 1;
 444     }
 445
 446     # Loop through all the mcount caller offsets and print a reference
 447     # to the caller based from the ref_func.
 448     if (!$opened) {
 449         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 450         $opened = 1;
 451         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 452         print FILE "\t.align $alignment\n" if (defined($alignment));
 453     }
 454     foreach my $cur_offset (@offsets) {
 455         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 456     }
 457 }
 458
 459 #
 460 # Step 2: find the sections and mcount call sites
 461 #
 462 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 463
 464 my $text;
 465
 466
 467 # read headers first
 468 my $read_headers = 1;
 469
 470 while (<IN>) {
 471
 472     if ($read_headers && /$mcount_section/) {
 473         #
 474         # Somehow the make process can execute this script on an
 475         # object twice. If it does, we would duplicate the mcount
 476         # section and it will cause the function tracer self test
 477         # to fail. Check if the mcount section exists, and if it does,
 478         # warn and exit.
 479         #
 480         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 481             "\tThis may be an indication that your build is corrupted.\n" .
 482             "\tDelete $inputfile and try again. If the same object file\n" .
 483             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 484         exit(-1);
 485     }
 486
 487     # is it a section?
 488     if (/$section_regex/) {
 489         $read_headers = 0;
 490
 491         # Only record text sections that we know are safe
 492         $read_function = defined($text_sections{$1});
 493         # print out any recorded offsets
 494         update_funcs();
 495
 496         # reset all markers and arrays
 497         $text_found = 0;
 498         undef($ref_func);
 499         undef(@offsets);
 500
 501     # section found, now is this a start of a function?
 502     } elsif ($read_function && /$function_regex/) {
 503         $text_found = 1;
 504         $text = $2;
 505
 506         # if this is either a local function or a weak function
 507         # keep looking for functions that are global that
 508         # we can use safely.
 509         if (!defined($locals{$text}) && !defined($weak{$text})) {
 510             $ref_func = $text;
 511             $read_function = 0;
 512             $offset = hex $1;
 513         } else {
 514             # if we already have a function, and this is weak, skip it
 515             if (!defined($ref_func) && !defined($weak{$text}) &&
 516                  # PPC64 can have symbols that start with .L and
 517                  # gcc considers these special. Don't use them!
 518                  $text !~ /^\.L/) {
 519                 $ref_func = $text;
 520                 $offset = hex $1;
 521             }
 522         }
 523     }
 524     # is this a call site to mcount? If so, record it to print later
 525     if ($text_found && /$mcount_regex/) {
 526         push(@offsets, (hex $1) + $mcount_adjust);
 527     }
 528 }
 529
 530 # dump out anymore offsets that may have been found
 531 update_funcs();
 532
 533 # If we did not find any mcount callers, we are done (do nothing).
 534 if (!$opened) {
 535     exit(0);
 536 }
 537
 538 close(FILE);
 539
 540 #
 541 # Step 3: Compile the file that holds the list of call sites to mcount.
 542 #
 543 `$cc -o $mcount_o -c $mcount_s`;
 544
 545 my @converts = keys %convert;
 546
 547 #
 548 # Step 4: Do we have sections that started with local functions?
 549 #
 550 if ($#converts >= 0) {
 551     my $globallist = "";
 552     my $locallist = "";
 553
 554     foreach my $con (@converts) {
 555         $globallist .= " --globalize-symbol $con";
 556         $locallist .= " --localize-symbol $con";
 557     }
 558
 559     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 560     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 561
 562     #
 563     # Step 5: set up each local function as a global
 564     #
 565     `$objcopy $globallist $inputfile $globalobj`;
 566
 567     #
 568     # Step 6: Link the global version to our list.
 569     #
 570     `$ld -r $globalobj $mcount_o -o $globalmix`;
 571
 572     #
 573     # Step 7: Convert the local functions back into local symbols
 574     #
 575     `$objcopy $locallist $globalmix $inputfile`;
 576
 577     # Remove the temp files
 578     `$rm $globalobj $globalmix`;
 579
 580 } else {
 581
 582     my $mix = $dirname . "/.tmp_mx_" . $filename;
 583
 584     #
 585     # Step 8: Link the object with our list of call sites object.
 586     #
 587     `$ld -r $inputfile $mcount_o -o $mix`;
 588
 589     #
 590     # Step 9: Move the result back to the original object.
 591     #
 592     `$mv $mix $inputfile`;
 593 }
 594
 595 # Clean up the temp files
 596 `$rm $mcount_o $mcount_s`;
 597
 598 exit(0);