arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 #else
  38 OUTPUT_ARCH(i386:x86-64)
  39 ENTRY(phys_startup_64)
  40 #endif
  41
  42 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  43 /*
  44  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  45  * we retain large page mappings for boundaries spanning kernel text, rodata
  46  * and data sections.
  47  *
  48  * However, kernel identity mappings will have different RWX permissions
  49  * to the pages mapping to text and to the pages padding (which are freed) the
  50  * text section. Hence kernel identity mappings will be broken to smaller
  51  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  52  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  53  * as well as retain 2MB large page mappings for kernel text.
  54  */
  55 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  56
  57 #define X64_ALIGN_DEBUG_RODATA_END                              \
  58                 . = ALIGN(HPAGE_SIZE);                          \
  59                 __end_rodata_hpage_align = .;
  60
  61 #else
  62
  63 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  64 #define X64_ALIGN_DEBUG_RODATA_END
  65
  66 #endif
  67
  68 PHDRS {
  69         text PT_LOAD FLAGS(5);          /* R_E */
  70         data PT_LOAD FLAGS(6);          /* RW_ */
  71 #ifdef CONFIG_X86_64
  72         user PT_LOAD FLAGS(5);          /* R_E */
  73 #ifdef CONFIG_SMP
  74         percpu PT_LOAD FLAGS(6);        /* RW_ */
  75 #endif
  76         init PT_LOAD FLAGS(7);          /* RWE */
  77 #endif
  78         note PT_NOTE FLAGS(0);          /* ___ */
  79 }
  80
  81 SECTIONS
  82 {
  83 #ifdef CONFIG_X86_32
  84         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  85         phys_startup_32 = startup_32 - LOAD_OFFSET;
  86 #else
  87         . = __START_KERNEL;
  88         phys_startup_64 = startup_64 - LOAD_OFFSET;
  89 #endif
  90
  91         /* Text and read-only data */
  92         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  93                 _text = .;
  94                 /* bootstrapping code */
  95                 HEAD_TEXT
  96 #ifdef CONFIG_X86_32
  97                 . = ALIGN(PAGE_SIZE);
  98                 *(.text..page_aligned)
  99 #endif
 100                 . = ALIGN(8);
 101                 _stext = .;
 102                 TEXT_TEXT
 103                 SCHED_TEXT
 104                 LOCK_TEXT
 105                 KPROBES_TEXT
 106                 IRQENTRY_TEXT
 107                 *(.fixup)
 108                 *(.gnu.warning)
 109                 /* End of text section */
 110                 _etext = .;
 111         } :text = 0x9090
 112
 113         NOTES :text :note
 114
 115         EXCEPTION_TABLE(16) :text = 0x9090
 116
 117 #if defined(CONFIG_DEBUG_RODATA)
 118         /* .text should occupy whole number of pages */
 119         . = ALIGN(PAGE_SIZE);
 120 #endif
 121         X64_ALIGN_DEBUG_RODATA_BEGIN
 122         RO_DATA(PAGE_SIZE)
 123         X64_ALIGN_DEBUG_RODATA_END
 124
 125         /* Data */
 126         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 127                 /* Start of data section */
 128                 _sdata = .;
 129
 130                 /* init_task */
 131                 INIT_TASK_DATA(THREAD_SIZE)
 132
 133 #ifdef CONFIG_X86_32
 134                 /* 32 bit has nosave before _edata */
 135                 NOSAVE_DATA
 136 #endif
 137
 138                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 139
 140                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 141
 142                 DATA_DATA
 143                 /*
 144                  * Workaround a binutils (2.20.51.0.12 to 2.21.51.0.3) bug.
 145                  * This makes jiffies relocatable in such binutils
 146                  */
 147 #ifdef CONFIG_X86_32
 148                 jiffies = jiffies_64;
 149 #else
 150                 jiffies_64 = jiffies;
 151 #endif
 152                 CONSTRUCTORS
 153
 154                 /* rarely changed data like cpu maps */
 155                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 156
 157                 /* End of data section */
 158                 _edata = .;
 159         } :data
 160
 161 #ifdef CONFIG_X86_64
 162
 163 #define VSYSCALL_ADDR (-10*1024*1024)
 164
 165 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
 166 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
 167
 168 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
 169 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
 170
 171         . = ALIGN(4096);
 172         __vsyscall_0 = .;
 173
 174         . = VSYSCALL_ADDR;
 175         .vsyscall_0 : AT(VLOAD(.vsyscall_0)) {
 176                 *(.vsyscall_0)
 177         } :user
 178
 179         . = ALIGN(L1_CACHE_BYTES);
 180         .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) {
 181                 *(.vsyscall_fn)
 182         }
 183
 184         . = ALIGN(L1_CACHE_BYTES);
 185         .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data)) {
 186                 *(.vsyscall_gtod_data)
 187         }
 188
 189         vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
 190         .vsyscall_clock : AT(VLOAD(.vsyscall_clock)) {
 191                 *(.vsyscall_clock)
 192         }
 193         vsyscall_clock = VVIRT(.vsyscall_clock);
 194
 195
 196         .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) {
 197                 *(.vsyscall_1)
 198         }
 199         .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) {
 200                 *(.vsyscall_2)
 201         }
 202
 203         .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) {
 204                 *(.vgetcpu_mode)
 205         }
 206         vgetcpu_mode = VVIRT(.vgetcpu_mode);
 207
 208         . = ALIGN(L1_CACHE_BYTES);
 209         .jiffies : AT(VLOAD(.jiffies)) {
 210                 *(.jiffies)
 211         }
 212         jiffies = VVIRT(.jiffies);
 213
 214         .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) {
 215                 *(.vsyscall_3)
 216         }
 217
 218         . = __vsyscall_0 + PAGE_SIZE;
 219
 220 #undef VSYSCALL_ADDR
 221 #undef VLOAD_OFFSET
 222 #undef VLOAD
 223 #undef VVIRT_OFFSET
 224 #undef VVIRT
 225
 226 #endif /* CONFIG_X86_64 */
 227
 228         /* Init code and data - will be freed after init */
 229         . = ALIGN(PAGE_SIZE);
 230         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 231                 __init_begin = .; /* paired with __init_end */
 232         }
 233
 234 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 235         /*
 236          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 237          * output PHDR, so the next output section - .init.text - should
 238          * start another segment - init.
 239          */
 240         PERCPU_VADDR(0, :percpu)
 241 #endif
 242
 243         INIT_TEXT_SECTION(PAGE_SIZE)
 244 #ifdef CONFIG_X86_64
 245         :init
 246 #endif
 247
 248         INIT_DATA_SECTION(16)
 249
 250         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 251                 __x86_cpu_dev_start = .;
 252                 *(.x86_cpu_dev.init)
 253                 __x86_cpu_dev_end = .;
 254         }
 255
 256         /*
 257          * start address and size of operations which during runtime
 258          * can be patched with virtualization friendly instructions or
 259          * baremetal native ones. Think page table operations.
 260          * Details in paravirt_types.h
 261          */
 262         . = ALIGN(8);
 263         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 264                 __parainstructions = .;
 265                 *(.parainstructions)
 266                 __parainstructions_end = .;
 267         }
 268
 269         /*
 270          * struct alt_inst entries. From the header (alternative.h):
 271          * "Alternative instructions for different CPU types or capabilities"
 272          * Think locking instructions on spinlocks.
 273          */
 274         . = ALIGN(8);
 275         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 276                 __alt_instructions = .;
 277                 *(.altinstructions)
 278                 __alt_instructions_end = .;
 279         }
 280
 281         /*
 282          * And here are the replacement instructions. The linker sticks
 283          * them as binary blobs. The .altinstructions has enough data to
 284          * get the address and the length of them to patch the kernel safely.
 285          */
 286         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 287                 *(.altinstr_replacement)
 288         }
 289
 290         /*
 291          * struct iommu_table_entry entries are injected in this section.
 292          * It is an array of IOMMUs which during run time gets sorted depending
 293          * on its dependency order. After rootfs_initcall is complete
 294          * this section can be safely removed.
 295          */
 296         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 297                 __iommu_table = .;
 298                 *(.iommu_table)
 299                 __iommu_table_end = .;
 300         }
 301         . = ALIGN(8);
 302         /*
 303          * .exit.text is discard at runtime, not link time, to deal with
 304          *  references from .altinstructions and .eh_frame
 305          */
 306         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 307                 EXIT_TEXT
 308         }
 309
 310         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 311                 EXIT_DATA
 312         }
 313
 314 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 315         PERCPU(THREAD_SIZE)
 316 #endif
 317
 318         . = ALIGN(PAGE_SIZE);
 319
 320         /* freed after init ends here */
 321         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 322                 __init_end = .;
 323         }
 324
 325         /*
 326          * smp_locks might be freed after init
 327          * start/end must be page aligned
 328          */
 329         . = ALIGN(PAGE_SIZE);
 330         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 331                 __smp_locks = .;
 332                 *(.smp_locks)
 333                 . = ALIGN(PAGE_SIZE);
 334                 __smp_locks_end = .;
 335         }
 336
 337 #ifdef CONFIG_X86_64
 338         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 339                 NOSAVE_DATA
 340         }
 341 #endif
 342
 343         /* BSS */
 344         . = ALIGN(PAGE_SIZE);
 345         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 346                 __bss_start = .;
 347                 *(.bss..page_aligned)
 348                 *(.bss)
 349                 . = ALIGN(PAGE_SIZE);
 350                 __bss_stop = .;
 351         }
 352
 353         . = ALIGN(PAGE_SIZE);
 354         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 355                 __brk_base = .;
 356                 . += 64 * 1024;         /* 64k alignment slop space */
 357                 *(.brk_reservation)     /* areas brk users have reserved */
 358                 __brk_limit = .;
 359         }
 360
 361         _end = .;
 362
 363         STABS_DEBUG
 364         DWARF_DEBUG
 365
 366         /* Sections to be discarded */
 367         DISCARDS
 368         /DISCARD/ : { *(.eh_frame) }
 369 }
 370
 371
 372 #ifdef CONFIG_X86_32
 373 /*
 374  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 375  */
 376 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 377            "kernel image bigger than KERNEL_IMAGE_SIZE");
 378 #else
 379 /*
 380  * Per-cpu symbols which need to be offset from __per_cpu_load
 381  * for the boot processor.
 382  */
 383 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 384 INIT_PER_CPU(gdt_page);
 385 INIT_PER_CPU(irq_stack_union);
 386
 387 /*
 388  * Build-time check on the image size:
 389  */
 390 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 391            "kernel image bigger than KERNEL_IMAGE_SIZE");
 392
 393 #ifdef CONFIG_SMP
 394 . = ASSERT((irq_stack_union == 0),
 395            "irq_stack_union is not at start of per-cpu area");
 396 #endif
 397
 398 #endif /* CONFIG_X86_32 */
 399
 400 #ifdef CONFIG_KEXEC
 401 #include <asm/kexec.h>
 402
 403 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 404            "kexec control code size is too big");
 405 #endif
 406